gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(server.c)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_GNU_SOURCE
  29 AC_SYS_LARGEFILE
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_PROG_RANLIB
  36
  37 AC_ARG_PROGRAM
  38
  39 # We require a C++11 compiler.  Check if one is available, and if
  40 # necessary, set CXX_DIALECT to some -std=xxx switch.
  41 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  42
  43 AC_HEADER_STDC
  44
  45 # Set the 'development' global.
  46 . $srcdir/../../bfd/development.sh
  47
  48 GDB_AC_SELFTEST([
  49   srv_selftest_objs="gdbsupport/selftest.o"
  50 ])
  51
  52 ACX_NONCANONICAL_TARGET
  53 ACX_NONCANONICAL_HOST
  54
  55 # Dependency checking.
  56 ZW_CREATE_DEPDIR
  57
  58 # Create sub-directories for objects and dependencies.
  59 CONFIG_SRC_SUBDIR="arch gdbsupport"
  60 AC_SUBST(CONFIG_SRC_SUBDIR)
  61
  62 AC_CONFIG_COMMANDS([gdbdepdir],[
  63   for subdir in ${CONFIG_SRC_SUBDIR}
  64   do
  65       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  66   done],
  67   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  68
  69 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  70
  71 gnulib_extra_configure_args=
  72 # If large-file support is disabled, make sure gnulib does the same.
  73 if test "$enable_largefile" = no; then
  74 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  75 fi
  76
  77 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  78 # to find the the source subdir to be configured directly under
  79 # gdbserver/.  We need to build gnulib under some other directory not
  80 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  81 # build it in the same directory, when building in the source dir.
  82 ACX_CONFIGURE_DIR(["../../gnulib"], ["build-gnulib-gdbserver"],
  83                   ["$gnulib_extra_configure_args"])
  84
  85 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  86
  87 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  88                  sys/procfs.h linux/elf.h dnl
  89                  fcntl.h signal.h sys/file.h dnl
  90                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  91                  netinet/tcp.h arpa/inet.h)
  92 AC_FUNC_FORK
  93 AC_CHECK_FUNCS(pread pwrite pread64)
  94
  95 GDB_AC_COMMON
  96
  97 # Check the return and argument types of ptrace.
  98 GDB_AC_PTRACE
  99
 100 # Check for UST
 101 ustlibs=""
 102 ustinc=""
 103
 104 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 105                           Equivalent to --with-ust-include=PATH/include
 106                           plus --with-ust-lib=PATH/lib])
 107 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 108 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 109
 110 case $with_ust in
 111   no)
 112     ustlibs=
 113     ustinc=
 114     ;;
 115   "" | yes)
 116     ustlibs=" -lust "
 117     ustinc=""
 118     ;;
 119   *)
 120     ustlibs="-L$with_ust/lib -lust"
 121     ustinc="-I$with_ust/include "
 122     ;;
 123 esac
 124 if test "x$with_ust_include" != x; then
 125   ustinc="-I$with_ust_include "
 126 fi
 127 if test "x$with_ust_lib" != x; then
 128   ustlibs="-L$with_ust_lib -lust"
 129 fi
 130
 131 if test "x$with_ust" != "xno"; then
 132   saved_CFLAGS="$CFLAGS"
 133   CFLAGS="$CFLAGS $ustinc"
 134   AC_MSG_CHECKING([for ust])
 135   AC_TRY_COMPILE([
 136 #define CONFIG_UST_GDB_INTEGRATION
 137 #include <ust/ust.h>
 138   ],[],
 139   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 140   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 141   CFLAGS="$saved_CFLAGS"
 142 fi
 143
 144 # Flags needed for UST
 145 AC_SUBST(ustlibs)
 146 AC_SUBST(ustinc)
 147
 148 AM_GDB_WARNINGS
 149
 150 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 151 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 152 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 153 dnl augment LIBS.
 154 old_LIBS="$LIBS"
 155 LIBS="$LIBS -ldl"
 156 AC_CHECK_FUNCS(dladdr)
 157 LIBS="$old_LIBS"
 158
 159 libiberty_INIT
 160
 161 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 162
 163 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 164 # Older amd64 Linux's don't have the fs_base and gs_base members of
 165 # `struct user_regs_struct'.
 166 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 167      [], [], [#include <sys/types.h>
 168 #include <sys/user.h>])
 169
 170
 171 AC_CHECK_TYPES(socklen_t, [], [],
 172 [#include <sys/types.h>
 173 #include <sys/socket.h>
 174 ])
 175
 176 case "${target}" in
 177   *-android*)
 178     # Starting with NDK version 9, <elf.h> actually includes definitions
 179     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 180     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 181     # leading to conflicts with the defintions from <linux/elf.h>.
 182     # This makes it impossible for us to include both <elf.h> and
 183     # <linux/elf.h>, which means that, in practice, we do not have
 184     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 185     # Therefore, do not try to auto-detect availability, as it would
 186     # get it wrong on this platform.
 187     ;;
 188   *)
 189     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 190     #include <elf.h>
 191     )
 192 esac
 193
 194 ACX_PKGVERSION([GDB])
 195 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 196 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 197 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 198
 199 # Check for various supplementary target information (beyond the
 200 # triplet) which might affect the choices in configure.srv.
 201 case "${target}" in
 202 changequote(,)dnl
 203   i[34567]86-*-linux*)
 204 changequote([,])dnl
 205     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 206                    [save_CPPFLAGS="$CPPFLAGS"
 207                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 208                     AC_EGREP_CPP([got it], [
 209 #if __x86_64__
 210 got it
 211 #endif
 212                  ], [gdb_cv_i386_is_x86_64=yes],
 213                     [gdb_cv_i386_is_x86_64=no])
 214                     CPPFLAGS="$save_CPPFLAGS"])
 215     ;;
 216
 217   x86_64-*-linux*)
 218     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 219                    [save_CPPFLAGS="$CPPFLAGS"
 220                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 221                     AC_EGREP_CPP([got it], [
 222 #if __x86_64__ && __ILP32__
 223 got it
 224 #endif
 225                  ], [gdb_cv_x86_is_x32=yes],
 226                     [gdb_cv_x86_is_x32=no])
 227                     CPPFLAGS="$save_CPPFLAGS"])
 228     ;;
 229
 230   m68k-*-*)
 231     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 232                    [save_CPPFLAGS="$CPPFLAGS"
 233                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 234                     AC_EGREP_CPP([got it], [
 235 #ifdef __mcoldfire__
 236 got it
 237 #endif
 238                  ], [gdb_cv_m68k_is_coldfire=yes],
 239                     [gdb_cv_m68k_is_coldfire=no])
 240                     CPPFLAGS="$save_CPPFLAGS"])
 241     ;;
 242 esac
 243
 244 . ${srcdir}/configure.srv
 245
 246 if test "${srv_mingwce}" = "yes"; then
 247   LIBS="$LIBS -lws2"
 248 elif test "${srv_mingw}" = "yes"; then
 249   # WIN32APILIBS is set by GDB_AC_COMMON.
 250   LIBS="$LIBS $WIN32APILIBS"
 251 elif test "${srv_qnx}" = "yes"; then
 252   LIBS="$LIBS -lsocket"
 253 elif test "${srv_lynxos}" = "yes"; then
 254   LIBS="$LIBS -lnetinet"
 255 fi
 256
 257 if test "${srv_linux_usrregs}" = "yes"; then
 258   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 259             [Define if the target supports PTRACE_PEEKUSR for register ]
 260             [access.])
 261 fi
 262
 263 if test "${srv_linux_regsets}" = "yes"; then
 264   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 265             [Define if the target supports register sets.])
 266
 267   AC_MSG_CHECKING(for PTRACE_GETREGS)
 268   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 269   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 270                   [PTRACE_GETREGS;],
 271                   [gdbsrv_cv_have_ptrace_getregs=yes],
 272                   [gdbsrv_cv_have_ptrace_getregs=no])])
 273   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 274   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 275     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 276               [Define if the target supports PTRACE_GETREGS for register ]
 277               [access.])
 278   fi
 279
 280   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 281   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 282   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 283                   [PTRACE_GETFPXREGS;],
 284                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 285                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 286   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 287   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 288     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 289               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 290               [register access.])
 291   fi
 292 fi
 293
 294 if test "${srv_linux_btrace}" = "yes"; then
 295   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 296             [Define if the target supports branch tracing.])
 297 fi
 298
 299 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 300 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 301   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 302 fi
 303
 304 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 305 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 306   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 307 fi
 308
 309 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 310 dnl needs it (and gdbreplay doesn't).
 311 old_LIBS="$LIBS"
 312 AC_CHECK_LIB(dl, dlopen)
 313 LIBS="$old_LIBS"
 314
 315 srv_thread_depfiles=
 316 srv_libs=
 317
 318 if test "$srv_linux_thread_db" = "yes"; then
 319   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 320     srv_libs="-ldl"
 321     AC_MSG_CHECKING(for the dynamic export flag)
 322     old_LDFLAGS="$LDFLAGS"
 323     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 324     # supported there.
 325     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 326     LDFLAGS="$LDFLAGS $RDYNAMIC"
 327     AC_TRY_LINK([], [],
 328                 [found="-Wl,--dynamic-list"
 329                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 330                 [RDYNAMIC="-rdynamic"
 331                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 332                  AC_TRY_LINK([], [],
 333                              [found="-rdynamic"],
 334                              [found="no"
 335                               RDYNAMIC=""])])
 336     AC_SUBST(RDYNAMIC)
 337     LDFLAGS="$old_LDFLAGS"
 338     AC_MSG_RESULT($found)
 339   else
 340     srv_libs="-lthread_db"
 341   fi
 342
 343   srv_thread_depfiles="thread-db.o proc-service.o"
 344   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 345   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 346   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 347                   [gdbsrv_cv_have_td_version=yes],
 348                   [gdbsrv_cv_have_td_version=no])])
 349   if test "$gdbsrv_cv_have_td_version" = yes; then
 350     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 351   fi
 352 fi
 353
 354 AC_ARG_WITH(libthread-db,
 355 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 356 [srv_libthread_db_path="${withval}"
 357   srv_libs="$srv_libthread_db_path"
 358 ])
 359
 360 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 361   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 362 fi
 363
 364 if test "$srv_xmlfiles" != ""; then
 365   srv_xmlbuiltin="xml-builtin.o"
 366   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 367
 368   tmp_xmlfiles=$srv_xmlfiles
 369   srv_xmlfiles=""
 370   for f in $tmp_xmlfiles; do
 371     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 372   done
 373 fi
 374
 375 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_selftest_objs"
 376 GDBSERVER_LIBS="$srv_libs"
 377
 378 dnl Check whether the target supports __sync_*_compare_and_swap.
 379 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 380                 gdbsrv_cv_have_sync_builtins, [
 381 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 382                 gdbsrv_cv_have_sync_builtins=yes,
 383                 gdbsrv_cv_have_sync_builtins=no)])
 384 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 385   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 386     [Define to 1 if the target supports __sync_*_compare_and_swap])
 387 fi
 388
 389 dnl Check for -fvisibility=hidden support in the compiler.
 390 saved_cflags="$CFLAGS"
 391 CFLAGS="$CFLAGS -fvisibility=hidden"
 392 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 393                         [gdbsrv_cv_have_visibility_hidden=yes],
 394                         [gdbsrv_cv_have_visibility_hidden=no])
 395 CFLAGS="$saved_cflags"
 396
 397 IPA_DEPFILES=""
 398 extra_libraries=""
 399
 400 # check whether to enable the inprocess agent
 401 if test "$ipa_obj" != "" \
 402    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 403    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 404    have_ipa=true
 405 else
 406    have_ipa=false
 407 fi
 408
 409 AC_ARG_ENABLE(inprocess-agent,
 410 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 411 [case "$enableval" in
 412   yes) want_ipa=true ;;
 413   no) want_ipa=false ;;
 414   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 415 esac],
 416 [want_ipa=$have_ipa])
 417
 418 if $want_ipa ; then
 419    if $have_ipa ; then
 420      IPA_DEPFILES="$ipa_obj"
 421      extra_libraries="$extra_libraries libinproctrace.so"
 422    else
 423      AC_MSG_ERROR([inprocess agent not supported for this target])
 424    fi
 425 fi
 426
 427 AC_SUBST(GDBSERVER_DEPFILES)
 428 AC_SUBST(GDBSERVER_LIBS)
 429 AC_SUBST(srv_xmlbuiltin)
 430 AC_SUBST(srv_xmlfiles)
 431 AC_SUBST(IPA_DEPFILES)
 432 AC_SUBST(extra_libraries)
 433
 434 GNULIB=build-gnulib-gdbserver/import
 435
 436 GNULIB_STDINT_H=
 437 if test x"$STDINT_H" != x; then
 438   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 439 fi
 440 AC_SUBST(GNULIB_STDINT_H)
 441
 442 AC_CONFIG_FILES([Makefile])
 443
 444 AC_OUTPUT