gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 AC_HEADER_STDC
  46
  47 # Set the 'development' global.
  48 . $srcdir/../../bfd/development.sh
  49
  50 # Enable -lmcheck by default (it provides cheap-enough memory
  51 # mangling), but turn it off for releases.
  52 if $development; then
  53   libmcheck_default=yes
  54 else
  55   libmcheck_default=no
  56 fi
  57 GDB_AC_LIBMCHECK(${libmcheck_default})
  58
  59 ACX_NONCANONICAL_TARGET
  60 ACX_NONCANONICAL_HOST
  61
  62 # Dependency checking.
  63 ZW_CREATE_DEPDIR
  64 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  65
  66 gnulib_extra_configure_args=
  67 # If large-file support is disabled, make sure gnulib does the same.
  68 if test "$enable_largefile" = no; then
  69 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  70 fi
  71
  72 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  73 # to find the the source subdir to be configured directly under
  74 # gdbserver/.  We need to build gnulib under some other directory not
  75 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  76 # build it in the same directory, when building in the source dir.
  77 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  78                   ["$gnulib_extra_configure_args"])
  79
  80 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  81
  82 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  83                  proc_service.h sys/procfs.h linux/elf.h dnl
  84                  fcntl.h signal.h sys/file.h dnl
  85                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  86                  netinet/tcp.h arpa/inet.h)
  87 AC_FUNC_FORK
  88 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
  89
  90 GDB_AC_COMMON
  91
  92 # Check the return and argument types of ptrace.
  93 GDB_AC_PTRACE
  94
  95 # Check for UST
  96 ustlibs=""
  97 ustinc=""
  98
  99 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 100                           Equivalent to --with-ust-include=PATH/include
 101                           plus --with-ust-lib=PATH/lib])
 102 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 103 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 104
 105 case $with_ust in
 106   no)
 107     ustlibs=
 108     ustinc=
 109     ;;
 110   "" | yes)
 111     ustlibs=" -lust "
 112     ustinc=""
 113     ;;
 114   *)
 115     ustlibs="-L$with_ust/lib -lust"
 116     ustinc="-I$with_ust/include "
 117     ;;
 118 esac
 119 if test "x$with_ust_include" != x; then
 120   ustinc="-I$with_ust_include "
 121 fi
 122 if test "x$with_ust_lib" != x; then
 123   ustlibs="-L$with_ust_lib -lust"
 124 fi
 125
 126 if test "x$with_ust" != "xno"; then
 127   saved_CFLAGS="$CFLAGS"
 128   CFLAGS="$CFLAGS $ustinc"
 129   AC_MSG_CHECKING([for ust])
 130   AC_TRY_COMPILE([
 131 #define CONFIG_UST_GDB_INTEGRATION
 132 #include <ust/ust.h>
 133   ],[],
 134   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 135   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 136   CFLAGS="$saved_CFLAGS"
 137 fi
 138
 139 # Flags needed for UST
 140 AC_SUBST(ustlibs)
 141 AC_SUBST(ustinc)
 142
 143 AM_GDB_WARNINGS
 144 dnl The codebase isn't clean yet with this flag.
 145 case " $WARN_CFLAGS " in
 146 *" -Wmissing-prototypes "*)
 147   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 148   ;;
 149 esac
 150
 151 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 152 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 153 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 154 dnl augment LIBS.
 155 old_LIBS="$LIBS"
 156 LIBS="$LIBS -ldl"
 157 AC_CHECK_FUNCS(dladdr)
 158 LIBS="$old_LIBS"
 159
 160 libiberty_INIT
 161
 162 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 163
 164 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 165
 166 AC_CHECK_TYPES(socklen_t, [], [],
 167 [#include <sys/types.h>
 168 #include <sys/socket.h>
 169 ])
 170
 171 case "${target}" in
 172   *-android*)
 173     # Starting with NDK version 9, <elf.h> actually includes definitions
 174     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 175     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 176     # leading to conflicts with the defintions from <linux/elf.h>.
 177     # This makes it impossible for us to include both <elf.h> and
 178     # <linux/elf.h>, which means that, in practice, we do not have
 179     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 180     # Therefore, do not try to auto-detect availability, as it would
 181     # get it wrong on this platform.
 182     ;;
 183   *)
 184     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 185     #include <elf.h>
 186     )
 187 esac
 188
 189 ACX_PKGVERSION([GDB])
 190 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 191 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 192 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 193
 194 # Check for various supplementary target information (beyond the
 195 # triplet) which might affect the choices in configure.srv.
 196 case "${target}" in
 197 changequote(,)dnl
 198   i[34567]86-*-linux*)
 199 changequote([,])dnl
 200     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 201                    [save_CPPFLAGS="$CPPFLAGS"
 202                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 203                     AC_EGREP_CPP([got it], [
 204 #if __x86_64__
 205 got it
 206 #endif
 207                  ], [gdb_cv_i386_is_x86_64=yes],
 208                     [gdb_cv_i386_is_x86_64=no])
 209                     CPPFLAGS="$save_CPPFLAGS"])
 210     ;;
 211
 212   x86_64-*-linux*)
 213     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 214                    [save_CPPFLAGS="$CPPFLAGS"
 215                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 216                     AC_EGREP_CPP([got it], [
 217 #if __x86_64__ && __ILP32__
 218 got it
 219 #endif
 220                  ], [gdb_cv_x86_is_x32=yes],
 221                     [gdb_cv_x86_is_x32=no])
 222                     CPPFLAGS="$save_CPPFLAGS"])
 223     ;;
 224
 225   m68k-*-*)
 226     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 227                    [save_CPPFLAGS="$CPPFLAGS"
 228                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 229                     AC_EGREP_CPP([got it], [
 230 #ifdef __mcoldfire__
 231 got it
 232 #endif
 233                  ], [gdb_cv_m68k_is_coldfire=yes],
 234                     [gdb_cv_m68k_is_coldfire=no])
 235                     CPPFLAGS="$save_CPPFLAGS"])
 236     ;;
 237 esac
 238
 239 . ${srcdir}/configure.srv
 240
 241 # Add in the common host objects.
 242 . ${srcdir}/../common/common.host
 243 srv_host_obs="$common_host_obs"
 244
 245 if test "${srv_mingwce}" = "yes"; then
 246   LIBS="$LIBS -lws2"
 247 elif test "${srv_mingw}" = "yes"; then
 248   LIBS="$LIBS -lws2_32"
 249 elif test "${srv_qnx}" = "yes"; then
 250   LIBS="$LIBS -lsocket"
 251 elif test "${srv_lynxos}" = "yes"; then
 252   LIBS="$LIBS -lnetinet"
 253 fi
 254
 255 if test "${srv_mingw}" = "yes"; then
 256   AC_DEFINE(USE_WIN32API, 1,
 257             [Define if we should use the Windows API, instead of the
 258              POSIX API.  On Windows, we use the Windows API when
 259              building for MinGW, but the POSIX API when building
 260              for Cygwin.])
 261 fi
 262
 263 if test "${srv_linux_usrregs}" = "yes"; then
 264   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 265             [Define if the target supports PTRACE_PEEKUSR for register ]
 266             [access.])
 267 fi
 268
 269 if test "${srv_linux_regsets}" = "yes"; then
 270   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 271             [Define if the target supports register sets.])
 272
 273   AC_MSG_CHECKING(for PTRACE_GETREGS)
 274   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 275   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 276                   [PTRACE_GETREGS;],
 277                   [gdbsrv_cv_have_ptrace_getregs=yes],
 278                   [gdbsrv_cv_have_ptrace_getregs=no])])
 279   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 280   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 281     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 282               [Define if the target supports PTRACE_GETREGS for register ]
 283               [access.])
 284   fi
 285
 286   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 287   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 288   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 289                   [PTRACE_GETFPXREGS;],
 290                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 291                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 292   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 293   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 294     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 295               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 296               [register access.])
 297   fi
 298 fi
 299
 300 if test "${srv_linux_btrace}" = "yes"; then
 301   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 302             [Define if the target supports branch tracing.])
 303 fi
 304
 305 if test "$ac_cv_header_sys_procfs_h" = yes; then
 306   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 307   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 308   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 309   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 310   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 311 fi
 312
 313 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 314 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 315   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 316 fi
 317
 318 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 319 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 320   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 321 fi
 322
 323 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 324 dnl needs it (and gdbreplay doesn't).
 325 old_LIBS="$LIBS"
 326 AC_CHECK_LIB(dl, dlopen)
 327 LIBS="$old_LIBS"
 328
 329 srv_thread_depfiles=
 330 srv_libs=
 331
 332 if test "$srv_linux_thread_db" = "yes"; then
 333   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 334     srv_libs="-ldl"
 335     AC_MSG_CHECKING(for the dynamic export flag)
 336     old_LDFLAGS="$LDFLAGS"
 337     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 338     # supported there.
 339     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 340     LDFLAGS="$LDFLAGS $RDYNAMIC"
 341     AC_TRY_LINK([], [],
 342                 [found="-Wl,--dynamic-list"
 343                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 344                 [RDYNAMIC="-rdynamic"
 345                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 346                  AC_TRY_LINK([], [],
 347                              [found="-rdynamic"],
 348                              [found="no"
 349                               RDYNAMIC=""])])
 350     AC_SUBST(RDYNAMIC)
 351     LDFLAGS="$old_LDFLAGS"
 352     AC_MSG_RESULT($found)
 353   else
 354     srv_libs="-lthread_db"
 355   fi
 356
 357   srv_thread_depfiles="thread-db.o proc-service.o"
 358   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 359   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 360   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 361                   [gdbsrv_cv_have_td_version=yes],
 362                   [gdbsrv_cv_have_td_version=no])])
 363   if test $gdbsrv_cv_have_td_version = yes; then
 364     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 365   fi
 366 fi
 367
 368 AC_ARG_WITH(libthread-db,
 369 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 370 [srv_libthread_db_path="${withval}"
 371   srv_libs="$srv_libthread_db_path"
 372 ])
 373
 374 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 375   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 376 fi
 377
 378 if test "$srv_xmlfiles" != ""; then
 379   srv_xmlbuiltin="xml-builtin.o"
 380   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 381
 382   tmp_xmlfiles=$srv_xmlfiles
 383   srv_xmlfiles=""
 384   for f in $tmp_xmlfiles; do
 385     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 386   done
 387 fi
 388
 389 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 390 GDBSERVER_LIBS="$srv_libs"
 391
 392 dnl Check whether the target supports __sync_*_compare_and_swap.
 393 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 394                 gdbsrv_cv_have_sync_builtins, [
 395 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 396                 gdbsrv_cv_have_sync_builtins=yes,
 397                 gdbsrv_cv_have_sync_builtins=no)])
 398 if test $gdbsrv_cv_have_sync_builtins = yes; then
 399   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 400     [Define to 1 if the target supports __sync_*_compare_and_swap])
 401 fi
 402
 403 dnl Check for -fvisibility=hidden support in the compiler.
 404 saved_cflags="$CFLAGS"
 405 CFLAGS="$CFLAGS -fvisibility=hidden"
 406 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 407                         [gdbsrv_cv_have_visibility_hidden=yes],
 408                         [gdbsrv_cv_have_visibility_hidden=no])
 409 CFLAGS="$saved_cflags"
 410
 411 dnl Check if we can disable the virtual address space randomization.
 412 dnl The functionality of setarch -R.
 413 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 414 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 415 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 416 #       define ADDR_NO_RANDOMIZE 0x0040000
 417 #      endif
 418        /* Test the flag could be set and stays set.  */
 419        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 420        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 421            return 1])])
 422 AC_RUN_IFELSE([PERSONALITY_TEST],
 423               [gdbsrv_cv_have_personality=true],
 424               [gdbsrv_cv_have_personality=false],
 425               [AC_LINK_IFELSE([PERSONALITY_TEST],
 426                               [gdbsrv_cv_have_personality=true],
 427                               [gdbsrv_cv_have_personality=false])])
 428 if $gdbsrv_cv_have_personality
 429 then
 430     AC_DEFINE([HAVE_PERSONALITY], 1,
 431               [Define if you support the personality syscall.])
 432 fi
 433
 434
 435 IPA_DEPFILES=""
 436 extra_libraries=""
 437
 438 # check whether to enable the inprocess agent
 439 if test "$ipa_obj" != "" \
 440    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 441    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 442    have_ipa=true
 443 else
 444    have_ipa=false
 445 fi
 446
 447 AC_ARG_ENABLE(inprocess-agent,
 448 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 449 [case "$enableval" in
 450   yes) want_ipa=true ;;
 451   no) want_ipa=false ;;
 452   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 453 esac],
 454 [want_ipa=$have_ipa])
 455
 456 if $want_ipa ; then
 457    if $have_ipa ; then
 458      IPA_DEPFILES="$ipa_obj"
 459      extra_libraries="$extra_libraries libinproctrace.so"
 460    else
 461      AC_MSG_ERROR([inprocess agent not supported for this target])
 462    fi
 463 fi
 464
 465 AC_SUBST(GDBSERVER_DEPFILES)
 466 AC_SUBST(GDBSERVER_LIBS)
 467 AC_SUBST(srv_xmlbuiltin)
 468 AC_SUBST(srv_xmlfiles)
 469 AC_SUBST(IPA_DEPFILES)
 470 AC_SUBST(extra_libraries)
 471
 472 GNULIB=build-gnulib-gdbserver/import
 473
 474 GNULIB_STDINT_H=
 475 if test x"$STDINT_H" != x; then
 476   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 477 fi
 478 AC_SUBST(GNULIB_STDINT_H)
 479
 480 AC_CONFIG_FILES([Makefile],
 481 [case x$CONFIG_HEADERS in
 482 xconfig.h:config.in)
 483 echo > stamp-h ;;
 484 esac
 485 ])
 486
 487 AC_OUTPUT