gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000, 2002-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 gl_EARLY
  30 AC_GNU_SOURCE
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35
  36 AC_ARG_PROGRAM
  37
  38 AC_HEADER_STDC
  39 AC_HEADER_DIRENT
  40
  41 AC_FUNC_ALLOCA
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45
  46 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  47                  proc_service.h sys/procfs.h thread_db.h linux/elf.h dnl
  48                  stdlib.h unistd.h dnl
  49                  errno.h fcntl.h signal.h sys/file.h malloc.h dnl
  50                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  51                  netinet/tcp.h arpa/inet.h sys/wait.h sys/un.h)
  52 AC_CHECK_FUNCS(pread pwrite pread64 readlink)
  53 AC_REPLACE_FUNCS(vasprintf vsnprintf)
  54
  55 # Check for UST
  56 ustlibs=""
  57 ustinc=""
  58
  59 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  60                           Equivalent to --with-ust-include=PATH/include
  61                           plus --with-ust-lib=PATH/lib])
  62 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
  63 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
  64
  65 case $with_ust in
  66   no)
  67     ustlibs=
  68     ustinc=
  69     ;;
  70   "" | yes)
  71     ustlibs=" -lust "
  72     ustinc=""
  73     ;;
  74   *)
  75     ustlibs="-L$with_ust/lib -lust"
  76     ustinc="-I$with_ust/include "
  77     ;;
  78 esac
  79 if test "x$with_ust_include" != x; then
  80   ustinc="-I$with_ust_include "
  81 fi
  82 if test "x$with_ust_lib" != x; then
  83   ustlibs="-L$with_ust_lib -lust"
  84 fi
  85
  86 if test "x$with_ust" != "xno"; then
  87   saved_CFLAGS="$CFLAGS"
  88   CFLAGS="$CFLAGS $ustinc"
  89   AC_MSG_CHECKING([for ust])
  90   AC_TRY_COMPILE([
  91 #define CONFIG_UST_GDB_INTEGRATION
  92 #include <ust/ust.h>
  93   ],[],
  94   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
  95   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
  96   CFLAGS="$saved_CFLAGS"
  97 fi
  98
  99 # Flags needed for UST
 100 AC_SUBST(ustlibs)
 101 AC_SUBST(ustinc)
 102
 103 AC_ARG_ENABLE(werror,
 104   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
 105   [case "${enableval}" in
 106      yes | y) ERROR_ON_WARNING="yes" ;;
 107      no | n)  ERROR_ON_WARNING="no" ;;
 108      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
 109    esac])
 110
 111 # Enable -Werror by default when using gcc
 112 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
 113     ERROR_ON_WARNING=yes
 114 fi
 115
 116 WERROR_CFLAGS=""
 117 if test "${ERROR_ON_WARNING}" = yes ; then
 118     WERROR_CFLAGS="-Werror"
 119 fi
 120
 121 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
 122 -Wformat-nonliteral -Wno-char-subscripts"
 123
 124 WARN_CFLAGS=""
 125 if test "x$GCC" = xyes
 126 then
 127     AC_MSG_CHECKING(compiler warning flags)
 128     # Separate out the -Werror flag as some files just cannot be
 129     # compiled with it enabled.
 130     for w in ${build_warnings}; do
 131         case $w in
 132         -Werr*) WERROR_CFLAGS=-Werror ;;
 133         *) # Check that GCC accepts it
 134             saved_CFLAGS="$CFLAGS"
 135             CFLAGS="$CFLAGS $w"
 136             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 137             CFLAGS="$saved_CFLAGS"
 138         esac
 139     done
 140     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 141 fi
 142 AC_SUBST(WARN_CFLAGS)
 143 AC_SUBST(WERROR_CFLAGS)
 144
 145 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 146 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 147 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 148 dnl augment LIBS.
 149 old_LIBS="$LIBS"
 150 LIBS="$LIBS -ldl"
 151 AC_CHECK_FUNCS(dladdr)
 152 LIBS="$old_LIBS"
 153
 154 have_errno=no
 155 AC_MSG_CHECKING(for errno)
 156 AC_TRY_LINK([
 157 #if HAVE_ERRNO_H
 158 #include <errno.h>
 159 #endif], [static int x; x = errno;],
 160   [AC_MSG_RESULT(yes - in errno.h); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) have_errno=yes])
 161 if test $have_errno = no; then
 162 AC_TRY_LINK([
 163 #if HAVE_ERRNO_H
 164 #include <errno.h>
 165 #endif], [extern int errno; static int x; x = errno;],
 166   [AC_MSG_RESULT(yes - must define); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) AC_DEFINE(MUST_DEFINE_ERRNO, 1, [Checking if errno must be defined])],
 167   [AC_MSG_RESULT(no)])
 168 fi
 169
 170 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 171
 172 AC_CHECK_TYPES(socklen_t, [], [],
 173 [#include <sys/types.h>
 174 #include <sys/socket.h>
 175 ])
 176
 177 AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 178 #include <elf.h>
 179 )
 180
 181 ACX_PKGVERSION([GDB])
 182 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 183 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 184 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 185
 186 # Check for various supplementary target information (beyond the
 187 # triplet) which might affect the choices in configure.srv.
 188 case "${target}" in
 189 changequote(,)dnl
 190   i[34567]86-*-linux*)
 191 changequote([,])dnl
 192     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 193                    [save_CPPFLAGS="$CPPFLAGS"
 194                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 195                     AC_EGREP_CPP([got it], [
 196 #if __x86_64__
 197 got it
 198 #endif
 199                  ], [gdb_cv_i386_is_x86_64=yes],
 200                     [gdb_cv_i386_is_x86_64=no])
 201                     CPPFLAGS="$save_CPPFLAGS"])
 202     ;;
 203   m68k-*-*)
 204     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 205                    [save_CPPFLAGS="$CPPFLAGS"
 206                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 207                     AC_EGREP_CPP([got it], [
 208 #ifdef __mcoldfire__
 209 got it
 210 #endif
 211                  ], [gdb_cv_m68k_is_coldfire=yes],
 212                     [gdb_cv_m68k_is_coldfire=no])
 213                     CPPFLAGS="$save_CPPFLAGS"])
 214     ;;
 215 esac
 216
 217 . ${srcdir}/configure.srv
 218
 219 if test "${srv_mingwce}" = "yes"; then
 220   LIBS="$LIBS -lws2"
 221 elif test "${srv_mingw}" = "yes"; then
 222   LIBS="$LIBS -lws2_32"
 223 elif test "${srv_qnx}" = "yes"; then
 224   LIBS="$LIBS -lsocket"
 225 elif test "${srv_lynxos}" = "yes"; then
 226   LIBS="$LIBS -lnetinet"
 227 fi
 228
 229 if test "${srv_mingw}" = "yes"; then
 230   AC_DEFINE(USE_WIN32API, 1,
 231             [Define if we should use the Windows API, instead of the
 232              POSIX API.  On Windows, we use the Windows API when
 233              building for MinGW, but the POSIX API when building
 234              for Cygwin.])
 235 fi
 236
 237 if test "${srv_linux_usrregs}" = "yes"; then
 238   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 239             [Define if the target supports PTRACE_PEEKUSR for register ]
 240             [access.])
 241 fi
 242
 243 if test "${srv_linux_regsets}" = "yes"; then
 244   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 245             [Define if the target supports register sets.])
 246
 247   AC_MSG_CHECKING(for PTRACE_GETREGS)
 248   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 249   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 250                   [PTRACE_GETREGS;],
 251                   [gdbsrv_cv_have_ptrace_getregs=yes],
 252                   [gdbsrv_cv_have_ptrace_getregs=no])])
 253   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 254   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 255     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 256               [Define if the target supports PTRACE_GETREGS for register ]
 257               [access.])
 258   fi
 259
 260   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 261   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 262   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 263                   [PTRACE_GETFPXREGS;],
 264                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 265                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 266   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 267   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 268     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 269               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 270               [register access.])
 271   fi
 272 fi
 273
 274 if test "$ac_cv_header_sys_procfs_h" = yes; then
 275   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 276   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 277   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 278   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 279 fi
 280
 281 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 282 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 283   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 284 fi
 285
 286 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 287 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 288   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 289 fi
 290
 291 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 292 dnl needs it (and gdbreplay doesn't).
 293 old_LIBS="$LIBS"
 294 AC_CHECK_LIB(dl, dlopen)
 295 LIBS="$old_LIBS"
 296
 297 srv_thread_depfiles=
 298 srv_libs=
 299 USE_THREAD_DB=
 300
 301 if test "$srv_linux_thread_db" = "yes"; then
 302   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 303     srv_libs="-ldl"
 304     AC_MSG_CHECKING(for the dynamic export flag)
 305     old_LDFLAGS="$LDFLAGS"
 306     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 307     # supported there.
 308     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 309     LDFLAGS="$LDFLAGS $RDYNAMIC"
 310     AC_TRY_LINK([], [],
 311                 [found="-Wl,--dynamic-list"
 312                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 313                 [RDYNAMIC="-rdynamic"
 314                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 315                  AC_TRY_LINK([], [],
 316                              [found="-rdynamic"],
 317                              [found="no"
 318                               RDYNAMIC=""])])
 319     AC_SUBST(RDYNAMIC)
 320     LDFLAGS="$old_LDFLAGS"
 321     AC_MSG_RESULT($found)
 322   else
 323     srv_libs="-lthread_db"
 324   fi
 325
 326   srv_thread_depfiles="thread-db.o proc-service.o"
 327   USE_THREAD_DB="-DUSE_THREAD_DB"
 328   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 329   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 330                   [gdbsrv_cv_have_td_version=yes],
 331                   [gdbsrv_cv_have_td_version=no])])
 332   if test $gdbsrv_cv_have_td_version = yes; then
 333     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 334   fi
 335 fi
 336
 337 AC_ARG_WITH(libthread-db,
 338 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 339 [srv_libthread_db_path="${withval}"
 340   srv_libs="$srv_libthread_db_path"
 341 ])
 342
 343 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 344   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 345 fi
 346
 347 if test "$srv_xmlfiles" != ""; then
 348   srv_xmlbuiltin="xml-builtin.o"
 349   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 350
 351   tmp_xmlfiles=$srv_xmlfiles
 352   srv_xmlfiles=""
 353   for f in $tmp_xmlfiles; do
 354     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 355   done
 356 fi
 357
 358 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 359 GDBSERVER_LIBS="$srv_libs"
 360
 361 dnl Check whether the target supports __sync_*_compare_and_swap.
 362 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 363                 gdbsrv_cv_have_sync_builtins, [
 364 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 365                 gdbsrv_cv_have_sync_builtins=yes,
 366                 gdbsrv_cv_have_sync_builtins=no)])
 367 if test $gdbsrv_cv_have_sync_builtins = yes; then
 368   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 369     [Define to 1 if the target supports __sync_*_compare_and_swap])
 370 fi
 371
 372 dnl Check for -fvisibility=hidden support in the compiler.
 373 saved_cflags="$CFLAGS"
 374 CFLAGS="$CFLAGS -fvisibility=hidden"
 375 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 376                         [gdbsrv_cv_have_visibility_hidden=yes],
 377                         [gdbsrv_cv_have_visibility_hidden=no])
 378 CFLAGS="$saved_cflags"
 379
 380 dnl Check if we can disable the virtual address space randomization.
 381 dnl The functionality of setarch -R.
 382 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 383 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 384 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 385 #       define ADDR_NO_RANDOMIZE 0x0040000
 386 #      endif
 387        /* Test the flag could be set and stays set.  */
 388        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 389        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 390            return 1])])
 391 AC_RUN_IFELSE([PERSONALITY_TEST],
 392               [gdbsrv_cv_have_personality=true],
 393               [gdbsrv_cv_have_personality=false],
 394               [AC_LINK_IFELSE([PERSONALITY_TEST],
 395                               [gdbsrv_cv_have_personality=true],
 396                               [gdbsrv_cv_have_personality=false])])
 397 if $gdbsrv_cv_have_personality
 398 then
 399     AC_DEFINE([HAVE_PERSONALITY], 1,
 400               [Define if you support the personality syscall.])
 401 fi
 402
 403
 404 IPA_DEPFILES=""
 405 extra_libraries=""
 406
 407 # check whether to enable the inprocess agent
 408 if test "$ipa_obj" != "" \
 409    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 410    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 411    have_ipa=true
 412 else
 413    have_ipa=false
 414 fi
 415
 416 AC_ARG_ENABLE(inprocess-agent,
 417 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 418 [case "$enableval" in
 419   yes) want_ipa=true ;;
 420   no) want_ipa=false ;;
 421   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 422 esac],
 423 [want_ipa=$have_ipa])
 424
 425 if $want_ipa ; then
 426    if $have_ipa ; then
 427      IPA_DEPFILES="$ipa_obj"
 428      extra_libraries="$extra_libraries libinproctrace.so"
 429    else
 430      AC_MSG_ERROR([inprocess agent not supported for this target])
 431    fi
 432 fi
 433
 434 AC_SUBST(GDBSERVER_DEPFILES)
 435 AC_SUBST(GDBSERVER_LIBS)
 436 AC_SUBST(USE_THREAD_DB)
 437 AC_SUBST(srv_xmlbuiltin)
 438 AC_SUBST(srv_xmlfiles)
 439 AC_SUBST(IPA_DEPFILES)
 440 AC_SUBST(extra_libraries)
 441
 442 gl_INIT
 443 # GDBserver does not use automake, but gnulib does.  This line lets
 444 # us generate its Makefile.in.
 445 AM_INIT_AUTOMAKE(gdbserver, UNUSED-VERSION, [no-define])
 446
 447 GNULIB_STDINT_H=
 448 if test x"$STDINT_H" != x; then
 449   GNULIB_STDINT_H=gnulib/$STDINT_H
 450 fi
 451 AC_SUBST(GNULIB_STDINT_H)
 452
 453 AC_OUTPUT(Makefile gnulib/import/Makefile:${srcdir}/../gnulib/import/Makefile.in,
 454 [case x$CONFIG_HEADERS in
 455 xconfig.h:config.in)
 456 echo > stamp-h ;;
 457 esac
 458 ])