gdb/testsuite/configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright 2002, 2003, 2004, 2005
   5 # Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22 AC_PREREQ(2.59)
  23 AC_INIT(gdb.base)
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 ACX_NONCANONICAL_TARGET
  30
  31 # Add HP-specific tests when appropriate.
  32 case $target in
  33   hppa*-*-hpux*)
  34     AC_CONFIG_SUBDIRS(gdb.hp) ;;
  35 esac
  36
  37 # With stabs.
  38 AC_ARG_WITH(stabs,
  39 [  --with-stabs            arrange to use stabs instead of host debug format],,
  40 [# We enable stabs tests by default on selected targets.
  41 case $target in
  42    powerpc-*-aix* \
  43  | rs6000-*-aix*  \
  44  | *-*-*bsd*      \
  45  | *-*-go32*      \
  46  | *-*-linux*     \
  47  | *-*-lynxos*    \
  48  | *-sun-*        \
  49  | hppa*-*-*      \
  50  | *-*-elf*       \
  51  )
  52     with_stabs=yes ;;
  53  *)
  54     with_stabs=no ;;
  55 esac])
  56
  57 # Add stabs tests when appropriate.
  58 if test $with_stabs = yes; then
  59    AC_CONFIG_SUBDIRS(gdb.stabs)
  60 fi
  61
  62 # Enable gdbtk.
  63 AC_ARG_ENABLE(gdbtk,
  64 [  --enable-gtk            enable gdbtk graphical user interface (GUI)],,
  65   [if test -d $srcdir/gdb.gdbtk; then
  66     enable_gdbtk=yes
  67   else
  68     enable_gdbtk=no
  69   fi])
  70 # We unconditionally disable gdbtk tests on selected platforms.
  71 case $host_os in
  72   go32* | windows*)
  73     enable_gdbtk=no ;;
  74 esac
  75
  76 # Add gdbtk tests when appropriate.
  77 if test $enable_gdbtk = yes; then
  78    AC_CONFIG_SUBDIRS(gdb.gdbtk)
  79 fi
  80
  81 # Enable shared libraries.
  82 AC_ARG_ENABLE(shared,
  83 [  --enable-shared         build shared libraries [deault=yes]],,
  84   enable_shared=yes)
  85
  86 # If we have shared libraries, try to set RPATH_ENVVAR reasonably,
  87 # such that we can find the shared libraries in the build tree.
  88 if test $enable_shared = no; then
  89   # The variable `RPATH_ENVVAR' itself is not likely to be used on any
  90   # platform.
  91   RPATH_ENVVAR=RPATH_ENVVAR
  92 else
  93   # The variable `LD_LIBRARY_PATH' is used on most platforms.
  94   RPATH_ENVVAR=LD_LIBRARY_PATH
  95   # The following exceptions are taken from Libtool 1.4.3.
  96   case $host_os in
  97     aix*)
  98       if test $host_cpu != ia64; then
  99         RPATH_ENVVAR=LIBPATH
 100       fi ;;
 101     darwin* | rhapsody*)
 102       RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
 103     hpux*)
 104       RPATH_ENVVAR=SHLIB_PATH ;;
 105   esac
 106 fi
 107 AC_SUBST(RPATH_ENVVAR)
 108
 109 AC_CHECK_HEADERS(pthread.h)
 110
 111 AC_EXEEXT
 112
 113 AC_OUTPUT([Makefile \
 114   gdb.ada/Makefile \
 115   gdb.arch/Makefile gdb.asm/Makefile gdb.base/Makefile \
 116   gdb.cp/Makefile gdb.disasm/Makefile gdb.dwarf2/Makefile \
 117   gdb.fortran/Makefile gdb.server/Makefile \
 118   gdb.java/Makefile gdb.mi/Makefile \
 119   gdb.objc/Makefile gdb.threads/Makefile gdb.trace/Makefile \
 120   gdb.xml/Makefile])