gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003, 2004, 2007, 2008, 2009, 2010, 2011
   2 # Free Software Foundation, Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # This file was written by Kendra.
  18
  19 if $tracelevel then {
  20     strace $tracelevel
  21 }
  22
  23 #
  24 # Test debugging assembly level programs.
  25 # This file uses asmsrc[12].s for input.
  26 #
  27
  28
  29 set asm-arch ""
  30 set asm-note "empty"
  31 set asm-flags ""
  32 set link-flags "-e _start"
  33 set debug-flags ""
  34
  35 switch -glob -- [istarget] {
  36     "alpha*-*-*" {
  37         set asm-arch alpha
  38         # ??? Won't work with ecoff systems like Tru64, but then we also
  39         # don't have any other -g flag that creates mdebug output.
  40         set asm-flags "-no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  41         set debug-flags "-gdwarf-2"
  42     }
  43     "*arm-*-*" {
  44         set asm-arch arm
  45     }
  46     "xscale-*-*" {
  47         set asm-arch arm
  48     }
  49     "frv-*-*" {
  50         set asm-arch frv
  51     }
  52     "s390-*-*" {
  53         set asm-arch s390
  54     }
  55     "s390x-*-*" {
  56         set asm-arch s390x
  57     }
  58     "x86_64-*-*" {
  59         set asm-arch x86_64
  60         set debug-flags "-gdwarf-2"
  61     }
  62     "i\[3456\]86-*-*" {
  63         set asm-arch i386
  64     }
  65     "lm32-*" {
  66         set asm-arch lm32
  67     }
  68     "m32r*-linux*" {
  69         set asm-arch m32r-linux
  70     }
  71     "m32c-*-*" {
  72         set asm-arch m32c
  73     }
  74     "m32r*-*" {
  75         set asm-arch m32r
  76         append link-flags "--whole-archive -lgloss --no-whole-archive"
  77     }
  78     "m6811-*-*" {
  79         set asm-arch m68hc11
  80         set asm-flags "-mshort-double -m68hc11 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  81         set debug-flags "-gdwarf-2"
  82         # This asm test is specific and uses the linker directly.
  83         # We must not use the target board linker script defined for other
  84         # tests.  Remove it and restore it later on.
  85         set board [target_info name]
  86         set old_ldscript [board_info $board ldscript]
  87         unset_board_info "ldscript"
  88     }
  89     "m6812-*-*" {
  90         set asm-arch m68hc11
  91         set asm-flags "-mshort-double -m68hc12 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  92         set debug-flags "-gdwarf-2"
  93         # This asm test is specific and uses the linker directly.
  94         # We must not use the target board linker script defined for other
  95         # tests.  Remove it and restore it later on.
  96         set board [target_info name]
  97         set old_ldscript [board_info $board ldscript]
  98         set_board_info ldscript ""
  99     }
 100     "mips*-*" {
 101         set asm-arch mips
 102     }
 103     "powerpc*-*" {
 104         if { [is_lp64_target] } {
 105             set asm-arch powerpc64
 106             set asm-flags "-a64 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 107             append link-flags " -m elf64ppc"
 108         } else {
 109             set asm-arch powerpc
 110             set asm-flags "-a32 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 111             append link-flags " -m elf32ppc"
 112         }
 113     }
 114     "sh*-*-*" {
 115         set asm-arch sh
 116         set debug-flags "-gdwarf-2"
 117     }
 118     "sparc-*-*" {
 119         set asm-arch sparc
 120     }
 121     "sparc64-*-*" {
 122         set asm-arch sparc64
 123         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 124         set debug-flags "-gdwarf-2"
 125     }
 126     "spu*-*-*" {
 127        set asm-arch spu
 128        set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir} --no-warn"
 129        set debug-flags "-gdwarf-2"
 130     }
 131     "xstormy16-*-*" {
 132         set asm-arch xstormy16
 133         set debug-flags "-gdwarf-2"
 134     }
 135     "v850-*-*" {
 136         set asm-arch v850
 137         set gdb_wrapper_initialized 1
 138     }
 139     "m68k-*-*" {
 140         set asm-arch m68k
 141     }
 142     "ia64-*-*" {
 143         set asm-arch ia64
 144         set debug-flags "-gdwarf-2"
 145     }
 146     "iq2000-*-*" {
 147         set asm-arch iq2000
 148     }
 149     "hppa*-linux-*" {
 150         set asm-arch pa
 151         set debug-flags "-gdwarf-2"
 152     }
 153     "hppa-*-openbsd*" {
 154         set asm-arch pa
 155         set debug-flags "-gdwarf-2"
 156     }
 157     "hppa64-*-hpux*" {
 158         set asm-arch pa64
 159         set debug-flags "-gdwarf-2"
 160     }
 161     "h83*-*" {
 162         set asm-arch h8300
 163         set debug-flags "-gdwarf-2"
 164     }
 165 }
 166
 167 if { "${asm-arch}" == "" } {
 168     untested asm-source.exp
 169     return -1
 170 }
 171
 172 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 173 if { [istarget "*-*-netbsdelf*"]
 174      || [istarget "alpha-*-netbsd*"]
 175      || [istarget "mips*-*-netbsd*"]
 176      || [istarget "powerpc-*-netbsd*"]
 177      || [istarget "x86_64-*-netbsd*"] } then {
 178     set asm-note "netbsd"
 179 }
 180
 181 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 182 # of handing a.out here since most OpenBSD/a.out systems use a rather
 183 # outdated assembler that doesn't assemble this test's code anyway.
 184 if { [istarget "*-*-openbsd*"] } then {
 185     set asm-note "openbsd"
 186 }
 187
 188 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 189 # switches according to compiler syntax.  If we pass these options straight
 190 # to the assembler, they won't always make sense.  If we don't pass them to
 191 # the assembler, the final link will complain that the object files were
 192 # built with different defaults.  So no matter what we do, we lose.  We may as
 193 # well get out of this test sooner rather than later.
 194 set dest [target_info name]
 195 if [board_info $dest exists multilib_flags] {
 196         set multilib_flags [board_info $dest multilib_flags]
 197         if { "${multilib_flags}" != "" } {
 198            untested asm-source.exp
 199            return -1
 200            return;
 201          }
 202 }
 203
 204 set testfile "asm-source"
 205 set binfile ${objdir}/${subdir}/${testfile}
 206 set srcfile1 asmsrc1.s
 207 set srcfile2 asmsrc2.s
 208
 209 remote_exec build "rm -f ${subdir}/arch.inc"
 210 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 211 remote_exec build "rm -f ${subdir}/note.inc"
 212 remote_download host ${srcdir}/${subdir}/${asm-note}.inc ${subdir}/note.inc
 213
 214 if { [string equal ${asm-flags} ""] } {
 215     set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 216 }
 217
 218 if { [string equal ${debug-flags} ""] } {
 219     set debug-flags "-gstabs"
 220 }
 221
 222 # Allow the target board to override the debug flags.
 223 if { [board_info $dest exists debug_flags] } then {
 224     set debug-flags "[board_info $dest debug_flags]"
 225 }
 226
 227 # The debug flags are in the format that gcc expects:
 228 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 229 # other languages in the test suite, we accept this input format.
 230 # So the user can run the test suite with:
 231 #
 232 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 233 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 234 #
 235 # However, the GNU assembler has different spellings than gcc.
 236 # So I adjust the debug flags here.
 237
 238 # The GNU assembler spells "dwarf-2" as "dwarf2".
 239 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 240
 241 # The GNU assembler before 2.15 did not support "stabs+".
 242 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 243
 244 # The GNU assembler does not support level options like "-g2" or "-g3".
 245 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 246
 247 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags} ${debug-flags}"] != ""} then {
 248      untested asm-source.exp
 249      return -1
 250 }
 251 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags} ${debug-flags}"] != ""} then {
 252      untested asm-source.exp
 253      return -1
 254 }
 255
 256 # We deliberately don't use gdb_compile here to link together the
 257 # assembled object files.  Using gdb_compile, and therefore the C
 258 # compiler, is conceptually wrong, since we're testing raw assembler
 259 # code here that provides its own startup code.  Using target_link
 260 # also avoids a lot of problems on many systems, most notably on
 261 # *-*-*bsd* and *-*-solaris2*.
 262 if {[target_link "asmsrc1.o asmsrc2.o" "${binfile}" ${link-flags}] != "" } then {
 263      untested asm-source.exp
 264      return -1
 265 }
 266
 267 # Restore the target board linker script for HC11/HC12.
 268 if { [istarget "m6811-*-*"] || [istarget "m6812-*-*"] } {
 269     set_board_info ldscript $old_ldscript
 270 }
 271
 272 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 273
 274 # Collect some line numbers.
 275 set line_main       [expr [gdb_get_line_number "main start" "asmsrc1.s"] + 1]
 276 set line_call_foo2  [expr [gdb_get_line_number "call foo2"  "asmsrc1.s"] + 1]
 277 set line_search_comment [expr [gdb_get_line_number "search" "asmsrc1.s"] + 1]
 278 set line_foo3       [expr [gdb_get_line_number "foo3 start" "asmsrc1.s"] + 1]
 279 set line_main_exit  [expr [gdb_get_line_number "main exit"  "asmsrc1.s"] + 1]
 280 set line_foo2       [expr [gdb_get_line_number "foo2 start" "asmsrc2.s"] + 1]
 281 set line_call_foo3  [expr [gdb_get_line_number "call foo3"  "asmsrc2.s"] + 1]
 282 set line_call_foo3_again [expr $line_call_foo3 + 1]
 283 set line_foo2_leave [expr [gdb_get_line_number "foo2 leave" "asmsrc2.s"] + 1]
 284
 285 gdb_start
 286 gdb_reinitialize_dir $srcdir/$subdir
 287 gdb_load ${binfile}
 288
 289 #
 290 # Run to `main' where we begin our tests.
 291 #
 292
 293 if ![runto_main] then {
 294     gdb_suppress_tests
 295 }
 296
 297 # Execute the `f' command and see if the result includes source info.
 298 gdb_test "f" "asmsrc1\[.\]s:$line_main.*several_nops" "f at main"
 299
 300 # See if we properly `next' over a macro with several insns.
 301 gdb_test "n" "$line_call_foo2\[         \]*.*foo2" "next over macro"
 302
 303 # See if we can properly `step' into a subroutine call.
 304 gdb_test "s" "$line_foo2\[      \]*.*" "step into foo2"
 305
 306 # Test 'info target', and incidentally capture the entry point address.
 307 set entry_point 0
 308 gdb_test_multiple "info target" "info target" {
 309     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 310         set entry_point $expect_out(1,string)
 311         pass "info target"
 312     }
 313 }
 314
 315 # Capture the start symbol (may be '_start' or 'start')
 316 set entry_symbol ""
 317 gdb_test_multiple "info symbol 0x$entry_point" "info symbol" {
 318     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 319         # We match the echoed `info symbol' command here, to help us
 320         # reliably identify the beginning of the start symbol in the
 321         # command's output.  You might think we could just use '^' to
 322         # start matching at the beginning of the line, but
 323         # unfortunately, in Expect, '^' matches the beginning of the
 324         # input that hasn't been matched by any expect clause yet.  If
 325         # every expect clause consumes a complete line, along with its
 326         # terminating CR/LF, this is equivalent to the beginning of a
 327         # line.  But expect clauses that end with `.*' will consume as
 328         # much as happened to arrive from the TTY --- exactly where
 329         # they leave you depends on inter-process timing.  :(
 330         set entry_symbol $expect_out(1,string)
 331         pass "info symbol"
 332     }
 333 }
 334
 335 # Now try a 'list' from the other source file.
 336 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 337
 338 # Now try a source file search
 339 gdb_test "search A routine for foo2 to call" \
 340         "$line_search_comment\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 341
 342 # See if `f' prints the right source file.
 343 gdb_test "f" ".*asmsrc2\[.\]s:$line_foo2.*" "f in foo2"
 344
 345 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 346 gdb_test "n" "$line_call_foo3\[         \]*.*foo3" "n in foo2"
 347
 348 # See if a simple `bt' prints the right source files and
 349 # doesn't fall off the stack.
 350
 351 gdb_test "bt 10" \
 352         "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2" \
 353         "bt ALL in foo2"
 354
 355 # See if a capped `bt' prints the right source files.
 356 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 2 in foo2"
 357
 358 # Step into another subroutine which lives back in the first source file.
 359 gdb_test "s" ".*" "s 2"
 360
 361 # Next over insns to set up the stack frame.
 362 gdb_test "n" ".*" "n 2"
 363
 364 # Now see if a capped `bt' is correct.
 365 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:$line_foo3.*\#1.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#2.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 3 in foo3"
 366
 367 # Try 'info source' from asmsrc1.s
 368 gdb_test "info source" \
 369         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 370         "info source asmsrc1.s"
 371
 372 # Try 'finishing' from foo3
 373 # Some architectures will have one or more instructions after the
 374 # call instruction which still is part of the call sequence, so we
 375 # must be prepared for a "finish" to show us the caller line
 376 # again as well as the statement after.
 377 gdb_test_multiple "finish" "finish from foo3" {
 378     -re "Run till exit from.*\[\r\n\]$line_call_foo3\[ \t\]+gdbasm_call foo3.*$gdb_prompt $" {
 379         pass "finish from foo3"
 380         gdb_test "s" ".*" "s after finish"
 381     }
 382     -re "Run till exit from.*\[\r\n\]$line_call_foo3_again\[ \t\]+gdbasm_call foo3.*$gdb_prompt $" {
 383         pass "finish from foo3"
 384     }
 385 }
 386
 387 # Try 'info source' from asmsrc2.s
 388 gdb_test "info source" \
 389         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 390         "info source asmsrc2.s"
 391
 392 # Try 'info sources'.  This can produce a lot of output on systems
 393 # with dynamic linking, where the system's shared libc was compiled
 394 # with debugging info; for example, on Linux, this produces 47kb of
 395 # output.  So we consume it as we go.
 396 set seen_asmsrc_1 0
 397 set seen_asmsrc_2 0
 398 gdb_test_multiple "info sources" "info sources" {
 399     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 400         set seen_asmsrc_1 1
 401         exp_continue
 402     }
 403     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 404         set seen_asmsrc_2 1
 405         exp_continue
 406     }
 407     -re ", " {
 408         exp_continue
 409     }
 410     -re "$gdb_prompt $" {
 411         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 412             pass "info sources"
 413         } else {
 414             fail "info sources"
 415         }
 416     }
 417 }
 418
 419
 420 # Try 'info line'
 421 gdb_test "info line" \
 422         "Line $line_call_foo3_again of.*asmsrc2.s.*starts at.*<\\.?foo2+.*> and ends at.*<\\.?foo2+.*>." \
 423         "info line"
 424
 425 # Try 'nexting' over next call to foo3
 426 gdb_test "next" "$line_foo2_leave\[ \t\]+gdbasm_leave" "next over foo3"
 427
 428 # Try 'return' from foo2
 429 # Like "finish", "return" command also can return to the caller
 430 # line again or the statement after, depending on the architecture.
 431 gdb_test_multiple "return" "return from foo2" {
 432     -re "Make (foo2|selected stack frame) return now\?.*" {
 433         send_gdb "y\n"
 434         exp_continue
 435     }
 436     -re "\#0.*main .*$line_call_foo2\[ \t\]+gdbasm_call foo2.*$gdb_prompt $" {
 437         pass "return from foo2"
 438         gdb_test "s" ".*" "s after return"
 439     }
 440     -re "\#0.*main .*$line_main_exit\[ \t\]+gdbasm_exit0.*$gdb_prompt $" {
 441         pass "return from foo2"
 442     }
 443 }
 444
 445 # Disassemble something, check the output
 446 proc test_dis { command var } {
 447     global gdb_prompt
 448     gdb_test_multiple "${command}" "${command}" {
 449         -re "${var}.*:.*(Cannot access|Bad address)" {
 450             # The "disassembler" was only accessing the local
 451             # executable and that would cause attempts to disassemble
 452             # variables to fail (memory not valid).
 453             fail "${command} (memory read error)"
 454         }
 455         -re "${var}.*:.*${gdb_prompt}" {
 456             pass "${command}"
 457         }
 458     }
 459 }
 460
 461 # See if we can look at a global variable, three ways
 462 gdb_test "print globalvar" ".* = 11" "look at global variable"
 463 test_dis "x/i &globalvar" "globalvar"
 464 test_dis "disassem &globalvar, &globalvar+1" "globalvar"
 465
 466 # See if we can look at a static variable, three ways
 467 gdb_test "print staticvar" ".* = 5" "look at static variable"
 468 test_dis "x/i &staticvar" "staticvar"
 469 test_dis "disassem &staticvar, &staticvar+1" "staticvar"
 470
 471 # See if we can look at a static function
 472 gdb_test "disassem foostatic" ".*<\\+0>:.*End of assembler dump." \
 473         "look at static function"
 474
 475 remote_exec build "rm -f ${subdir}/arch.inc"
 476 remote_exec build "rm -f ${subdir}/note.inc"