gdb/testsuite/gdb.base/index-cache.exp

   1 #   Copyright 2018-2019 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # This test checks that the index-cache feature generates the expected files at
  17 # the expected location.
  18
  19 standard_testfile
  20
  21 if { [prepare_for_testing "failed to prepare" $testfile $srcfile \
  22           {additional_flags=-Wl,--build-id}] } {
  23     return
  24 }
  25
  26 # The index cache won't be used in certain circumstances, for which we must
  27 # account in this test:
  28 #
  29 #  - the binary already has an index section
  30 #  - we use the -readnow switch
  31 set has_index_section [exec_has_index_section $binfile]
  32 set uses_readnow [expr [string first "-readnow" $GDBFLAGS] != -1]
  33 set expecting_index_cache_use [expr !$has_index_section && !$uses_readnow]
  34
  35 # List the files in DIR on the host (where GDB-under-test runs).
  36 # Return a list of two elements:
  37 #   - 0 on success, -1 on failure
  38 #   - the list of files on success, empty on failure
  39
  40 proc ls_host { dir } {
  41     lassign [remote_exec host ls "-1 $dir"] ret output
  42
  43     if { $ret != 0 } {
  44         fail "failed to list files on host in $dir"
  45         return -1
  46     }
  47
  48     # ls -1 returns a list separated by \r\n.  split will return a bunch of
  49     # empty entries (it treats a sequence of split characters as separate
  50     # fields, plus there is a \r\n at the end of the result).  Ignore empty
  51     # list elements.
  52     set filtered {}
  53     set files [split $output \r\n]
  54
  55     foreach file $files {
  56         if { $file != "" } {
  57             lappend filtered $file
  58         }
  59     }
  60
  61     return [list 0 $filtered]
  62 }
  63
  64 # Execute "show index-cache stats" and verify the output against expected
  65 # values.
  66
  67 proc check_cache_stats { expected_hits expected_misses } {
  68     set re [multi_line \
  69         "  Cache hits .this session.: $expected_hits" \
  70         "Cache misses .this session.: $expected_misses" \
  71     ]
  72
  73     gdb_test "show index-cache stats" $re "check index-cache stats"
  74 }
  75
  76 # Run CODE using a fresh GDB configured based on the other parameters.
  77
  78 proc run_test_with_flags { cache_dir cache_enabled code } {
  79     global GDBFLAGS testfile
  80
  81     save_vars { GDBFLAGS } {
  82         set GDBFLAGS "$GDBFLAGS -iex \"set index-cache directory $cache_dir\""
  83         set GDBFLAGS "$GDBFLAGS -iex \"set index-cache $cache_enabled\""
  84
  85         clean_restart ${testfile}
  86
  87         uplevel 1 $code
  88     }
  89 }
  90
  91 # Test administrative stuff.
  92
  93 proc_with_prefix test_basic_stuff { } {
  94     global testfile
  95
  96     clean_restart ${testfile}
  97
  98     # Check that the index cache is disabled by default.
  99     gdb_test \
 100         "show index-cache" \
 101         " is currently disabled." \
 102         "index-cache is disabled by default"
 103
 104     # Test that we can enable it and "show index-cache" reflects that.
 105     gdb_test_no_output "set index-cache on" "enable index cache"
 106     gdb_test \
 107         "show index-cache" \
 108         " is currently enabled." \
 109         "index-cache is now enabled"
 110
 111     # Test the "set/show index-cache directory" commands.
 112     gdb_test "set index-cache directory" "Argument required.*" "set index-cache directory without arg"
 113     gdb_test_no_output "set index-cache directory /tmp" "change the index cache directory"
 114     gdb_test \
 115         "show index-cache directory" \
 116         "The directory of the index cache is \"/tmp\"."  \
 117         "show index cache directory"
 118 }
 119
 120 # Test loading a binary with the cache disabled.  No file should be created.
 121
 122 proc_with_prefix test_cache_disabled { cache_dir } {
 123     lassign [ls_host $cache_dir] ret files_before
 124
 125     run_test_with_flags $cache_dir off {
 126         lassign [ls_host $cache_dir] ret files_after
 127
 128         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 129         gdb_assert "$nfiles_created == 0" "no files were created"
 130
 131         check_cache_stats 0 0
 132     }
 133 }
 134
 135 # Test a cache miss.  We expect to have at least one file in the cache if the
 136 # index cache is going to be used (see expecting_index_cache_use) and a cache
 137 # miss in the stats.  If the cache is not going to be used, we expect to have
 138 # no files and no cache hits nor misses.
 139
 140 proc_with_prefix test_cache_enabled_miss { cache_dir } {
 141     global testfile expecting_index_cache_use
 142
 143     lassign [ls_host $cache_dir] ret files_before
 144
 145     run_test_with_flags $cache_dir on {
 146
 147         lassign [ls_host $cache_dir] ret files_after
 148         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 149         if { $expecting_index_cache_use } {
 150             gdb_assert "$nfiles_created > 0" "at least one file was created"
 151         } else {
 152             gdb_assert "$nfiles_created == 0" "no file was created"
 153         }
 154
 155         set build_id [get_build_id  [standard_output_file ${testfile}]]
 156         if { $build_id == "" } {
 157             fail "couldn't get executable build id"
 158             return
 159         }
 160
 161         set expected_created_file [list "${build_id}.gdb-index"]
 162         set found_idx [lsearch -exact $files_after $expected_created_file]
 163         if { $expecting_index_cache_use } {
 164             gdb_assert "$found_idx >= 0" "expected file is there"
 165         } else {
 166             gdb_assert "$found_idx == -1" "no index cache file generated"
 167         }
 168
 169         remote_exec host rm "-f $cache_dir/$expected_created_file"
 170
 171         if { $expecting_index_cache_use } {
 172             check_cache_stats 0 1
 173         } else {
 174             check_cache_stats 0 0
 175         }
 176     }
 177 }
 178
 179
 180 # Test a cache hit.  We should have at least one file in the cache if the index
 181 # cache is going to be used (see expecting_index_cache_use) and a cache hit in
 182 # the stats.  If the cache is not going to be used, we expect to have no files
 183 # and no cache hits nor misses.
 184
 185 proc_with_prefix test_cache_enabled_hit { cache_dir } {
 186     global expecting_index_cache_use
 187
 188     # Just to populate the cache.
 189     run_test_with_flags $cache_dir on {}
 190
 191     lassign [ls_host $cache_dir] ret files_before
 192
 193     run_test_with_flags $cache_dir on {
 194         lassign [ls_host $cache_dir] ret files_after
 195         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 196         gdb_assert "$nfiles_created == 0" "no files were created"
 197
 198         if { $expecting_index_cache_use } {
 199             check_cache_stats 1 0
 200         } else {
 201             check_cache_stats 0 0
 202         }
 203     }
 204 }
 205
 206 test_basic_stuff
 207
 208 # The cache dir should be on the host (possibly remote), so we can't use the
 209 # standard output directory for that (it's on the build machine).
 210 lassign [remote_exec host mktemp -d] ret cache_dir
 211
 212 if { $ret != 0 } {
 213     fail "couldn't create temporary cache dir"
 214     return
 215 }
 216
 217 # The ouput of mktemp contains an end of line, remove it.
 218 set cache_dir [string trimright $cache_dir \r\n]
 219
 220 test_cache_disabled $cache_dir
 221 test_cache_enabled_miss $cache_dir
 222 test_cache_enabled_hit $cache_dir
 223
 224 # Test again with the cache disabled, now that it is populated.
 225 test_cache_disabled $cache_dir
 226