gdb/testsuite/lib/gdb.exp

   1 # Copyright (C) 1992, 1994, 1995, 1997 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19
  20 # This file was written by Fred Fish. (fnf@cygnus.com)
  21
  22 # Generic gdb subroutines that should work for any target.  If these
  23 # need to be modified for any target, it can be done with a variable
  24 # or by passing arguments.
  25
  26 load_lib libgloss.exp
  27
  28 global GDB
  29 global CHILL_LIB
  30 global CHILL_RT0
  31
  32 if ![info exists CHILL_LIB] {
  33     set CHILL_LIB [findfile $base_dir/../../gcc/ch/runtime/libchill.a "$base_dir/../../gcc/ch/runtime/libchill.a" [transform -lchill]]
  34 }
  35 verbose "using CHILL_LIB = $CHILL_LIB" 2
  36 if ![info exists CHILL_RT0] {
  37     set CHILL_RT0 [findfile $base_dir/../../gcc/ch/runtime/chillrt0.o "$base_dir/../../gcc/ch/runtime/chillrt0.o" ""]
  38 }
  39 verbose "using CHILL_RT0 = $CHILL_RT0" 2
  40
  41 if ![info exists GDB] {
  42     if ![is_remote host] {
  43         set GDB [findfile $base_dir/../../gdb/gdb "$base_dir/../../gdb/gdb" [transform gdb]]
  44     } else {
  45         set GDB [transform gdb];
  46     }
  47 }
  48 verbose "using GDB = $GDB" 2
  49
  50 global GDBFLAGS
  51 if ![info exists GDBFLAGS] {
  52     set GDBFLAGS "-nx"
  53 }
  54 verbose "using GDBFLAGS = $GDBFLAGS" 2
  55
  56 # The variable prompt is a regexp which matches the gdb prompt.  Set it if it
  57 # is not already set.
  58 global gdb_prompt
  59 if ![info exists prompt] then {
  60     set gdb_prompt "\[(\]gdb\[)\]"
  61 }
  62
  63 #
  64 # gdb_version -- extract and print the version number of GDB
  65 #
  66 proc default_gdb_version {} {
  67     global GDB
  68     global GDBFLAGS
  69     global gdb_prompt
  70     set fileid [open "gdb_cmd" w];
  71     puts $fileid "q";
  72     close $fileid;
  73     set cmdfile [remote_download host "gdb_cmd"];
  74     set output [remote_exec host "$GDB -nw --command $cmdfile"]
  75     remote_file build delete "gdb_cmd";
  76     remote_file host delete "$cmdfile";
  77     set tmp [lindex $output 1];
  78     set version ""
  79     regexp " \[0-9\]\[^ \t\n\r\]+" "$tmp" version
  80     if ![is_remote host] {
  81         clone_output "[which $GDB] version $version $GDBFLAGS\n"
  82     } else {
  83         clone_output "$GDB on remote host version $version $GDBFLAGS\n"
  84     }
  85 }
  86
  87 proc gdb_version { } {
  88     return [default_gdb_version];
  89 }
  90
  91 #
  92 # gdb_unload -- unload a file if one is loaded
  93 #
  94
  95 proc gdb_unload {} {
  96     global verbose
  97     global GDB
  98     global gdb_prompt
  99     send_gdb "file\n"
 100     gdb_expect {
 101         -re "No exec file now\[^\r\n\]*\[\r\n\]" { exp_continue }
 102         -re "No symbol file now\[^\r\n\]*\[\r\n\]" { exp_continue }
 103         -re "A program is being debugged already..*Kill it.*y or n. $"\
 104             { send_gdb "y\n"
 105                 verbose "\t\tKilling previous program being debugged"
 106             exp_continue
 107         }
 108         -re "Discard symbol table from .*y or n.*$" {
 109             send_gdb "y\n"
 110             exp_continue
 111         }
 112         -re "$gdb_prompt $" {}
 113         timeout {
 114             perror "couldn't unload file in $GDB (timed out)."
 115             return -1
 116         }
 117     }
 118 }
 119
 120 # Many of the tests depend on setting breakpoints at various places and
 121 # running until that breakpoint is reached.  At times, we want to start
 122 # with a clean-slate with respect to breakpoints, so this utility proc
 123 # lets us do this without duplicating this code everywhere.
 124 #
 125
 126 proc delete_breakpoints {} {
 127     global gdb_prompt
 128
 129     send_gdb "delete breakpoints\n"
 130     gdb_expect {
 131          -re "Delete all breakpoints.*y or n.*$" {
 132             send_gdb "y\n";
 133             exp_continue
 134         }
 135          -re "$gdb_prompt $" { # This happens if there were no breakpoints
 136             }
 137          timeout { perror "Delete all breakpoints in delete_breakpoints (timeout)" ; return }
 138     }
 139     send_gdb "info breakpoints\n"
 140     gdb_expect {
 141          -re "No breakpoints or watchpoints..*$gdb_prompt $" {}
 142          -re "$gdb_prompt $" { perror "breakpoints not deleted" ; return }
 143          -re "Delete all breakpoints.*or n.*$" {
 144             send_gdb "y\n";
 145             exp_continue
 146         }
 147          timeout { perror "info breakpoints (timeout)" ; return }
 148     }
 149 }
 150
 151
 152 #
 153 # Generic run command.
 154 #
 155 # The second pattern below matches up to the first newline *only*.
 156 # Using ``.*$'' could swallow up output that we attempt to match
 157 # elsewhere.
 158 #
 159 proc gdb_run_cmd {args} {
 160     global gdb_prompt
 161
 162     if [target_info exists gdb_init_command] {
 163         send_gdb "[target_info gdb_init_command]\n";
 164         gdb_expect {
 165             -re "$gdb_prompt $" { }
 166             default {
 167                 perror "gdb_init_command for target failed";
 168                 return;
 169             }
 170         }
 171     }
 172
 173     if [target_info exists use_gdb_stub] {
 174         if [target_info exists gdb,start_symbol] {
 175             set start [target_info gdb,start_symbol];
 176         } else {
 177             set start "start";
 178         }
 179         send_gdb  "jump *$start\n"
 180         gdb_expect {
 181             -re "Continuing at \[^\r\n\]*\[\r\n\]" {
 182                 if ![target_info exists gdb_stub] {
 183                     return;
 184                 }
 185             }
 186             -re "No symbol \"start\" in current.*$gdb_prompt $" {
 187                 send_gdb "jump *_start\n";
 188                 exp_continue;
 189             }
 190             -re "No symbol \"_start\" in current.*$gdb_prompt $" {
 191                 perror "Can't find start symbol to run in gdb_run";
 192                 return;
 193             }
 194             -re "Line.* Jump anyway.*y or n. $" {
 195                 send_gdb "y\n"
 196                 exp_continue;
 197             }
 198             -re "No symbol.*context.*$gdb_prompt $" {}
 199             -re "The program is not being run.*$gdb_prompt $" {
 200                 gdb_load "";
 201                 send_gdb "jump *$start\n";
 202                 exp_continue;
 203             }
 204             timeout { perror "Jump to start() failed (timeout)"; return }
 205         }
 206         if [target_info exists gdb_stub] {
 207             gdb_expect {
 208                 -re "$gdb_prompt $" {
 209                     send_gdb "continue\n"
 210                 }
 211             }
 212         }
 213         return
 214     }
 215     send_gdb "run $args\n"
 216 # This doesn't work quite right yet.
 217     gdb_expect {
 218         -re "The program .* has been started already.*y or n. $" {
 219             send_gdb "y\n"
 220             exp_continue
 221         }
 222         -re "Starting program: \[^\r\n\]*" {}
 223     }
 224 }
 225
 226 proc gdb_breakpoint { function } {
 227     global gdb_prompt
 228     global decimal
 229
 230     send_gdb "break $function\n"
 231     # The first two regexps are what we get with -g, the third is without -g.
 232     gdb_expect {
 233         -re "Breakpoint \[0-9\]* at .*: file .*, line $decimal.\r\n$gdb_prompt $" {}
 234         -re "Breakpoint \[0-9\]*: file .*, line $decimal.\r\n$gdb_prompt $" {}
 235         -re "Breakpoint \[0-9\]* at .*$gdb_prompt $" {}
 236         -re "$gdb_prompt $" { fail "setting breakpoint at $function" ; return 0 }
 237         timeout { fail "setting breakpoint at $function (timeout)" ; return 0 }
 238     }
 239     return 1;
 240 }
 241
 242 # Set breakpoint at function and run gdb until it breaks there.
 243 # Since this is the only breakpoint that will be set, if it stops
 244 # at a breakpoint, we will assume it is the one we want.  We can't
 245 # just compare to "function" because it might be a fully qualified,
 246 # single quoted C++ function specifier.
 247
 248 proc runto { function } {
 249     global gdb_prompt
 250     global decimal
 251
 252     delete_breakpoints
 253
 254     if ![gdb_breakpoint $function] {
 255         return 0;
 256     }
 257
 258     gdb_run_cmd
 259
 260     # the "at foo.c:36" output we get with -g.
 261     # the "in func" output we get without -g.
 262     gdb_expect {
 263         -re "Break.* at .*:$decimal.*$gdb_prompt $" {
 264             return 1
 265         }
 266         -re "Breakpoint \[0-9\]*, \[0-9xa-f\]* in .*$gdb_prompt $" {
 267             return 1
 268         }
 269         -re "$gdb_prompt $" {
 270             fail "running to $function in runto"
 271             return 0
 272         }
 273         timeout {
 274             fail "running to $function in runto (timeout)"
 275             return 0
 276         }
 277     }
 278     return 1
 279 }
 280
 281 #
 282 # runto_main -- ask gdb to run until we hit a breakpoint at main.
 283 #               The case where the target uses stubs has to be handled
 284 #               specially--if it uses stubs, assuming we hit
 285 #               breakpoint() and just step out of the function.
 286 #
 287 proc runto_main {} {
 288     global gdb_prompt
 289     global decimal
 290
 291     if ![target_info exists gdb_stub] {
 292         return [runto main]
 293     }
 294
 295     delete_breakpoints
 296
 297     send_gdb "step\n"
 298     # if use stubs step out of the breakpoint() function.
 299     gdb_expect {
 300         -re "main.* at .*$gdb_prompt $" {}
 301         -re "_start.*$gdb_prompt $" {}
 302         timeout { fail "single step at breakpoint() (timeout)" ; return 0 }
 303     }
 304     return 1
 305 }
 306
 307 #
 308 # gdb_test -- send_gdb a command to gdb and test the result.
 309 #             Takes three parameters.
 310 #             Parameters:
 311 #                First one is the command to execute.  If this is the null string
 312 #                  then no command is sent.
 313 #                Second one is the pattern to match for a PASS, and must NOT include
 314 #                  the \r\n sequence immediately before the gdb prompt.
 315 #                Third one is an optional message to be printed. If this
 316 #                  a null string "", then the pass/fail messages use the command
 317 #                  string as the message.
 318 #             Returns:
 319 #                1 if the test failed,
 320 #                0 if the test passes,
 321 #               -1 if there was an internal error.
 322 #
 323 proc gdb_test { args } {
 324     global verbose
 325     global gdb_prompt
 326     global GDB
 327     global expect_out
 328     upvar timeout timeout
 329
 330     if [llength $args]>2 then {
 331         set message [lindex $args 2]
 332     } else {
 333         set message [lindex $args 0]
 334     }
 335     set command [lindex $args 0]
 336     set pattern [lindex $args 1]
 337
 338     if [llength $args]==5 {
 339         set question_string [lindex $args 3];
 340         set response_string [lindex $args 4];
 341     } else {
 342         set question_string "^FOOBAR$"
 343     }
 344
 345     if $verbose>2 then {
 346         send_user "Sending \"$command\" to gdb\n"
 347         send_user "Looking to match \"$pattern\"\n"
 348         send_user "Message is \"$message\"\n"
 349     }
 350
 351     set result -1
 352     if ![string match $command ""] {
 353         if { [send_gdb "$command\n"] != "" } {
 354             global suppress_flag;
 355
 356             if { ! $suppress_flag } {
 357                 perror "Couldn't send $command to GDB.";
 358             }
 359             fail "$message";
 360             return $result;
 361         }
 362     }
 363
 364     gdb_expect {
 365          -re "Ending remote debugging.*$gdb_prompt$" {
 366             if ![isnative] then {
 367                 warning "Can`t communicate to remote target."
 368             }
 369             gdb_exit
 370             gdb_start
 371             set result -1
 372         }
 373          -re "\[\r\n\]*($pattern)\[\r\n\]+$gdb_prompt $" {
 374             if ![string match "" $message] then {
 375                 pass "$message"
 376             }
 377             set result 0
 378         }
 379          -re "(${question_string})$" {
 380             send_gdb "$response_string\n";
 381             exp_continue;
 382         }
 383          -re "Undefined command:.*$gdb_prompt" {
 384             perror "Undefined command \"$command\"."
 385             set result 1
 386         }
 387          -re "Ambiguous command.*$gdb_prompt $" {
 388             perror "\"$command\" is not a unique command name."
 389             set result 1
 390         }
 391          -re "Program exited with code \[0-9\]+.*$gdb_prompt $" {
 392             if ![string match "" $message] then {
 393                 set errmsg "$message: the program exited"
 394             } else {
 395                 set errmsg "$command: the program exited"
 396             }
 397             fail "$errmsg"
 398             return -1
 399         }
 400          -re "The program is not being run.*$gdb_prompt $" {
 401             if ![string match "" $message] then {
 402                 set errmsg "$message: the program is no longer running"
 403             } else {
 404                 set errmsg "$command: the program is no longer running"
 405             }
 406             fail "$errmsg"
 407             return -1
 408         }
 409          -re ".*$gdb_prompt $" {
 410             if ![string match "" $message] then {
 411                 fail "$message"
 412             }
 413             set result 1
 414         }
 415          "<return>" {
 416             send_gdb "\n"
 417             perror "Window too small."
 418         }
 419          -re "\\(y or n\\) " {
 420             send_gdb "n\n"
 421             perror "Got interactive prompt."
 422         }
 423          eof {
 424              perror "Process no longer exists"
 425              if { $message != "" } {
 426                  fail "$message"
 427              }
 428              return -1
 429         }
 430          full_buffer {
 431             perror "internal buffer is full."
 432         }
 433         timeout {
 434             if ![string match "" $message] then {
 435                 fail "$message (timeout)"
 436             }
 437             set result 1
 438         }
 439     }
 440     return $result
 441 }
 442 \f
 443 # Test that a command gives an error.  For pass or fail, return
 444 # a 1 to indicate that more tests can proceed.  However a timeout
 445 # is a serious error, generates a special fail message, and causes
 446 # a 0 to be returned to indicate that more tests are likely to fail
 447 # as well.
 448
 449 proc test_print_reject { args } {
 450     global gdb_prompt
 451     global verbose
 452
 453     if [llength $args]==2 then {
 454         set expectthis [lindex $args 1]
 455     } else {
 456         set expectthis "should never match this bogus string"
 457     }
 458     set sendthis [lindex $args 0]
 459     if $verbose>2 then {
 460         send_user "Sending \"$sendthis\" to gdb\n"
 461         send_user "Looking to match \"$expectthis\"\n"
 462     }
 463     send_gdb "$sendthis\n"
 464     gdb_expect {
 465         -re "A .* in expression.*\\.*$gdb_prompt $" {
 466             pass "reject $sendthis"
 467             return 1
 468         }
 469         -re "Invalid syntax in expression.*$gdb_prompt $" {
 470             pass "reject $sendthis"
 471             return 1
 472         }
 473         -re "Junk after end of expression.*$gdb_prompt $" {
 474             pass "reject $sendthis"
 475             return 1
 476         }
 477         -re "Invalid number.*$gdb_prompt $" {
 478             pass "reject $sendthis"
 479             return 1
 480         }
 481         -re "Invalid character constant.*$gdb_prompt $" {
 482             pass "reject $sendthis"
 483             return 1
 484         }
 485         -re "No symbol table is loaded.*$gdb_prompt $" {
 486             pass "reject $sendthis"
 487             return 1
 488         }
 489         -re "No symbol .* in current context.*$gdb_prompt $" {
 490             pass "reject $sendthis"
 491             return 1
 492         }
 493         -re "$expectthis.*$gdb_prompt $" {
 494             pass "reject $sendthis"
 495             return 1
 496         }
 497         -re ".*$gdb_prompt $" {
 498             fail "reject $sendthis"
 499             return 1
 500         }
 501         default {
 502             fail "reject $sendthis (eof or timeout)"
 503             return 0
 504         }
 505     }
 506 }
 507 \f
 508 # Given an input string, adds backslashes as needed to create a
 509 # regexp that will match the string.
 510
 511 proc string_to_regexp {str} {
 512     set result $str
 513     regsub -all {[]*+.|()^$\[]} $str {\\&} result
 514     return $result
 515 }
 516
 517 # Same as gdb_test, but the second parameter is not a regexp,
 518 # but a string that must match exactly.
 519
 520 proc gdb_test_exact { args } {
 521     upvar timeout timeout
 522
 523     set command [lindex $args 0]
 524
 525     # This applies a special meaning to a null string pattern.  Without
 526     # this, "$pattern\r\n$gdb_prompt $" will match anything, including error
 527     # messages from commands that should have no output except a new
 528     # prompt.  With this, only results of a null string will match a null
 529     # string pattern.
 530
 531     set pattern [lindex $args 1]
 532     if [string match $pattern ""] {
 533         set pattern [string_to_regexp [lindex $args 0]]
 534     } else {
 535         set pattern [string_to_regexp [lindex $args 1]]
 536     }
 537
 538     # It is most natural to write the pattern argument with only
 539     # embedded \n's, especially if you are trying to avoid Tcl quoting
 540     # problems.  But gdb_expect really wants to see \r\n in patterns.  So
 541     # transform the pattern here.  First transform \r\n back to \n, in
 542     # case some users of gdb_test_exact already do the right thing.
 543     regsub -all "\r\n" $pattern "\n" pattern
 544     regsub -all "\n" $pattern "\r\n" pattern
 545     if [llength $args]==3 then {
 546         set message [lindex $args 2]
 547     } else {
 548         set message $command
 549     }
 550
 551     return [gdb_test $command $pattern $message]
 552 }
 553 \f
 554 proc gdb_reinitialize_dir { subdir } {
 555     global gdb_prompt
 556
 557     if [is_remote host] {
 558         return "";
 559     }
 560     send_gdb "dir\n"
 561     gdb_expect {
 562         -re "Reinitialize source path to empty.*y or n. " {
 563             send_gdb "y\n"
 564             gdb_expect {
 565                 -re "Source directories searched.*$gdb_prompt $" {
 566                     send_gdb "dir $subdir\n"
 567                     gdb_expect {
 568                         -re "Source directories searched.*$gdb_prompt $" {
 569                             verbose "Dir set to $subdir"
 570                         }
 571                         -re "$gdb_prompt $" {
 572                             perror "Dir \"$subdir\" failed."
 573                         }
 574                     }
 575                 }
 576                 -re "$gdb_prompt $" {
 577                     perror "Dir \"$subdir\" failed."
 578                 }
 579             }
 580         }
 581         -re "$gdb_prompt $" {
 582             perror "Dir \"$subdir\" failed."
 583         }
 584     }
 585 }
 586
 587 #
 588 # gdb_exit -- exit the GDB, killing the target program if necessary
 589 #
 590 proc default_gdb_exit {} {
 591     global GDB
 592     global GDBFLAGS
 593     global verbose
 594     global gdb_spawn_id;
 595
 596     gdb_stop_suppressing_tests;
 597
 598     if ![info exists gdb_spawn_id] {
 599         return;
 600     }
 601
 602     verbose "Quitting $GDB $GDBFLAGS"
 603
 604     # This used to be 1 for unix-gdb.exp
 605     set timeout 5
 606     verbose "Timeout is now $timeout seconds" 2
 607
 608     if [is_remote host] {
 609         send_gdb "quit\n";
 610         gdb_expect {
 611              -re "and kill it.*y or n. " {
 612                 send_gdb "y\n";
 613                 exp_continue;
 614             }
 615             timeout { }
 616         }
 617     }
 618
 619     remote_close host;
 620     unset gdb_spawn_id
 621 }
 622
 623 #
 624 # load a file into the debugger.
 625 # return a -1 if anything goes wrong.
 626 #
 627 proc gdb_file_cmd { arg } {
 628     global verbose
 629     global loadpath
 630     global loadfile
 631     global GDB
 632     global gdb_prompt
 633     upvar timeout timeout
 634
 635     if [is_remote host] {
 636         set arg [remote_download host $arg];
 637         if { $arg == "" } {
 638             error "download failed"
 639             return -1;
 640         }
 641     }
 642
 643     send_gdb "file $arg\n"
 644     gdb_expect {
 645         -re "Reading symbols from.*done.*$gdb_prompt $" {
 646             verbose "\t\tLoaded $arg into the $GDB"
 647             return 0
 648         }
 649         -re "has no symbol-table.*$gdb_prompt $" {
 650             perror "$arg wasn't compiled with \"-g\""
 651             return -1
 652         }
 653         -re "A program is being debugged already.*Kill it.*y or n. $" {
 654             send_gdb "y\n"
 655                 verbose "\t\tKilling previous program being debugged"
 656             exp_continue
 657         }
 658         -re "Load new symbol table from \".*\".*y or n. $" {
 659             send_gdb "y\n"
 660             gdb_expect {
 661                 -re "Reading symbols from.*done.*$gdb_prompt $" {
 662                     verbose "\t\tLoaded $arg with new symbol table into $GDB"
 663                     return 0
 664                 }
 665                 timeout {
 666                     perror "(timeout) Couldn't load $arg, other program already loaded."
 667                     return -1
 668                 }
 669             }
 670         }
 671         -re "No such file or directory.*$gdb_prompt $" {
 672             perror "($arg) No such file or directory\n"
 673             return -1
 674         }
 675         -re "$gdb_prompt $" {
 676             perror "couldn't load $arg into $GDB."
 677             return -1
 678             }
 679         timeout {
 680             perror "couldn't load $arg into $GDB (timed out)."
 681             return -1
 682         }
 683         eof {
 684             # This is an attempt to detect a core dump, but seems not to
 685             # work.  Perhaps we need to match .* followed by eof, in which
 686             # gdb_expect does not seem to have a way to do that.
 687             perror "couldn't load $arg into $GDB (end of file)."
 688             return -1
 689         }
 690     }
 691 }
 692
 693 #
 694 # start gdb -- start gdb running, default procedure
 695 #
 696 # When running over NFS, particularly if running many simultaneous
 697 # tests on different hosts all using the same server, things can
 698 # get really slow.  Give gdb at least 3 minutes to start up.
 699 #
 700 proc default_gdb_start { } {
 701     global verbose
 702     global GDB
 703     global GDBFLAGS
 704     global gdb_prompt
 705     global timeout
 706     global gdb_spawn_id;
 707
 708     gdb_stop_suppressing_tests;
 709
 710     verbose "Spawning $GDB -nw $GDBFLAGS"
 711
 712     if [info exists gdb_spawn_id] {
 713         return 0;
 714     }
 715
 716     set oldtimeout $timeout
 717     set timeout [expr "$timeout + 180"]
 718     if [is_remote host] {
 719         set res [remote_spawn host "$GDB -nw $GDBFLAGS --command gdbinit"];
 720     } else {
 721         if { [which $GDB] == 0 } then {
 722             perror "$GDB does not exist."
 723             exit 1
 724         }
 725
 726         set res [remote_spawn host "$GDB -nw $GDBFLAGS"];
 727     }
 728     if { $res < 0 || $res == "" } {
 729         perror "Spawning $GDB failed."
 730         return 1;
 731     }
 732     set timeout 10
 733     gdb_expect {
 734         -re "\[\r\n\]$gdb_prompt $" {
 735             verbose "GDB initialized."
 736         }
 737         -re "$gdb_prompt $"     {
 738             perror "GDB never initialized."
 739             set timeout $oldtimeout
 740             verbose "Timeout restored to $timeout seconds" 2
 741             return -1
 742         }
 743         timeout {
 744             perror "(timeout) GDB never initialized after $timeout seconds."
 745             remote_close host;
 746             return -1
 747         }
 748     }
 749     set timeout $oldtimeout
 750     verbose "Timeout restored to $timeout seconds" 2
 751     set gdb_spawn_id -1;
 752     # force the height to "unlimited", so no pagers get used
 753
 754     send_gdb "set height 0\n"
 755     gdb_expect {
 756         -re "$gdb_prompt $" {
 757             verbose "Setting height to 0." 2
 758         }
 759         timeout {
 760             warning "Couldn't set the height to 0"
 761         }
 762     }
 763     # force the width to "unlimited", so no wraparound occurs
 764     send_gdb "set width 0\n"
 765     gdb_expect {
 766         -re "$gdb_prompt $" {
 767             verbose "Setting width to 0." 2
 768         }
 769         timeout {
 770             warning "Couldn't set the width to 0."
 771         }
 772     }
 773     return 0;
 774 }
 775
 776 #
 777 # FIXME: this is a copy of the new library procedure, but it's here too
 778 # till the new dejagnu gets installed everywhere. I'd hate to break the
 779 # gdb testsuite.
 780 #
 781 global argv0
 782 if ![info exists argv0] then {
 783     proc exp_continue { } {
 784         continue -expect
 785     }
 786 }
 787
 788 # * For crosses, the CHILL runtime doesn't build because it can't find
 789 # setjmp.h, stdio.h, etc.
 790 # * For AIX (as of 16 Mar 95), (a) there is no language code for
 791 # CHILL in output_epilog in gcc/config/rs6000/rs6000.c, (b) collect2
 792 # does not get along with AIX's too-clever linker.
 793 # * On Irix5, there is a bug whereby set of bool, etc., don't get
 794 # TYPE_LOW_BOUND for the bool right because force_to_range_type doesn't
 795 # work with stub types.
 796 # Lots of things seem to fail on the PA, and since it's not a supported
 797 # chill target at the moment, don't run the chill tests.
 798
 799 proc skip_chill_tests {} {
 800     if ![info exists do_chill_tests] {
 801         return 1;
 802     }
 803     eval set skip_chill [expr ![isnative] || [istarget "*-*-aix*"] || [istarget "*-*-irix5*"] || [istarget "*-*-irix6*"] || [istarget "alpha-*-osf*"] || [istarget "hppa*-*-*"]]
 804     verbose "Skip chill tests is $skip_chill"
 805     return $skip_chill
 806 }
 807
 808 proc get_compiler_info {binfile} {
 809     # Create and source the file that provides information about the compiler
 810     # used to compile the test case.
 811     global srcdir
 812     global subdir
 813     # These two come from compiler.c.
 814     global signed_keyword_not_used
 815     global gcc_compiled
 816
 817     if { [gdb_compile "${srcdir}/${subdir}/compiler.c" "${binfile}.ci" preprocess {}] != "" } {
 818         perror "Couldn't make ${binfile}.ci file"
 819         return 1;
 820     }
 821     source ${binfile}.ci
 822     return 0;
 823 }
 824
 825 proc gdb_compile {source dest type options} {
 826     global GDB_TESTCASE_OPTIONS;
 827
 828     if [target_info exists gdb_stub] {
 829         set options2 { "additional_flags=-Dusestubs" }
 830         lappend options "libs=[target_info gdb_stub]";
 831         set options [concat $options2 $options]
 832     }
 833     if [info exists GDB_TESTCASE_OPTIONS] {
 834         lappend options "additional_flags=$GDB_TESTCASE_OPTIONS";
 835     }
 836     verbose "options are $options"
 837     verbose "source is $source $dest $type $options"
 838     set result [target_compile $source $dest $type $options];
 839     regsub "\[\r\n\]*$" "$result" "" result;
 840     regsub "^\[\r\n\]*" "$result" "" result;
 841     if { $result != "" } {
 842         clone_output "gdb compile failed, $result"
 843     }
 844     return $result;
 845 }
 846
 847 proc send_gdb { string } {
 848     global suppress_flag;
 849     if { $suppress_flag } {
 850         return "suppressed";
 851     }
 852     return [remote_send host "$string"];
 853 }
 854
 855 #
 856 #
 857
 858 proc gdb_expect { args } {
 859     upvar timeout timeout
 860     if [target_info exists gdb,timeout] {
 861         if [info exists timeout] {
 862             set oldt $timeout;
 863             if { $timeout < [target_info gdb,timeout] } {
 864                 set timeout [target_info gdb,timeout];
 865             }
 866         } else {
 867             set timeout [target_info gdb,timeout];
 868         }
 869     }
 870     set code [catch {uplevel remote_expect host $timeout $args} string];
 871     if [target_info exists gdb,timeout] {
 872         if [info exists oldt] {
 873             set timeout $oldt
 874         } else {
 875             unset timeout
 876         }
 877     }
 878
 879     if {$code == 1} {
 880         global errorInfo errorCode;
 881
 882         return -code error -errorinfo $errorInfo -errorcode $errorCode $string
 883     } elseif {$code == 2} {
 884         return -code return $string
 885     } elseif {$code == 3} {
 886         return
 887     } elseif {$code > 4} {
 888         return -code $code $string
 889     }
 890 }
 891
 892 #
 893 # Set suppress_flag, which will cause all subsequent calls to send_gdb and
 894 # gdb_expect to fail immediately (until the next call to
 895 # gdb_stop_suppressing_tests).
 896 #
 897 proc gdb_suppress_tests { args } {
 898     global suppress_flag;
 899
 900     incr suppress_flag;
 901
 902     if { [llength $args] > 0 } {
 903         warning "[lindex $args 0]\n";
 904     } else {
 905         warning "Because of previous failure, all subsequent tests in this group will automatically fail.\n";
 906     }
 907 }
 908
 909 #
 910 # Clear suppress_flag.
 911 #
 912 proc gdb_stop_suppressing_tests { } {
 913     global suppress_flag;
 914
 915     if [info exists suppress_flag] {
 916         if { $suppress_flag != 0 } {
 917             set suppress_flag 0;
 918             clone_output "Tests restarted.\n";
 919         }
 920     } else {
 921         set suppress_flag 0;
 922     }
 923 }
 924
 925 proc gdb_start { } {
 926     default_gdb_start
 927 }
 928
 929 proc gdb_exit { } {
 930     catch default_gdb_exit
 931 }
 932
 933 #
 934 # gdb_load -- load a file into the debugger.
 935 #             return a -1 if anything goes wrong.
 936 #
 937 proc gdb_load { arg } {
 938     return [gdb_file_cmd $arg]
 939 }
 940
 941 proc gdb_continue { function } {
 942     global decimal
 943
 944     return [gdb_test "continue" ".*Breakpoint $decimal, $function .*" "continue to $function"];
 945 }
 946
 947 proc default_gdb_init { args } {
 948     gdb_stop_suppressing_tests;
 949
 950     # Uh, this is lame. Really, really, really lame. But there's this *one*
 951     # testcase that will fail in random places if we don't increase this.
 952     match_max -d 20000
 953
 954     # We want to add the name of the TCL testcase to the PASS/FAIL messages.
 955     if { [llength $args] > 0 } {
 956         global pf_prefix
 957
 958         set file [lindex $args 0];
 959
 960         set pf_prefix "[file tail [file dirname $file]]/[file tail $file]:";
 961     }
 962 }
 963
 964 proc gdb_init { args } {
 965     return [default_gdb_init];
 966 }
 967
 968 proc gdb_finish { } {
 969     gdb_exit;
 970 }