gdb/testsuite/lib/selftest-support.exp

   1 # Copyright 2003-2018 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Find a pathname to a file that we would execute if the shell was asked
  17 # to run $arg using the current PATH.
  18
  19 proc find_gdb { arg } {
  20
  21     # If the arg directly specifies an existing executable file, then
  22     # simply use it.
  23
  24     if [file executable $arg] then {
  25         return $arg
  26     }
  27
  28     set result [which $arg]
  29     if [string match "/" [ string range $result 0 0 ]] then {
  30         return $result
  31     }
  32
  33     # If everything fails, just return the unqualified pathname as default
  34     # and hope for best.
  35
  36     return $arg
  37 }
  38
  39 # A helper proc that sets up for self-testing.
  40 # EXECUTABLE is the gdb to use.
  41 # FUNCTION is the function to break in, either captured_main
  42 # or captured_command_loop.
  43
  44 proc selftest_setup { executable function } {
  45     global gdb_prompt
  46     global timeout
  47     global INTERNAL_GDBFLAGS
  48
  49     # load yourself into the debugger
  50     # This can take a relatively long time, particularly for testing where
  51     # the executable is being accessed over a network, or where gdb does not
  52     # support partial symbols for a particular target and has to load the
  53     # entire symbol table.  Set the timeout to 10 minutes, which should be
  54     # adequate for most environments (it *has* timed out with 5 min on a
  55     # SPARCstation SLC under moderate load, so this isn't unreasonable).
  56     # After gdb is started, set the timeout to 30 seconds for the duration
  57     # of this test, and then back to the original value.
  58
  59     set oldtimeout $timeout
  60     set timeout 600
  61     verbose "Timeout is now $timeout seconds" 2
  62
  63     global gdb_file_cmd_debug_info
  64     set gdb_file_cmd_debug_info "unset"
  65
  66     set result [gdb_load $executable]
  67     set timeout $oldtimeout
  68     verbose "Timeout is now $timeout seconds" 2
  69
  70     if { $result != 0 } then {
  71         return -1
  72     }
  73
  74     if { $gdb_file_cmd_debug_info != "debug" } then {
  75         untested "no debug information, skipping testcase."
  76         return -1
  77     }
  78
  79     # Set a breakpoint at main
  80     gdb_test "break $function" \
  81             "Breakpoint.*at.* file.*, line.*" \
  82             "breakpoint in $function"
  83
  84     # run yourself
  85     # It may take a very long time for the inferior gdb to start (lynx),
  86     # so we bump it back up for the duration of this command.
  87     set timeout 600
  88
  89     set description "run until breakpoint at $function"
  90     gdb_test_multiple "run $INTERNAL_GDBFLAGS" "$description" {
  91         -re "Starting program.*Breakpoint \[0-9\]+,.*$function \\(\\).* at .*main.c:.*$gdb_prompt $" {
  92             pass "$description"
  93         }
  94         -re "Starting program.*Breakpoint \[0-9\]+,.*$function \\(\\).*$gdb_prompt $" {
  95             xfail "$description (line numbers scrambled?)"
  96         }
  97         -re "Starting program.*Breakpoint \[0-9\]+,.* at .*main.c:.*$function.*$gdb_prompt $" {
  98             # $function may be inlined, so the program stops at the line
  99             # calling $function.
 100             pass "$description"
 101         }
 102         -re "vfork: No more processes.*$gdb_prompt $" {
 103             fail "$description (out of virtual memory)"
 104             set timeout $oldtimeout
 105             verbose "Timeout is now $timeout seconds" 2
 106             return -1
 107         }
 108         -re ".*$gdb_prompt $" {
 109             fail "$description"
 110             set timeout $oldtimeout
 111             verbose "Timeout is now $timeout seconds" 2
 112             return -1
 113         }
 114     }
 115
 116     set timeout $oldtimeout
 117     verbose "Timeout is now $timeout seconds" 2
 118
 119     return 0
 120 }
 121
 122 # A simple way to run some self-tests.
 123
 124 proc do_self_tests {function body} {
 125     global GDB tool
 126
 127     # Are we testing with a remote board?  In that case, the target
 128     # won't have access to the GDB's auxilliary data files
 129     # (data-directory, etc.).  It's simpler to just skip.
 130     if [is_remote target] {
 131         return
 132     }
 133
 134     # ... or seemingly testing with a cross debugger?  Likely GDB
 135     # wouldn't be able to debug itself then...
 136     if ![isnative] {
 137         return
 138     }
 139
 140     # ... or with a stub-like server?  I.e., gdbserver + "target
 141     # remote"?  In that case we won't be able to pass command line
 142     # arguments to GDB, and selftest_setup wants to do exactly that.
 143     if [target_info exists use_gdb_stub] {
 144         return
 145     }
 146
 147     # Run the test with self.  Copy the file executable file in case
 148     # this OS doesn't like to edit its own text space.
 149
 150     set GDB_FULLPATH [find_gdb $GDB]
 151
 152     if {[is_remote host]} {
 153         set xgdb x$tool
 154     } else {
 155         set xgdb [standard_output_file x$tool]
 156     }
 157
 158     # Remove any old copy lying around.
 159     remote_file host delete $xgdb
 160
 161     gdb_start
 162     set file [remote_download host $GDB_FULLPATH $xgdb]
 163
 164     set result [selftest_setup $file $function]
 165     if {$result == 0} then {
 166         set result [uplevel $body]
 167     }
 168
 169     gdb_exit
 170     catch "remote_file host delete $file"
 171
 172     if {$result < 0} then {
 173         warning "Couldn't test self"
 174     }
 175 }