gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-variable -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags \
  45 -Wno-error=deprecated-register \
  46 -Wsuggest-override \
  47 -Wimplicit-fallthrough=3 \
  48 -Wduplicated-cond \
  49 -Wshadow=local \
  50 -Wdeprecated-copy \
  51 -Wdeprecated-copy-dtor \
  52 -Wredundant-move \
  53 -Wmissing-declarations"
  54
  55 case "${host}" in
  56   *-*-mingw32*)
  57     # Enable -Wno-format by default when using gcc on mingw since many
  58     # GCC versions complain about %I64.
  59     build_warnings="$build_warnings -Wno-format" ;;
  60   *-*-solaris*)
  61     # Solaris 11.4 <python2.7/ceval.h> uses #pragma no_inline that GCC
  62     # doesn't understand.
  63     build_warnings="$build_warnings -Wno-unknown-pragmas"
  64     # Solaris 11 <unistd.h> marks vfork deprecated.
  65     build_warnings="$build_warnings -Wno-deprecated-declarations" ;;
  66   *)
  67     # Note that gcc requires -Wformat for -Wformat-nonliteral to work,
  68     # but there's a special case for this below.
  69     build_warnings="$build_warnings -Wformat-nonliteral" ;;
  70 esac
  71
  72 AC_ARG_ENABLE(build-warnings,
  73 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  74 [case "${enableval}" in
  75   yes)  ;;
  76   no)   build_warnings="-w";;
  77   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  78         build_warnings="${build_warnings} ${t}";;
  79   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  80         build_warnings="${t} ${build_warnings}";;
  81   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  82 esac
  83 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  84   echo "Setting compiler warning flags = $build_warnings" 6>&1
  85 fi])dnl
  86 AC_ARG_ENABLE(gdb-build-warnings,
  87 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  88 [case "${enableval}" in
  89   yes)  ;;
  90   no)   build_warnings="-w";;
  91   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  92         build_warnings="${build_warnings} ${t}";;
  93   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  94         build_warnings="${t} ${build_warnings}";;
  95   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  96 esac
  97 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  98   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  99 fi])dnl
 100
 101 # The set of warnings supported by a C++ compiler is not the same as
 102 # of the C compiler.
 103 AC_LANG_PUSH([C++])
 104
 105 WARN_CFLAGS=""
 106 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 107 then
 108     AC_MSG_CHECKING(compiler warning flags)
 109     # Separate out the -Werror flag as some files just cannot be
 110     # compiled with it enabled.
 111     for w in ${build_warnings}; do
 112         # GCC does not complain about -Wno-unknown-warning.  Invert
 113         # and test -Wunknown-warning instead.
 114         case $w in
 115         -Wno-*)
 116                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
 117         -Wformat-nonliteral)
 118                 # gcc requires -Wformat before -Wformat-nonliteral
 119                 # will work, so stick them together.
 120                 w="-Wformat $w"
 121                 wtest="$w"
 122                 ;;
 123         *)
 124                 wtest=$w ;;
 125         esac
 126
 127         case $w in
 128         -Werr*) WERROR_CFLAGS=-Werror ;;
 129         *)
 130             # Check whether GCC accepts it.
 131             saved_CFLAGS="$CFLAGS"
 132             CFLAGS="$CFLAGS -Werror $wtest"
 133             saved_CXXFLAGS="$CXXFLAGS"
 134             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 135             if test "x$w" = "x-Wunused-variable"; then
 136               # Check for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=38958,
 137               # fixed in GCC 4.9.  This test is derived from the gdb
 138               # source code that triggered this bug in GCC.
 139               AC_TRY_COMPILE(
 140                 [struct scoped_restore_base {};
 141                  struct scoped_restore_tmpl : public scoped_restore_base {
 142                    ~scoped_restore_tmpl() {}
 143                  };],
 144                 [const scoped_restore_base &b = scoped_restore_tmpl();],
 145                 WARN_CFLAGS="${WARN_CFLAGS} $w",)
 146             else
 147               AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 148             fi
 149             CFLAGS="$saved_CFLAGS"
 150             CXXFLAGS="$saved_CXXFLAGS"
 151         esac
 152     done
 153     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 154 fi
 155 AC_SUBST(WARN_CFLAGS)
 156 AC_SUBST(WERROR_CFLAGS)
 157
 158 AC_LANG_POP([C++])
 159 ])