gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([gprof.c])
   5
   6 AC_CANONICAL_TARGET([])
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(gprof, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 dnl For simplicity, we use the BFD configuration file for most
  17 dnl things.  However, we also need our own configuration file for
  18 dnl the automake PACKAGE and VERSION macros.  We don't name it
  19 dnl config.h, to avoid any possible confusion with the bfd config.h.
  20 AC_CONFIG_HEADERS([gconfig.h:gconfig.in])
  21
  22 AC_PROG_CC
  23 AC_PROG_INSTALL
  24
  25 AC_CHECK_FUNCS(setmode)
  26
  27 ALL_LINGUAS="fr tr sv es id da pt_BR de vi rw ga"
  28 CY_GNU_GETTEXT
  29
  30 AM_MAINTAINER_MODE
  31 AC_EXEEXT
  32
  33 AC_CHECK_HEADERS(sys/gmon_out.h)
  34
  35 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
  36 AC_CACHE_VAL(gprof_cv_decl_getopt_unistd_h,
  37 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
  38 gprof_cv_decl_getopt_unistd_h=yes, gprof_cv_decl_getopt_unistd_h=no)])
  39 AC_MSG_RESULT($gprof_cv_decl_getopt_unistd_h)
  40 if test $gprof_cv_decl_getopt_unistd_h = yes; then
  41   AC_DEFINE([HAVE_DECL_GETOPT], 1,
  42             [Is the prototype for getopt in <unistd.h> in the expected format?])
  43 fi
  44
  45 AM_BINUTILS_WARNINGS
  46
  47 dnl Required by html and install-html
  48 AC_SUBST(datarootdir)
  49 AC_SUBST(docdir)
  50 AC_SUBST(htmldir)
  51
  52 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
  53 AC_CONFIG_COMMANDS([default],[[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile]],[[]])
  54 AC_OUTPUT