padata: use %*pb[l] to print bitmaps including cpumasks and nodemasks
[deliverable/linux.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 *(_kprobe_blacklist) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 *(_ftrace_events) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .;
128 #else
129 #define FTRACE_EVENTS()
130 #endif
131
132 #ifdef CONFIG_TRACING
133 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
134 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
135 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
136 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
137 *(__tracepoint_str) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
139 #else
140 #define TRACE_PRINTKS()
141 #define TRACEPOINT_STR()
142 #endif
143
144 #ifdef CONFIG_FTRACE_SYSCALLS
145 #define TRACE_SYSCALLS() . = ALIGN(8); \
146 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
147 *(__syscalls_metadata) \
148 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
149 #else
150 #define TRACE_SYSCALLS()
151 #endif
152
153
154 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
155 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
156 #define OF_TABLE(cfg, name) __OF_TABLE(config_enabled(cfg), name)
157 #define _OF_TABLE_0(name)
158 #define _OF_TABLE_1(name) \
159 . = ALIGN(8); \
160 VMLINUX_SYMBOL(__##name##_of_table) = .; \
161 *(__##name##_of_table) \
162 *(__##name##_of_table_end)
163
164 #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
165 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
166 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
167 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
168 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
169 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
170 #define EARLYCON_OF_TABLES() OF_TABLE(CONFIG_SERIAL_EARLYCON, earlycon)
171
172 #define KERNEL_DTB() \
173 STRUCT_ALIGN(); \
174 VMLINUX_SYMBOL(__dtb_start) = .; \
175 *(.dtb.init.rodata) \
176 VMLINUX_SYMBOL(__dtb_end) = .;
177
178 /* .data section */
179 #define DATA_DATA \
180 *(.data) \
181 *(.ref.data) \
182 *(.data..shared_aligned) /* percpu related */ \
183 MEM_KEEP(init.data) \
184 MEM_KEEP(exit.data) \
185 *(.data.unlikely) \
186 STRUCT_ALIGN(); \
187 *(__tracepoints) \
188 /* implement dynamic printk debug */ \
189 . = ALIGN(8); \
190 VMLINUX_SYMBOL(__start___jump_table) = .; \
191 *(__jump_table) \
192 VMLINUX_SYMBOL(__stop___jump_table) = .; \
193 . = ALIGN(8); \
194 VMLINUX_SYMBOL(__start___verbose) = .; \
195 *(__verbose) \
196 VMLINUX_SYMBOL(__stop___verbose) = .; \
197 LIKELY_PROFILE() \
198 BRANCH_PROFILE() \
199 TRACE_PRINTKS() \
200 TRACEPOINT_STR()
201
202 /*
203 * Data section helpers
204 */
205 #define NOSAVE_DATA \
206 . = ALIGN(PAGE_SIZE); \
207 VMLINUX_SYMBOL(__nosave_begin) = .; \
208 *(.data..nosave) \
209 . = ALIGN(PAGE_SIZE); \
210 VMLINUX_SYMBOL(__nosave_end) = .;
211
212 #define PAGE_ALIGNED_DATA(page_align) \
213 . = ALIGN(page_align); \
214 *(.data..page_aligned)
215
216 #define READ_MOSTLY_DATA(align) \
217 . = ALIGN(align); \
218 *(.data..read_mostly) \
219 . = ALIGN(align);
220
221 #define CACHELINE_ALIGNED_DATA(align) \
222 . = ALIGN(align); \
223 *(.data..cacheline_aligned)
224
225 #define INIT_TASK_DATA(align) \
226 . = ALIGN(align); \
227 *(.data..init_task)
228
229 /*
230 * Read only Data
231 */
232 #define RO_DATA_SECTION(align) \
233 . = ALIGN((align)); \
234 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
235 VMLINUX_SYMBOL(__start_rodata) = .; \
236 *(.rodata) *(.rodata.*) \
237 *(__vermagic) /* Kernel version magic */ \
238 . = ALIGN(8); \
239 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
240 *(__tracepoints_ptrs) /* Tracepoints: pointer array */\
241 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
242 *(__tracepoints_strings)/* Tracepoints: strings */ \
243 } \
244 \
245 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
246 *(.rodata1) \
247 } \
248 \
249 BUG_TABLE \
250 \
251 /* PCI quirks */ \
252 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
253 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
254 *(.pci_fixup_early) \
255 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
256 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
257 *(.pci_fixup_header) \
258 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
259 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
260 *(.pci_fixup_final) \
261 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
262 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
263 *(.pci_fixup_enable) \
264 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
265 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
266 *(.pci_fixup_resume) \
267 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
268 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
269 *(.pci_fixup_resume_early) \
270 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
271 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
272 *(.pci_fixup_suspend) \
273 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
274 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
275 *(.pci_fixup_suspend_late) \
276 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
277 } \
278 \
279 /* Built-in firmware blobs */ \
280 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
281 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
282 *(.builtin_fw) \
283 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
284 } \
285 \
286 TRACEDATA \
287 \
288 /* Kernel symbol table: Normal symbols */ \
289 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
290 VMLINUX_SYMBOL(__start___ksymtab) = .; \
291 *(SORT(___ksymtab+*)) \
292 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
293 } \
294 \
295 /* Kernel symbol table: GPL-only symbols */ \
296 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
297 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
298 *(SORT(___ksymtab_gpl+*)) \
299 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
300 } \
301 \
302 /* Kernel symbol table: Normal unused symbols */ \
303 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
304 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
305 *(SORT(___ksymtab_unused+*)) \
306 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
307 } \
308 \
309 /* Kernel symbol table: GPL-only unused symbols */ \
310 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
311 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
312 *(SORT(___ksymtab_unused_gpl+*)) \
313 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
314 } \
315 \
316 /* Kernel symbol table: GPL-future-only symbols */ \
317 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
318 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
319 *(SORT(___ksymtab_gpl_future+*)) \
320 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
321 } \
322 \
323 /* Kernel symbol table: Normal symbols */ \
324 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
325 VMLINUX_SYMBOL(__start___kcrctab) = .; \
326 *(SORT(___kcrctab+*)) \
327 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
328 } \
329 \
330 /* Kernel symbol table: GPL-only symbols */ \
331 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
332 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
333 *(SORT(___kcrctab_gpl+*)) \
334 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
335 } \
336 \
337 /* Kernel symbol table: Normal unused symbols */ \
338 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
339 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
340 *(SORT(___kcrctab_unused+*)) \
341 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
342 } \
343 \
344 /* Kernel symbol table: GPL-only unused symbols */ \
345 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
346 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
347 *(SORT(___kcrctab_unused_gpl+*)) \
348 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
349 } \
350 \
351 /* Kernel symbol table: GPL-future-only symbols */ \
352 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
353 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
354 *(SORT(___kcrctab_gpl_future+*)) \
355 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
356 } \
357 \
358 /* Kernel symbol table: strings */ \
359 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
360 *(__ksymtab_strings) \
361 } \
362 \
363 /* __*init sections */ \
364 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
365 *(.ref.rodata) \
366 MEM_KEEP(init.rodata) \
367 MEM_KEEP(exit.rodata) \
368 } \
369 \
370 /* Built-in module parameters. */ \
371 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
372 VMLINUX_SYMBOL(__start___param) = .; \
373 *(__param) \
374 VMLINUX_SYMBOL(__stop___param) = .; \
375 } \
376 \
377 /* Built-in module versions. */ \
378 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
379 VMLINUX_SYMBOL(__start___modver) = .; \
380 *(__modver) \
381 VMLINUX_SYMBOL(__stop___modver) = .; \
382 . = ALIGN((align)); \
383 VMLINUX_SYMBOL(__end_rodata) = .; \
384 } \
385 . = ALIGN((align));
386
387 /* RODATA & RO_DATA provided for backward compatibility.
388 * All archs are supposed to use RO_DATA() */
389 #define RODATA RO_DATA_SECTION(4096)
390 #define RO_DATA(align) RO_DATA_SECTION(align)
391
392 #define SECURITY_INIT \
393 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
394 VMLINUX_SYMBOL(__security_initcall_start) = .; \
395 *(.security_initcall.init) \
396 VMLINUX_SYMBOL(__security_initcall_end) = .; \
397 }
398
399 /* .text section. Map to function alignment to avoid address changes
400 * during second ld run in second ld pass when generating System.map */
401 #define TEXT_TEXT \
402 ALIGN_FUNCTION(); \
403 *(.text.hot) \
404 *(.text) \
405 *(.ref.text) \
406 MEM_KEEP(init.text) \
407 MEM_KEEP(exit.text) \
408 *(.text.unlikely)
409
410
411 /* sched.text is aling to function alignment to secure we have same
412 * address even at second ld pass when generating System.map */
413 #define SCHED_TEXT \
414 ALIGN_FUNCTION(); \
415 VMLINUX_SYMBOL(__sched_text_start) = .; \
416 *(.sched.text) \
417 VMLINUX_SYMBOL(__sched_text_end) = .;
418
419 /* spinlock.text is aling to function alignment to secure we have same
420 * address even at second ld pass when generating System.map */
421 #define LOCK_TEXT \
422 ALIGN_FUNCTION(); \
423 VMLINUX_SYMBOL(__lock_text_start) = .; \
424 *(.spinlock.text) \
425 VMLINUX_SYMBOL(__lock_text_end) = .;
426
427 #define KPROBES_TEXT \
428 ALIGN_FUNCTION(); \
429 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
430 *(.kprobes.text) \
431 VMLINUX_SYMBOL(__kprobes_text_end) = .;
432
433 #define ENTRY_TEXT \
434 ALIGN_FUNCTION(); \
435 VMLINUX_SYMBOL(__entry_text_start) = .; \
436 *(.entry.text) \
437 VMLINUX_SYMBOL(__entry_text_end) = .;
438
439 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
440 #define IRQENTRY_TEXT \
441 ALIGN_FUNCTION(); \
442 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
443 *(.irqentry.text) \
444 VMLINUX_SYMBOL(__irqentry_text_end) = .;
445 #else
446 #define IRQENTRY_TEXT
447 #endif
448
449 /* Section used for early init (in .S files) */
450 #define HEAD_TEXT *(.head.text)
451
452 #define HEAD_TEXT_SECTION \
453 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
454 HEAD_TEXT \
455 }
456
457 /*
458 * Exception table
459 */
460 #define EXCEPTION_TABLE(align) \
461 . = ALIGN(align); \
462 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
463 VMLINUX_SYMBOL(__start___ex_table) = .; \
464 *(__ex_table) \
465 VMLINUX_SYMBOL(__stop___ex_table) = .; \
466 }
467
468 /*
469 * Init task
470 */
471 #define INIT_TASK_DATA_SECTION(align) \
472 . = ALIGN(align); \
473 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
474 INIT_TASK_DATA(align) \
475 }
476
477 #ifdef CONFIG_CONSTRUCTORS
478 #define KERNEL_CTORS() . = ALIGN(8); \
479 VMLINUX_SYMBOL(__ctors_start) = .; \
480 *(.ctors) \
481 *(.init_array) \
482 VMLINUX_SYMBOL(__ctors_end) = .;
483 #else
484 #define KERNEL_CTORS()
485 #endif
486
487 /* init and exit section handling */
488 #define INIT_DATA \
489 *(.init.data) \
490 MEM_DISCARD(init.data) \
491 KERNEL_CTORS() \
492 MCOUNT_REC() \
493 *(.init.rodata) \
494 FTRACE_EVENTS() \
495 TRACE_SYSCALLS() \
496 KPROBE_BLACKLIST() \
497 MEM_DISCARD(init.rodata) \
498 CLK_OF_TABLES() \
499 RESERVEDMEM_OF_TABLES() \
500 CLKSRC_OF_TABLES() \
501 IOMMU_OF_TABLES() \
502 CPU_METHOD_OF_TABLES() \
503 KERNEL_DTB() \
504 IRQCHIP_OF_MATCH_TABLE() \
505 EARLYCON_OF_TABLES()
506
507 #define INIT_TEXT \
508 *(.init.text) \
509 MEM_DISCARD(init.text)
510
511 #define EXIT_DATA \
512 *(.exit.data) \
513 MEM_DISCARD(exit.data) \
514 MEM_DISCARD(exit.rodata)
515
516 #define EXIT_TEXT \
517 *(.exit.text) \
518 MEM_DISCARD(exit.text)
519
520 #define EXIT_CALL \
521 *(.exitcall.exit)
522
523 /*
524 * bss (Block Started by Symbol) - uninitialized data
525 * zeroed during startup
526 */
527 #define SBSS(sbss_align) \
528 . = ALIGN(sbss_align); \
529 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
530 *(.sbss) \
531 *(.scommon) \
532 }
533
534 /*
535 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
536 * sections to the front of bss.
537 */
538 #ifndef BSS_FIRST_SECTIONS
539 #define BSS_FIRST_SECTIONS
540 #endif
541
542 #define BSS(bss_align) \
543 . = ALIGN(bss_align); \
544 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
545 BSS_FIRST_SECTIONS \
546 *(.bss..page_aligned) \
547 *(.dynbss) \
548 *(.bss) \
549 *(COMMON) \
550 }
551
552 /*
553 * DWARF debug sections.
554 * Symbols in the DWARF debugging sections are relative to
555 * the beginning of the section so we begin them at 0.
556 */
557 #define DWARF_DEBUG \
558 /* DWARF 1 */ \
559 .debug 0 : { *(.debug) } \
560 .line 0 : { *(.line) } \
561 /* GNU DWARF 1 extensions */ \
562 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
563 .debug_sfnames 0 : { *(.debug_sfnames) } \
564 /* DWARF 1.1 and DWARF 2 */ \
565 .debug_aranges 0 : { *(.debug_aranges) } \
566 .debug_pubnames 0 : { *(.debug_pubnames) } \
567 /* DWARF 2 */ \
568 .debug_info 0 : { *(.debug_info \
569 .gnu.linkonce.wi.*) } \
570 .debug_abbrev 0 : { *(.debug_abbrev) } \
571 .debug_line 0 : { *(.debug_line) } \
572 .debug_frame 0 : { *(.debug_frame) } \
573 .debug_str 0 : { *(.debug_str) } \
574 .debug_loc 0 : { *(.debug_loc) } \
575 .debug_macinfo 0 : { *(.debug_macinfo) } \
576 /* SGI/MIPS DWARF 2 extensions */ \
577 .debug_weaknames 0 : { *(.debug_weaknames) } \
578 .debug_funcnames 0 : { *(.debug_funcnames) } \
579 .debug_typenames 0 : { *(.debug_typenames) } \
580 .debug_varnames 0 : { *(.debug_varnames) } \
581
582 /* Stabs debugging sections. */
583 #define STABS_DEBUG \
584 .stab 0 : { *(.stab) } \
585 .stabstr 0 : { *(.stabstr) } \
586 .stab.excl 0 : { *(.stab.excl) } \
587 .stab.exclstr 0 : { *(.stab.exclstr) } \
588 .stab.index 0 : { *(.stab.index) } \
589 .stab.indexstr 0 : { *(.stab.indexstr) } \
590 .comment 0 : { *(.comment) }
591
592 #ifdef CONFIG_GENERIC_BUG
593 #define BUG_TABLE \
594 . = ALIGN(8); \
595 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
596 VMLINUX_SYMBOL(__start___bug_table) = .; \
597 *(__bug_table) \
598 VMLINUX_SYMBOL(__stop___bug_table) = .; \
599 }
600 #else
601 #define BUG_TABLE
602 #endif
603
604 #ifdef CONFIG_PM_TRACE
605 #define TRACEDATA \
606 . = ALIGN(4); \
607 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
608 VMLINUX_SYMBOL(__tracedata_start) = .; \
609 *(.tracedata) \
610 VMLINUX_SYMBOL(__tracedata_end) = .; \
611 }
612 #else
613 #define TRACEDATA
614 #endif
615
616 #define NOTES \
617 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
618 VMLINUX_SYMBOL(__start_notes) = .; \
619 *(.note.*) \
620 VMLINUX_SYMBOL(__stop_notes) = .; \
621 }
622
623 #define INIT_SETUP(initsetup_align) \
624 . = ALIGN(initsetup_align); \
625 VMLINUX_SYMBOL(__setup_start) = .; \
626 *(.init.setup) \
627 VMLINUX_SYMBOL(__setup_end) = .;
628
629 #define INIT_CALLS_LEVEL(level) \
630 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
631 *(.initcall##level##.init) \
632 *(.initcall##level##s.init) \
633
634 #define INIT_CALLS \
635 VMLINUX_SYMBOL(__initcall_start) = .; \
636 *(.initcallearly.init) \
637 INIT_CALLS_LEVEL(0) \
638 INIT_CALLS_LEVEL(1) \
639 INIT_CALLS_LEVEL(2) \
640 INIT_CALLS_LEVEL(3) \
641 INIT_CALLS_LEVEL(4) \
642 INIT_CALLS_LEVEL(5) \
643 INIT_CALLS_LEVEL(rootfs) \
644 INIT_CALLS_LEVEL(6) \
645 INIT_CALLS_LEVEL(7) \
646 VMLINUX_SYMBOL(__initcall_end) = .;
647
648 #define CON_INITCALL \
649 VMLINUX_SYMBOL(__con_initcall_start) = .; \
650 *(.con_initcall.init) \
651 VMLINUX_SYMBOL(__con_initcall_end) = .;
652
653 #define SECURITY_INITCALL \
654 VMLINUX_SYMBOL(__security_initcall_start) = .; \
655 *(.security_initcall.init) \
656 VMLINUX_SYMBOL(__security_initcall_end) = .;
657
658 #ifdef CONFIG_BLK_DEV_INITRD
659 #define INIT_RAM_FS \
660 . = ALIGN(4); \
661 VMLINUX_SYMBOL(__initramfs_start) = .; \
662 *(.init.ramfs) \
663 . = ALIGN(8); \
664 *(.init.ramfs.info)
665 #else
666 #define INIT_RAM_FS
667 #endif
668
669 /*
670 * Default discarded sections.
671 *
672 * Some archs want to discard exit text/data at runtime rather than
673 * link time due to cross-section references such as alt instructions,
674 * bug table, eh_frame, etc. DISCARDS must be the last of output
675 * section definitions so that such archs put those in earlier section
676 * definitions.
677 */
678 #define DISCARDS \
679 /DISCARD/ : { \
680 EXIT_TEXT \
681 EXIT_DATA \
682 EXIT_CALL \
683 *(.discard) \
684 *(.discard.*) \
685 }
686
687 /**
688 * PERCPU_INPUT - the percpu input sections
689 * @cacheline: cacheline size
690 *
691 * The core percpu section names and core symbols which do not rely
692 * directly upon load addresses.
693 *
694 * @cacheline is used to align subsections to avoid false cacheline
695 * sharing between subsections for different purposes.
696 */
697 #define PERCPU_INPUT(cacheline) \
698 VMLINUX_SYMBOL(__per_cpu_start) = .; \
699 *(.data..percpu..first) \
700 . = ALIGN(PAGE_SIZE); \
701 *(.data..percpu..page_aligned) \
702 . = ALIGN(cacheline); \
703 *(.data..percpu..read_mostly) \
704 . = ALIGN(cacheline); \
705 *(.data..percpu) \
706 *(.data..percpu..shared_aligned) \
707 VMLINUX_SYMBOL(__per_cpu_end) = .;
708
709 /**
710 * PERCPU_VADDR - define output section for percpu area
711 * @cacheline: cacheline size
712 * @vaddr: explicit base address (optional)
713 * @phdr: destination PHDR (optional)
714 *
715 * Macro which expands to output section for percpu area.
716 *
717 * @cacheline is used to align subsections to avoid false cacheline
718 * sharing between subsections for different purposes.
719 *
720 * If @vaddr is not blank, it specifies explicit base address and all
721 * percpu symbols will be offset from the given address. If blank,
722 * @vaddr always equals @laddr + LOAD_OFFSET.
723 *
724 * @phdr defines the output PHDR to use if not blank. Be warned that
725 * output PHDR is sticky. If @phdr is specified, the next output
726 * section in the linker script will go there too. @phdr should have
727 * a leading colon.
728 *
729 * Note that this macros defines __per_cpu_load as an absolute symbol.
730 * If there is no need to put the percpu section at a predetermined
731 * address, use PERCPU_SECTION.
732 */
733 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
734 VMLINUX_SYMBOL(__per_cpu_load) = .; \
735 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
736 - LOAD_OFFSET) { \
737 PERCPU_INPUT(cacheline) \
738 } phdr \
739 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
740
741 /**
742 * PERCPU_SECTION - define output section for percpu area, simple version
743 * @cacheline: cacheline size
744 *
745 * Align to PAGE_SIZE and outputs output section for percpu area. This
746 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
747 * __per_cpu_start will be identical.
748 *
749 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
750 * except that __per_cpu_load is defined as a relative symbol against
751 * .data..percpu which is required for relocatable x86_32 configuration.
752 */
753 #define PERCPU_SECTION(cacheline) \
754 . = ALIGN(PAGE_SIZE); \
755 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
756 VMLINUX_SYMBOL(__per_cpu_load) = .; \
757 PERCPU_INPUT(cacheline) \
758 }
759
760
761 /*
762 * Definition of the high level *_SECTION macros
763 * They will fit only a subset of the architectures
764 */
765
766
767 /*
768 * Writeable data.
769 * All sections are combined in a single .data section.
770 * The sections following CONSTRUCTORS are arranged so their
771 * typical alignment matches.
772 * A cacheline is typical/always less than a PAGE_SIZE so
773 * the sections that has this restriction (or similar)
774 * is located before the ones requiring PAGE_SIZE alignment.
775 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
776 * matches the requirement of PAGE_ALIGNED_DATA.
777 *
778 * use 0 as page_align if page_aligned data is not used */
779 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
780 . = ALIGN(PAGE_SIZE); \
781 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
782 INIT_TASK_DATA(inittask) \
783 NOSAVE_DATA \
784 PAGE_ALIGNED_DATA(pagealigned) \
785 CACHELINE_ALIGNED_DATA(cacheline) \
786 READ_MOSTLY_DATA(cacheline) \
787 DATA_DATA \
788 CONSTRUCTORS \
789 }
790
791 #define INIT_TEXT_SECTION(inittext_align) \
792 . = ALIGN(inittext_align); \
793 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
794 VMLINUX_SYMBOL(_sinittext) = .; \
795 INIT_TEXT \
796 VMLINUX_SYMBOL(_einittext) = .; \
797 }
798
799 #define INIT_DATA_SECTION(initsetup_align) \
800 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
801 INIT_DATA \
802 INIT_SETUP(initsetup_align) \
803 INIT_CALLS \
804 CON_INITCALL \
805 SECURITY_INITCALL \
806 INIT_RAM_FS \
807 }
808
809 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
810 . = ALIGN(sbss_align); \
811 VMLINUX_SYMBOL(__bss_start) = .; \
812 SBSS(sbss_align) \
813 BSS(bss_align) \
814 . = ALIGN(stop_align); \
815 VMLINUX_SYMBOL(__bss_stop) = .;
This page took 0.048097 seconds and 5 git commands to generate.