projects / deliverable / linux.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Merge branch 'for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git/jmorris...
[deliverable/linux.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU(PAGE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * [_stext, _etext] is the text section
44 * [_sdata, _edata] is the data section
45 *
46 * Some of the included output section have their own set of constants.
47 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48 * [__nosave_begin, __nosave_end] for the nosave data
49 */
50
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
54
55 #ifndef SYMBOL_PREFIX
56 #define VMLINUX_SYMBOL(sym) sym
57 #else
58 #define PASTE2(x,y) x##y
59 #define PASTE(x,y) PASTE2(x,y)
60 #define VMLINUX_SYMBOL(sym) PASTE(SYMBOL_PREFIX, sym)
61 #endif
62
63 /* Align . to a 8 byte boundary equals to maximum function alignment. */
64 #define ALIGN_FUNCTION() . = ALIGN(8)
65
66 /*
67 * Align to a 32 byte boundary equal to the
68 * alignment gcc 4.5 uses for a struct
69 */
70 #define STRUCT_ALIGNMENT 32
71 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
72
73 /* The actual configuration determine if the init/exit sections
74 * are handled as text/data or they can be discarded (which
75 * often happens at runtime)
76 */
77 #ifdef CONFIG_HOTPLUG
78 #define DEV_KEEP(sec) *(.dev##sec)
79 #define DEV_DISCARD(sec)
80 #else
81 #define DEV_KEEP(sec)
82 #define DEV_DISCARD(sec) *(.dev##sec)
83 #endif
84
85 #ifdef CONFIG_HOTPLUG_CPU
86 #define CPU_KEEP(sec) *(.cpu##sec)
87 #define CPU_DISCARD(sec)
88 #else
89 #define CPU_KEEP(sec)
90 #define CPU_DISCARD(sec) *(.cpu##sec)
91 #endif
92
93 #if defined(CONFIG_MEMORY_HOTPLUG)
94 #define MEM_KEEP(sec) *(.mem##sec)
95 #define MEM_DISCARD(sec)
96 #else
97 #define MEM_KEEP(sec)
98 #define MEM_DISCARD(sec) *(.mem##sec)
99 #endif
100
101 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
102 #define MCOUNT_REC() . = ALIGN(8); \
103 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
104 *(__mcount_loc) \
105 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
106 #else
107 #define MCOUNT_REC()
108 #endif
109
110 #ifdef CONFIG_TRACE_BRANCH_PROFILING
111 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
112 *(_ftrace_annotated_branch) \
113 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
114 #else
115 #define LIKELY_PROFILE()
116 #endif
117
118 #ifdef CONFIG_PROFILE_ALL_BRANCHES
119 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
120 *(_ftrace_branch) \
121 VMLINUX_SYMBOL(__stop_branch_profile) = .;
122 #else
123 #define BRANCH_PROFILE()
124 #endif
125
126 #ifdef CONFIG_EVENT_TRACING
127 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .; \
128 *(_ftrace_events) \
129 VMLINUX_SYMBOL(__stop_ftrace_events) = .;
130 #else
131 #define FTRACE_EVENTS()
132 #endif
133
134 #ifdef CONFIG_TRACING
135 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
136 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
137 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
138 #else
139 #define TRACE_PRINTKS()
140 #endif
141
142 #ifdef CONFIG_FTRACE_SYSCALLS
143 #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
144 *(__syscalls_metadata) \
145 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
146 #else
147 #define TRACE_SYSCALLS()
148 #endif
149
150
151 #define KERNEL_DTB() \
152 STRUCT_ALIGN(); \
153 VMLINUX_SYMBOL(__dtb_start) = .; \
154 *(.dtb.init.rodata) \
155 VMLINUX_SYMBOL(__dtb_end) = .;
156
157 /* .data section */
158 #define DATA_DATA \
159 *(.data) \
160 *(.ref.data) \
161 *(.data..shared_aligned) /* percpu related */ \
162 DEV_KEEP(init.data) \
163 DEV_KEEP(exit.data) \
164 CPU_KEEP(init.data) \
165 CPU_KEEP(exit.data) \
166 MEM_KEEP(init.data) \
167 MEM_KEEP(exit.data) \
168 . = ALIGN(32); \
169 VMLINUX_SYMBOL(__start___tracepoints) = .; \
170 *(__tracepoints) \
171 VMLINUX_SYMBOL(__stop___tracepoints) = .; \
172 /* implement dynamic printk debug */ \
173 . = ALIGN(8); \
174 VMLINUX_SYMBOL(__start___verbose) = .; \
175 *(__verbose) \
176 VMLINUX_SYMBOL(__stop___verbose) = .; \
177 LIKELY_PROFILE() \
178 BRANCH_PROFILE() \
179 TRACE_PRINTKS() \
180 \
181 STRUCT_ALIGN(); \
182 FTRACE_EVENTS() \
183 \
184 STRUCT_ALIGN(); \
185 TRACE_SYSCALLS()
186
187 /*
188 * Data section helpers
189 */
190 #define NOSAVE_DATA \
191 . = ALIGN(PAGE_SIZE); \
192 VMLINUX_SYMBOL(__nosave_begin) = .; \
193 *(.data..nosave) \
194 . = ALIGN(PAGE_SIZE); \
195 VMLINUX_SYMBOL(__nosave_end) = .;
196
197 #define PAGE_ALIGNED_DATA(page_align) \
198 . = ALIGN(page_align); \
199 *(.data..page_aligned)
200
201 #define READ_MOSTLY_DATA(align) \
202 . = ALIGN(align); \
203 *(.data..read_mostly)
204
205 #define CACHELINE_ALIGNED_DATA(align) \
206 . = ALIGN(align); \
207 *(.data..cacheline_aligned)
208
209 #define INIT_TASK_DATA(align) \
210 . = ALIGN(align); \
211 *(.data..init_task)
212
213 /*
214 * Read only Data
215 */
216 #define RO_DATA_SECTION(align) \
217 . = ALIGN((align)); \
218 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
219 VMLINUX_SYMBOL(__start_rodata) = .; \
220 *(.rodata) *(.rodata.*) \
221 *(__vermagic) /* Kernel version magic */ \
222 *(__markers_strings) /* Markers: strings */ \
223 *(__tracepoints_strings)/* Tracepoints: strings */ \
224 } \
225 \
226 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
227 *(.rodata1) \
228 } \
229 \
230 BUG_TABLE \
231 \
232 JUMP_TABLE \
233 \
234 /* PCI quirks */ \
235 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
236 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
237 *(.pci_fixup_early) \
238 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
239 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
240 *(.pci_fixup_header) \
241 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
242 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
243 *(.pci_fixup_final) \
244 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
245 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
246 *(.pci_fixup_enable) \
247 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
248 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
249 *(.pci_fixup_resume) \
250 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
251 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
252 *(.pci_fixup_resume_early) \
253 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
254 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
255 *(.pci_fixup_suspend) \
256 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
257 } \
258 \
259 /* Built-in firmware blobs */ \
260 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
261 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
262 *(.builtin_fw) \
263 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
264 } \
265 \
266 /* RapidIO route ops */ \
267 .rio_ops : AT(ADDR(.rio_ops) - LOAD_OFFSET) { \
268 VMLINUX_SYMBOL(__start_rio_switch_ops) = .; \
269 *(.rio_switch_ops) \
270 VMLINUX_SYMBOL(__end_rio_switch_ops) = .; \
271 } \
272 \
273 TRACEDATA \
274 \
275 /* Kernel symbol table: Normal symbols */ \
276 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
277 VMLINUX_SYMBOL(__start___ksymtab) = .; \
278 *(__ksymtab) \
279 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
280 } \
281 \
282 /* Kernel symbol table: GPL-only symbols */ \
283 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
284 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
285 *(__ksymtab_gpl) \
286 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
287 } \
288 \
289 /* Kernel symbol table: Normal unused symbols */ \
290 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
291 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
292 *(__ksymtab_unused) \
293 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
294 } \
295 \
296 /* Kernel symbol table: GPL-only unused symbols */ \
297 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
298 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
299 *(__ksymtab_unused_gpl) \
300 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
301 } \
302 \
303 /* Kernel symbol table: GPL-future-only symbols */ \
304 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
305 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
306 *(__ksymtab_gpl_future) \
307 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
308 } \
309 \
310 /* Kernel symbol table: Normal symbols */ \
311 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
312 VMLINUX_SYMBOL(__start___kcrctab) = .; \
313 *(__kcrctab) \
314 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
315 } \
316 \
317 /* Kernel symbol table: GPL-only symbols */ \
318 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
319 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
320 *(__kcrctab_gpl) \
321 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
322 } \
323 \
324 /* Kernel symbol table: Normal unused symbols */ \
325 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
326 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
327 *(__kcrctab_unused) \
328 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
329 } \
330 \
331 /* Kernel symbol table: GPL-only unused symbols */ \
332 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
333 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
334 *(__kcrctab_unused_gpl) \
335 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
336 } \
337 \
338 /* Kernel symbol table: GPL-future-only symbols */ \
339 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
340 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
341 *(__kcrctab_gpl_future) \
342 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
343 } \
344 \
345 /* Kernel symbol table: strings */ \
346 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
347 *(__ksymtab_strings) \
348 } \
349 \
350 /* __*init sections */ \
351 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
352 *(.ref.rodata) \
353 DEV_KEEP(init.rodata) \
354 DEV_KEEP(exit.rodata) \
355 CPU_KEEP(init.rodata) \
356 CPU_KEEP(exit.rodata) \
357 MEM_KEEP(init.rodata) \
358 MEM_KEEP(exit.rodata) \
359 } \
360 \
361 /* Built-in module parameters. */ \
362 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
363 VMLINUX_SYMBOL(__start___param) = .; \
364 *(__param) \
365 VMLINUX_SYMBOL(__stop___param) = .; \
366 . = ALIGN((align)); \
367 VMLINUX_SYMBOL(__end_rodata) = .; \
368 } \
369 . = ALIGN((align));
370
371 /* RODATA & RO_DATA provided for backward compatibility.
372 * All archs are supposed to use RO_DATA() */
373 #define RODATA RO_DATA_SECTION(4096)
374 #define RO_DATA(align) RO_DATA_SECTION(align)
375
376 #define SECURITY_INIT \
377 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
378 VMLINUX_SYMBOL(__security_initcall_start) = .; \
379 *(.security_initcall.init) \
380 VMLINUX_SYMBOL(__security_initcall_end) = .; \
381 }
382
383 /* .text section. Map to function alignment to avoid address changes
384 * during second ld run in second ld pass when generating System.map */
385 #define TEXT_TEXT \
386 ALIGN_FUNCTION(); \
387 *(.text.hot) \
388 *(.text) \
389 *(.ref.text) \
390 DEV_KEEP(init.text) \
391 DEV_KEEP(exit.text) \
392 CPU_KEEP(init.text) \
393 CPU_KEEP(exit.text) \
394 MEM_KEEP(init.text) \
395 MEM_KEEP(exit.text) \
396 *(.text.unlikely)
397
398
399 /* sched.text is aling to function alignment to secure we have same
400 * address even at second ld pass when generating System.map */
401 #define SCHED_TEXT \
402 ALIGN_FUNCTION(); \
403 VMLINUX_SYMBOL(__sched_text_start) = .; \
404 *(.sched.text) \
405 VMLINUX_SYMBOL(__sched_text_end) = .;
406
407 /* spinlock.text is aling to function alignment to secure we have same
408 * address even at second ld pass when generating System.map */
409 #define LOCK_TEXT \
410 ALIGN_FUNCTION(); \
411 VMLINUX_SYMBOL(__lock_text_start) = .; \
412 *(.spinlock.text) \
413 VMLINUX_SYMBOL(__lock_text_end) = .;
414
415 #define KPROBES_TEXT \
416 ALIGN_FUNCTION(); \
417 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
418 *(.kprobes.text) \
419 VMLINUX_SYMBOL(__kprobes_text_end) = .;
420
421 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
422 #define IRQENTRY_TEXT \
423 ALIGN_FUNCTION(); \
424 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
425 *(.irqentry.text) \
426 VMLINUX_SYMBOL(__irqentry_text_end) = .;
427 #else
428 #define IRQENTRY_TEXT
429 #endif
430
431 /* Section used for early init (in .S files) */
432 #define HEAD_TEXT *(.head.text)
433
434 #define HEAD_TEXT_SECTION \
435 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
436 HEAD_TEXT \
437 }
438
439 /*
440 * Exception table
441 */
442 #define EXCEPTION_TABLE(align) \
443 . = ALIGN(align); \
444 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
445 VMLINUX_SYMBOL(__start___ex_table) = .; \
446 *(__ex_table) \
447 VMLINUX_SYMBOL(__stop___ex_table) = .; \
448 }
449
450 /*
451 * Init task
452 */
453 #define INIT_TASK_DATA_SECTION(align) \
454 . = ALIGN(align); \
455 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
456 INIT_TASK_DATA(align) \
457 }
458
459 #ifdef CONFIG_CONSTRUCTORS
460 #define KERNEL_CTORS() . = ALIGN(8); \
461 VMLINUX_SYMBOL(__ctors_start) = .; \
462 *(.ctors) \
463 VMLINUX_SYMBOL(__ctors_end) = .;
464 #else
465 #define KERNEL_CTORS()
466 #endif
467
468 /* init and exit section handling */
469 #define INIT_DATA \
470 *(.init.data) \
471 DEV_DISCARD(init.data) \
472 CPU_DISCARD(init.data) \
473 MEM_DISCARD(init.data) \
474 KERNEL_CTORS() \
475 *(.init.rodata) \
476 MCOUNT_REC() \
477 DEV_DISCARD(init.rodata) \
478 CPU_DISCARD(init.rodata) \
479 MEM_DISCARD(init.rodata) \
480 KERNEL_DTB()
481
482 #define INIT_TEXT \
483 *(.init.text) \
484 DEV_DISCARD(init.text) \
485 CPU_DISCARD(init.text) \
486 MEM_DISCARD(init.text)
487
488 #define EXIT_DATA \
489 *(.exit.data) \
490 DEV_DISCARD(exit.data) \
491 DEV_DISCARD(exit.rodata) \
492 CPU_DISCARD(exit.data) \
493 CPU_DISCARD(exit.rodata) \
494 MEM_DISCARD(exit.data) \
495 MEM_DISCARD(exit.rodata)
496
497 #define EXIT_TEXT \
498 *(.exit.text) \
499 DEV_DISCARD(exit.text) \
500 CPU_DISCARD(exit.text) \
501 MEM_DISCARD(exit.text)
502
503 #define EXIT_CALL \
504 *(.exitcall.exit)
505
506 /*
507 * bss (Block Started by Symbol) - uninitialized data
508 * zeroed during startup
509 */
510 #define SBSS(sbss_align) \
511 . = ALIGN(sbss_align); \
512 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
513 *(.sbss) \
514 *(.scommon) \
515 }
516
517 #define BSS(bss_align) \
518 . = ALIGN(bss_align); \
519 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
520 *(.bss..page_aligned) \
521 *(.dynbss) \
522 *(.bss) \
523 *(COMMON) \
524 }
525
526 /*
527 * DWARF debug sections.
528 * Symbols in the DWARF debugging sections are relative to
529 * the beginning of the section so we begin them at 0.
530 */
531 #define DWARF_DEBUG \
532 /* DWARF 1 */ \
533 .debug 0 : { *(.debug) } \
534 .line 0 : { *(.line) } \
535 /* GNU DWARF 1 extensions */ \
536 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
537 .debug_sfnames 0 : { *(.debug_sfnames) } \
538 /* DWARF 1.1 and DWARF 2 */ \
539 .debug_aranges 0 : { *(.debug_aranges) } \
540 .debug_pubnames 0 : { *(.debug_pubnames) } \
541 /* DWARF 2 */ \
542 .debug_info 0 : { *(.debug_info \
543 .gnu.linkonce.wi.*) } \
544 .debug_abbrev 0 : { *(.debug_abbrev) } \
545 .debug_line 0 : { *(.debug_line) } \
546 .debug_frame 0 : { *(.debug_frame) } \
547 .debug_str 0 : { *(.debug_str) } \
548 .debug_loc 0 : { *(.debug_loc) } \
549 .debug_macinfo 0 : { *(.debug_macinfo) } \
550 /* SGI/MIPS DWARF 2 extensions */ \
551 .debug_weaknames 0 : { *(.debug_weaknames) } \
552 .debug_funcnames 0 : { *(.debug_funcnames) } \
553 .debug_typenames 0 : { *(.debug_typenames) } \
554 .debug_varnames 0 : { *(.debug_varnames) } \
555
556 /* Stabs debugging sections. */
557 #define STABS_DEBUG \
558 .stab 0 : { *(.stab) } \
559 .stabstr 0 : { *(.stabstr) } \
560 .stab.excl 0 : { *(.stab.excl) } \
561 .stab.exclstr 0 : { *(.stab.exclstr) } \
562 .stab.index 0 : { *(.stab.index) } \
563 .stab.indexstr 0 : { *(.stab.indexstr) } \
564 .comment 0 : { *(.comment) }
565
566 #ifdef CONFIG_GENERIC_BUG
567 #define BUG_TABLE \
568 . = ALIGN(8); \
569 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
570 VMLINUX_SYMBOL(__start___bug_table) = .; \
571 *(__bug_table) \
572 VMLINUX_SYMBOL(__stop___bug_table) = .; \
573 }
574 #else
575 #define BUG_TABLE
576 #endif
577
578 #define JUMP_TABLE \
579 . = ALIGN(8); \
580 __jump_table : AT(ADDR(__jump_table) - LOAD_OFFSET) { \
581 VMLINUX_SYMBOL(__start___jump_table) = .; \
582 *(__jump_table) \
583 VMLINUX_SYMBOL(__stop___jump_table) = .; \
584 }
585
586 #ifdef CONFIG_PM_TRACE
587 #define TRACEDATA \
588 . = ALIGN(4); \
589 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
590 VMLINUX_SYMBOL(__tracedata_start) = .; \
591 *(.tracedata) \
592 VMLINUX_SYMBOL(__tracedata_end) = .; \
593 }
594 #else
595 #define TRACEDATA
596 #endif
597
598 #define NOTES \
599 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
600 VMLINUX_SYMBOL(__start_notes) = .; \
601 *(.note.*) \
602 VMLINUX_SYMBOL(__stop_notes) = .; \
603 }
604
605 #define INIT_SETUP(initsetup_align) \
606 . = ALIGN(initsetup_align); \
607 VMLINUX_SYMBOL(__setup_start) = .; \
608 *(.init.setup) \
609 VMLINUX_SYMBOL(__setup_end) = .;
610
611 #define INITCALLS \
612 *(.initcallearly.init) \
613 VMLINUX_SYMBOL(__early_initcall_end) = .; \
614 *(.initcall0.init) \
615 *(.initcall0s.init) \
616 *(.initcall1.init) \
617 *(.initcall1s.init) \
618 *(.initcall2.init) \
619 *(.initcall2s.init) \
620 *(.initcall3.init) \
621 *(.initcall3s.init) \
622 *(.initcall4.init) \
623 *(.initcall4s.init) \
624 *(.initcall5.init) \
625 *(.initcall5s.init) \
626 *(.initcallrootfs.init) \
627 *(.initcall6.init) \
628 *(.initcall6s.init) \
629 *(.initcall7.init) \
630 *(.initcall7s.init)
631
632 #define INIT_CALLS \
633 VMLINUX_SYMBOL(__initcall_start) = .; \
634 INITCALLS \
635 VMLINUX_SYMBOL(__initcall_end) = .;
636
637 #define CON_INITCALL \
638 VMLINUX_SYMBOL(__con_initcall_start) = .; \
639 *(.con_initcall.init) \
640 VMLINUX_SYMBOL(__con_initcall_end) = .;
641
642 #define SECURITY_INITCALL \
643 VMLINUX_SYMBOL(__security_initcall_start) = .; \
644 *(.security_initcall.init) \
645 VMLINUX_SYMBOL(__security_initcall_end) = .;
646
647 #ifdef CONFIG_BLK_DEV_INITRD
648 #define INIT_RAM_FS \
649 . = ALIGN(4); \
650 VMLINUX_SYMBOL(__initramfs_start) = .; \
651 *(.init.ramfs) \
652 . = ALIGN(8); \
653 *(.init.ramfs.info)
654 #else
655 #define INIT_RAM_FS
656 #endif
657
658 /*
659 * Default discarded sections.
660 *
661 * Some archs want to discard exit text/data at runtime rather than
662 * link time due to cross-section references such as alt instructions,
663 * bug table, eh_frame, etc. DISCARDS must be the last of output
664 * section definitions so that such archs put those in earlier section
665 * definitions.
666 */
667 #define DISCARDS \
668 /DISCARD/ : { \
669 EXIT_TEXT \
670 EXIT_DATA \
671 EXIT_CALL \
672 *(.discard) \
673 *(.discard.*) \
674 }
675
676 /**
677 * PERCPU_VADDR - define output section for percpu area
678 * @vaddr: explicit base address (optional)
679 * @phdr: destination PHDR (optional)
680 *
681 * Macro which expands to output section for percpu area. If @vaddr
682 * is not blank, it specifies explicit base address and all percpu
683 * symbols will be offset from the given address. If blank, @vaddr
684 * always equals @laddr + LOAD_OFFSET.
685 *
686 * @phdr defines the output PHDR to use if not blank. Be warned that
687 * output PHDR is sticky. If @phdr is specified, the next output
688 * section in the linker script will go there too. @phdr should have
689 * a leading colon.
690 *
691 * Note that this macros defines __per_cpu_load as an absolute symbol.
692 * If there is no need to put the percpu section at a predetermined
693 * address, use PERCPU().
694 */
695 #define PERCPU_VADDR(vaddr, phdr) \
696 VMLINUX_SYMBOL(__per_cpu_load) = .; \
697 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
698 - LOAD_OFFSET) { \
699 VMLINUX_SYMBOL(__per_cpu_start) = .; \
700 *(.data..percpu..first) \
701 . = ALIGN(PAGE_SIZE); \
702 *(.data..percpu..page_aligned) \
703 *(.data..percpu..readmostly) \
704 *(.data..percpu) \
705 *(.data..percpu..shared_aligned) \
706 VMLINUX_SYMBOL(__per_cpu_end) = .; \
707 } phdr \
708 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
709
710 /**
711 * PERCPU - define output section for percpu area, simple version
712 * @align: required alignment
713 *
714 * Align to @align and outputs output section for percpu area. This
715 * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
716 * __per_cpu_start will be identical.
717 *
718 * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
719 * that __per_cpu_load is defined as a relative symbol against
720 * .data..percpu which is required for relocatable x86_32
721 * configuration.
722 */
723 #define PERCPU(align) \
724 . = ALIGN(align); \
725 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
726 VMLINUX_SYMBOL(__per_cpu_load) = .; \
727 VMLINUX_SYMBOL(__per_cpu_start) = .; \
728 *(.data..percpu..first) \
729 . = ALIGN(PAGE_SIZE); \
730 *(.data..percpu..page_aligned) \
731 *(.data..percpu..readmostly) \
732 *(.data..percpu) \
733 *(.data..percpu..shared_aligned) \
734 VMLINUX_SYMBOL(__per_cpu_end) = .; \
735 }
736
737
738 /*
739 * Definition of the high level *_SECTION macros
740 * They will fit only a subset of the architectures
741 */
742
743
744 /*
745 * Writeable data.
746 * All sections are combined in a single .data section.
747 * The sections following CONSTRUCTORS are arranged so their
748 * typical alignment matches.
749 * A cacheline is typical/always less than a PAGE_SIZE so
750 * the sections that has this restriction (or similar)
751 * is located before the ones requiring PAGE_SIZE alignment.
752 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
753 * matches the requirment of PAGE_ALIGNED_DATA.
754 *
755 * use 0 as page_align if page_aligned data is not used */
756 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
757 . = ALIGN(PAGE_SIZE); \
758 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
759 INIT_TASK_DATA(inittask) \
760 NOSAVE_DATA \
761 PAGE_ALIGNED_DATA(pagealigned) \
762 CACHELINE_ALIGNED_DATA(cacheline) \
763 READ_MOSTLY_DATA(cacheline) \
764 DATA_DATA \
765 CONSTRUCTORS \
766 }
767
768 #define INIT_TEXT_SECTION(inittext_align) \
769 . = ALIGN(inittext_align); \
770 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
771 VMLINUX_SYMBOL(_sinittext) = .; \
772 INIT_TEXT \
773 VMLINUX_SYMBOL(_einittext) = .; \
774 }
775
776 #define INIT_DATA_SECTION(initsetup_align) \
777 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
778 INIT_DATA \
779 INIT_SETUP(initsetup_align) \
780 INIT_CALLS \
781 CON_INITCALL \
782 SECURITY_INITCALL \
783 INIT_RAM_FS \
784 }
785
786 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
787 . = ALIGN(sbss_align); \
788 VMLINUX_SYMBOL(__bss_start) = .; \
789 SBSS(sbss_align) \
790 BSS(bss_align) \
791 . = ALIGN(stop_align); \
792 VMLINUX_SYMBOL(__bss_stop) = .;
Linux kernel - Deliverables
This page took 0.047016 seconds and 6 git commands to generate.