ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2018 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_GREP
  35 AC_GNU_SOURCE
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_PROG_INSTALL
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51 AC_ARG_ENABLE(64-bit-bfd,
  52 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  53 [case "${enableval}" in
  54   yes)  want64=true  ;;
  55   no)   want64=false ;;
  56   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  57 esac],[want64=false])dnl
  58
  59 AC_ARG_WITH(sysroot,
  60 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  61 [
  62  case ${with_sysroot} in
  63  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  64  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  65  esac
  66
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  68  use_sysroot=yes
  69
  70  if test "x$prefix" = xNONE; then
  71   test_prefix=/usr/local
  72  else
  73   test_prefix=$prefix
  74  fi
  75  if test "x$exec_prefix" = xNONE; then
  76   test_exec_prefix=$test_prefix
  77  else
  78   test_exec_prefix=$exec_prefix
  79  fi
  80  case ${TARGET_SYSTEM_ROOT} in
  81  "${test_prefix}"|"${test_prefix}/"*|\
  82  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  83  '${prefix}'|'${prefix}/'*|\
  84  '${exec_prefix}'|'${exec_prefix}/'*)
  85    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  86    TARGET_SYSTEM_ROOT_DEFINE="$t"
  87    ;;
  88  esac
  89 ], [
  90  use_sysroot=no
  91  TARGET_SYSTEM_ROOT=
  92  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  93 ])
  94 AC_SUBST(use_sysroot)
  95 AC_SUBST(TARGET_SYSTEM_ROOT)
  96 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  97
  98 dnl Use --enable-gold to decide if this linker should be the default.
  99 dnl "install_as_default" is set to false if gold is the default linker.
 100 dnl "installed_linker" is the installed BFD linker name.
 101 AC_ARG_ENABLE(gold,
 102 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 103 [case "${enableval}" in
 104  default)
 105    install_as_default=no
 106    installed_linker=ld.bfd
 107    ;;
 108  yes|no)
 109    install_as_default=yes
 110    installed_linker=ld.bfd
 111    ;;
 112  *)
 113    AC_MSG_ERROR([invalid --enable-gold argument])
 114    ;;
 115  esac],
 116 [install_as_default=yes
 117  installed_linker=ld.bfd])
 118 AC_SUBST(install_as_default)
 119 AC_SUBST(installed_linker)
 120
 121 AC_ARG_ENABLE([got],
 122 AS_HELP_STRING([--enable-got=<type>],
 123                [GOT handling scheme (target, single, negative, multigot)]),
 124 [case "${enableval}" in
 125   target | single | negative | multigot)  got_handling=$enableval ;;
 126   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 127 esac],
 128 [got_handling=target])
 129
 130 case "${got_handling}" in
 131   target)
 132     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 133               [Define to choose default GOT handling scheme]) ;;
 134   single)
 135     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 136               [Define to choose default GOT handling scheme]) ;;
 137   negative)
 138     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 139               [Define to choose default GOT handling scheme]) ;;
 140   multigot)
 141     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 142               [Define to choose default GOT handling scheme]) ;;
 143   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 144 esac
 145
 146 # PR gas/19109
 147 # Decide the default method for compressing debug sections.
 148 ac_default_compressed_debug_sections=unset
 149 # Provide a configure time option to override our default.
 150 AC_ARG_ENABLE(compressed_debug_sections,
 151               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 152               [compress debug sections by default])],
 153 [case ,"${enableval}", in
 154   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 155   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 156 esac])dnl
 157
 158 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 159 ac_default_new_dtags=unset
 160 # Provide a configure time option to override our default.
 161 AC_ARG_ENABLE(new_dtags,
 162               AS_HELP_STRING([--enable-new-dtags],
 163               [set DT_RUNPATH instead of DT_RPATH by default])],
 164 [case "${enableval}" in
 165   yes) ac_default_new_dtags=1 ;;
 166   no) ac_default_new_dtags=0 ;;
 167 esac])dnl
 168
 169 # Decide if -z relro should be enabled in ELF linker by default.
 170 ac_default_ld_z_relro=unset
 171 # Provide a configure time option to override our default.
 172 AC_ARG_ENABLE(relro,
 173               AS_HELP_STRING([--enable-relro],
 174               [enable -z relro in ELF linker by default]),
 175 [case "${enableval}" in
 176   yes)  ac_default_ld_z_relro=1 ;;
 177   no)  ac_default_ld_z_relro=0 ;;
 178 esac])dnl
 179
 180 # Decide if -z separate-code should be enabled in ELF linker by default.
 181 ac_default_ld_z_separate_code=unset
 182 AC_ARG_ENABLE(separate-code,
 183               AS_HELP_STRING([--enable-separate-code],
 184               [enable -z separate-code in ELF linker by default]),
 185 [case "${enableval}" in
 186   yes) ac_default_ld_z_separate_code=1 ;;
 187   no) ac_default_ld_z_separate_code=0 ;;
 188 esac])
 189
 190 # Decide which "--hash-style" to use by default
 191 # Provide a configure time option to override our default.
 192 AC_ARG_ENABLE([default-hash-style],
 193 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 194                [use this default hash style]),
 195 [case "${enable_default_hash_style}" in
 196   sysv | gnu | both) ;;
 197   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 198 esac],
 199 [case "${target}" in
 200   # Enable gnu hash only on GNU targets, but not mips
 201   mips*-*-*) enable_default_hash_style=sysv ;;
 202   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 203   *) enable_default_hash_style=sysv ;;
 204 esac])
 205
 206 case "${enable_default_hash_style}" in
 207   sysv | both) ac_default_emit_sysv_hash=1 ;;
 208   *) ac_default_emit_sysv_hash=0 ;;
 209 esac
 210
 211 case "${enable_default_hash_style}" in
 212   gnu | both) ac_default_emit_gnu_hash=1 ;;
 213   *) ac_default_emit_gnu_hash=0 ;;
 214 esac
 215
 216 AM_BINUTILS_WARNINGS
 217
 218 AM_LC_MESSAGES
 219
 220 AC_CONFIG_HEADERS([config.h:config.in])
 221
 222 # PR 14072
 223 AH_VERBATIM([00_CONFIG_H_CHECK],
 224 [/* Check that config.h is #included before system headers
 225    (this works only for glibc, but that should be enough).  */
 226 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 227 #  error config.h must be #included before system headers
 228 #endif
 229 #define __CONFIG_H__ 1])
 230
 231 if test -z "$target" ; then
 232     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 233 fi
 234 if test -z "$host" ; then
 235     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 236 fi
 237
 238 # host-specific stuff:
 239
 240 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 241 ZW_GNU_GETTEXT_SISTER_DIR
 242 AM_PO_SUBDIRS
 243
 244 AC_EXEEXT
 245
 246 AC_PROG_YACC
 247 AM_PROG_LEX
 248
 249 AM_MAINTAINER_MODE
 250 AM_CONDITIONAL(GENINSRC_NEVER, false)
 251 ACX_PROG_CMP_IGNORE_INITIAL
 252
 253 . ${srcdir}/configure.host
 254
 255 AC_SUBST(HDEFINES)
 256 AC_SUBST(NATIVE_LIB_DIRS)
 257
 258 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 259 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 260 ACX_HEADER_STRING
 261 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 262 AC_CHECK_FUNCS(open lseek close)
 263 AC_HEADER_DIRENT
 264
 265 dnl AC_CHECK_HEADERS(sys/mman.h)
 266 AC_FUNC_MMAP
 267
 268 AC_SEARCH_LIBS([dlopen], [dl])
 269 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 270
 271 AC_ARG_ENABLE(initfini-array,
 272 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 273 [case "${enableval}" in
 274  yes|no) ;;
 275  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 276  esac], [enable_initfini_array=yes])
 277 AC_SUBST(enable_initfini_array)
 278 if test $enable_initfini_array = yes; then
 279   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 280     [Define .init_array/.fini_array sections are available and working.])
 281 fi
 282
 283 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 284 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 285 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 286 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 287 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 288 if test $ld_cv_decl_getopt_unistd_h = yes; then
 289   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 290             [Is the prototype for getopt in <unistd.h> in the expected format?])
 291 fi
 292
 293 BFD_BINARY_FOPEN
 294
 295 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 296
 297 # When converting linker scripts into strings for use in emulation
 298 # files, use astring.sed if the compiler supports ANSI string
 299 # concatenation, or ostring.sed otherwise.  This is to support the
 300 # broken Microsoft MSVC compiler, which limits the length of string
 301 # constants, while still supporting pre-ANSI compilers which do not
 302 # support string concatenation.
 303 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 304 AC_CACHE_VAL(ld_cv_string_concatenation,
 305 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 306   ld_cv_string_concatenation=yes,
 307   ld_cv_string_concatenation=no)])
 308 AC_MSG_RESULT($ld_cv_string_concatenation)
 309 if test "$ld_cv_string_concatenation" = "yes"; then
 310   STRINGIFY=astring.sed
 311 else
 312   STRINGIFY=ostring.sed
 313 fi
 314 AC_SUBST(STRINGIFY)
 315
 316 # target-specific stuff:
 317
 318 all_targets=
 319 EMUL=
 320 all_emuls=
 321 all_emul_extras=
 322 all_libpath=
 323
 324 dnl We need to get an arbitrary number of tdir definitions into
 325 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 326 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 327 dnl file.
 328 rm -f tdirs
 329
 330 # If the host is 64-bit, then we enable 64-bit targets by default.
 331 # This is consistent with what ../bfd/configure.ac does.
 332 if test x${want64} = xfalse; then
 333   AC_CHECK_SIZEOF(void *)
 334   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 335     want64=true
 336   fi
 337 fi
 338
 339 elf_list_options=FALSE
 340 elf_shlib_list_options=FALSE
 341 elf_plt_unwind_list_options=FALSE
 342 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 343 do
 344   if test "$targ_alias" = "all"; then
 345     all_targets=true
 346     elf_list_options=TRUE
 347     elf_shlib_list_options=TRUE
 348     elf_plt_unwind_list_options=TRUE
 349   else
 350     # Canonicalize the secondary target names.
 351     result=`$ac_config_sub $targ_alias 2>/dev/null`
 352     if test -n "$result"; then
 353         targ=$result
 354     else
 355         targ=$targ_alias
 356     fi
 357
 358     . ${srcdir}/configure.tgt
 359
 360     if test "$targ" = "$target"; then
 361       EMUL=$targ_emul
 362     fi
 363
 364     if test x${want64} = xfalse; then
 365       . ${srcdir}/../bfd/config.bfd
 366     fi
 367
 368     if test x${want64} = xtrue; then
 369       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 370       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 371     fi
 372
 373     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 374         case " $all_emuls " in
 375         *" e${i}.o "*) ;;
 376         *)
 377           all_emuls="$all_emuls e${i}.o"
 378           eval result=\$tdir_$i
 379           test -z "$result" && result=$targ_alias
 380           echo tdir_$i=$result >> tdirs
 381           case "${i}" in
 382           *elf*)
 383             elf_list_options=TRUE
 384             ;;
 385           *)
 386             if $GREP "TEMPLATE_NAME=elf32" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 387               elf_list_options=TRUE
 388             fi
 389             ;;
 390           esac
 391           if test "$elf_list_options" = "TRUE"; then
 392             . ${srcdir}/emulparams/${i}.sh
 393             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 394               elf_shlib_list_options=TRUE
 395             fi
 396             if test x${PLT_UNWIND} = xyes; then
 397               elf_plt_unwind_list_options=TRUE
 398             fi
 399           fi
 400           ;;
 401         esac
 402     done
 403
 404     for i in $targ_emul $targ_extra_libpath; do
 405         case " $all_libpath " in
 406         *" ${i} "*) ;;
 407         *)
 408           if test -z "$all_libpath"; then
 409             all_libpath=${i}
 410           else
 411             all_libpath="$all_libpath ${i}"
 412           fi
 413           ;;
 414         esac
 415     done
 416
 417     for i in $targ_extra_ofiles; do
 418         case " $all_emul_extras " in
 419         *" ${i} "*) ;;
 420         *)
 421           all_emul_extras="$all_emul_extras ${i}"
 422           ;;
 423         esac
 424     done
 425
 426   fi
 427 done
 428
 429 if test x$ac_default_compressed_debug_sections = xyes ; then
 430   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 431 fi
 432
 433 if test "${ac_default_new_dtags}" = unset; then
 434   ac_default_new_dtags=0
 435 fi
 436 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 437   $ac_default_new_dtags,
 438   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 439
 440 if test "${ac_default_ld_z_relro}" = unset; then
 441   ac_default_ld_z_relro=0
 442 fi
 443 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 444   $ac_default_ld_z_relro,
 445   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 446
 447 if test "${ac_default_ld_z_separate_code}" = unset; then
 448   ac_default_ld_z_separate_code=0
 449 fi
 450 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 451   $ac_default_ld_z_separate_code,
 452   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 453
 454 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 455   [$ac_default_emit_sysv_hash],
 456   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 457
 458 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 459   [$ac_default_emit_gnu_hash],
 460   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 461
 462 AC_SUBST(elf_list_options)
 463 AC_SUBST(elf_shlib_list_options)
 464 AC_SUBST(elf_plt_unwind_list_options)
 465 AC_SUBST(EMUL)
 466
 467 TDIRS=tdirs
 468 AC_SUBST_FILE(TDIRS)
 469
 470 if test x${all_targets} = xtrue; then
 471   if test x${want64} = xtrue; then
 472     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 473     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 474   else
 475     EMULATION_OFILES='$(ALL_EMULATIONS)'
 476     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 477   fi
 478 else
 479   EMULATION_OFILES=$all_emuls
 480   EMUL_EXTRA_OFILES=$all_emul_extras
 481 fi
 482 AC_SUBST(EMULATION_OFILES)
 483 AC_SUBST(EMUL_EXTRA_OFILES)
 484 AC_SUBST(LIB_PATH)
 485
 486 EMULATION_LIBPATH=$all_libpath
 487 AC_SUBST(EMULATION_LIBPATH)
 488
 489 if test x${enable_static} = xno; then
 490   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 491 else
 492   TESTBFDLIB="../bfd/.libs/libbfd.a"
 493 fi
 494 AC_SUBST(TESTBFDLIB)
 495
 496 target_vendor=${target_vendor=$host_vendor}
 497 case "$target_vendor" in
 498   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 499   *)  EXTRA_SHLIB_EXTENSION= ;;
 500 esac
 501
 502 case "$target_os" in
 503   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 504 esac
 505
 506 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 507   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 508    [Additional extension a shared object might have.])
 509 fi
 510
 511 AC_CONFIG_COMMANDS([default],
 512 [[
 513 case "$srcdir" in
 514   .) srcdirpre= ;;
 515   *) srcdirpre='$(srcdir)/' ;;
 516 esac
 517 POFILES=
 518 GMOFILES=
 519 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 520   if test $lang != dummy; then
 521     POFILES="$POFILES $srcdirpre$lang.po"
 522     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 523   fi
 524 done
 525 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 526     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 527     -e "s,@POFILES@,$POFILES," \
 528     -e "s,@GMOFILES@,$GMOFILES," \
 529     po/Makefile.in > po/Makefile]],[[]])
 530
 531 dnl Required by html, pdf, install-pdf and install-html
 532 AC_SUBST(datarootdir)
 533 AC_SUBST(docdir)
 534 AC_SUBST(htmldir)
 535 AC_SUBST(pdfdir)
 536
 537 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 538 AC_OUTPUT