ld/testsuite/ld-elf/non-contiguous.ld

   1 /*
   2  section .data.1 fits in .raml
   3  sections .data.2 .data.3 fit in .ramu
   4  section .data.4 fits in .ramz
   5 */
   6 MEMORY
   7 {
   8   RAML (rwx) : ORIGIN = 0x1FFF0000, LENGTH = 0x00014
   9   RAMU (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00040
  10   RAMZ (rwx) : ORIGIN = 0x20040000, LENGTH = 0x00040
  11 }
  12
  13 SECTIONS
  14 {
  15    /* Ignore this target specific info in output comparison.  */
  16    /DISCARD/ : {
  17              *(.ARM.attributes)
  18              *(.ARC.attributes)
  19              *(.riscv.attributes)
  20              *(.c6xabi.attributes)
  21              *(.trampolines)
  22              *(.reginfo)
  23              *(.note.renesas)
  24              *(.MIPS.abiflags)
  25              *(.MSP430.attributes)
  26              *(.gnu.attributes)
  27    }
  28
  29    .raml : /*AT ( ADDR (.text) + SIZEOF (.text) )*/
  30    {  _raml_start = . ;
  31       *(.boot) ;
  32       *(.data) *(.data.*) ;
  33       _raml_end = . ;
  34    } > RAML
  35
  36    .ramu : AT ( ADDR (.raml) + SIZEOF (.raml) )
  37    {  _ramu_start = . ;
  38       *(.data) *(.data.*) ;
  39       _ramu_end = . ;
  40    } > RAMU
  41
  42    .ramz : AT ( ADDR (.ramu) + SIZEOF (.ramu) )
  43    {  _ramz_start = . ;
  44       *(.data) *(.data.*) ;
  45      _ramz_end = . ;
  46    } > RAMZ
  47 }