ld/testsuite/ld-srec/srec.exp

   1 # Test linking directly to S-records.
   2 # By Ian Lance Taylor, Cygnus Support.
   3 #   Copyright 1999, 2000, 2001, 2002, 2003, 2005, 2006, 2007, 2009, 2011
   4 #   Free Software Foundation, Inc.
   5 #
   6 # This file is part of the GNU Binutils.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  21 # MA 02110-1301, USA.
  22
  23 # Get the offset from an S-record line to the start of the data.
  24
  25 proc srec_off { l } {
  26     if [string match "S1*" $l] {
  27         return 8
  28     } else { if [string match "S2*" $l] {
  29         return 10
  30     } else { if [string match "S3*" $l] {
  31         return 12
  32     } else {
  33         return -1
  34     } } }
  35 }
  36
  37 # See if an S-record line contains only zero data.
  38
  39 proc srec_zero { l } {
  40     if [string match "S\[0789\]*" $l] {
  41         return 1
  42     }
  43
  44     # Strip the address and checksum.
  45     if [string match "S\[123\]*" $l] {
  46         set l [string range $l [srec_off $l] [expr [string length $l] - 3]]
  47     } else {
  48         return 0
  49     }
  50
  51     # The rest must be zero.
  52     return [string match "" [string trim $l "0"]]
  53 }
  54
  55 # Get the address of an S-record line.
  56
  57 proc srec_addr { l } {
  58     if [string match "S\[123\]*" $l] {
  59         set addr [string range $l 4 [expr [srec_off $l] - 1]]
  60     } else {
  61         return -1
  62     }
  63
  64     return "0x$addr"
  65 }
  66
  67 # Get the number of data bytes in an S-record line.
  68
  69 proc srec_len { l } {
  70     if ![string match "S\[123\]*" $l] {
  71         return 0
  72     }
  73
  74     return [expr "0x[string range $l 2 3]" - ([srec_off $l] - 4) / 2 - 1]
  75 }
  76
  77 # Extract bytes from an S-record line.
  78
  79 proc srec_extract { l start len } {
  80     set off [srec_off $l]
  81     set rlen [srec_len $l]
  82     set stop [expr $start + $len]
  83     if { $stop > $rlen } {
  84         set stop [expr $rlen]
  85     }
  86     set start [expr $start * 2 + $off]
  87     set stop [expr $stop * 2 + $off - 1]
  88     return [string range $l $start $stop]
  89 }
  90
  91 # See if a range of bytes in an S-record line is all zeroes.
  92
  93 proc srec_zero_range { l start len } {
  94     return [string match "" [string trim [srec_extract $l $start $len] "0"]]
  95 }
  96
  97 # Trim an S-record line such that the specified number of bytes remain
  98 # at the end.
  99
 100 proc srec_trim { l leave } {
 101     set off [srec_off $l]
 102     set addr [srec_addr $l]
 103     set len [srec_len $l]
 104
 105     if { $leave >= $len } {
 106         return $l
 107     }
 108
 109     set s1 [string range $l 0 1]
 110     set s2 [format "%02x" [expr ($off - 4) / 2 + $leave + 1]]
 111     set s3 [format "%0[expr $off - 4]x" [expr $addr + $len - $leave]]
 112     set s4 [string range $l [expr [string length $l] - ($leave * 2) - 2] end]
 113     set s "${s1}${s2}${s3}${s4}"
 114
 115     verbose "srec_trim { '$l' $leave } returning '$s'" 2
 116
 117     return $s
 118 }
 119
 120 # Report failure when comparing S-record lines
 121
 122 proc srec_compare_fail { which l1 l2 } {
 123     send_log "comparison failure $which:\n$l1\n$l2\n"
 124     verbose "comparison failure $which:\n$l1\n$l2"
 125 }
 126
 127 # Compare S-record files.  We don't want to fuss about things like
 128 # extra zeroes.  Note that BFD always sorts S-records by address.
 129
 130 proc srec_compare { f1 f2 } {
 131     set e1 [gets $f1 l1]
 132     set e2 [gets $f2 l2]
 133
 134     while { $e1 != -1 } {
 135         set l1 [string trimright $l1 "\r\n"]
 136         set l2 [string trimright $l2 "\r\n"]
 137         if { $e2 == -1 } {
 138             # If l1 contains data, it must be zero.
 139             if ![srec_zero $l1] {
 140                 send_log "data after EOF: $l1\n"
 141                 verbose "data after EOF: $l1"
 142                 return 0
 143             }
 144         } else { if { [string compare $l1 $l2] == 0 } {
 145             set e1 [gets $f1 l1]
 146             set e2 [gets $f2 l2]
 147         } else { if { [srec_zero $l1] } {
 148             set e1 [gets $f1 l1]
 149         } else { if { [srec_zero $l2] } {
 150             set e2 [gets $f2 l2]
 151         } else {
 152             # The strings are not the same, and neither is all zeroes.
 153             set a1 [srec_addr $l1]
 154             set n1 [srec_len $l1]
 155             set a2 [srec_addr $l2]
 156             set n2 [srec_len $l2]
 157
 158             if { $a1 < $a2 && ![srec_zero_range $l1 0 [expr $a2 - $a1]] } {
 159                 verbose "$a1 $a2 [srec_extract $l1 0 [expr $a2 - $a1]]" 2
 160                 srec_compare_fail 1 $l1 $l2
 161                 return 0
 162             }
 163             if { $a2 < $a1 && ![srec_zero_range $l2 0 [expr $a1 - $a2]] } {
 164                 srec_compare_fail 2 $l1 $l2
 165                 return 0
 166             }
 167
 168             # Here we know that any initial data in both lines is
 169             # zero.  Now make sure that any overlapping data matches.
 170             if { $a1 < $a2 } {
 171                 set os1 [expr $a2 - $a1]
 172                 set os2 0
 173             } else {
 174                 set os1 0
 175                 set os2 [expr $a1 - $a2]
 176             }
 177             if { $a1 + $n1 < $a2 + $n2 } {
 178                 set ol [expr $n1 - $os1]
 179             } else {
 180                 set ol [expr $n2 - $os2]
 181             }
 182
 183             set x1 [srec_extract $l1 $os1 $ol]
 184             set x2 [srec_extract $l2 $os2 $ol]
 185             if { [string compare $x1 $x2] != 0 } {
 186                 verbose "$os1 $ol $x1" 2
 187                 verbose "$os2 $ol $x2" 2
 188                 srec_compare_fail 3 $l1 $l2
 189                 return 0
 190             }
 191
 192             # These strings match.  Trim the data from the larger
 193             # string, read a new copy of the smaller string, and
 194             # continue.
 195             if { $a1 + $n1 < $a2 + $n2 } {
 196                 set l2 [srec_trim $l2 [expr ($a2 + $n2) - ($a1 + $n1)]]
 197                 set e1 [gets $f1 l1]
 198             } else { if { $a1 + $n1 > $a2 + $n2 } {
 199                 set l1 [srec_trim $l1 [expr ($a1 + $n1) - ($a2 + $n2)]]
 200                 set e2 [gets $f2 l2]
 201             } else {
 202                 set e1 [gets $f1 l1]
 203                 set e2 [gets $f2 l2]
 204             } }
 205         } } } }
 206     }
 207
 208     # We've reached the end of the first file.  The remainder of the
 209     # second file must contain only zeroes.
 210     while { $e2 != -1 } {
 211         set l2 [string trimright $l2 "\r\n"]
 212         if ![srec_zero $l2] {
 213             send_log "data after EOF: $l2\n"
 214             verbose "data after EOF: $l2"
 215             return 0
 216         }
 217         set e2 [gets $f2 l2]
 218     }
 219
 220     return 1
 221 }
 222
 223 # Link twice, objcopy, and compare
 224
 225 proc run_srec_test { test objs } {
 226     global ld
 227     global objcopy
 228     global sizeof_headers
 229     global host_triplet
 230
 231     # Tell the ELF linker to not do anything clever with .eh_frame,
 232     # not to put anything in small data, and define various symbols.
 233     set flags "--traditional-format -G 0 "
 234     append flags [ld_simple_link_defsyms]
 235
 236     # If the linker script uses SIZEOF_HEADERS, use a -Ttext argument
 237     # to force both the normal link and the S-record link to be put in
 238     # the same place.  We don't always use -Ttext because it interacts
 239     # poorly with a.out.
 240
 241     if { $sizeof_headers } {
 242         set flags "$flags -Ttext 0x1000"
 243     }
 244
 245     if [istarget sh64*-*-elf] {
 246         # This is what gcc passes to ld by default.
 247         set flags "$flags -mshelf32"
 248         # SH64 targets cannot convert format in the linker
 249         # using the -oformat command line switch.
 250         setup_xfail "sh64*-*-*"
 251     }
 252
 253     if {[istarget arm*-*-*]} {
 254         # ARM targets cannot convert format in the linker
 255         # using the --oformat command line switch
 256         setup_xfail "arm*-*-*"
 257     }
 258
 259     # V850 targets need libgcc.a
 260     if [istarget v850*-*-elf] {
 261         set objs "$objs -L ../gcc -lgcc"
 262     }
 263
 264     # Xtensa ELF targets relax by default; S-Record linker does not
 265     if [istarget xtensa*-*-*] {
 266         set flags "$flags -no-relax"
 267     }
 268
 269     if [istarget powerpc64*-*-*] {
 270         set flags "$flags --no-toc-optimize"
 271     }
 272
 273     # Epiphany needs some help too
 274     if [istarget epiphany*-*-*] {
 275         set flags "$flags --defsym _start=00000060"
 276         setup_xfail "epiphany*-*-*"
 277     }
 278
 279     if [istarget m681*-*-*] {
 280         set flags "$flags --defsym _start=0xc000"
 281         setup_xfail "m681*-*-*"
 282     }
 283
 284     if [istarget m68hc1*-*-*] {
 285         set flags "$flags --defsym _start=0xc000"
 286         setup_xfail "m68hc1*-*-*"
 287     }
 288
 289     if [istarget m9s12x*-*-*] {
 290         set flags "$flags --defsym _start=0xc000"
 291         setup_xfail "m9s12x*-*-*"
 292     }
 293
 294     if { ![ld_simple_link $ld tmpdir/sr1 "$flags $objs"] \
 295          || ![ld_simple_link $ld tmpdir/sr2.sr "$flags --oformat srec $objs"] } {
 296         fail $test
 297         return
 298     }
 299
 300     send_log "$objcopy -O srec tmpdir/sr1 tmpdir/sr1.sr\n"
 301     set exec_output [run_host_cmd "$objcopy" "-O srec tmpdir/sr1 tmpdir/sr1.sr"]
 302     set exec_output [prune_warnings $exec_output]
 303     if ![string match "" $exec_output] {
 304         send_log "$exec_output\n"
 305         verbose "$exec_output"
 306         unresolved $test
 307         return
 308     }
 309
 310     set f1 [open tmpdir/sr1.sr r]
 311     set f2 [open tmpdir/sr2.sr r]
 312     if [srec_compare $f1 $f2] {
 313         pass $test
 314     } else {
 315         fail $test
 316     }
 317     close $f1
 318     close $f2
 319 }
 320
 321 set test1 "S-records"
 322 set test2 "S-records with constructors"
 323
 324 # See whether the default linker script uses SIZEOF_HEADERS.
 325 set exec_output [run_host_cmd "$ld" "--verbose"]
 326 set sizeof_headers [string match "*SIZEOF_HEADERS*" $exec_output]
 327
 328 # First test linking a C program.  We don't require any libraries.  We
 329 # link it normally, and objcopy to the S-record format, and then link
 330 # directly to the S-record format, and require that the two files
 331 # contain the same data.
 332
 333 if { ![is_remote host] && [which $CC] == 0 } {
 334     untested $test1
 335     untested $test2
 336     return
 337 }
 338
 339 if { ![ld_compile $CC $srcdir/$subdir/sr1.c tmpdir/sr1.o] \
 340      || ![ld_compile $CC $srcdir/$subdir/sr2.c tmpdir/sr2.o] } {
 341     unresolved $test1
 342     unresolved $test2
 343     return
 344 }
 345
 346 # The i386-aout target is confused: the linker does not put the
 347 # sections where objdump finds them.  I don't know which is wrong.
 348 setup_xfail "i*86-*-aout*"
 349
 350 # These tests fail on the native MIPS ELF targets because the GP value
 351 # in the .reginfo section is not updated when the S-record version is
 352 # written out.  The mips-elf target itself does not use a .reginfo section.
 353 setup_xfail "mips*-*-irix5*" "mips*-*-irix6*" "mips*-*-linux*"
 354
 355 # The S-record linker doesn't do the magic TOC handling that XCOFF
 356 # linkers do.
 357 setup_xfail "*-*-aix*" "*-*-xcoff*"
 358
 359 # The S-record linker doesn't build ARM/Thumb stubs.
 360 setup_xfail "arm-*-coff"
 361 setup_xfail "arm-*-pe*"
 362 # setup_xfail "arm-*elf*"
 363 setup_xfail "arm*-*-linux*"
 364
 365 # The S-record linker doesn't include the .{zda} sections.
 366 setup_xfail "v850*-*-elf"
 367
 368 # The S-record linker doesn't handle Alpha Elf relaxation.
 369 setup_xfail "alpha*-*-elf*" "alpha*-*-linux-*" "alpha*-*-gnu*"
 370 setup_xfail "alpha*-*-netbsd*"
 371
 372 # The S-record linker hasn't any hope of coping with HPPA relocs.
 373 # Or MeP complex relocs.
 374 setup_xfail "hppa*-*-*" "mep-*-*"
 375
 376 # The S-record linker doesn't handle IA64 Elf relaxation.
 377 setup_xfail "ia64-*-*"
 378
 379 # The S-record linker doesn't support the special PE headers - the PE
 380 # emulation tries to write pe-specific information to the PE headers
 381 # in the output bfd, but it's not a PE bfd (it's an srec bfd)
 382 setup_xfail "*-*-cygwin*" "*-*-mingw*" "*-*-pe*" "*-*-winnt*"
 383 setup_xfail "score-*-*"
 384
 385 # The S-record linker doesn't support Blackfin ELF FDPIC ABI.
 386 setup_xfail "bfin-*-linux-uclibc"
 387
 388 # On tile, we appear to be getting some random-seeming zeroing or 24-bit
 389 # rightshifts (!) in the output when directly generating S-records from
 390 # the linker.  Not clear what could be causing this but we don't
 391 # anticipate creating s-records (and could always use objcopy to
 392 # generate the format if need be).
 393 setup_xfail "tile*-*-*"
 394
 395 run_srec_test $test1 "tmpdir/sr1.o tmpdir/sr2.o"
 396
 397 # Now try linking a C++ program with global constructors and
 398 # destructors.  Note that since we are not linking against any
 399 # libraries, this program won't actually work or anything.
 400
 401 if { ![is_remote host] && [which $CXX] == 0 } {
 402     untested $test2
 403     return
 404 }
 405
 406 if ![ld_compile "$CXX $CXXFLAGS -fno-exceptions" $srcdir/$subdir/sr3.cc tmpdir/sr3.o] {
 407     unresolved $test2
 408     return
 409 }
 410
 411 # See above.
 412 setup_xfail "i*86-*-aout*"
 413 setup_xfail "mips*-*-irix5*" "mips*-*-irix6*" "mips*-*-linux*"
 414 setup_xfail "*-*-aix*" "*-*-xcoff*"
 415 setup_xfail "arm*-*-*"
 416 setup_xfail "v850*-*-elf"
 417 setup_xfail "alpha*-*-elf*" "alpha*-*-linux-*" "alpha*-*-gnu*"
 418 setup_xfail "alpha*-*-netbsd*"
 419 setup_xfail "hppa*-*-*" "mep-*-*"
 420 setup_xfail "ia64-*-*"
 421 setup_xfail "*-*-cygwin*" "*-*-mingw*" "*-*-pe*" "*-*-winnt*"
 422 setup_xfail "score-*-*"
 423 setup_xfail "bfin-*-linux-uclibc"
 424 setup_xfail "tile*-*-*"
 425
 426 run_srec_test $test2 "tmpdir/sr3.o"