libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 GCC_NO_EXECUTABLES
 132 AC_PROG_CC
 133 AC_SYS_LARGEFILE
 134 AC_PROG_CPP_WERROR
 135
 136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 139
 140 AC_PROG_CC_C_O
 141 # autoconf is lame and doesn't give us any substitution variable for this.
 142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 143   NO_MINUS_C_MINUS_O=yes
 144 else
 145   OUTPUT_OPTION='-o $@'
 146 fi
 147 AC_SUBST(NO_MINUS_C_MINUS_O)
 148 AC_SUBST(OUTPUT_OPTION)
 149
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_BIGENDIAN
 153
 154 dnl When we start using libtool:
 155 dnl Default to a non shared library.  This may be overridden by the
 156 dnl configure option --enable-shared.
 157 dnl AM_DISABLE_SHARED
 158
 159 dnl When we start using libtool:
 160 dnl AM_PROG_LIBTOOL
 161
 162 dnl When we start using automake:
 163 dnl AM_CONFIG_HEADER(config.h:config.in)
 164 AC_CONFIG_HEADER(config.h:config.in)
 165
 166 dnl When we start using automake:
 167 dnl AM_MAINTAINER_MODE
 168 dnl AC_EXEEXT
 169
 170 dnl When we start using automake:
 171 dnl AM_PROG_INSTALL
 172 AC_PROG_INSTALL
 173
 174 # Don't build the shared library for build.
 175 if [[ -n "${with_build_subdir}" ]]; then
 176   enable_shared=no
 177 fi
 178
 179 frag=
 180 case "${host}" in
 181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 182                         frag=mh-aix ;;
 183   *-*-cxux7*)           frag=mh-cxux7 ;;
 184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 186   i370-*-opened*)       frag=mh-openedition ;;
 187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 188 esac
 189
 190 if [[ -n "${frag}" ]]; then
 191   frag=${libiberty_topdir}/libiberty/config/$frag
 192 fi
 193
 194 GCC_PICFLAG
 195
 196 # If they didn't specify --enable-shared, don't generate shared libs.
 197 case "${enable_shared}" in
 198   yes) shared=yes ;;
 199   no) shared=no ;;
 200   "") shared=no ;;
 201   *) shared=yes ;;
 202 esac
 203 if [[ "${shared}" != "yes" ]]; then
 204   PICFLAG=
 205 fi
 206 AC_SUBST(PICFLAG)
 207
 208 echo "# Warning: this fragment is automatically generated" > temp-frag
 209
 210 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 211   echo "Appending ${frag} to xhost-mkfrag"
 212   echo "# Following fragment copied from ${frag}" >> temp-frag
 213   cat ${frag} >> temp-frag
 214 fi
 215
 216 # record if we want to build shared libs.
 217 if [[ "${shared}" = "yes" ]]; then
 218   echo enable_shared = yes >> temp-frag
 219 else
 220   echo enable_shared = no >> temp-frag
 221 fi
 222
 223 frag=xhost-mkfrag
 224 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 225
 226 host_makefile_frag=${frag}
 227 AC_SUBST_FILE(host_makefile_frag)
 228
 229 # It's OK to check for header files.  Although the compiler may not be
 230 # able to link anything, it had better be able to at least compile
 231 # something.
 232 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 233 AC_HEADER_SYS_WAIT
 234 AC_HEADER_TIME
 235
 236 libiberty_AC_DECLARE_ERRNO
 237
 238 # Determine the size of an int for struct fibnode.
 239 AC_CHECK_SIZEOF([int])
 240
 241 # Look for a 64-bit type.
 242 AC_MSG_CHECKING([for a 64-bit type])
 243 AC_CACHE_VAL(liberty_cv_uint64,
 244 [AC_TRY_COMPILE(
 245 [#ifdef HAVE_STDINT_H
 246 #include <stdint.h>
 247 #endif],
 248 [extern uint64_t foo;],
 249 liberty_cv_uint64=uint64_t,
 250 [AC_TRY_COMPILE(
 251 [#ifdef HAVE_LIMITS_H
 252 #include <limits.h>
 253 #endif
 254 #ifndef CHAR_BIT
 255 #define CHAR_BIT 8
 256 #endif],
 257 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 258 liberty_cv_uint64="unsigned long",
 259 [AC_TRY_COMPILE(
 260 [#ifdef HAVE_LIMITS_H
 261 #include <limits.h>
 262 #endif
 263 #ifndef CHAR_BIT
 264 #define CHAR_BIT 8
 265 #endif],
 266 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 267 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 268 AC_MSG_RESULT($liberty_cv_uint64)
 269 if test "$liberty_cv_uint64" != none; then
 270   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 271                      [Define to an unsigned 64-bit type available in the compiler.])
 272 fi
 273
 274 AC_TYPE_INTPTR_T
 275 AC_TYPE_UINTPTR_T
 276 AC_TYPE_SSIZE_T
 277
 278 # Given the above check, we always have uintptr_t or a fallback
 279 # definition.  So define HAVE_UINTPTR_T in case any imported code
 280 # relies on it.
 281 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 282
 283 AC_TYPE_PID_T
 284
 285 # This is the list of functions which libiberty will provide if they
 286 # are not available on the host.
 287
 288 funcs="asprintf"
 289 funcs="$funcs atexit"
 290 funcs="$funcs basename"
 291 funcs="$funcs bcmp"
 292 funcs="$funcs bcopy"
 293 funcs="$funcs bsearch"
 294 funcs="$funcs bzero"
 295 funcs="$funcs calloc"
 296 funcs="$funcs clock"
 297 funcs="$funcs ffs"
 298 funcs="$funcs getcwd"
 299 funcs="$funcs getpagesize"
 300 funcs="$funcs gettimeofday"
 301 funcs="$funcs index"
 302 funcs="$funcs insque"
 303 funcs="$funcs memchr"
 304 funcs="$funcs memcmp"
 305 funcs="$funcs memcpy"
 306 funcs="$funcs memmem"
 307 funcs="$funcs memmove"
 308 funcs="$funcs mempcpy"
 309 funcs="$funcs memset"
 310 funcs="$funcs mkstemps"
 311 funcs="$funcs putenv"
 312 funcs="$funcs random"
 313 funcs="$funcs rename"
 314 funcs="$funcs rindex"
 315 funcs="$funcs setenv"
 316 funcs="$funcs snprintf"
 317 funcs="$funcs sigsetmask"
 318 funcs="$funcs stpcpy"
 319 funcs="$funcs stpncpy"
 320 funcs="$funcs strcasecmp"
 321 funcs="$funcs strchr"
 322 funcs="$funcs strdup"
 323 funcs="$funcs strncasecmp"
 324 funcs="$funcs strndup"
 325 funcs="$funcs strrchr"
 326 funcs="$funcs strstr"
 327 funcs="$funcs strtod"
 328 funcs="$funcs strtol"
 329 funcs="$funcs strtoul"
 330 funcs="$funcs strverscmp"
 331 funcs="$funcs tmpnam"
 332 funcs="$funcs vasprintf"
 333 funcs="$funcs vfprintf"
 334 funcs="$funcs vprintf"
 335 funcs="$funcs vsnprintf"
 336 funcs="$funcs vsprintf"
 337 funcs="$funcs waitpid"
 338 funcs="$funcs setproctitle"
 339
 340 # Also in the old function.def file: alloca, vfork, getopt.
 341
 342 vars="sys_errlist sys_nerr sys_siglist"
 343
 344 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 345  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 346  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 347  sysmp table times wait3 wait4"
 348
 349 # These are neither executed nor required, but they help keep
 350 # autoheader happy without adding a bunch of text to acconfig.h.
 351 if test "x" = "y"; then
 352   AC_CHECK_FUNCS(asprintf atexit \
 353     basename bcmp bcopy bsearch bzero \
 354     calloc canonicalize_file_name clock \
 355     dup3 \
 356     ffs __fsetlocking \
 357     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 358     index insque \
 359     memchr memcmp memcpy memmem memmove memset mkstemps \
 360     on_exit \
 361     psignal pstat_getdynamic pstat_getstatic putenv \
 362     random realpath rename rindex \
 363     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 364      stpcpy stpncpy strcasecmp strchr strdup \
 365      strerror strncasecmp strndup strrchr strsignal strstr strtod strtol \
 366      strtoul strverscmp sysconf sysctl sysmp \
 367     table times tmpnam \
 368     vasprintf vfprintf vprintf vsprintf \
 369     wait3 wait4 waitpid)
 370   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 371   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 372   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 373   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 374 fi
 375
 376 # For each of these functions, if the host does not provide the
 377 # function we want to put FN.o in LIBOBJS, and if the host does
 378 # provide the function, we want to define HAVE_FN in config.h.
 379
 380 setobjs=
 381 CHECK=
 382 target_header_dir=
 383 if test -n "${with_target_subdir}"; then
 384
 385   # We are being configured as a target library.  AC_REPLACE_FUNCS
 386   # may not work correctly, because the compiler may not be able to
 387   # link executables.  Note that we may still be being configured
 388   # native.
 389
 390   # If we are being configured for newlib, we know which functions
 391   # newlib provide and which ones we will be expected to provide.
 392
 393   if test "x${with_newlib}" = "xyes"; then
 394     AC_LIBOBJ([asprintf])
 395     AC_LIBOBJ([basename])
 396     AC_LIBOBJ([insque])
 397     AC_LIBOBJ([random])
 398     AC_LIBOBJ([strdup])
 399     AC_LIBOBJ([vasprintf])
 400
 401     for f in $funcs; do
 402       case "$f" in
 403         asprintf | basename | insque | random | strdup | vasprintf)
 404           ;;
 405         *)
 406           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 407           AC_DEFINE_UNQUOTED($n)
 408           ;;
 409       esac
 410     done
 411
 412     # newlib doesnt provide any of the variables in $vars, so we
 413     # dont have to check them here.
 414
 415     # Of the functions in $checkfuncs, newlib only has strerror.
 416     AC_DEFINE(HAVE_STRERROR)
 417
 418     setobjs=yes
 419
 420   fi
 421
 422   # If we are being configured for Mingw, we know which functions
 423   # Mingw provides and which ones we will be expected to provide.
 424
 425   case "${host}" in
 426   *-*-mingw*)
 427     AC_LIBOBJ([asprintf])
 428     AC_LIBOBJ([basename])
 429     AC_LIBOBJ([bcmp])
 430     AC_LIBOBJ([bcopy])
 431     AC_LIBOBJ([bzero])
 432     AC_LIBOBJ([clock])
 433     AC_LIBOBJ([ffs])
 434     AC_LIBOBJ([getpagesize])
 435     AC_LIBOBJ([index])
 436     AC_LIBOBJ([insque])
 437     AC_LIBOBJ([mempcpy])
 438     AC_LIBOBJ([mkstemps])
 439     AC_LIBOBJ([random])
 440     AC_LIBOBJ([rindex])
 441     AC_LIBOBJ([sigsetmask])
 442     AC_LIBOBJ([stpcpy])
 443     AC_LIBOBJ([stpncpy])
 444     AC_LIBOBJ([strndup])
 445     AC_LIBOBJ([strverscmp])
 446     AC_LIBOBJ([vasprintf])
 447     AC_LIBOBJ([waitpid])
 448
 449     for f in $funcs; do
 450       case "$f" in
 451         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
 452           ;;
 453         *)
 454           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 455           AC_DEFINE_UNQUOTED($n)
 456           ;;
 457       esac
 458     done
 459
 460     # Mingw doesnt provide any of the variables in $vars, so we
 461     # dont have to check them here.
 462
 463     # Of the functions in $checkfuncs, Mingw only has strerror.
 464     AC_DEFINE(HAVE_STRERROR)
 465
 466     setobjs=yes
 467     ;;
 468
 469   *-*-msdosdjgpp)
 470     AC_LIBOBJ([vasprintf])
 471     AC_LIBOBJ([vsnprintf])
 472     AC_LIBOBJ([snprintf])
 473     AC_LIBOBJ([asprintf])
 474
 475     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 476              getcwd getpagesize getrusage gettimeofday \
 477              index insque memchr memcmp memcpy memmove memset psignal \
 478              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 479              strchr strdup strerror strncasecmp strrchr strstr strtod \
 480              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 481              vsprintf waitpid
 482     do
 483       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 484       AC_DEFINE_UNQUOTED($n)
 485     done
 486
 487
 488     setobjs=yes
 489     ;;
 490
 491   esac
 492
 493   # We may wish to install the target headers somewhere.
 494   AC_ARG_ENABLE(install-libiberty,
 495   [  --enable-install-libiberty       Install headers for end users],
 496   enable_install_libiberty=$enableval,
 497   enable_install_libiberty=no)dnl
 498
 499   # Option parsed, now set things appropriately.
 500   case x"$enable_install_libiberty" in
 501     xyes|x)
 502       target_header_dir=libiberty
 503       ;;
 504     xno)
 505       target_header_dir=
 506       ;;
 507     *)
 508       # This could be sanity-checked in various ways...
 509       target_header_dir="${enable_install_libiberty}"
 510       ;;
 511   esac
 512
 513
 514 else
 515
 516    # Not a target library, so we set things up to run the test suite.
 517    CHECK=really-check
 518
 519 fi
 520
 521 AC_SUBST(CHECK)
 522 AC_SUBST(target_header_dir)
 523
 524 case "${host}" in
 525   *-*-cygwin* | *-*-mingw*)
 526     AC_DEFINE(HAVE_SYS_ERRLIST)
 527     AC_DEFINE(HAVE_SYS_NERR)
 528     ;;
 529 esac
 530
 531 if test -z "${setobjs}"; then
 532   case "${host}" in
 533
 534   *-*-vxworks*)
 535     # Handle VxWorks configuration specially, since on VxWorks the
 536     # libraries are actually on the target board, not in the file
 537     # system.
 538     AC_LIBOBJ([basename])
 539     AC_LIBOBJ([getpagesize])
 540     AC_LIBOBJ([insque])
 541     AC_LIBOBJ([random])
 542     AC_LIBOBJ([strcasecmp])
 543     AC_LIBOBJ([strncasecmp])
 544     AC_LIBOBJ([strdup])
 545     AC_LIBOBJ([vfork])
 546     AC_LIBOBJ([waitpid])
 547     AC_LIBOBJ([vasprintf])
 548     for f in $funcs; do
 549       case "$f" in
 550         basename | getpagesize | insque | random | strcasecmp)
 551           ;;
 552         strncasecmp | strdup | vfork | waitpid | vasprintf)
 553           ;;
 554         *)
 555           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 556           AC_DEFINE_UNQUOTED($n)
 557           ;;
 558       esac
 559     done
 560
 561     # VxWorks doesn't provide any of the variables in $vars, so we
 562     # don't have to check them here.
 563
 564     # Of the functions in $checkfuncs, VxWorks only has strerror.
 565     AC_DEFINE(HAVE_STRERROR)
 566
 567     setobjs=yes
 568     ;;
 569
 570   esac
 571 fi
 572
 573 if test -z "${setobjs}"; then
 574
 575   case "${host}" in
 576
 577   *-*-mingw32*)
 578     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 579     # macros, so the test below won't find them.
 580     libiberty_cv_var_sys_nerr=yes
 581     libiberty_cv_var_sys_errlist=yes
 582     ;;
 583
 584   *-*-msdosdjgpp*)
 585     # vfork and fork are stubs.
 586     ac_cv_func_vfork_works=no
 587     ;;
 588
 589   *-*-uwin*)
 590     # Under some versions of uwin, vfork is notoriously buggy and the test
 591     # can hang configure; on other versions, vfork exists just as a stub.
 592     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 593     ac_cv_func_vfork_works=no
 594     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 595     # macros (actually, these are imported from a DLL, but the end effect
 596     # is the same), so the test below won't find them.
 597     libiberty_cv_var_sys_nerr=yes
 598     libiberty_cv_var_sys_errlist=yes
 599     ;;
 600
 601   *-*-*vms*)
 602     # Under VMS, vfork works very different than on Unix. The standard test
 603     # won't work, and it isn't easily adaptable. It makes more sense to
 604     # just force it.
 605     ac_cv_func_vfork_works=yes
 606     ;;
 607
 608   esac
 609
 610   # We haven't set the list of objects yet.  Use the standard autoconf
 611   # tests.  This will only work if the compiler works.
 612   AC_ISC_POSIX
 613   AC_REPLACE_FUNCS($funcs)
 614   libiberty_AC_FUNC_C_ALLOCA
 615   AC_FUNC_FORK
 616   if test $ac_cv_func_vfork_works = no; then
 617     AC_LIBOBJ([vfork])
 618   fi
 619   # We only need _doprnt if we might use it to implement v*printf.
 620   if test $ac_cv_func_vprintf != yes \
 621      || test $ac_cv_func_vfprintf != yes \
 622      || test $ac_cv_func_vsprintf != yes; then
 623     AC_REPLACE_FUNCS(_doprnt)
 624   else
 625     AC_CHECK_FUNCS(_doprnt)
 626   fi
 627
 628   for v in $vars; do
 629     AC_MSG_CHECKING([for $v])
 630     AC_CACHE_VAL(libiberty_cv_var_$v,
 631       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 632                       [eval "libiberty_cv_var_$v=yes"],
 633                       [eval "libiberty_cv_var_$v=no"])])
 634     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 635       AC_MSG_RESULT(yes)
 636       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 637       AC_DEFINE_UNQUOTED($n)
 638     else
 639       AC_MSG_RESULT(no)
 640     fi
 641   done
 642
 643   # special check for _system_configuration because AIX <4.3.2 do not
 644   # contain the `physmem' member.
 645   AC_MSG_CHECKING([for external symbol _system_configuration])
 646   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 647                         [[double x = _system_configuration.physmem;]])],
 648     [AC_MSG_RESULT([yes])
 649     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 650               [Define if you have the _system_configuration variable.])],
 651     [AC_MSG_RESULT([no])])
 652
 653   AC_CHECK_FUNCS($checkfuncs)
 654   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 655   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 656   AC_CHECK_DECLS([strverscmp])
 657   libiberty_NEED_DECLARATION(canonicalize_file_name)
 658 fi
 659
 660 # Figure out which version of pexecute to use.
 661 case "${host}" in
 662      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 663      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 664      *-*-msdos*)                pexecute=pex-msdos  ;;
 665      *)                         pexecute=pex-unix   ;;
 666 esac
 667 AC_SUBST(pexecute)
 668
 669 libiberty_AC_FUNC_STRNCMP
 670
 671 # Install a library built with a cross compiler in $(tooldir) rather
 672 # than $(libdir).
 673 if test -z "${with_cross_host}"; then
 674   INSTALL_DEST=libdir
 675 else
 676   INSTALL_DEST=tooldir
 677 fi
 678 AC_SUBST(INSTALL_DEST)
 679
 680 m4_pattern_allow(LIBOBJS)
 681 L=""
 682 for l in x $LIBOBJS; do
 683   case $l in
 684     x) ;;
 685     *) L="$L ./$l" ;;
 686   esac
 687 done
 688 LIBOBJS="$L"
 689
 690 dnl Required by html and install-html
 691 AC_SUBST(datarootdir)
 692 AC_SUBST(docdir)
 693 AC_SUBST(htmldir)
 694
 695 # We need multilib support, but only if configuring for the target.
 696 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 697 AC_CONFIG_COMMANDS([default],
 698   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 699 if test -n "$CONFIG_FILES"; then
 700   if test -n "${with_target_subdir}"; then
 701     # FIXME: We shouldn't need to set ac_file
 702     ac_file=Makefile
 703     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 704     . ${libiberty_topdir}/config-ml.in
 705   fi
 706 fi]],
 707 [[srcdir=${srcdir}
 708 host=${host}
 709 target=${target}
 710 with_target_subdir=${with_target_subdir}
 711 with_multisubdir=${with_multisubdir}
 712 ac_configure_args="--enable-multilib ${ac_configure_args}"
 713 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 714 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 715 libiberty_topdir=${libiberty_topdir}
 716 ]])
 717 AC_OUTPUT