libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(pexecute.c)
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
   9 AC_ARG_WITH(cross-host,
  10 [  --with-cross-host=HOST           Configuring with a cross compiler])
  11 AC_ARG_WITH(newlib,
  12 [  --with-newlib                    Configuring with newlib])
  13
  14 if test "${srcdir}" = "."; then
  15   if test -z "${with_target_subdir}"; then
  16     libiberty_topdir="${srcdir}/.."
  17   else
  18     if test "${with_target_subdir}" != "."; then
  19       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  20     else
  21       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  22     fi
  23   fi
  24 else
  25   libiberty_topdir="${srcdir}/.."
  26 fi
  27 AC_CONFIG_AUX_DIR($libiberty_topdir)
  28
  29 AC_CANONICAL_HOST
  30
  31 dnl When we start using automake:
  32 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  40 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  41 # are probably using a cross compiler, which will not be able to fully
  42 # link an executable.  This should really be fixed in autoconf
  43 # itself.
  44
  45 AC_DEFUN(LIB_AC_PROG_CC,
  46 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  47 AC_PROVIDE([AC_PROG_CC])
  48 AC_CHECK_PROG(CC, gcc, gcc)
  49 if test -z "$CC"; then
  50   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  51   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  52 fi
  53
  54 AC_PROG_CC_GNU
  55
  56 if test $ac_cv_prog_gcc = yes; then
  57   GCC=yes
  58   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
  59 dnl Check whether -g works, even if CFLAGS is set, in case the package
  60 dnl plays around with CFLAGS (such as to build both debugging and
  61 dnl normal versions of a library), tasteless as that idea is.
  62   ac_test_CFLAGS="${CFLAGS+set}"
  63   ac_save_CFLAGS="$CFLAGS"
  64   CFLAGS=
  65   AC_PROG_CC_G
  66   if test "$ac_test_CFLAGS" = set; then
  67     CFLAGS="$ac_save_CFLAGS"
  68   elif test $ac_cv_prog_cc_g = yes; then
  69     CFLAGS="-g -O2"
  70   else
  71     CFLAGS="-O2"
  72   fi
  73 else
  74   GCC=
  75   ac_libiberty_warn_cflags=
  76   test "${CFLAGS+set}" = set || CFLAGS="-g"
  77 fi
  78 ])
  79 AC_SUBST(ac_libiberty_warn_cflags)
  80
  81 LIB_AC_PROG_CC
  82
  83 AC_ISC_POSIX
  84
  85 dnl When we start using libtool:
  86 dnl Default to a non shared library.  This may be overridden by the
  87 dnl configure option --enable-shared.
  88 dnl AM_DISABLE_SHARED
  89
  90 dnl When we start using libtool:
  91 dnl AM_PROG_LIBTOOL
  92
  93 dnl When we start using automake:
  94 dnl AM_CONFIG_HEADER(config.h:config.in)
  95 AC_CONFIG_HEADER(config.h:config.in)
  96
  97 dnl When we start using automake:
  98 dnl AM_MAINTAINER_MODE
  99 dnl AC_EXEEXT
 100
 101 dnl When we start using automake:
 102 dnl AM_PROG_INSTALL
 103 AC_PROG_INSTALL
 104
 105 . ${srcdir}/config.table
 106 host_makefile_frag=${frag}
 107 AC_SUBST_FILE(host_makefile_frag)
 108
 109 # It's OK to check for header files.  Although the compiler may not be
 110 # able to link anything, it had better be able to at least compile
 111 # something.
 112 AC_CHECK_HEADERS(sys/file.h sys/param.h stdlib.h string.h unistd.h strings.h sys/time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h)
 113 AC_HEADER_SYS_WAIT
 114
 115 libiberty_AC_DECLARE_ERRNO
 116
 117 # This is the list of functions which libiberty will provide if they
 118 # are not available on the host.
 119
 120 funcs="asprintf"
 121 funcs="$funcs atexit"
 122 funcs="$funcs basename"
 123 funcs="$funcs bcmp"
 124 funcs="$funcs bcopy"
 125 funcs="$funcs bzero"
 126 funcs="$funcs calloc"
 127 funcs="$funcs clock"
 128 funcs="$funcs getcwd"
 129 funcs="$funcs getpagesize"
 130 funcs="$funcs index"
 131 funcs="$funcs insque"
 132 funcs="$funcs memchr"
 133 funcs="$funcs memcmp"
 134 funcs="$funcs memcpy"
 135 funcs="$funcs memmove"
 136 funcs="$funcs memset"
 137 funcs="$funcs mkstemps"
 138 funcs="$funcs putenv"
 139 funcs="$funcs random"
 140 funcs="$funcs rename"
 141 funcs="$funcs rindex"
 142 funcs="$funcs setenv"
 143 funcs="$funcs sigsetmask"
 144 funcs="$funcs strcasecmp"
 145 funcs="$funcs strchr"
 146 funcs="$funcs strdup"
 147 funcs="$funcs strncasecmp"
 148 funcs="$funcs strrchr"
 149 funcs="$funcs strstr"
 150 funcs="$funcs strtod"
 151 funcs="$funcs strtol"
 152 funcs="$funcs strtoul"
 153 funcs="$funcs tmpnam"
 154 funcs="$funcs vasprintf"
 155 funcs="$funcs vfprintf"
 156 funcs="$funcs vprintf"
 157 funcs="$funcs vsprintf"
 158 funcs="$funcs waitpid"
 159
 160 # Also in the old function.def file: alloca, vfork, getopt.
 161
 162 vars="sys_errlist sys_nerr sys_siglist"
 163
 164 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 165
 166 # These are neither executed nor required, but they help keep
 167 # autoheader happy without adding a bunch of text to acconfig.h.
 168 if test "x" = "y"; then
 169   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bzero calloc clock getcwd)
 170   AC_CHECK_FUNCS(getpagesize index insque mkstemps memchr memcmp memcpy memmove)
 171   AC_CHECK_FUNCS(memset putenv random rename rindex sigsetmask strcasecmp)
 172   AC_CHECK_FUNCS(setenv strchr strdup strncasecmp strrchr strstr strtod strtol)
 173   AC_CHECK_FUNCS(strtoul tmpnam vasprintf vfprintf vprintf vsprintf waitpid)
 174   AC_DEFINE(HAVE_SYS_ERRLIST)
 175   AC_DEFINE(HAVE_SYS_NERR)
 176   AC_DEFINE(HAVE_SYS_SIGLIST)
 177   AC_CHECK_FUNCS(getrusage on_exit psignal strerror strsignal sysconf times)
 178   AC_CHECK_FUNCS(sbrk gettimeofday)
 179 fi
 180
 181 # For each of these functions, if the host does not provide the
 182 # function we want to put FN.o in LIBOBJS, and if the host does
 183 # provide the function, we want to define HAVE_FN in config.h.  Also,
 184 # if the host does not provide alloca, we set ALLOCA to alloca.o
 185
 186 setobjs=
 187 CHECK=
 188 if test -n "${with_target_subdir}"; then
 189
 190   # We are being configured as a target library.  AC_REPLACE_FUNCS
 191   # may not work correctly, because the compiler may not be able to
 192   # link executables.  Note that we may still be being configured
 193   # native.
 194
 195   # If we are being configured for newlib, we know which functions
 196   # newlib provide and which ones we will be expected to provide.
 197
 198   if test "x${with_newlib}" = "xyes"; then
 199     ALLOCA="alloca.o"
 200     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 201
 202     for f in $funcs; do
 203       case "$f" in
 204         asprintf | basename | insque | random | strdup | vasprintf)
 205           ;;
 206         *)
 207           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 208           AC_DEFINE_UNQUOTED($n)
 209           ;;
 210       esac
 211     done
 212
 213     # newlib doesnt provide any of the variables in $vars, so we
 214     # dont have to check them here.
 215
 216     # Of the functions in $checkfuncs, newlib only has strerror.
 217     AC_DEFINE(HAVE_STRERROR)
 218
 219     setobjs=yes
 220
 221   fi
 222
 223 else
 224
 225    # Not a target library, so we set things up to run the test suite.
 226    CHECK=check-cplus-dem
 227
 228 fi
 229
 230 AC_SUBST(CHECK)
 231
 232 if test -z "${setobjs}"; then
 233   case "${host}" in
 234
 235   *-*-vxworks*)
 236     # Handle VxWorks configuration specially, since on VxWorks the
 237     # libraries are actually on the target board, not in the file
 238     # system.
 239     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 240     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 241     for f in $funcs; do
 242       case "$f" in
 243         basename | getpagesize | insque | random | strcasecmp)
 244           ;;
 245         strncasecmp | strdup | vfork | waitpid | vasprintf)
 246           ;;
 247         *)
 248           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 249           AC_DEFINE_UNQUOTED($n)
 250           ;;
 251       esac
 252     done
 253
 254     # VxWorks doesn't provide any of the variables in $vars, so we
 255     # don't have to check them here.
 256
 257     # Of the functions in $checkfuncs, VxWorks only has strerror.
 258     AC_DEFINE(HAVE_STRERROR)
 259
 260     setobjs=yes
 261     ;;
 262
 263   esac
 264 fi
 265
 266 if test -z "${setobjs}"; then
 267
 268   case "${host}" in
 269
 270   *-*-cygwin*)
 271     # The Cygwin library actually uses a couple of files from
 272     # libiberty when it is built.  If we are building a native
 273     # Cygwin, and we run the tests, we will appear to have these
 274     # files.  However, when we go on to build winsup, we will wind up
 275     # with a library which does not have the files, since they should
 276     # have come from libiberty.
 277
 278     # We handle this by removing the functions the winsup library
 279     # provides from our shell variables, so that they appear to be
 280     # missing.
 281
 282     funcs="`echo $funcs | sed -e 's/random//'`"
 283     LIBOBJS="$LIBOBJS random.o"
 284     vars="`echo $vars | sed -e 's/sys_siglist//'`"
 285     checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 286     ;;
 287
 288   *-*-mingw32*)
 289     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 290     # macros, so the test below won't find them.
 291     vars="`echo $vars | sed -e 's/sys_nerr//' -e 's/sys_errlist//'`"
 292     AC_DEFINE(HAVE_SYS_NERR)
 293     AC_DEFINE(HAVE_SYS_ERRLIST)
 294     ;;
 295
 296   *-*-uwin*)
 297     # Under some versions of uwin, vfork is notoriously buggy and the test
 298     # can hang configure; on other versions, vfork exists just as a stub.
 299     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 300     ac_cv_func_vfork_works=no
 301     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 302     # macros (actually, these are imported from a DLL, but the end effect
 303     # is the same), so the test below won't find them.
 304     AC_DEFINE(HAVE_SYS_NERR)
 305     AC_DEFINE(HAVE_SYS_ERRLIST)
 306     ;;
 307
 308   esac
 309
 310   # We haven't set the list of objects yet.  Use the standard autoconf
 311   # tests.  This will only work if the compiler works.
 312   AC_PROG_CC_WORKS
 313   AC_REPLACE_FUNCS($funcs)
 314
 315   case "${host}" in
 316   *-*-interix)
 317     # On Interix, it wrongly concludes that the MSVC compiler supports alloca.
 318     # (MSVC does on Win32, not on Interix.)
 319     # This should be temporary.
 320
 321     ac_cv_header_alloca_h=no
 322     ac_cv_func_alloca_works=no
 323     ALLOCA=alloca.o
 324     cat >> confdefs.h <<\EOF
 325 #define C_ALLOCA 1
 326 EOF
 327     cat >> confdefs.h <<EOF
 328 #define STACK_DIRECTION -1
 329 EOF
 330     ;;
 331   *)
 332     AC_FUNC_ALLOCA
 333     ;;
 334   esac
 335
 336   AC_FUNC_VFORK
 337   if test $ac_cv_func_vfork_works = no; then
 338     LIBOBJS="$LIBOBJS vfork.o"
 339   fi
 340   for v in $vars; do
 341     AC_MSG_CHECKING([for $v])
 342     AC_CACHE_VAL(libiberty_cv_var_$v,
 343       [AC_TRY_LINK([int *p;], [extern int $v; p = &$v;],
 344                    [eval "libiberty_cv_var_$v=yes"],
 345                    [eval "libiberty_cv_var_$v=no"])])
 346     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 347       AC_MSG_RESULT(yes)
 348       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 349       AC_DEFINE_UNQUOTED($n)
 350     else
 351       AC_MSG_RESULT(no)
 352     fi
 353   done
 354   AC_CHECK_FUNCS($checkfuncs)
 355 fi
 356
 357 libiberty_AC_FUNC_STRNCMP
 358
 359 # Install a library built with a cross compiler in $(tooldir) rather
 360 # than $(libdir).
 361 if test -z "${with_cross_host}"; then
 362   INSTALL_DEST=libdir
 363 else
 364   INSTALL_DEST=tooldir
 365 fi
 366 AC_SUBST(INSTALL_DEST)
 367
 368 # We need multilib support, but only if configuring for the target.
 369 AC_OUTPUT(Makefile testsuite/Makefile,
 370 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 371 if test -n "$CONFIG_FILES"; then
 372   if test -n "${with_target_subdir}"; then
 373     # FIXME: We shouldn't need to set ac_file
 374     ac_file=Makefile
 375     . ${libiberty_topdir}/config-ml.in
 376   fi
 377 fi],
 378 srcdir=${srcdir}
 379 host=${host}
 380 target=${target}
 381 with_target_subdir=${with_target_subdir}
 382 with_multisubdir=${with_multisubdir}
 383 ac_configure_args="--enable-multilib ${ac_configure_args}"
 384 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 385 libiberty_topdir=${libiberty_topdir}
 386 )