sim/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.12.1)dnl
   3 AC_INIT(Makefile.in)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7 AC_CHECK_TOOL(AR, ar)
   8 AC_CHECK_TOOL(RANLIB, ranlib, :)
   9
  10 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  11 AC_CANONICAL_SYSTEM
  12 AC_ARG_PROGRAM
  13 AC_PROG_CC
  14 AC_SUBST(CFLAGS)
  15 AC_SUBST(HDEFINES)
  16 AR=${AR-ar}
  17 AC_SUBST(AR)
  18 AC_PROG_RANLIB
  19
  20 # Put a plausible default for CC_FOR_BUILD in Makefile.
  21 AC_C_CROSS
  22 if test "x$cross_compiling" = "xno"; then
  23   CC_FOR_BUILD='$(CC)'
  24 else
  25   CC_FOR_BUILD=gcc
  26 fi
  27 AC_SUBST(CC_FOR_BUILD)
  28
  29 # If a cpu ever has more than one simulator to choose from, use
  30 # --enable-sim=... to choose.
  31 AC_ARG_ENABLE(sim,
  32 [  --enable-sim ],
  33 [case "${enableval}" in
  34 yes | no) ;;
  35 *)      AC_MSG_ERROR(bad value ${enableval} given for --enable-sim option) ;;
  36 esac])
  37
  38 # Assume simulator can be built with cc.
  39 # If the user passes --enable-sim built it regardless of $(CC).
  40 only_if_gcc=no
  41 only_if_enabled=no
  42 extra_subdirs=common
  43
  44 # WHEN ADDING ENTRIES TO THIS MATRIX:
  45 #  Make sure that the left side always has two dashes.  Otherwise you
  46 #  can get spurious matches.  Even for unambiguous cases, do this as a
  47 #  convention, else the table becomes a real mess to understand and maintain.
  48
  49 case "${target}" in
  50   arm*-*-*)
  51         sim_target=arm
  52         extra_subdirs="${extra_subdirs} testsuite"
  53         ;;
  54   strongarm*-*-*)       sim_target=arm ;;
  55   thumb*-*-*)           sim_target=arm ;;
  56   d10v-*-*)             sim_target=d10v ;;
  57   d30v-*-*)
  58         sim_target=d30v
  59         only_if_gcc=yes
  60         extra_subdirs="${extra_subdirs} igen"
  61         ;;
  62   fr30-*-*)             sim_target=fr30 ;;
  63   h8300*-*-*)           sim_target=h8300 ;;
  64   h8500-*-*)            sim_target=h8500 ;;
  65   i960-*-*)             sim_target=i960 ;;
  66   m32r-*-*)             sim_target=m32r ;;
  67   mcore-*-*)            sim_target=mcore ;;
  68   mips*-*-*)
  69         # The MIPS simulator can only be compiled by gcc.
  70         sim_target=mips
  71         only_if_gcc=yes
  72         extra_subdirs="${extra_subdirs} igen"
  73         ;;
  74   mn10300*-*-*)
  75         # The mn10300 simulator can only be compiled by gcc.
  76         sim_target=mn10300
  77         only_if_gcc=yes
  78         extra_subdirs="${extra_subdirs} igen"
  79         ;;
  80   mn10200*-*-*)
  81         sim_target=mn10200
  82         ;;
  83   sh*-*-*)              sim_target=sh ;;
  84   powerpc*-*-eabi* | powerpc*-*-solaris* | powerpc*-*-sysv4* | powerpc*-*-elf* | powerpc*-*-linux* )
  85         # The PowerPC simulator uses the GCC extension long long as well as
  86         # ANSI prototypes, so don't enable it for random host compilers
  87         # unless asked to.
  88         sim_target=ppc
  89         only_if_gcc=yes
  90         #extra_subdirs="${extra_subdirs}"
  91         ;;
  92   v850-*-*)
  93         # The V850 simulator can only be compiled by gcc.
  94         sim_target=v850
  95         extra_subdirs="${extra_subdirs} igen"
  96         only_if_gcc=yes
  97         ;;
  98   v850e-*-*)
  99         # The V850 simulator can only be compiled by gcc.
 100         sim_target=v850
 101         extra_subdirs="${extra_subdirs} igen"
 102         only_if_gcc=yes
 103         ;;
 104   v850ea-*-*)
 105         # The V850 simulator can only be compiled by gcc.
 106         sim_target=v850
 107         extra_subdirs="${extra_subdirs} igen"
 108         only_if_gcc=yes
 109         ;;
 110   w65-*-*)
 111         sim_target=w65
 112         # The w65 is suffering from gradual decay.
 113         only_if_enabled=yes
 114         ;;
 115   z8k*-*-*)             sim_target=z8k ;;
 116   sparc64-*-*)
 117         only_if_gcc=yes
 118         sim_target=none # Don't build erc32 if sparc64.
 119         ;;
 120   sparclite*-*-* | sparc86x*-*-*)
 121         # The SPARC simulator can only be compiled by gcc.
 122         only_if_gcc=yes
 123         sim_target=erc32
 124         ;;
 125   sparc*-*-*)
 126         # The SPARC simulator can only be compiled by gcc.
 127         only_if_gcc=yes
 128         # Unfortunately erc32 won't build on many hosts, so only enable
 129         # it if the user really really wants it.
 130         only_if_enabled=yes
 131         sim_target=erc32
 132         ;;
 133   *)                    sim_target=none ;;
 134 esac
 135
 136
 137 # Is there a testsuite directory for the target?
 138 testdir=`echo ${target} | sed -e 's/-.*-/-/'`
 139 if test -r ${srcdir}/testsuite/${testdir}/configure ; then
 140   extra_subdirs="${extra_subdirs} testsuite"
 141 fi
 142
 143
 144 case "${enable_sim}" in
 145 no)     sim_target=none ;;
 146 yes)
 147         if test ${only_if_gcc} = yes ; then
 148                 if test "${GCC}" != yes ; then
 149                         echo "Can't enable simulator since not compiling with GCC."
 150                         sim_target=none
 151                 fi
 152         fi
 153         ;;
 154 *)
 155         if test ${only_if_enabled} = yes ; then
 156                 sim_target=none
 157         else
 158                 if test ${only_if_gcc} = yes ; then
 159                         if test "${GCC}" != yes ; then
 160                                 sim_target=none
 161                         fi
 162                 fi
 163         fi
 164         ;;
 165 esac
 166
 167 if test x"${sim_target}" != xnone ; then
 168         configdirs="${extra_subdirs} ${sim_target}"
 169         AC_CONFIG_SUBDIRS($configdirs)
 170 fi
 171
 172 AC_OUTPUT(Makefile)
 173
 174 exit 0