sim/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.5)dnl
   3 AC_INIT(Makefile.in)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7 AC_CHECK_TOOL(AR, ar)
   8 AC_CHECK_TOOL(RANLIB, ranlib, :)
   9
  10 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  11 AC_CANONICAL_SYSTEM
  12 AC_ARG_PROGRAM
  13 AC_PROG_CC
  14 AC_SUBST(CFLAGS)
  15 AC_SUBST(HDEFINES)
  16 AR=${AR-ar}
  17 AC_SUBST(AR)
  18 AC_PROG_RANLIB
  19
  20 # Put a plausible default for CC_FOR_BUILD in Makefile.
  21 AC_C_CROSS
  22 if test "x$cross_compiling" = "xno"; then
  23   CC_FOR_BUILD='$(CC)'
  24 else
  25   CC_FOR_BUILD=gcc
  26 fi
  27 AC_SUBST(CC_FOR_BUILD)
  28
  29 # If a cpu ever has more than one simulator to choose from, use
  30 # --enable-sim=... to choose.
  31 AC_ARG_ENABLE(sim,
  32 [  --enable-sim ],
  33 [case "${enableval}" in
  34 yes | no) ;;
  35 *)      AC_MSG_ERROR(bad value ${enableval} given for --enable-sim option) ;;
  36 esac])
  37
  38 # Assume simulator can be built with cc.
  39 # If the user passes --enable-sim built it regardless of $(CC).
  40 only_if_gcc=no
  41 only_if_enabled=no
  42 extra_subdirs=common
  43
  44 # WHEN ADDING ENTRIES TO THIS MATRIX:
  45 #  Make sure that the left side always has two dashes.  Otherwise you
  46 #  can get spurious matches.  Even for unambiguous cases, do this as a
  47 #  convention, else the table becomes a real mess to understand and maintain.
  48
  49 case "${target}" in
  50   arm*-*-*)             sim_target=arm ;;
  51   d10v-*-*)             sim_target=d10v ;;
  52 # start-sanitize-d30v
  53   d30v-*-*)
  54         sim_target=d30v
  55         only_if_gcc=yes
  56         extra_subdirs="${extra_subdirs} igen"
  57         ;;
  58 # end-sanitize-d30v
  59   h8300*-*-*)           sim_target=h8300 ;;
  60   h8500-*-*)            sim_target=h8500 ;;
  61   m32r-*-*)             sim_target=m32r ;;
  62   mips*-*-*)
  63         # The MIPS simulator can only be compiled by gcc.
  64         sim_target=mips
  65         only_if_gcc=yes
  66         ;;
  67   mn10300*-*-*)
  68         # The mn10300 simulator can only be compiled by gcc.
  69         sim_target=mn10300
  70         only_if_gcc=yes
  71         ;;
  72   mn10200*-*-*)
  73         sim_target=mn10200
  74         ;;
  75   sh*-*-*)              sim_target=sh ;;
  76   powerpc*-*-eabi* | powerpc*-*-solaris* | powerpc*-*-sysv4* | powerpc*-*-elf* | powerpc*-*-linux* )
  77         # The PowerPC simulator uses the GCC extension long long as well as
  78         # ANSI prototypes, so don't enable it for random host compilers
  79         # unless asked to.
  80         sim_target=ppc
  81         only_if_gcc=yes
  82         #extra_subdirs="${extra_subdirs}"
  83         ;;
  84 # start-sanitize-tic80
  85   tic80-*-*)
  86         sim_target=tic80
  87         only_if_gcc=yes
  88         extra_subdirs="${extra_subdirs} igen"
  89         ;;
  90 # end-sanitize-tic80
  91   v850-*-*)
  92         # The V850 simulator can only be compiled by gcc.
  93         sim_target=v850
  94         extra_subdirs="${extra_subdirs} igen"
  95         only_if_gcc=yes
  96         ;;
  97 # start-sanitize-v850e
  98   v850e-*-*)
  99         # The V850 simulator can only be compiled by gcc.
 100         sim_target=v850
 101         extra_subdirs="${extra_subdirs} igen"
 102         only_if_gcc=yes
 103         ;;
 104   v850eq-*-*)
 105         # The V850 simulator can only be compiled by gcc.
 106         sim_target=v850
 107         extra_subdirs="${extra_subdirs} igen"
 108         only_if_gcc=yes
 109         ;;
 110 # end-sanitize-v850e
 111   w65-*-*)
 112         sim_target=w65
 113         # The w65 is suffering from gradual decay.
 114         only_if_enabled=yes
 115         ;;
 116   z8k*-*-*)             sim_target=z8k ;;
 117   sparc64-*-*)
 118         sim_target=none # Don't build erc32 if sparc64.
 119         ;;
 120   sparc*-*-*)
 121         # The SPARC simulator can only be compiled by gcc.
 122         sim_target=erc32
 123         only_if_gcc=yes
 124         # Unfortunately erc32 won't build on many hosts, so only enable
 125         # it if the user really really wants it.
 126         only_if_enabled=yes
 127         ;;
 128   *)                    sim_target=none ;;
 129 esac
 130
 131
 132 # Is there a testsuite directory for the target?
 133 testdir=`echo ${target} | sed -e 's/-.*-/-/'`
 134 if test -r ${srcdir}/testsuite/${testdir}/configure ; then
 135   extra_subdirs="${extra_subdirs} testsuite"
 136 fi
 137
 138
 139 case "${enable_sim}" in
 140 no)     sim_target=none ;;
 141 yes)
 142         if test ${only_if_gcc} = yes ; then
 143                 if test "${GCC}" != yes ; then
 144                         echo "Can't enable simulator since not compiling with GCC."
 145                         sim_target=none
 146                 fi
 147         fi
 148         ;;
 149 *)
 150         if test ${only_if_enabled} = yes ; then
 151                 sim_target=none
 152         else
 153                 if test ${only_if_gcc} = yes ; then
 154                         if test "${GCC}" != yes ; then
 155                                 sim_target=none
 156                         fi
 157                 fi
 158         fi
 159         ;;
 160 esac
 161
 162 if test x"${sim_target}" != xnone ; then
 163         configdirs="${extra_subdirs} ${sim_target}"
 164         AC_CONFIG_SUBDIRS($configdirs)
 165 fi
 166
 167 AC_OUTPUT(Makefile)
 168
 169 exit 0