configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.2.6],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_AUX_DIR([config])
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  12 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_MKDIR_P
  17
  18 AC_CONFIG_HEADERS([config.h])
  19
  20 AC_SYS_LARGEFILE
  21
  22 # Checks for programs.
  23 AC_PROG_CC_STDC
  24 AC_PROG_MAKE_SET
  25 LT_INIT
  26 AC_PROG_YACC
  27 AC_PROG_LEX
  28
  29 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  30         if test x"$YACC" != "xbison -y"; then
  31                 AC_MSG_ERROR([[bison not found and is required when building from git.
  32                 Please install bison]])
  33         fi
  34         AC_PATH_PROG([BISON],[bison])
  35         AX_PROG_BISON_VERSION([2.4], [],[
  36                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  37         ])
  38 fi
  39
  40 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  41         if test x"$LEX" != "xflex"; then
  42                 AC_MSG_ERROR([[flex not found and is required when building from git.
  43                 Please install flex]])
  44         fi
  45         AC_PATH_PROG([FLEX],[flex])
  46         AX_PROG_FLEX_VERSION([2.5.35], [],[
  47                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  48         ])
  49 fi
  50
  51
  52 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  53
  54 # Checks for typedefs, structures, and compiler characteristics.
  55 AC_C_INLINE
  56 AC_TYPE_PID_T
  57 AC_TYPE_SIZE_T
  58
  59 # Checks for library functions.
  60 AC_FUNC_MALLOC
  61 AC_FUNC_MMAP
  62 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  63
  64 # Check for MinGW32.
  65 MINGW32=no
  66 case $host in
  67   *-*-mingw*)
  68         MINGW32=yes;;
  69 esac
  70
  71 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  72
  73 # Check for libuuid
  74 AC_CHECK_LIB([uuid], [uuid_generate],
  75 [
  76         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  77         have_libuuid=yes
  78 ],
  79 [
  80         # libuuid not found, check for uuid_create in libc.
  81         AC_CHECK_LIB([c], [uuid_create],
  82         [
  83                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  84                 have_libc_uuid=yes
  85         ],
  86         [
  87                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  88                 if test "x$MINGW32" = xno; then
  89                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  90                 fi
  91         ])
  92 ]
  93 )
  94 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  95 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  96
  97 # Check for fmemopen
  98 AC_CHECK_LIB([c], [fmemopen],
  99 [
 100         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 101 ]
 102 )
 103
 104 # Check for open_memstream
 105 AC_CHECK_LIB([c], [open_memstream],
 106 [
 107         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 108 ]
 109 )
 110
 111 AC_CHECK_LIB([popt], [poptGetContext], [],
 112         [AC_MSG_ERROR([Cannot find popt.])]
 113 )
 114
 115
 116 # For Python
 117 # SWIG version needed or newer:
 118 swig_version=2.0.0
 119
 120 AC_ARG_ENABLE([python-bindings],
 121               [AC_HELP_STRING([--enable-python-bindings],
 122                               [generate Python bindings])],
 123               [enable_python=yes], [enable_python=no])
 124
 125 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 126
 127 if test "x${enable_python:-yes}" = xyes; then
 128   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 129   AM_PATH_PYTHON
 130
 131   AM_PATH_PYTHON_MODULES([PYTHON])
 132   # pythondir is the path where extra modules are to be installed
 133   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 134   # pyexecdir is the path that contains shared objects used by the extra modules
 135   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 136   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 137   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 138   AS_IF([test -z "$PYTHON_INCLUDE"], [
 139     AS_IF([test -z "$PYTHON_CONFIG"], [
 140       AC_PATH_PROGS([PYTHON_CONFIG],
 141                     [python$PYTHON_VERSION-config python-config],
 142                     [no],
 143                     [`dirname $PYTHON`])
 144       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 145     ])
 146     AC_MSG_CHECKING([python include flags])
 147     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 148     AC_MSG_RESULT([$PYTHON_INCLUDE])
 149   ])
 150
 151 else
 152     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 153 [if you want Python bindings.])
 154
 155 fi
 156
 157 pkg_modules="gmodule-2.0 >= 2.0.0"
 158 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 159 AC_SUBST(PACKAGE_LIBS)
 160
 161 LIBS="$LIBS $GMODULE_LIBS"
 162 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 163 AC_SUBST(PACKAGE_CFLAGS)
 164
 165 babeltraceincludedir="${includedir}/babeltrace"
 166 AC_SUBST(babeltraceincludedir)
 167
 168 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 169 AC_SUBST(babeltracectfincludedir)
 170
 171 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 172 AC_SUBST(babeltracectfwriterincludedir)
 173
 174 AC_CONFIG_FILES([
 175         Makefile
 176         types/Makefile
 177         compat/Makefile
 178         formats/Makefile
 179         formats/ctf/Makefile
 180         formats/ctf/types/Makefile
 181         formats/ctf-text/Makefile
 182         formats/ctf-text/types/Makefile
 183         formats/ctf-metadata/Makefile
 184         formats/bt-dummy/Makefile
 185         formats/lttng-live/Makefile
 186         formats/ctf/metadata/Makefile
 187         formats/ctf/writer/Makefile
 188         converter/Makefile
 189         doc/Makefile
 190         lib/Makefile
 191         lib/prio_heap/Makefile
 192         include/Makefile
 193         bindings/Makefile
 194         bindings/python/Makefile
 195         tests/Makefile
 196         tests/bin/Makefile
 197         tests/lib/Makefile
 198         tests/utils/Makefile
 199         tests/utils/tap/Makefile
 200         extras/Makefile
 201         extras/valgrind/Makefile
 202         babeltrace.pc
 203         babeltrace-ctf.pc
 204 ])
 205 AC_OUTPUT