[deliverable/binutils-gdb.git] / libctf / configure.ac

dnl                                            -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.
dnl
dnl   Copyright (C) 2019-2021 Free Software Foundation, Inc.
dnl
dnl This file is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program; see the file COPYING.  If not see
dnl <http://www.gnu.org/licenses/>.
dnl

AC_PREREQ(2.64)
AC_INIT([libctf], 1.2.0)
AC_CONFIG_SRCDIR(ctf-impl.h)
AC_CONFIG_MACRO_DIR(..)
AC_CONFIG_MACRO_DIR(../config)
AC_CONFIG_MACRO_DIR(../bfd)
AC_USE_SYSTEM_EXTENSIONS
AM_INIT_AUTOMAKE

# Checks for programs.
AC_PROG_MAKE_SET
AC_PROG_CC
AC_PROG_RANLIB
AM_PROG_AR
ZW_GNU_GETTEXT_SISTER_DIR

dnl Default to a non shared library.  This may be overridden by the
dnl configure option --enable-shared.
AC_DISABLE_SHARED

LT_INIT
AC_SYS_LARGEFILE

MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])

# Figure out what compiler warnings we can enable.
# See config/warnings.m4 for details.

ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wno-narrowing -Wwrite-strings \
			  -Wmissing-format-attribute], [warn])
ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
			  -Wold-style-definition], [c_warn])
ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])

# Only enable with --enable-werror-always until existing warnings are
# corrected.
ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])

AM_MAINTAINER_MODE
AM_INSTALL_LIBBFD
ACX_PROG_CC_WARNING_OPTS([-Wall], [ac_libctf_warn_cflags])

AC_FUNC_MMAP
# Needed for BFD capability checks.
AC_SEARCH_LIBS(dlopen, dl)
AM_ZLIB

GCC_ENABLE([libctf-hash-debugging], [no], [], [Enable expensive debugging of CTF deduplication type hashing])
if test "${enable_libctf_hash_debugging}" = yes; then
    AC_DEFINE(ENABLE_LIBCTF_HASH_DEBUGGING, 1, [Enable expensive debugging of CTF deduplication type hashing])
fi
AM_CONDITIONAL(ENABLE_LIBCTF_HASH_DEBUGGING, test "${enable_libctf_hash_debugging}" = yes)

# Similar to GDB_AC_CHECK_BFD.
OLD_CFLAGS=$CFLAGS
OLD_LDFLAGS=$LDFLAGS
OLD_LIBS=$LIBS
# Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
# points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
# always want our bfd.
CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
ZLIBDIR=`echo $zlibdir | sed 's,\$(top_builddir)/,,g'`
LDFLAGS="-L../bfd -L../libiberty $ZLIBDIR $LDFLAGS"
intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
LIBS="-lbfd -liberty -lz $intl $LIBS"
AC_CACHE_CHECK([for ELF support in BFD], ac_cv_libctf_bfd_elf,
[AC_TRY_LINK([#include <stdlib.h>
	     #include "bfd.h"
	     #include "elf-bfd.h"],
	    [(void) bfd_section_from_elf_index (NULL, 0);
	     return 0;],
	    [ac_cv_libctf_bfd_elf=yes],
	    [ac_cv_libctf_bfd_elf=no])])
CFLAGS=$OLD_CFLAGS
LDFLAGS=$OLD_LDFLAGS
LIBS=$OLD_LIBS

if test $ac_cv_libctf_bfd_elf = yes; then
  AC_DEFINE([HAVE_BFD_ELF], 1,
	    [Whether libbfd was configured for an ELF target.])
fi

AC_C_BIGENDIAN
AC_CHECK_HEADERS(byteswap.h endian.h)
AC_CHECK_FUNCS(pread)

dnl Check for bswap_{16,32,64}
AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64], [], [], [[#include <byteswap.h>]])
AC_CHECK_DECLS([asprintf, vasprintf, stpcpy])

dnl Check for qsort_r.  (Taken from gnulib.)
AC_CHECK_FUNCS_ONCE([qsort_r])
if test $ac_cv_func_qsort_r = yes; then
  AC_CACHE_CHECK([for qsort_r signature], [ac_cv_libctf_qsort_r_signature],
    [AC_LINK_IFELSE(
       [AC_LANG_PROGRAM([[#undef qsort_r
                          #include <stdlib.h>
                          void qsort_r (void *, size_t, size_t,
                                        int (*) (void const *, void const *,
                                                 void *),
                                        void *);
                          void (*p) (void *, size_t, size_t,
                                     int (*) (void const *, void const *,
                                              void *),
                                     void *) = qsort_r;
                        ]])],
       [ac_cv_libctf_qsort_r_signature=GNU],
       [AC_LINK_IFELSE(
          [AC_LANG_PROGRAM([[#undef qsort_r
	                     #include <stdlib.h>
                             void qsort_r (void *, size_t, size_t, void *,
                                           int (*) (void *,
                                                    void const *,
                                                    void const *));
                             void (*p) (void *, size_t, size_t, void *,
                                        int (*) (void *, void const *,
                                                 void const *)) = qsort_r;
                           ]])],
          [ac_cv_libctf_qsort_r_signature=BSD],
          [ac_cv_libctf_qsort_r_signature=unknown])])])
fi

case x$ac_cv_libctf_qsort_r_signature in
  xGNU)     AC_DEFINE([HAVE_QSORT_R_ARG_LAST], 1,
	     [Whether a qsort_r exists with a void *arg as its last arg.]);;
  xBSD)     AC_DEFINE([HAVE_QSORT_R_COMPAR_LAST], 1,
	     [Whether a qsort_r exists with the compar function as its last arg.]);;
  *) ac_cv_libctf_qsort_r_signature=unknown;;
esac

AM_CONDITIONAL(NEED_CTF_QSORT_R, test "${ac_cv_libctf_qsort_r_signature}" = unknown)

AC_CACHE_CHECK([for O_CLOEXEC], [ac_cv_libctf_macro_O_CLOEXEC],
  [AC_LINK_IFELSE(
    [AC_LANG_PROGRAM([[#include <fcntl.h>
                       #ifndef O_CLOEXEC
                         choke me;
                       #endif
                     ]],
                     [[return O_CLOEXEC;]])],
    [ac_cv_libctf_macro_O_CLOEXEC=yes],
    [ac_cv_libctf_macro_O_CLOEXEC=no])])

if test $ac_cv_libctf_macro_O_CLOEXEC = yes; then
  AC_DEFINE([HAVE_O_CLOEXEC], 1,
	    [Whether the platform has a definition of O_CLOEXEC.])
fi

CTF_LIBADD="-L`pwd`/../libiberty -liberty"
SHARED_LDFLAGS=

# Horrible hacks to build DLLs on Windows and a shared library elsewhere.
if test "$enable_shared" = "yes"; then
# When building a shared libctf, link against the pic version of libiberty
# so that apps that use libctf won't need libiberty just to satisfy any
# libctf references.  We can't do that if a pic libiberty is unavailable
# since including non-pic # code would insert text relocations into libctf.
# Note that linking against libbfd as we do here, which is itself linked
# against libiberty, may not satisfy all the libctf libiberty references
# since libbfd may not pull in the entirety of libiberty.
# Also, jam libintl into the right place in all of this: after libiberty,
# which uses it, but before -lcygwin, which it uses.
changequote(,)dnl
  x=`sed -n -e 's/^[ 	]*PICFLAG[ 	]*=[ 	]*//p' < ../libiberty/Makefile | sed -n '$p'`
changequote([,])dnl
  if test -n "$x"; then
    CTF_LIBADD="-L`pwd`/../libiberty/pic -liberty"
  fi
fi

CTF_LIBADD="$CTF_LIBADD $LIBINTL"

if test "$enable_shared" = "yes"; then
  case "${host}" in
  # More hacks to build DLLs on Windows.
    *-*-cygwin*)
      SHARED_LDFLAGS="-no-undefined"
      CTF_LIBADD="$CTF_LIBADD -lcygwin"
      ;;
  esac
fi
AC_SUBST(SHARED_LDFLAGS)
AC_SUBST(CTF_LIBADD)

AC_PATH_PROG([EXPECT], [expect])
AC_CACHE_CHECK([for Tcl supporting try/catch], [ac_cv_libctf_tcl_try],
  [ac_cv_libctf_tcl_try=`if test -z $EXPECT; then echo no; else $EXPECT << EOF
if @<:@llength @<:@info commands try@:>@@:>@ then { puts yes } else { puts no }
EOF
fi`
])
AM_CONDITIONAL(TCL_TRY, test "${ac_cv_libctf_tcl_try}" = yes)

# Use a version script, if possible, or an -export-symbols-regex otherwise.
VERSION_FLAGS='-export-symbols-regex ctf_.*'
if $LD --help 2>&1 | grep -- --version-script >/dev/null; then
    VERSION_FLAGS="-Wl,--version-script='$srcdir/libctf.ver'"
fi
AC_SUBST(VERSION_FLAGS)

AC_CONFIG_FILES(Makefile)
AC_CONFIG_HEADERS(config.h)
AC_OUTPUT

GNU_MAKE_JOBSERVER
Commit	Line	Data
0e65dfba NA	1	dnl -- Autoconf --
	2	dnl Process this file with autoconf to produce a configure script.
	3	dnl
250d07de	4	dnl Copyright (C) 2019-2021 Free Software Foundation, Inc.
0e65dfba NA	5	dnl
	6	dnl This file is free software; you can redistribute it and/or modify
	7	dnl it under the terms of the GNU General Public License as published by
	8	dnl the Free Software Foundation; either version 2 of the License, or
	9	dnl (at your option) any later version.
	10	dnl
	11	dnl This program is distributed in the hope that it will be useful,
	12	dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	dnl GNU General Public License for more details.
	15	dnl
	16	dnl You should have received a copy of the GNU General Public License
	17	dnl along with this program; see the file COPYING. If not see
	18	dnl <http://www.gnu.org/licenses/>.
	19	dnl
	20
	21	AC_PREREQ(2.64)
987cf30a	22	AC_INIT([libctf], 1.2.0)
0e65dfba	23	AC_CONFIG_SRCDIR(ctf-impl.h)
a7c23ac9	24	AC_CONFIG_MACRO_DIR(..)
0e65dfba	25	AC_CONFIG_MACRO_DIR(../config)
87279e3c	26	AC_CONFIG_MACRO_DIR(../bfd)
0e65dfba NA	27	AC_USE_SYSTEM_EXTENSIONS
	28	AM_INIT_AUTOMAKE
	29
	30	# Checks for programs.
	31	AC_PROG_MAKE_SET
	32	AC_PROG_CC
	33	AC_PROG_RANLIB
	34	AM_PROG_AR
8e6635bd	35	ZW_GNU_GETTEXT_SISTER_DIR
0e65dfba	36
87279e3c NA	37	dnl Default to a non shared library. This may be overridden by the
	38	dnl configure option --enable-shared.
	39	AC_DISABLE_SHARED
	40
	41	LT_INIT
0e65dfba NA	42	AC_SYS_LARGEFILE
	43
	44	MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
	45	AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
	46	AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
	47	AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
	48
	49	# Figure out what compiler warnings we can enable.
	50	# See config/warnings.m4 for details.
	51
	52	ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wno-narrowing -Wwrite-strings \
	53	-Wmissing-format-attribute], [warn])
	54	ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
	55	-Wold-style-definition], [c_warn])
	56	ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
	57
	58	# Only enable with --enable-werror-always until existing warnings are
	59	# corrected.
	60	ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
	61
	62	AM_MAINTAINER_MODE
87279e3c	63	AM_INSTALL_LIBBFD
0e65dfba NA	64	ACX_PROG_CC_WARNING_OPTS([-Wall], [ac_libctf_warn_cflags])
	65
	66	AC_FUNC_MMAP
87279e3c	67	# Needed for BFD capability checks.
9698cf9b	68	AC_SEARCH_LIBS(dlopen, dl)
a0486bac	69	AM_ZLIB
9698cf9b	70
a9b98702 NA	71	GCC_ENABLE([libctf-hash-debugging], [no], [], [Enable expensive debugging of CTF deduplication type hashing])
	72	if test "${enable_libctf_hash_debugging}" = yes; then
	73	AC_DEFINE(ENABLE_LIBCTF_HASH_DEBUGGING, 1, [Enable expensive debugging of CTF deduplication type hashing])
	74	fi
	75	AM_CONDITIONAL(ENABLE_LIBCTF_HASH_DEBUGGING, test "${enable_libctf_hash_debugging}" = yes)
	76
9698cf9b NA	77	# Similar to GDB_AC_CHECK_BFD.
	78	OLD_CFLAGS=$CFLAGS
	79	OLD_LDFLAGS=$LDFLAGS
	80	OLD_LIBS=$LIBS
	81	# Put the old CFLAGS/LDFLAGS last, in case the user's (C\|LD)FLAGS
	82	# points somewhere with bfd, with -I/foo/lib and -L/foo/lib. We
	83	# always want our bfd.
	84	CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
	85	ZLIBDIR=`echo $zlibdir \| sed 's,\$(top_builddir)/,,g'`
	86	LDFLAGS="-L../bfd -L../libiberty $ZLIBDIR $LDFLAGS"
	87	intl=`echo $LIBINTL \| sed 's,${top_builddir}/,,g'`
	88	LIBS="-lbfd -liberty -lz $intl $LIBS"
	89	AC_CACHE_CHECK([for ELF support in BFD], ac_cv_libctf_bfd_elf,
	90	[AC_TRY_LINK([#include <stdlib.h>
	91	#include "bfd.h"
	92	#include "elf-bfd.h"],
	93	[(void) bfd_section_from_elf_index (NULL, 0);
	94	return 0;],
	95	[ac_cv_libctf_bfd_elf=yes],
	96	[ac_cv_libctf_bfd_elf=no])])
	97	CFLAGS=$OLD_CFLAGS
	98	LDFLAGS=$OLD_LDFLAGS
	99	LIBS=$OLD_LIBS
	100
	101	if test $ac_cv_libctf_bfd_elf = yes; then
	102	AC_DEFINE([HAVE_BFD_ELF], 1,
	103	[Whether libbfd was configured for an ELF target.])
	104	fi
	105
a0486bac JM	106	AC_C_BIGENDIAN
a0486bac JM	107	AC_CHECK_HEADERS(byteswap.h endian.h)
0e65dfba	108	AC_CHECK_FUNCS(pread)
6b22174f	109
e755667f NA	110	dnl Check for bswap_{16,32,64}
e755667f NA	111	AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64], [], [], [[#include <byteswap.h>]])
0f0c11f7	112	AC_CHECK_DECLS([asprintf, vasprintf, stpcpy])
3a657c60	113
6b22174f NA	114	dnl Check for qsort_r. (Taken from gnulib.)
	115	AC_CHECK_FUNCS_ONCE([qsort_r])
	116	if test $ac_cv_func_qsort_r = yes; then
	117	AC_CACHE_CHECK([for qsort_r signature], [ac_cv_libctf_qsort_r_signature],
	118	[AC_LINK_IFELSE(
	119	[AC_LANG_PROGRAM([[#undef qsort_r
	120	#include <stdlib.h>
	121	void qsort_r (void *, size_t, size_t,
	122	int () (void const , void const *,
	123	void *),
	124	void *);
	125	void (p) (void , size_t, size_t,
	126	int () (void const , void const *,
	127	void *),
	128	void *) = qsort_r;
	129	]])],
	130	[ac_cv_libctf_qsort_r_signature=GNU],
	131	[AC_LINK_IFELSE(
	132	[AC_LANG_PROGRAM([[#undef qsort_r
	133	#include <stdlib.h>
	134	void qsort_r (void , size_t, size_t, void ,
	135	int () (void ,
	136	void const *,
	137	void const *));
	138	void (p) (void , size_t, size_t, void *,
	139	int () (void , void const *,
	140	void const *)) = qsort_r;
	141	]])],
	142	[ac_cv_libctf_qsort_r_signature=BSD],
	143	[ac_cv_libctf_qsort_r_signature=unknown])])])
	144	fi
	145
	146	case x$ac_cv_libctf_qsort_r_signature in
	147	xGNU) AC_DEFINE([HAVE_QSORT_R_ARG_LAST], 1,
	148	[Whether a qsort_r exists with a void *arg as its last arg.]);;
	149	xBSD) AC_DEFINE([HAVE_QSORT_R_COMPAR_LAST], 1,
	150	[Whether a qsort_r exists with the compar function as its last arg.]);;
	151	*) ac_cv_libctf_qsort_r_signature=unknown;;
	152	esac
	153
	154	AM_CONDITIONAL(NEED_CTF_QSORT_R, test "${ac_cv_libctf_qsort_r_signature}" = unknown)
0e65dfba	155
ad118caa NA	156	AC_CACHE_CHECK([for O_CLOEXEC], [ac_cv_libctf_macro_O_CLOEXEC],
	157	[AC_LINK_IFELSE(
	158	[AC_LANG_PROGRAM([[#include <fcntl.h>
	159	#ifndef O_CLOEXEC
	160	choke me;
	161	#endif
	162	]],
	163	[[return O_CLOEXEC;]])],
	164	[ac_cv_libctf_macro_O_CLOEXEC=yes],
	165	[ac_cv_libctf_macro_O_CLOEXEC=no])])
	166
	167	if test $ac_cv_libctf_macro_O_CLOEXEC = yes; then
	168	AC_DEFINE([HAVE_O_CLOEXEC], 1,
	169	[Whether the platform has a definition of O_CLOEXEC.])
	170	fi
	171
1038406a	172	CTF_LIBADD="-L`pwd`/../libiberty -liberty"
87279e3c	173	SHARED_LDFLAGS=
95148614 NA	174
95148614 NA	175	# Horrible hacks to build DLLs on Windows and a shared library elsewhere.
87279e3c NA	176	if test "$enable_shared" = "yes"; then
	177	# When building a shared libctf, link against the pic version of libiberty
	178	# so that apps that use libctf won't need libiberty just to satisfy any
95148614 NA	179	# libctf references. We can't do that if a pic libiberty is unavailable
95148614 NA	180	# since including non-pic # code would insert text relocations into libctf.
87279e3c NA	181	# Note that linking against libbfd as we do here, which is itself linked
	182	# against libiberty, may not satisfy all the libctf libiberty references
	183	# since libbfd may not pull in the entirety of libiberty.
95148614 NA	184	# Also, jam libintl into the right place in all of this: after libiberty,
95148614 NA	185	# which uses it, but before -lcygwin, which it uses.
87279e3c NA	186	changequote(,)dnl
	187	x=`sed -n -e 's/^[ ]PICFLAG[ ]=[ ]*//p' < ../libiberty/Makefile \| sed -n '$p'`
	188	changequote([,])dnl
	189	if test -n "$x"; then
1038406a	190	CTF_LIBADD="-L`pwd`/../libiberty/pic -liberty"
87279e3c	191	fi
95148614 NA	192	fi
	193
	194	CTF_LIBADD="$CTF_LIBADD $LIBINTL"
87279e3c	195
95148614	196	if test "$enable_shared" = "yes"; then
87279e3c NA	197	case "${host}" in
	198	# More hacks to build DLLs on Windows.
	199	--cygwin*)
	200	SHARED_LDFLAGS="-no-undefined"
95148614	201	CTF_LIBADD="$CTF_LIBADD -lcygwin"
87279e3c NA	202	;;
	203	esac
	204	fi
	205	AC_SUBST(SHARED_LDFLAGS)
1038406a	206	AC_SUBST(CTF_LIBADD)
87279e3c	207
cbd8f5bb NA	208	AC_PATH_PROG([EXPECT], [expect])
	209	AC_CACHE_CHECK([for Tcl supporting try/catch], [ac_cv_libctf_tcl_try],
	210	[ac_cv_libctf_tcl_try=`if test -z $EXPECT; then echo no; else $EXPECT << EOF
	211	if @<:@llength @<:@info commands try@:>@@:>@ then { puts yes } else { puts no }
	212	EOF
	213	fi`
	214	])
	215	AM_CONDITIONAL(TCL_TRY, test "${ac_cv_libctf_tcl_try}" = yes)
	216
87279e3c NA	217	# Use a version script, if possible, or an -export-symbols-regex otherwise.
	218	VERSION_FLAGS='-export-symbols-regex ctf_.*'
	219	if $LD --help 2>&1 \| grep -- --version-script >/dev/null; then
	220	VERSION_FLAGS="-Wl,--version-script='$srcdir/libctf.ver'"
	221	fi
	222	AC_SUBST(VERSION_FLAGS)
	223
0e65dfba NA	224	AC_CONFIG_FILES(Makefile)
	225	AC_CONFIG_HEADERS(config.h)
	226	AC_OUTPUT
d546b610 L	227
d546b610 L	228	GNU_MAKE_JOBSERVER