configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre1])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([include/config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT(win32-dll)
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53
  54 # Check linker option
  55 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  56 AC_SUBST([LD_NO_AS_NEEDED])
  57
  58 AC_HEADER_STDBOOL
  59 AC_CHECK_HEADERS([ \
  60         fcntl.h \
  61         float.h \
  62         ftw.h \
  63         libintl.h \
  64         limits.h \
  65         malloc.h \
  66         netdb.h \
  67         netinet/in.h \
  68         stddef.h \
  69         sys/socket.h \
  70 ])
  71
  72 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  73         if test x"$(basename "$YACC")" != "xbison -y"; then
  74                 AC_MSG_ERROR([[bison not found and is required when building from git.
  75                 Please install bison]])
  76         fi
  77         AC_PATH_PROG([BISON],[bison])
  78         AX_PROG_BISON_VERSION([2.4], [],[
  79                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  80         ])
  81 fi
  82
  83 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  84         if test x"$LEX" != "xflex"; then
  85                 AC_MSG_ERROR([[flex not found and is required when building from git.
  86                 Please install flex]])
  87         fi
  88         AC_PATH_PROG([FLEX],[flex])
  89         AX_PROG_FLEX_VERSION([2.5.35], [],[
  90                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  91         ])
  92 fi
  93
  94
  95 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule-no-export)
  96
  97 # Check what libraries are required on this platform to link sockets programs.
  98 AX_LIB_SOCKET_NSL
  99
 100 # Checks for typedefs, structures, and compiler characteristics.
 101 AC_C_INLINE
 102 AC_TYPE_PID_T
 103 AC_TYPE_SIZE_T
 104 AC_TYPE_INT16_T
 105 AC_TYPE_INT32_T
 106 AC_TYPE_INT64_T
 107 AC_TYPE_INT8_T
 108 AC_TYPE_OFF_T
 109 AC_TYPE_SSIZE_T
 110 AC_TYPE_UINT16_T
 111 AC_TYPE_UINT32_T
 112 AC_TYPE_UINT64_T
 113 AC_TYPE_UINT8_T
 114
 115 # Checks for library functions.
 116 AC_FUNC_ALLOCA
 117 AC_FUNC_FORK
 118 AC_FUNC_MKTIME
 119 AC_FUNC_MMAP
 120 AC_FUNC_STRERROR_R
 121 AC_CHECK_FUNCS([ \
 122         atexit \
 123         dup2 \
 124         ftruncate \
 125         gethostbyname \
 126         gethostname \
 127         gettimeofday \
 128         localtime_r \
 129         memchr \
 130         memset \
 131         mkdir \
 132         mkdtemp \
 133         munmap \
 134         rmdir \
 135         setenv \
 136         socket \
 137         strchr \
 138         strdup \
 139         strerror \
 140         strndup \
 141         strnlen \
 142         strrchr \
 143         strtoul \
 144         strtoull \
 145         tzset \
 146         uname \
 147 ])
 148
 149 # AC_FUNC_MALLOC causes problems when cross-compiling.
 150 #AC_FUNC_MALLOC
 151 #AC_FUNC_REALLOC
 152
 153 MINGW32=no
 154 DEFAULT_ENABLE_DEBUG_INFO=yes
 155 LT_NO_UNDEFINED=""
 156 AS_CASE([$host_os],
 157   [solaris*|darwin*],
 158     [
 159         DEFAULT_ENABLE_DEBUG_INFO=no
 160     ],
 161   [cygwin*],
 162     [
 163         DEFAULT_ENABLE_DEBUG_INFO=no
 164         LT_NO_UNDEFINED="-no-undefined"
 165     ],
 166   [mingw*],
 167     [
 168         MINGW32=yes
 169         DEFAULT_ENABLE_DEBUG_INFO=no
 170         LT_NO_UNDEFINED="-no-undefined"
 171     ]
 172 )
 173
 174 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 175 AC_SUBST(LT_NO_UNDEFINED)
 176
 177 # Check for uuid in system libs
 178 AC_CHECK_FUNCS([uuid_generate],
 179 [
 180   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 181   link_with_libuuid=no
 182 ],
 183 [
 184   # First, check the pkg-config module is available, otherwise explicitly check
 185   # for libuuid, or uuid support in the C-library.
 186   PKG_CHECK_MODULES([UUID], [uuid],
 187   [
 188     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 189     link_with_libuuid=yes
 190   ],
 191   [
 192     # Check for libuuid
 193     AC_CHECK_LIB([uuid], [uuid_generate],
 194     [
 195       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 196       link_with_libuuid=yes
 197     ],
 198     [
 199       # libuuid not found, check for uuid_create in libc.
 200       AC_CHECK_LIB([c], [uuid_create],
 201       [
 202         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 203         link_with_libc_uuid=yes
 204       ],
 205       [
 206         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 207         if test "x$MINGW32" = xno; then
 208           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 209         fi
 210       ])
 211     ])
 212   ])
 213 ])
 214
 215 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 216 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 217
 218 # Check for fmemopen
 219 AC_CHECK_LIB([c], [fmemopen],
 220 [
 221         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 222 ]
 223 )
 224
 225 # Check for open_memstream
 226 AC_CHECK_LIB([c], [open_memstream],
 227 [
 228         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 229 ]
 230 )
 231
 232 # Check for posix_fallocate
 233 AC_CHECK_LIB([c], [posix_fallocate],
 234 [
 235         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 236 ]
 237 )
 238
 239 AC_CHECK_LIB([popt], [poptGetContext], [],
 240         [AC_MSG_ERROR([Cannot find popt.])]
 241 )
 242
 243 # Plugins
 244 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 245 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 246
 247 # For Python
 248 # SWIG version needed or newer:
 249 swig_version=2.0.0
 250
 251 AC_ARG_ENABLE([python-bindings],
 252               [AC_HELP_STRING([--enable-python-bindings],
 253                               [generate Python bindings])],
 254               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 255
 256 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 257
 258 AC_ARG_ENABLE(
 259         [python-plugins],
 260         [AC_HELP_STRING(
 261                 [--enable-python-plugins],
 262                 [add support for the Babeltrace library and converter to load Python plugins])
 263         ],
 264         [enable_python_plugins=$enableval],
 265         [enable_python_plugins=no]
 266 )
 267
 268 if test "x${enable_python_bindings:-yes}" = xyes; then
 269   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 270 else
 271     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 272 [if you want Python bindings.])
 273 fi
 274
 275 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 276   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 277
 278   AM_PATH_PYTHON_MODULES([PYTHON])
 279   # pythondir is the path where extra modules are to be installed
 280   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 281   # pyexecdir is the path that contains shared objects used by the extra modules
 282   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 283   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 284   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 285   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 286   AS_IF([test -z "$PYTHON_INCLUDE"], [
 287     AS_IF([test -z "$PYTHON_CONFIG"], [
 288       AC_PATH_PROGS([PYTHON_CONFIG],
 289                     [python$PYTHON_VERSION-config python-config],
 290                     [no],
 291                     [`dirname $PYTHON`])
 292       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 293     ])
 294     AC_MSG_CHECKING([Python include flags])
 295     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 296     AC_MSG_RESULT([$PYTHON_INCLUDE])
 297   ])
 298   AS_IF([test -z "$PYTHON_LIBS"], [
 299     AS_IF([test -z "$PYTHON_CONFIG"], [
 300       AC_PATH_PROGS([PYTHON_CONFIG],
 301                     [python$PYTHON_VERSION-config python-config],
 302                     [no],
 303                     [`dirname $PYTHON`])
 304       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 305     ])
 306     AC_MSG_CHECKING([Python library flags])
 307     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 308     AC_MSG_RESULT([$PYTHON_LIBS])
 309   ])
 310 fi
 311
 312 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 313
 314 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 315 AS_IF(
 316   [test "x$enable_python_plugins" != xno],
 317   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 318 )
 319
 320 AC_ARG_ENABLE([python-bindings-doc],
 321               [AC_HELP_STRING([--enable-python-bindings-doc],
 322                               [generate Python bindings documentation])],
 323               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 324
 325 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 326
 327 AC_ARG_ENABLE([python-bindings-tests],
 328               [AC_HELP_STRING([--enable-python-bindings-tests],
 329                               [test Python bindings])],
 330               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 331
 332 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 333
 334 if test "x${enable_python_bindings:-no}" = xno; then
 335   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 336     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 337   fi
 338
 339   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 340     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 341   fi
 342 fi
 343
 344 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 345     AM_CHECK_PYTHON_SPHINX([PYTHON])
 346     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 347       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 348     )
 349 fi
 350
 351 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 352     AM_CHECK_PYTHON_TAPPY([PYTHON])
 353     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 354         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 355     )
 356 fi
 357
 358 # Set default enable state for debug info.
 359 # The _enable_debug_info variable is prepended with an underscore to
 360 # avoid clashing with the one generated by AC_ARG_ENABLE.
 361 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 362
 363 # Optional debug info feature
 364 # Do _not_ indent the help string below (appears in the configure --help
 365 # output).
 366 AC_ARG_ENABLE([debug-info],
 367 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 368 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 369         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 370
 371 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 372
 373 AS_IF([test "x$_enable_debug_info" = xyes], [
 374         # Check if libelf and libdw are present
 375         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 376         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 377         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 378         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 379 ], [])
 380
 381 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 382 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 383 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 384         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 385         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 386         built_in_plugins=yes
 387         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 388 ])
 389 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 390
 391 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 392 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 393 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 394   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 395   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 396   AS_IF([test "x$enable_python_plugins" = "xno"], [
 397     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 398   ])
 399   built_in_python_plugin_support=yes
 400   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 401 ])
 402 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 403
 404 PKG_CHECK_MODULES(GMODULE, [gmodule-no-export-2.0 >= 2.0.0])
 405
 406 # Logging
 407 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 408 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=VERBOSE])
 409 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 410         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 411 ])
 412 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 413
 414 AM_CFLAGS="-Wall -Wformat $PTHREAD_CFLAGS $GLIB_CFLAGS"
 415 AC_SUBST(AM_CFLAGS)
 416
 417 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 418 AC_SUBST(AM_CPPFLAGS)
 419
 420 LIBS="$GLIB_LIBS"
 421
 422 babeltraceincludedir="${includedir}/babeltrace"
 423 AC_SUBST(babeltraceincludedir)
 424
 425 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 426 AC_SUBST(babeltracectfwriterincludedir)
 427
 428 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 429 AC_SUBST(babeltracectfincludedir)
 430
 431 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 432 AC_SUBST(babeltracectfirincludedir)
 433
 434 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 435 AC_SUBST(babeltracepluginincludedir)
 436
 437 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 438 AC_SUBST(babeltracegraphincludedir)
 439
 440 program_transform_name="s&babeltrace\.bin&babeltrace&;s&babeltrace-log\.bin&babeltrace-log&;$program_transform_name"
 441 AC_SUBST(program_transform_name)
 442
 443 # check for Doxygen
 444 AC_ARG_ENABLE(
 445   [api-doc],
 446   [AC_HELP_STRING(
 447     [--enable-api-doc],
 448     [generate and install HTML API documentation]
 449   )],
 450   [enable_api_doc=$enableval],
 451   [enable_api_doc=no]
 452 )
 453 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 454
 455 AS_IF([test "x$enable_api_doc" = "xyes"], [
 456   DX_DOXYGEN_FEATURE(ON)
 457   DX_DOT_FEATURE(OFF)
 458   DX_HTML_FEATURE(ON)
 459   DX_CHM_FEATURE(OFF)
 460   DX_CHI_FEATURE(OFF)
 461   DX_MAN_FEATURE(OFF)
 462   DX_RTF_FEATURE(OFF)
 463   DX_XML_FEATURE(OFF)
 464   DX_PDF_FEATURE(OFF)
 465   DX_PS_FEATURE(OFF)
 466   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 467 ])
 468
 469         #TODO: removed, work in progress
 470         #bindings/python/Makefile
 471         #bindings/python/babeltrace/Makefile
 472         #bindings/python/bt2/Makefile
 473         #bindings/python/bt2/__init__.py
 474 AC_CONFIG_FILES([
 475         Makefile
 476         common/Makefile
 477         compat/Makefile
 478         cli/Makefile
 479         doc/Makefile
 480         doc/api/Makefile
 481         doc/api/Doxyfile
 482         doc/bindings/Makefile
 483         doc/bindings/python/Makefile
 484         doc/images/Makefile
 485         lib/Makefile
 486         lib/prio_heap/Makefile
 487         lib/plugin/Makefile
 488         lib/graph/Makefile
 489         lib/graph/notification/Makefile
 490         lib/ctf-ir/Makefile
 491         lib/ctf-writer/Makefile
 492         include/Makefile
 493         logging/Makefile
 494         bindings/Makefile
 495         tests/Makefile
 496         tests/cli/Makefile
 497         tests/cli/intersection/Makefile
 498         tests/lib/Makefile
 499         tests/lib/writer/Makefile
 500         tests/lib/test-plugin-plugins/Makefile
 501         tests/utils/Makefile
 502         tests/utils/tap/Makefile
 503         tests/bindings/Makefile
 504         tests/bindings/python/Makefile
 505         tests/bindings/python/bt2/Makefile
 506         tests/plugins/Makefile
 507         extras/Makefile
 508         extras/valgrind/Makefile
 509         plugins/Makefile
 510         plugins/ctf/Makefile
 511         plugins/ctf/common/Makefile
 512         plugins/ctf/common/btr/Makefile
 513         plugins/ctf/common/metadata/Makefile
 514         plugins/ctf/common/notif-iter/Makefile
 515         plugins/ctf/fs-src/Makefile
 516         plugins/ctf/fs-sink/Makefile
 517         plugins/ctf/lttng-live/Makefile
 518         plugins/text/Makefile
 519   plugins/text/dmesg/Makefile
 520         plugins/text/pretty/Makefile
 521         plugins/utils/Makefile
 522         plugins/utils/dummy/Makefile
 523         plugins/utils/counter/Makefile
 524         plugins/utils/trimmer/Makefile
 525         plugins/utils/muxer/Makefile
 526         python-plugin-provider/Makefile
 527         plugins/libctfcopytrace/Makefile
 528         plugins/lttng-utils/Makefile
 529         babeltrace.pc
 530         babeltrace-ctf.pc
 531 ])
 532
 533 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 534 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 535 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 536 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 537 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 538
 539 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 540
 541 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 542 AC_CONFIG_FILES([tests/cli/test_trace_copy], [chmod +x tests/cli/test_trace_copy])
 543 AC_CONFIG_FILES([tests/cli/test_debug_info], [chmod +x tests/cli/test_debug_info])
 544 AC_CONFIG_FILES([tests/cli/test_trimmer], [chmod +x tests/cli/test_trimmer])
 545 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 546 AC_CONFIG_FILES([tests/cli/test_convert_args], [chmod +x tests/cli/test_convert_args])
 547 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 548 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 549 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 550 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 551 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 552
 553 AS_IF([test "x$enable_python" = "xyes"], [
 554         AC_CONFIG_FILES(
 555                 [tests/bindings/python/bt2/testall.sh],
 556                 [chmod +x tests/bindings/python/bt2/testall.sh]
 557         )
 558 ])
 559
 560 AC_OUTPUT
 561
 562 #
 563 # Mini-report on what will be built.
 564 #
 565
 566 PPRINT_INIT
 567 PPRINT_SET_INDENT(1)
 568 PPRINT_SET_TS(38)
 569
 570 AS_ECHO
 571 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 572 AS_ECHO
 573
 574 PPRINT_SUBTITLE([System])
 575
 576 # Target architecture we're building for.
 577 target_arch=$host_cpu
 578 [
 579 for f in $CFLAGS; do
 580         if test $f = "-m32"; then
 581                 target_arch="32-bit"
 582         elif test $f = "-m64"; then
 583                 target_arch="64-bit"
 584         fi
 585 done
 586 ]
 587
 588 PPRINT_PROP_STRING([Target architecture], $target_arch)
 589
 590 AS_ECHO
 591 PPRINT_SUBTITLE([Python 3 language support])
 592 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 593 PPRINT_PROP_BOOL([Python bindings], $value)
 594 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 595 PPRINT_PROP_BOOL([Python plugin support], $value)
 596 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 597   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 598   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 599 ])
 600
 601 AS_ECHO
 602 PPRINT_SUBTITLE([Plugins])
 603 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 604 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 605 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 606 PPRINT_PROP_BOOL(['text' plugin], 1)
 607 PPRINT_PROP_BOOL(['utils' plugin], 1)
 608
 609 AS_ECHO
 610 PPRINT_SUBTITLE([Built-in features])
 611 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 612 PPRINT_PROP_BOOL([Built-in plugins], $value)
 613 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 614 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 615
 616 AS_ECHO
 617 PPRINT_SUBTITLE([Documentation])
 618 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 619 PPRINT_PROP_BOOL([HTML API documentation], $value)
 620 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 621 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 622
 623 AS_ECHO
 624 PPRINT_SUBTITLE([Logging])
 625 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 626
 627 AS_ECHO
 628 PPRINT_SUBTITLE([Testing])
 629 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 630 PPRINT_PROP_BOOL([Python bindings tests], $value)
 631
 632 report_bindir="`eval eval echo $bindir`"
 633 report_libdir="`eval eval echo $libdir`"
 634 report_sysconfdif="`eval eval echo $sysconfdir`"
 635
 636 # Print the bindir and libdir this `make install' will install into.
 637 AS_ECHO
 638 PPRINT_SUBTITLE([Install directories])
 639 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 640 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 641 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 642 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])