opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  47 AC_ARG_ENABLE(build-warnings,
  48 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  49 [case "${enableval}" in
  50   yes)  ;;
  51   no)   build_warnings="-w";;
  52   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  53         build_warnings="${build_warnings} ${t}";;
  54   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  55         build_warnings="${t} ${build_warnings}";;
  56   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  57 esac
  58 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  59   echo "Setting warning flags = $build_warnings" 6>&1
  60 fi])dnl
  61 WARN_CFLAGS=""
  62 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  63     WARN_CFLAGS="${build_warnings}"
  64 fi
  65 AC_SUBST(WARN_CFLAGS)
  66
  67 AM_CONFIG_HEADER(config.h:config.in)
  68
  69 if test -z "$target" ; then
  70     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  71 fi
  72
  73 AM_MAINTAINER_MODE
  74 AM_INSTALL_LIBBFD
  75 AC_EXEEXT
  76
  77 # host-specific stuff:
  78
  79 AC_PROG_CC
  80
  81 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl"
  82 CY_GNU_GETTEXT
  83
  84 . ${srcdir}/../bfd/configure.host
  85
  86 BFD_CC_FOR_BUILD
  87
  88 AC_SUBST(HDEFINES)
  89 AC_PROG_INSTALL
  90
  91 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  92
  93 cgen_maint=no
  94 cgendir='$(srcdir)/../cgen'
  95
  96 AC_ARG_ENABLE(cgen-maint,
  97 [  --enable-cgen-maint[=dir]    build cgen generated files],
  98 [case "${enableval}" in
  99   yes)  cgen_maint=yes ;;
 100   no)   cgen_maint=no ;;
 101   *)
 102         # argument is cgen install directory (not implemented yet).
 103         # Having a `share' directory might be more appropriate for the .scm,
 104         # .cpu, etc. files.
 105         cgen_maint=yes
 106         cgendir=${cgen_maint}/lib/cgen
 107         ;;
 108 esac])dnl
 109 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 110 AC_SUBST(cgendir)
 111
 112 using_cgen=no
 113
 114 # Horrible hacks to build DLLs on Windows.
 115 WIN32LDFLAGS=
 116 WIN32LIBADD=
 117 case "${host}" in
 118 *-*-cygwin*)
 119   if test "$enable_shared" = "yes"; then
 120     WIN32LDFLAGS="-no-undefined"
 121     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 122   fi
 123   ;;
 124 esac
 125 AC_SUBST(WIN32LDFLAGS)
 126 AC_SUBST(WIN32LIBADD)
 127
 128 # target-specific stuff:
 129
 130 # Canonicalize the secondary target names.
 131 if test -n "$enable_targets" ; then
 132     for targ in `echo $enable_targets | sed 's/,/ /g'`
 133     do
 134         result=`$ac_config_sub $targ 2>/dev/null`
 135         if test -n "$result" ; then
 136             canon_targets="$canon_targets $result"
 137         else
 138             # Allow targets that config.sub doesn't recognize, like "all".
 139             canon_targets="$canon_targets $targ"
 140         fi
 141     done
 142 fi
 143
 144 all_targets=false
 145 selarchs=
 146 for targ in $target $canon_targets
 147 do
 148     if test "x$targ" = "xall" ; then
 149         all_targets=true
 150     else
 151         . $srcdir/../bfd/config.bfd
 152         selarchs="$selarchs $targ_archs"
 153     fi
 154 done
 155
 156 # Utility var, documents generic cgen support files.
 157
 158 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 159
 160 # We don't do any links based on the target system, just makefile config.
 161
 162 if test x${all_targets} = xfalse ; then
 163
 164     # Target architecture .o files.
 165     ta=
 166
 167     for arch in $selarchs
 168     do
 169         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 170         archdefs="$archdefs -DARCH_$ad"
 171         case "$arch" in
 172         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 173         bfd_alliant_arch)       ;;
 174         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 175         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 176         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 177         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 178         bfd_convex_arch)        ;;
 179         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo" ;;
 180         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 181         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 182         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 183         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 184         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 185         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 186         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 187         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 188         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 189         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 190         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 191         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 192         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 193         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 194         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 195         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 196         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 197         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 198         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 199         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 200         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 201         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 202         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 203         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 204         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 205         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 206         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 207         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 208         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 209         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 210         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 211         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 212         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 213         bfd_pyramid_arch)       ;;
 214         bfd_romp_arch)          ;;
 215         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 216         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 217         bfd_sh_arch)
 218           # We can't decide what we want just from the CPU family.
 219           # We want SH5 support unless a specific version of sh is
 220           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 221           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 222           for t in $target $canon_targets; do
 223             case $t in
 224               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 225               sh-*-linux* | shl-*-linux*)
 226                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 227                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 228                                 break;;
 229             esac;
 230           done
 231                                 ta="$ta sh-dis.lo" ;;
 232         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 233         bfd_tahoe_arch)         ;;
 234         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 235         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 236         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 237         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 238         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 239         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 240         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 241         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 242         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 243         bfd_we32k_arch)         ;;
 244         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 245         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 246         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 247         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 248
 249         "")                     ;;
 250         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 251         esac
 252     done
 253
 254     if test $using_cgen = yes ; then
 255         ta="$ta $cgen_files"
 256     fi
 257
 258     # Weed out duplicate .o files.
 259     f=""
 260     for i in $ta ; do
 261         case " $f " in
 262         *" $i "*) ;;
 263         *) f="$f $i" ;;
 264         esac
 265     done
 266     ta="$f"
 267
 268     # And duplicate -D flags.
 269     f=""
 270     for i in $archdefs ; do
 271         case " $f " in
 272         *" $i "*) ;;
 273         *) f="$f $i" ;;
 274         esac
 275     done
 276     archdefs="$f"
 277
 278     BFD_MACHINES="$ta"
 279
 280 else    # all_targets is true
 281     archdefs=-DARCH_all
 282     BFD_MACHINES='$(ALL_MACHINES)'
 283 fi
 284
 285 AC_SUBST(archdefs)
 286 AC_SUBST(BFD_MACHINES)
 287
 288 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 289 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])