configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [0])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_dev_stage], [-rc4])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  34 m4_define([bt_version_name], [])
  35 m4_define([bt_version_description], [])
  36
  37 AC_INIT([babeltrace], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  38
  39 # Following the numbering scheme proposed by libtool for the library version
  40 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  41 m4_define([bt_lib_version_current], [0])
  42 m4_define([bt_lib_version_revision], [0])
  43 m4_define([bt_lib_version_age], [0])
  44 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  45
  46 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  47
  48 AC_CONFIG_HEADERS([src/common/config.h])
  49 AC_CONFIG_AUX_DIR([config])
  50 AC_CONFIG_MACRO_DIR([m4])
  51
  52 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  53 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  54 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  55 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  56 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  57 AC_DEFINE([BT_VERSION_DESCRIPTION], ["]bt_version_description["], [Babeltrace version description])
  58
  59 AC_CANONICAL_TARGET
  60 AC_CANONICAL_HOST
  61
  62
  63 ##                     ##
  64 ## Automake base setup ##
  65 ##                     ##
  66
  67 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  68 AM_MAINTAINER_MODE([enable])
  69
  70 # Enable silent rules if available (Introduced in AM 1.11)
  71 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  72
  73
  74 ##                      ##
  75 ## OS specific defaults ##
  76 ##                      ##
  77
  78 MINGW32=no
  79 DEFAULT_ENABLE_DEBUG_INFO=yes
  80 LT_NO_UNDEFINED=""
  81 AS_CASE([$host_os],
  82   [solaris*|darwin*],
  83     [
  84         DEFAULT_ENABLE_DEBUG_INFO=no
  85     ],
  86   [cygwin*],
  87     [
  88         DEFAULT_ENABLE_DEBUG_INFO=no
  89         LT_NO_UNDEFINED="-no-undefined"
  90     ],
  91   [mingw*],
  92     [
  93         MINGW32=yes
  94         DEFAULT_ENABLE_DEBUG_INFO=no
  95         LT_NO_UNDEFINED="-no-undefined"
  96     ]
  97 )
  98
  99 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 100 AC_SUBST(LT_NO_UNDEFINED)
 101
 102
 103 ##                   ##
 104 ## C compiler checks ##
 105 ##                   ##
 106
 107 AC_USE_SYSTEM_EXTENSIONS
 108 AC_SYS_LARGEFILE
 109
 110 # Choose the c compiler
 111 AC_PROG_CC
 112
 113 # Make sure the c compiler supports C99
 114 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 115
 116 # Make sure the c compiler supports __attributes__
 117 AX_C___ATTRIBUTE__
 118 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 119   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 120
 121 # Make sur we have pthread support
 122 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 123
 124 # Checks for typedefs, structures, and compiler characteristics.
 125 AC_C_INLINE
 126 AC_C_TYPEOF
 127 AC_TYPE_PID_T
 128 AC_TYPE_SIZE_T
 129 AC_TYPE_INT16_T
 130 AC_TYPE_INT32_T
 131 AC_TYPE_INT64_T
 132 AC_TYPE_INT8_T
 133 AC_TYPE_OFF_T
 134 AC_TYPE_SSIZE_T
 135 AC_TYPE_UINT16_T
 136 AC_TYPE_UINT32_T
 137 AC_TYPE_UINT64_T
 138 AC_TYPE_UINT8_T
 139 AC_CHECK_TYPES([ptrdiff_t])
 140
 141
 142 ##               ##
 143 ## Header checks ##
 144 ##               ##
 145
 146 AC_HEADER_STDBOOL
 147 AC_CHECK_HEADERS([ \
 148         fcntl.h \
 149         float.h \
 150         ftw.h \
 151         libintl.h \
 152         limits.h \
 153         malloc.h \
 154         netdb.h \
 155         netinet/in.h \
 156         stddef.h \
 157         sys/socket.h \
 158         sys/time.h
 159 ])
 160
 161
 162 ##               ##
 163 ## Linker checks ##
 164 ##               ##
 165
 166 # Check if the linker supports no-as-needed
 167 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 168 AC_SUBST([LD_NO_AS_NEEDED])
 169
 170 # Check if the linker supports whole-archive
 171 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 172   [
 173     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 174     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 175   ],[
 176     # Fallback to force_load for the macOS linker
 177     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 178       [
 179         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 180         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 181       ],[
 182         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 183       ]
 184     )
 185   ]
 186 )
 187
 188 # Initialize and configure libtool
 189 LT_INIT([win32-dll])
 190
 191
 192 ##                 ##
 193 ## Programs checks ##
 194 ##                 ##
 195
 196 AC_PROG_MAKE_SET
 197 AC_PROG_MKDIR_P
 198 AC_PROG_LN_S
 199 AC_PATH_PROG([report_fold], [fold])
 200
 201 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 202 # is not distributed in tarballs
 203 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 204 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 205
 206 # check for bison
 207 AC_PROG_YACC
 208 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 209
 210 AS_IF([test "x$have_bison" != "xyes"], [
 211   AS_IF([test "x$in_git_repo" = "xyes"], [
 212     AC_MSG_FAILURE([dnl
 213 Bison >= 2.4 is required when building from the Git repository. You can
 214 set the YACC variable to override automatic detection.
 215     ])
 216   ], [
 217     AC_MSG_WARN([dnl
 218 Missing Bison >= 2.4. Note that the parser files are already built in
 219 this distribution tarball, so Bison is only needed if you intend to
 220 modify their sources. You can set the YACC variable to override automatic
 221 detection.
 222     ])
 223   ])
 224 ])
 225 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 226
 227 # check for flex
 228 AC_PROG_LEX
 229 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 230
 231 AS_IF([test "x$have_flex" != "xyes"], [
 232   AS_IF([test "x$in_git_repo" = "xyes"], [
 233     AC_MSG_FAILURE([dnl
 234 Flex >= 2.5.35 is required when building from the Git repository. You can
 235 set the LEX variable to override automatic detection.
 236     ])
 237   ], [
 238     AC_MSG_WARN([dnl
 239 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 240 this distribution tarball, so Flex is only needed if you intend to
 241 modify their sources. You can set the LEX variable to override automatic
 242 detection.
 243     ])
 244   ])
 245 ])
 246 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 247
 248
 249 ##                ##
 250 ## Library checks ##
 251 ##                ##
 252
 253 # Check what libraries are required on this platform to link sockets programs.
 254 AX_LIB_SOCKET_NSL
 255
 256 # Check for glib >= 2.28 with gmodule support
 257 AM_PATH_GLIB_2_0([2.28.0], [],
 258   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 259   [gmodule-no-export]
 260 )
 261
 262 # Checks for library functions.
 263 AC_FUNC_ALLOCA
 264 AC_FUNC_FORK
 265 AC_FUNC_MKTIME
 266 AC_FUNC_MMAP
 267 AC_FUNC_STRERROR_R
 268 AC_FUNC_STRNLEN
 269 AC_CHECK_FUNCS([ \
 270         atexit \
 271         dup2 \
 272         ftruncate \
 273         gethostbyname \
 274         gettimeofday \
 275         localtime_r \
 276         memchr \
 277         memset \
 278         mkdir \
 279         mkdtemp \
 280         munmap \
 281         rmdir \
 282         setenv \
 283         socket \
 284         strchr \
 285         strdup \
 286         strerror \
 287         strndup \
 288         strnlen \
 289         strrchr \
 290         strstr \
 291         strtoul \
 292         strtoull \
 293         tzset \
 294 ])
 295
 296 # AC_FUNC_MALLOC causes problems when cross-compiling.
 297 #AC_FUNC_MALLOC
 298 #AC_FUNC_REALLOC
 299
 300 # Check for fmemopen
 301 AC_CHECK_LIB([c], [fmemopen],
 302   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 303 )
 304
 305 # Check for open_memstream
 306 AC_CHECK_LIB([c], [open_memstream],
 307   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 308 )
 309
 310 # Check for posix_fallocate
 311 AC_CHECK_LIB([c], [posix_fallocate],
 312   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 313 )
 314
 315 ##                 ##
 316 ## User variables  ##
 317 ##                 ##
 318
 319 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 320 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 321 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 322
 323 # BABELTRACE_PLUGINS_DIR: Plugins directory
 324 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 325 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 326
 327 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 328 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 329 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 330
 331 # BABELTRACE_MINIMAL_LOG_LEVEL:
 332 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 333 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 334 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 335        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 336        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 337   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 338 )
 339 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 340
 341 # BABELTRACE_DEV_MODE:
 342 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 343 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 344         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 345 ], [BABELTRACE_DEV_MODE=0])
 346
 347 # BABELTRACE_DEBUG_MODE:
 348 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 349 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 350         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 351 ], [BABELTRACE_DEBUG_MODE=0])
 352
 353
 354 ##                              ##
 355 ## Optionnal features selection ##
 356 ##                              ##
 357
 358 # Python bindings
 359 # Disabled by default
 360 AC_ARG_ENABLE([python-bindings],
 361   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 362   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 363   [enable_python_bindings=no]
 364 )
 365
 366 # Python bindings documentation
 367 # Disabled by default
 368 AC_ARG_ENABLE([python-bindings-doc],
 369   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 370   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 371   [enable_python_bindings_doc=no]
 372 )
 373
 374 # Python plugins
 375 # Disabled by default
 376 AC_ARG_ENABLE([python-plugins],
 377   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])],
 378   [], dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 379   [enable_python_plugins=no]
 380 )
 381
 382 # Debug info
 383 # Enabled by default, except on some platforms
 384 AC_ARG_ENABLE([debug-info],
 385   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 386   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 387   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 388 )
 389
 390 # API documentation
 391 # Disabled by default
 392 AC_ARG_ENABLE([api-doc],
 393   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 394   [enable_api_doc=$enableval],
 395   [enable_api_doc=no]
 396 )
 397
 398 # Built-in plugins
 399 # Disabled by default
 400 AC_ARG_ENABLE([built-in-plugins],
 401   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])],
 402   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 403   [enable_built_in_plugins=no]
 404 )
 405
 406 # Built-in python plugin support
 407 # Disabled by default
 408 AC_ARG_ENABLE([built-in-python-plugin-support],
 409   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])],
 410   [], dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 411   [enable_built_in_python_plugin_support=no]
 412 )
 413
 414 # Man pages
 415 # Enabled by default
 416 AC_ARG_ENABLE([man-pages],
 417   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 418   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 419   [enable_man_pages=yes]
 420 )
 421
 422
 423 # Set automake variables for optionnal feature conditionnals in Makefile.am
 424 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 425 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 426 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 427 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 428 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 429 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 430 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 431 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 432 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 433
 434 # Set defines for optionnal features conditionnals in the source code
 435
 436 ## jgalar: still used?
 437 AS_IF([test "x$enable_python_plugins" = xyes],
 438   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 439 )
 440
 441 AS_IF([test "x$enable_debug_info" = xyes],
 442   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 443 )
 444
 445 AS_IF([test "x$enable_built_in_plugins" = xyes],
 446   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 447 )
 448
 449 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 450   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 451 )
 452
 453 AS_IF([test "x$enable_debug_info" = xyes],
 454   [ENABLE_DEBUG_INFO_VAL=1],
 455   [ENABLE_DEBUG_INFO_VAL=0]
 456 )
 457
 458 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 459
 460
 461 # Check for conflicting optional features user choices
 462
 463 AS_IF([test "x$enable_python_bindings" = xno],
 464   [
 465     AS_IF([test "x$enable_python_bindings_doc" = xyes], [AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])])
 466   ]
 467 )
 468
 469 AS_IF([test "x$enable_built_in_plugins" = xyes],
 470   [
 471     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 472     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 473     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 474   ]
 475 )
 476
 477 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 478   [
 479     AS_IF([test "x$enable_python_plugins" = xno], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 480     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 481     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 482     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 483   ]
 484 )
 485
 486
 487 # Check for optionnal features dependencies
 488
 489 AS_IF([test "x$enable_python_bindings" = xyes],
 490   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 491 )
 492
 493 AM_PATH_PYTHON([3.0], [
 494   AM_PATH_PYTHON_MODULES([PYTHON])
 495
 496   # pythondir is the path where extra modules are to be installed
 497   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 498
 499   # pyexecdir is the path that contains shared objects used by the extra modules
 500   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 501
 502   AS_IF([test -z "$PYTHON_CONFIG"], [
 503     AC_PATH_PROGS([PYTHON_CONFIG],
 504                   [python$PYTHON_VERSION-config python-config],
 505                   [],
 506                   [`dirname $PYTHON`])
 507   ])
 508
 509   AS_IF([test -n "$PYTHON_CONFIG"], [
 510     AS_IF([test -z "$PYTHON_INCLUDE"], [
 511       AC_MSG_CHECKING([Python include flags])
 512       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 513       AC_MSG_RESULT([$PYTHON_INCLUDE])
 514     ])
 515
 516     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 517       AC_MSG_CHECKING([Python library flags])
 518       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 519       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 520         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 521       ])
 522       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 523     ])
 524   ])
 525 ], [:])
 526
 527 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 528 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 529
 530 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 531 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 532
 533 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 534   AS_IF([test "x$have_python_dev" = xno], [
 535     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 536   ])
 537 ])
 538
 539 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 540   [
 541     AM_CHECK_PYTHON_SPHINX([PYTHON])
 542     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 543       [AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])]
 544     )
 545   ]
 546 )
 547
 548 AS_IF([test "x$enable_debug_info" = xyes],
 549   [
 550     # Check if libelf and libdw are present
 551     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 552     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 553     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 554     ELFUTILS_LIBS="-lelf -ldw"
 555   ]
 556 )
 557 AC_SUBST([ELFUTILS_LIBS])
 558
 559 AS_IF([test "x$enable_api_doc" = "xyes"],
 560   [
 561     DX_DOXYGEN_FEATURE(ON)
 562     DX_DOT_FEATURE(OFF)
 563     DX_HTML_FEATURE(ON)
 564     DX_CHM_FEATURE(OFF)
 565     DX_CHI_FEATURE(OFF)
 566     DX_MAN_FEATURE(OFF)
 567     DX_RTF_FEATURE(OFF)
 568     DX_XML_FEATURE(OFF)
 569     DX_PDF_FEATURE(OFF)
 570     DX_PS_FEATURE(OFF)
 571     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 572     AS_IF([test -z "$DX_DOXYGEN"],
 573           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 574     )
 575   ]
 576 )
 577
 578 have_asciidoc_xmlto=no
 579 warn_prebuilt_man_pages=no
 580
 581 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 582 AC_PATH_PROG([XMLTO], [xmlto], [no])
 583
 584 AS_IF([test "x$enable_man_pages" = "xyes"], [
 585   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 586     AS_IF([test "x$in_git_repo" = "xyes"], [
 587       # this is an error because we're in the Git repo, which
 588       # means the man pages are not already generated for us,
 589       # thus asciixmlto are required because we were asked
 590       # to build the man pages
 591       AC_MSG_ERROR([
 592 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 593 --disable-man-pages to disable building the man pages, in which case
 594 they will not be installed.
 595       ])
 596     ], [
 597       # only warn here: since we're in the tarball, the man
 598       # pages should already be generated at this point, thus
 599       # asciidoc/xmlto are not strictly required
 600       warn_prebuilt_man_pages=yes
 601     ])
 602   ], [
 603     have_asciidoc_xmlto=yes
 604   ])
 605 ])
 606
 607 # export AsciiDoc and xmlto existence
 608 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 609
 610 # a wonderful hack that seems necessary because $libdir is
 611 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 612 # by autoconf when it's not specified by the user
 613 AS_IF([test "x$exec_prefix" = xNONE], [
 614   AS_IF([test "x$prefix" = xNONE], [
 615     PREFIX="$ac_default_prefix"
 616   ], [
 617     PREFIX="$prefix"
 618   ])
 619
 620   LIBDIR="$PREFIX/lib"
 621 ], [
 622   LIBDIR="$libdir"
 623 ])
 624
 625 AC_SUBST(LIBDIR)
 626
 627 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 628 # test).
 629 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 630
 631 # Check that the current size_t matches the size that glib thinks it should
 632 # be. This catches problems on multi-arch where people try to do a 32-bit
 633 # build while pointing at 64-bit glib headers. This is a common error because
 634 # glib.h is not platform specific but it includes glibconfig.h which is and
 635 # is usually installed in a non-standard path.
 636
 637 # Do this before enabling all the warning flags, as the
 638 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 639 # test fail unnecessarily.
 640
 641 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 642 # output. Specifically allow pkg_config_libdir to be able to print the
 643 # error message.
 644 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 645
 646 save_CFLAGS=${CFLAGS}
 647 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 648 AC_COMPILE_IFELSE([
 649   AC_LANG_PROGRAM([dnl
 650 #include <glib.h>
 651 #include <unistd.h>
 652   ], [dnl
 653 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 654   ])
 655 ],[:],[
 656   AC_MSG_ERROR([dnl
 657 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 658 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 659 target.
 660   ])
 661 ])
 662 CFLAGS=${save_CFLAGS}
 663
 664 # Detect C and LD warning flags supported by the compiler.
 665 AX_COMPILER_FLAGS(
 666         [WARN_CFLAGS], dnl CFLAGS variable name
 667         [WARN_LDFLAGS], dnl LDFLAGS variable name (unused for now)
 668         [], dnl is-release
 669         [], dnl Extra base CFLAGS
 670         [ dnl Extra "yes" CFLAGS
 671                 dnl Disable these flags, either because we don't want them
 672                 dnl or because we want them but are not ready to enable them
 673                 dnl yet.
 674                 -Wno-sign-compare dnl
 675                 -Wno-inline dnl
 676                 -Wno-declaration-after-statement dnl
 677                 -Wno-switch-enum dnl
 678                 -Wno-switch-default dnl
 679                 -Wno-packed dnl
 680                 -Wno-pointer-arith dnl
 681                 -Wno-format-nonliteral dnl
 682                 -Wno-double-promotion dnl
 683                 -Wno-cast-align dnl
 684                 dnl
 685                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 686                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 687                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 688                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 689                 dnl It's simpler to just disable the warning globally.
 690                 dnl
 691                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 692                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 693                 dnl reproduce the warning using that package.
 694                 dnl
 695                 dnl Ref: https://github.com/swig/swig/issues/1259
 696                 -Wno-cast-function-type dnl
 697         ])
 698
 699 # CFLAGS from AX_COMPILER_FLAGS.
 700 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 701
 702 # The test used in AX_COMPILER_FLAGS, generated using AC_LANG_PROGRAM, is
 703 # written in such a way that it triggers a -Wold-style-definition warning.  So
 704 # if the user has -Werror in their CFLAGS, that warning flag will end up
 705 # disabled, because the test program will not build.
 706 #
 707 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 708 # (it is accepted for compatibility although it has no effect), and there is
 709 # not reason to not want it.
 710
 711 AM_CFLAGS="${AM_CFLAGS} -Wold-style-definition"
 712
 713 # We want this one to always be an error.
 714 AM_CFLAGS="${AM_CFLAGS} -Werror=implicit-function-declaration"
 715
 716 # Done for AM_CFLAGS.
 717 AC_SUBST(AM_CFLAGS)
 718
 719 # Set global CPPFLAGS in AM_CPPFLAGS
 720 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 721 AC_SUBST(AM_CPPFLAGS)
 722
 723 # Add glib to global link libs
 724 LIBS="$LIBS $GLIB_LIBS"
 725
 726 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 727 # to rename babeltrace2.bin to babeltrace2 at install time.
 728 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 729 AC_SUBST(program_transform_name)
 730
 731 AC_CONFIG_FILES([
 732         doc/api/Makefile
 733         doc/api/libbabeltrace2/Doxyfile
 734         doc/api/libbabeltrace2/Makefile
 735         doc/bindings/Makefile
 736         doc/bindings/python/Makefile
 737         doc/contributing-images/Makefile
 738         doc/Makefile
 739         doc/man/asciidoc-attrs.conf
 740         doc/man/Makefile
 741         include/Makefile
 742         Makefile
 743         src/argpar/Makefile
 744         src/autodisc/Makefile
 745         src/babeltrace2-ctf-writer.pc
 746         src/babeltrace2.pc
 747         src/bindings/Makefile
 748         src/bindings/python/bt2/bt2/version.py
 749         src/bindings/python/bt2/Makefile
 750         src/bindings/python/bt2/setup.py
 751         src/bindings/python/Makefile
 752         src/cli/Makefile
 753         src/common/Makefile
 754         src/compat/Makefile
 755         src/ctfser/Makefile
 756         src/ctf-writer/Makefile
 757         src/fd-cache/Makefile
 758         src/lib/graph/Makefile
 759         src/lib/graph/message/Makefile
 760         src/lib/Makefile
 761         src/lib/plugin/Makefile
 762         src/lib/prio-heap/Makefile
 763         src/lib/trace-ir/Makefile
 764         src/logging/Makefile
 765         src/Makefile
 766         src/plugins/common/Makefile
 767         src/plugins/common/muxing/Makefile
 768         src/plugins/common/param-validation/Makefile
 769         src/plugins/ctf/common/bfcr/Makefile
 770         src/plugins/ctf/common/Makefile
 771         src/plugins/ctf/common/metadata/Makefile
 772         src/plugins/ctf/common/msg-iter/Makefile
 773         src/plugins/ctf/fs-sink/Makefile
 774         src/plugins/ctf/fs-src/Makefile
 775         src/plugins/ctf/lttng-live/Makefile
 776         src/plugins/ctf/Makefile
 777         src/plugins/lttng-utils/debug-info/Makefile
 778         src/plugins/lttng-utils/Makefile
 779         src/plugins/Makefile
 780         src/plugins/text/dmesg/Makefile
 781         src/plugins/text/Makefile
 782         src/plugins/text/pretty/Makefile
 783         src/plugins/text/details/Makefile
 784         src/plugins/utils/counter/Makefile
 785         src/plugins/utils/dummy/Makefile
 786         src/plugins/utils/Makefile
 787         src/plugins/utils/muxer/Makefile
 788         src/plugins/utils/trimmer/Makefile
 789         src/py-common/Makefile
 790         src/python-plugin-provider/Makefile
 791         src/param-parse/Makefile
 792         src/string-format/Makefile
 793         tests/bitfield/Makefile
 794         tests/ctf-writer/Makefile
 795         tests/lib/Makefile
 796         tests/lib/test-plugin-plugins/Makefile
 797         tests/Makefile
 798         tests/param-validation/Makefile
 799         tests/plugins/Makefile
 800         tests/plugins/src.ctf.fs/Makefile
 801         tests/plugins/src.ctf.fs/succeed/Makefile
 802         tests/plugins/sink.ctf.fs/Makefile
 803         tests/plugins/sink.ctf.fs/succeed/Makefile
 804         tests/plugins/flt.lttng-utils.debug-info/Makefile
 805         tests/plugins/flt.utils.muxer/Makefile
 806         tests/plugins/flt.utils.muxer/succeed/Makefile
 807         tests/plugins/flt.utils.trimmer/Makefile
 808         tests/utils/Makefile
 809         tests/utils/tap/Makefile
 810 ])
 811
 812 AC_OUTPUT
 813
 814 #
 815 # Mini-report on what will be built.
 816 #
 817
 818 PPRINT_INIT
 819 PPRINT_SET_INDENT(1)
 820 PPRINT_SET_TS(38)
 821
 822 AS_ECHO
 823
 824 AS_IF([test -n "bt_version_name"], [
 825         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 826 ], [
 827         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 828 ])
 829
 830 AS_ECHO
 831
 832 AS_IF([test -n "bt_version_description"], [
 833         AS_IF([test -n "$report_fold"], [
 834                 AS_ECHO("`AS_ECHO("bt_version_description") | $report_fold -s`")
 835         ], [
 836                 AS_ECHO("bt_version_description")
 837         ])
 838
 839         AS_ECHO
 840 ])
 841
 842 PPRINT_SUBTITLE([System])
 843
 844 # Target architecture we're building for.
 845 target_arch=$host_cpu
 846 [
 847 for f in $CFLAGS; do
 848         if test $f = "-m32"; then
 849                 target_arch="32-bit"
 850         elif test $f = "-m64"; then
 851                 target_arch="64-bit"
 852         fi
 853 done
 854 ]
 855
 856 PPRINT_PROP_STRING([Target architecture], $target_arch)
 857
 858 AS_ECHO
 859 PPRINT_SUBTITLE([Python 3 language support])
 860 test "x$have_python" = "xyes" && value=1 || value=0
 861 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 862 test "x$have_python_dev" = "xyes" && value=1 || value=0
 863 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 864 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 865 PPRINT_PROP_BOOL([Python bindings], $value)
 866 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 867 PPRINT_PROP_BOOL([Python plugin support], $value)
 868 AS_IF([test "x$have_python" = "xyes"], [
 869   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 870 ])
 871 AS_IF([test "x$have_python_dev" = "xyes"], [
 872   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 873   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 874   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 875 ])
 876 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 877   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 878   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 879 ])
 880
 881 AS_ECHO
 882 PPRINT_SUBTITLE([Plugins])
 883 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 884 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 885 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 886 PPRINT_PROP_BOOL(['text' plugin], 1)
 887 PPRINT_PROP_BOOL(['utils' plugin], 1)
 888
 889 AS_ECHO
 890 PPRINT_SUBTITLE([Built-in features])
 891 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 892 PPRINT_PROP_BOOL([Built-in plugins], $value)
 893 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 894 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 895
 896 AS_ECHO
 897 PPRINT_SUBTITLE([Documentation])
 898
 899 # man pages build enabled/disabled
 900 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 901
 902 AS_IF([test "x$enable_man_pages" != "xno"], [
 903   AS_IF([test "x$in_git_repo" = "xyes"], [
 904     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 905   ], [
 906     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 907       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 908     ], [
 909       PPRINT_PROP_STRING([build_man_pages_msg],
 910         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 911         $PPRINT_COLOR_SUBTITLE)
 912     ])
 913   ])
 914 ], [
 915   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 916 ])
 917
 918 m4_popdef([build_man_pages_msg])
 919
 920 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 921 PPRINT_PROP_BOOL([HTML API documentation], $value)
 922 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 923 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 924
 925 AS_ECHO
 926 PPRINT_SUBTITLE([Logging])
 927 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 928
 929 AS_ECHO
 930 PPRINT_SUBTITLE([Special build modes])
 931 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 932 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 933
 934 report_bindir="`eval eval echo $bindir`"
 935 report_libdir="`eval eval echo $libdir`"
 936 report_sysconfdif="`eval eval echo $sysconfdir`"
 937 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 938 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 939
 940 # Print the bindir and libdir this `make install' will install into.
 941 AS_ECHO
 942 PPRINT_SUBTITLE([Install directories])
 943 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 944 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 945 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 946 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 947 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])