configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.50])
   5 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 AM_MAINTAINER_MODE([enable])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 AC_PROG_MKDIR_P
  21 AC_PROG_LN_S
  22
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  26
  27 AC_SYS_LARGEFILE
  28
  29 # Checks for programs.
  30 AC_PROG_CC_STDC
  31 AC_PROG_MAKE_SET
  32 LT_INIT
  33 AC_PROG_YACC
  34 AC_PROG_LEX
  35
  36 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  37         if test x"$YACC" != "xbison -y"; then
  38                 AC_MSG_ERROR([[bison not found and is required when building from git.
  39                 Please install bison]])
  40         fi
  41         AC_PATH_PROG([BISON],[bison])
  42         AX_PROG_BISON_VERSION([2.4], [],[
  43                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  44         ])
  45 fi
  46
  47 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  48         if test x"$LEX" != "xflex"; then
  49                 AC_MSG_ERROR([[flex not found and is required when building from git.
  50                 Please install flex]])
  51         fi
  52         AC_PATH_PROG([FLEX],[flex])
  53         AX_PROG_FLEX_VERSION([2.5.35], [],[
  54                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  55         ])
  56 fi
  57
  58
  59 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  60
  61 # Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_INLINE
  63 AC_TYPE_PID_T
  64 AC_TYPE_SIZE_T
  65 AC_TYPE_INT16_T
  66 AC_TYPE_INT32_T
  67 AC_TYPE_INT64_T
  68 AC_TYPE_INT8_T
  69 AC_TYPE_OFF_T
  70 AC_TYPE_SSIZE_T
  71 AC_TYPE_UINT16_T
  72 AC_TYPE_UINT32_T
  73 AC_TYPE_UINT64_T
  74 AC_TYPE_UINT8_T
  75
  76 # Checks for library functions.
  77 AC_FUNC_MALLOC
  78 AC_FUNC_MMAP
  79 AC_CHECK_FUNCS([ \
  80         bzero gettimeofday munmap strtoul ftruncate gethostbyname \
  81         localtime_r memset mkdir rmdir setenv socket \
  82         strchr strdup strerror strndup strrchr strtoull tzset \
  83 ])
  84
  85 # Check for MinGW32.
  86 MINGW32=no
  87 case $host in
  88   *-*-mingw*)
  89         MINGW32=yes;;
  90 esac
  91
  92 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  93
  94 # Check for libuuid
  95 AC_CHECK_LIB([uuid], [uuid_generate],
  96 [
  97         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  98         have_libuuid=yes
  99 ],
 100 [
 101         # libuuid not found, check for uuid_create in libc.
 102         AC_CHECK_LIB([c], [uuid_create],
 103         [
 104                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 105                 have_libc_uuid=yes
 106         ],
 107         [
 108                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 109                 if test "x$MINGW32" = xno; then
 110                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 111                 fi
 112         ])
 113 ]
 114 )
 115 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 116 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 117
 118 # Check for fmemopen
 119 AC_CHECK_LIB([c], [fmemopen],
 120 [
 121         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 122 ]
 123 )
 124
 125 # Check for open_memstream
 126 AC_CHECK_LIB([c], [open_memstream],
 127 [
 128         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 129 ]
 130 )
 131
 132 AC_CHECK_LIB([popt], [poptGetContext], [],
 133         [AC_MSG_ERROR([Cannot find popt.])]
 134 )
 135
 136
 137 # For Python
 138 # SWIG version needed or newer:
 139 swig_version=2.0.0
 140
 141 AC_ARG_ENABLE([python-bindings],
 142               [AC_HELP_STRING([--enable-python-bindings],
 143                               [generate Python bindings])],
 144               [enable_python=yes], [enable_python=no])
 145
 146 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 147
 148 AC_ARG_ENABLE([python-bindings-doc],
 149               [AC_HELP_STRING([--enable-python-bindings-doc],
 150                               [generate Python bindings documentation])],
 151               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 152
 153 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 154   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 155 fi
 156
 157 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 158
 159 if test "x${enable_python:-yes}" = xyes; then
 160   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 161   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 162
 163   AM_PATH_PYTHON_MODULES([PYTHON])
 164   # pythondir is the path where extra modules are to be installed
 165   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 166   # pyexecdir is the path that contains shared objects used by the extra modules
 167   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 168   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 169   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 170   AS_IF([test -z "$PYTHON_INCLUDE"], [
 171     AS_IF([test -z "$PYTHON_CONFIG"], [
 172       AC_PATH_PROGS([PYTHON_CONFIG],
 173                     [python$PYTHON_VERSION-config python-config],
 174                     [no],
 175                     [`dirname $PYTHON`])
 176       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 177     ])
 178     AC_MSG_CHECKING([python include flags])
 179     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 180     AC_MSG_RESULT([$PYTHON_INCLUDE])
 181   ])
 182 else
 183     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 184 [if you want Python bindings.])
 185
 186 fi
 187
 188 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 189     AM_CHECK_PYTHON_SPHINX([PYTHON])
 190     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 191       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 192     )
 193 fi
 194
 195 pkg_modules="gmodule-2.0 >= 2.0.0"
 196 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 197 AC_SUBST(PACKAGE_LIBS)
 198
 199 LIBS="$LIBS $GMODULE_LIBS"
 200 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 201 AC_SUBST(PACKAGE_CFLAGS)
 202
 203 babeltraceincludedir="${includedir}/babeltrace"
 204 AC_SUBST(babeltraceincludedir)
 205
 206 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 207 AC_SUBST(babeltracectfincludedir)
 208
 209 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 210 AC_SUBST(babeltracectfwriterincludedir)
 211
 212 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 213 AC_SUBST(babeltracectfirincludedir)
 214
 215 AC_CONFIG_FILES([
 216         Makefile
 217         types/Makefile
 218         compat/Makefile
 219         formats/Makefile
 220         formats/ctf/Makefile
 221         formats/ctf/types/Makefile
 222         formats/ctf-text/Makefile
 223         formats/ctf-text/types/Makefile
 224         formats/ctf-metadata/Makefile
 225         formats/bt-dummy/Makefile
 226         formats/lttng-live/Makefile
 227         formats/ctf/metadata/Makefile
 228         formats/ctf/writer/Makefile
 229         formats/ctf/ir/Makefile
 230         converter/Makefile
 231         doc/Makefile
 232         doc/bindings/Makefile
 233         doc/bindings/python/Makefile
 234         lib/Makefile
 235         lib/prio_heap/Makefile
 236         include/Makefile
 237         bindings/Makefile
 238         bindings/python/Makefile
 239         tests/Makefile
 240         tests/bin/Makefile
 241         tests/lib/Makefile
 242         tests/utils/Makefile
 243         tests/utils/tap/Makefile
 244         extras/Makefile
 245         extras/valgrind/Makefile
 246         babeltrace.pc
 247         babeltrace-ctf.pc
 248 ])
 249 AC_OUTPUT