configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.5.2],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
   3 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   4
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25
  26 # Checks for programs.
  27 AC_PROG_MAKE_SET
  28 LT_INIT
  29 AC_PROG_YACC
  30 AC_PROG_LEX
  31 AC_PROG_MKDIR_P
  32 AC_PROG_LN_S
  33
  34 AX_C___ATTRIBUTE__
  35 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  36         [:],
  37         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  38
  39 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  40 LIBS="$PTHREAD_LIBS $LIBS"
  41 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  42 CC="$PTHREAD_CC"
  43
  44 # Check linker option
  45 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  46 AC_SUBST([LD_NO_AS_NEEDED])
  47
  48 AC_HEADER_STDBOOL
  49 AC_CHECK_HEADERS([ \
  50         fcntl.h \
  51         float.h \
  52         libintl.h \
  53         limits.h \
  54         malloc.h \
  55         netdb.h \
  56         netinet/in.h \
  57         stddef.h \
  58         sys/socket.h \
  59 ])
  60
  61 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  62         if test x"$(basename "$YACC")" != "xbison -y"; then
  63                 AC_MSG_ERROR([[bison not found and is required when building from git.
  64                 Please install bison]])
  65         fi
  66         AC_PATH_PROG([BISON],[bison])
  67         AX_PROG_BISON_VERSION([2.4], [],[
  68                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  69         ])
  70 fi
  71
  72 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  73         if test x"$LEX" != "xflex"; then
  74                 AC_MSG_ERROR([[flex not found and is required when building from git.
  75                 Please install flex]])
  76         fi
  77         AC_PATH_PROG([FLEX],[flex])
  78         AX_PROG_FLEX_VERSION([2.5.35], [],[
  79                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  80         ])
  81 fi
  82
  83 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  84
  85 # Check what libraries are required on this platform to link sockets programs.
  86 AX_LIB_SOCKET_NSL
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_PID_T
  91 AC_TYPE_SIZE_T
  92
  93 # Checks for library functions.
  94 AC_FUNC_ALLOCA
  95 AC_FUNC_FORK
  96 AC_FUNC_MALLOC
  97 AC_FUNC_MKTIME
  98 AC_FUNC_MMAP
  99 AC_FUNC_REALLOC
 100 AC_CHECK_FUNCS([ \
 101         atexit \
 102         dirfd \
 103         dup2 \
 104         ftruncate \
 105         gethostbyname \
 106         gethostname \
 107         gettimeofday \
 108         localtime_r \
 109         memchr \
 110         memset \
 111         mkdir \
 112         mkdtemp \
 113         munmap \
 114         rmdir \
 115         setenv \
 116         socket \
 117         strchr \
 118         strdup \
 119         strerror \
 120         strndup \
 121         strnlen \
 122         strrchr \
 123         strtoul \
 124         strtoull \
 125         tzset \
 126         uname \
 127 ])
 128
 129 MINGW32=no
 130 DEFAULT_ENABLE_DEBUG_INFO=yes
 131 LT_NO_UNDEFINED=""
 132 AS_CASE([$host_os],
 133   [solaris*|darwin*],
 134     [
 135         DEFAULT_ENABLE_DEBUG_INFO=no
 136     ],
 137   [mingw*],
 138     [
 139         MINGW32=yes
 140         LT_NO_UNDEFINED="-no-undefined"
 141     ],
 142   [cygwin*],
 143     [
 144         LT_NO_UNDEFINED="-no-undefined"
 145     ]
 146 )
 147
 148 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 149 AC_SUBST(LT_NO_UNDEFINED)
 150
 151 # Check what libraries are required on this platform to link sockets programs.
 152 AX_LIB_SOCKET_NSL
 153
 154 # Check for uuid in system libs
 155 AC_CHECK_FUNCS([uuid_generate],
 156 [
 157   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 158   link_with_libuuid=no
 159 ],
 160 [
 161   # First, check the pkg-config module is available, otherwise explicitly check
 162   # for libuuid, or uuid support in the C-library.
 163   PKG_CHECK_MODULES([UUID], [uuid],
 164   [
 165     LIBS="${UUID_LIBS} ${LIBS}"
 166     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 167     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 168     link_with_libuuid=yes
 169   ],
 170   [
 171     # Check for libuuid
 172     AC_CHECK_LIB([uuid], [uuid_generate],
 173     [
 174       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 175       link_with_libuuid=yes
 176     ],
 177     [
 178       # libuuid not found, check for uuid_create in libc.
 179       AC_CHECK_LIB([c], [uuid_create],
 180       [
 181         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 182         link_with_libc_uuid=yes
 183       ],
 184       [
 185         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 186         if test "x$MINGW32" = xno; then
 187           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 188         fi
 189       ])
 190     ])
 191   ])
 192 ])
 193
 194 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 195 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 196
 197 # Check for fmemopen
 198 AC_CHECK_LIB([c], [fmemopen],
 199 [
 200         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 201 ]
 202 )
 203
 204 # Check for open_memstream
 205 AC_CHECK_LIB([c], [open_memstream],
 206 [
 207         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 208 ]
 209 )
 210
 211 # Check for posix_fallocate
 212 AC_CHECK_LIB([c], [posix_fallocate],
 213 [
 214         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 215 ]
 216 )
 217
 218 # Check for faccessat
 219 AC_CHECK_LIB([c], [faccessat],
 220 [
 221         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 222 ]
 223 )
 224
 225 AC_CHECK_LIB([popt], [poptGetContext], [],
 226         [AC_MSG_ERROR([Cannot find popt.])]
 227 )
 228
 229 # For Python
 230 # SWIG version needed or newer:
 231 swig_version=2.0.0
 232
 233 AC_ARG_ENABLE([python-bindings],
 234               [AC_HELP_STRING([--enable-python-bindings],
 235                               [generate Python bindings])],
 236               [enable_python=yes], [enable_python=no])
 237
 238 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 239
 240 if test "x${enable_python:-yes}" = xyes; then
 241   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 242   AM_PATH_PYTHON
 243
 244   AM_PATH_PYTHON_MODULES([PYTHON])
 245   # pythondir is the path where extra modules are to be installed
 246   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 247   # pyexecdir is the path that contains shared objects used by the extra modules
 248   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 249   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 250   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 251   AS_IF([test -z "$PYTHON_INCLUDE"], [
 252     AS_IF([test -z "$PYTHON_CONFIG"], [
 253       AC_PATH_PROGS([PYTHON_CONFIG],
 254                     [python$PYTHON_VERSION-config python-config],
 255                     [no],
 256                     [`dirname $PYTHON`])
 257       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 258     ])
 259     AC_MSG_CHECKING([python include flags])
 260     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 261     AC_MSG_RESULT([$PYTHON_INCLUDE])
 262   ])
 263
 264 else
 265     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 266 [if you want Python bindings.])
 267
 268 fi
 269
 270 # Set default enable state for debug info.
 271 # The _enable_debug_info variable is prepended with an underscore to
 272 # avoid clashing with the one generated by AC_ARG_ENABLE.
 273 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 274
 275 # Optional debug info feature
 276 # Do _not_ indent the help string below (appears in the configure --help
 277 # output).
 278 AC_ARG_ENABLE([debug-info],
 279 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 280 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 281         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 282
 283 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 284 AS_IF([test "x$_enable_debug_info" = xyes], [
 285             # Check if libelf and libdw are present
 286             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 287             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 288             AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 289             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 290 ], [])
 291
 292 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 293 AC_SUBST(PACKAGE_LIBS)
 294
 295 LIBS="$LIBS $GMODULE_LIBS"
 296 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 297 AC_SUBST(PACKAGE_CFLAGS)
 298
 299 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 300 AC_SUBST(DEFAULT_INCLUDES)
 301
 302 babeltraceincludedir="${includedir}/babeltrace"
 303 AC_SUBST(babeltraceincludedir)
 304
 305 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 306 AC_SUBST(babeltracectfincludedir)
 307
 308 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 309 AC_SUBST(babeltracectfwriterincludedir)
 310
 311 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 312 AC_SUBST(babeltracectfirincludedir)
 313
 314 AC_CONFIG_FILES([
 315         Makefile
 316         types/Makefile
 317         compat/Makefile
 318         formats/Makefile
 319         formats/ctf/Makefile
 320         formats/ctf/types/Makefile
 321         formats/ctf-text/Makefile
 322         formats/ctf-text/types/Makefile
 323         formats/ctf-metadata/Makefile
 324         formats/bt-dummy/Makefile
 325         formats/lttng-live/Makefile
 326         formats/ctf/metadata/Makefile
 327         formats/ctf/writer/Makefile
 328         formats/ctf/ir/Makefile
 329         converter/Makefile
 330         doc/Makefile
 331         lib/Makefile
 332         lib/prio_heap/Makefile
 333         include/Makefile
 334         bindings/Makefile
 335         bindings/python/Makefile
 336         bindings/python/babeltrace/Makefile
 337         tests/Makefile
 338         tests/bin/Makefile
 339         tests/bin/intersection/Makefile
 340         tests/lib/Makefile
 341         tests/utils/Makefile
 342         tests/utils/tap/Makefile
 343         extras/Makefile
 344         extras/valgrind/Makefile
 345         babeltrace.pc
 346         babeltrace-ctf.pc
 347 ])
 348
 349 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 350 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 351 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 352 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 353 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 354
 355 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 356 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 357 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 358 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 359
 360 AC_OUTPUT
 361
 362 #
 363 # Mini-report on what will be built.
 364 #
 365
 366 PPRINT_INIT
 367 PPRINT_SET_INDENT(1)
 368 PPRINT_SET_TS(38)
 369
 370 AS_ECHO
 371 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 372 AS_ECHO
 373
 374 PPRINT_SUBTITLE([Features])
 375
 376 # Target architecture we're building for.
 377 target_arch=$host_cpu
 378 [
 379 for f in $CFLAGS; do
 380         if test $f = "-m32"; then
 381                 target_arch="32-bit"
 382         elif test $f = "-m64"; then
 383                 target_arch="64-bit"
 384         fi
 385 done
 386 ]
 387 PPRINT_PROP_STRING([Target architecture], $target_arch)
 388
 389 # python bindings enabled/disabled
 390 test "x$enable_python" = "xyes" && value=1 || value=0
 391 PPRINT_PROP_BOOL([Python bindings], $value)
 392
 393 # python bindings doc enabled/disabled
 394 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 395 PPRINT_PROP_BOOL([Python bindings doc], $value)
 396
 397 # debug info enabled/disabled
 398 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 399 PPRINT_PROP_BOOL([Debug information output], $value)
 400
 401
 402 report_bindir="`eval eval echo $bindir`"
 403 report_libdir="`eval eval echo $libdir`"
 404
 405 # Print the bindir and libdir this `make install' will install into.
 406 AS_ECHO
 407 PPRINT_SUBTITLE([Install directories])
 408 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 409 PPRINT_PROP_STRING([Libraries], [$report_libdir])