configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.5.1],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
   3 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   4
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25
  26 # Checks for programs.
  27 AC_PROG_MAKE_SET
  28 LT_INIT
  29 AC_PROG_YACC
  30 AC_PROG_LEX
  31 AC_PROG_MKDIR_P
  32 AC_PROG_LN_S
  33
  34 AX_C___ATTRIBUTE__
  35 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  36         [:],
  37         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  38
  39 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  40 LIBS="$PTHREAD_LIBS $LIBS"
  41 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  42 CC="$PTHREAD_CC"
  43
  44 # Check linker option
  45 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  46 AC_SUBST([LD_NO_AS_NEEDED])
  47
  48 AC_HEADER_STDBOOL
  49 AC_CHECK_HEADERS([ \
  50         fcntl.h \
  51         float.h \
  52         libintl.h \
  53         limits.h \
  54         malloc.h \
  55         netdb.h \
  56         netinet/in.h \
  57         stddef.h \
  58         sys/socket.h \
  59 ])
  60
  61 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  62         if test x"$(basename "$YACC")" != "xbison -y"; then
  63                 AC_MSG_ERROR([[bison not found and is required when building from git.
  64                 Please install bison]])
  65         fi
  66         AC_PATH_PROG([BISON],[bison])
  67         AX_PROG_BISON_VERSION([2.4], [],[
  68                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  69         ])
  70 fi
  71
  72 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  73         if test x"$LEX" != "xflex"; then
  74                 AC_MSG_ERROR([[flex not found and is required when building from git.
  75                 Please install flex]])
  76         fi
  77         AC_PATH_PROG([FLEX],[flex])
  78         AX_PROG_FLEX_VERSION([2.5.35], [],[
  79                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  80         ])
  81 fi
  82
  83 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  84
  85 # Check what libraries are required on this platform to link sockets programs.
  86 AX_LIB_SOCKET_NSL
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_PID_T
  91 AC_TYPE_SIZE_T
  92
  93 # Checks for library functions.
  94 AC_FUNC_ALLOCA
  95 AC_FUNC_FORK
  96 AC_FUNC_MALLOC
  97 AC_FUNC_MKTIME
  98 AC_FUNC_MMAP
  99 AC_FUNC_REALLOC
 100 AC_CHECK_FUNCS([ \
 101         atexit \
 102         dirfd \
 103         dup2 \
 104         ftruncate \
 105         gethostbyname \
 106         gethostname \
 107         gettimeofday \
 108         localtime_r \
 109         memchr \
 110         memset \
 111         mkdir \
 112         mkdtemp \
 113         munmap \
 114         rmdir \
 115         setenv \
 116         socket \
 117         strchr \
 118         strdup \
 119         strerror \
 120         strndup \
 121         strnlen \
 122         strrchr \
 123         strtoul \
 124         strtoull \
 125         tzset \
 126         uname \
 127 ])
 128
 129 MINGW32=no
 130 DEFAULT_ENABLE_DEBUG_INFO=yes
 131 AS_CASE([$host_os],
 132   [solaris*|darwin*],
 133     [
 134         DEFAULT_ENABLE_DEBUG_INFO=no
 135     ],
 136   [mingw*],
 137     [
 138         MINGW32=yes
 139     ]
 140 )
 141
 142 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 143
 144 # Check what libraries are required on this platform to link sockets programs.
 145 AX_LIB_SOCKET_NSL
 146
 147 # Check for uuid in system libs
 148 AC_CHECK_FUNCS([uuid_generate],
 149 [
 150   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 151   link_with_libuuid=no
 152 ],
 153 [
 154   # First, check the pkg-config module is available, otherwise explicitly check
 155   # for libuuid, or uuid support in the C-library.
 156   PKG_CHECK_MODULES([UUID], [uuid],
 157   [
 158     LIBS="${UUID_LIBS} ${LIBS}"
 159     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 160     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 161     link_with_libuuid=yes
 162   ],
 163   [
 164     # Check for libuuid
 165     AC_CHECK_LIB([uuid], [uuid_generate],
 166     [
 167       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 168       link_with_libuuid=yes
 169     ],
 170     [
 171       # libuuid not found, check for uuid_create in libc.
 172       AC_CHECK_LIB([c], [uuid_create],
 173       [
 174         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 175         link_with_libc_uuid=yes
 176       ],
 177       [
 178         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 179         if test "x$MINGW32" = xno; then
 180           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 181         fi
 182       ])
 183     ])
 184   ])
 185 ])
 186
 187 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 188 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 189
 190 # Check for fmemopen
 191 AC_CHECK_LIB([c], [fmemopen],
 192 [
 193         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 194 ]
 195 )
 196
 197 # Check for open_memstream
 198 AC_CHECK_LIB([c], [open_memstream],
 199 [
 200         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 201 ]
 202 )
 203
 204 # Check for posix_fallocate
 205 AC_CHECK_LIB([c], [posix_fallocate],
 206 [
 207         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 208 ]
 209 )
 210
 211 # Check for faccessat
 212 AC_CHECK_LIB([c], [faccessat],
 213 [
 214         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 215 ]
 216 )
 217
 218 AC_CHECK_LIB([popt], [poptGetContext], [],
 219         [AC_MSG_ERROR([Cannot find popt.])]
 220 )
 221
 222 # For Python
 223 # SWIG version needed or newer:
 224 swig_version=2.0.0
 225
 226 AC_ARG_ENABLE([python-bindings],
 227               [AC_HELP_STRING([--enable-python-bindings],
 228                               [generate Python bindings])],
 229               [enable_python=yes], [enable_python=no])
 230
 231 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 232
 233 if test "x${enable_python:-yes}" = xyes; then
 234   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 235   AM_PATH_PYTHON
 236
 237   AM_PATH_PYTHON_MODULES([PYTHON])
 238   # pythondir is the path where extra modules are to be installed
 239   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 240   # pyexecdir is the path that contains shared objects used by the extra modules
 241   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 242   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 243   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 244   AS_IF([test -z "$PYTHON_INCLUDE"], [
 245     AS_IF([test -z "$PYTHON_CONFIG"], [
 246       AC_PATH_PROGS([PYTHON_CONFIG],
 247                     [python$PYTHON_VERSION-config python-config],
 248                     [no],
 249                     [`dirname $PYTHON`])
 250       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 251     ])
 252     AC_MSG_CHECKING([python include flags])
 253     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 254     AC_MSG_RESULT([$PYTHON_INCLUDE])
 255   ])
 256
 257 else
 258     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 259 [if you want Python bindings.])
 260
 261 fi
 262
 263 # Set default enable state for debug info.
 264 # The _enable_debug_info variable is prepended with an underscore to
 265 # avoid clashing with the one generated by AC_ARG_ENABLE.
 266 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 267
 268 # Optional debug info feature
 269 # Do _not_ indent the help string below (appears in the configure --help
 270 # output).
 271 AC_ARG_ENABLE([debug-info],
 272 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 273 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 274         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 275
 276 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 277 AS_IF([test "x$_enable_debug_info" = xyes], [
 278             # Check if libelf and libdw are present
 279             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 280             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 281             AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 282             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 283 ], [])
 284
 285 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 286 AC_SUBST(PACKAGE_LIBS)
 287
 288 LIBS="$LIBS $GMODULE_LIBS"
 289 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 290 AC_SUBST(PACKAGE_CFLAGS)
 291
 292 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 293 AC_SUBST(DEFAULT_INCLUDES)
 294
 295 babeltraceincludedir="${includedir}/babeltrace"
 296 AC_SUBST(babeltraceincludedir)
 297
 298 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 299 AC_SUBST(babeltracectfincludedir)
 300
 301 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 302 AC_SUBST(babeltracectfwriterincludedir)
 303
 304 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 305 AC_SUBST(babeltracectfirincludedir)
 306
 307 AC_CONFIG_FILES([
 308         Makefile
 309         types/Makefile
 310         compat/Makefile
 311         formats/Makefile
 312         formats/ctf/Makefile
 313         formats/ctf/types/Makefile
 314         formats/ctf-text/Makefile
 315         formats/ctf-text/types/Makefile
 316         formats/ctf-metadata/Makefile
 317         formats/bt-dummy/Makefile
 318         formats/lttng-live/Makefile
 319         formats/ctf/metadata/Makefile
 320         formats/ctf/writer/Makefile
 321         formats/ctf/ir/Makefile
 322         converter/Makefile
 323         doc/Makefile
 324         lib/Makefile
 325         lib/prio_heap/Makefile
 326         include/Makefile
 327         bindings/Makefile
 328         bindings/python/Makefile
 329         bindings/python/babeltrace/Makefile
 330         tests/Makefile
 331         tests/bin/Makefile
 332         tests/bin/intersection/Makefile
 333         tests/lib/Makefile
 334         tests/utils/Makefile
 335         tests/utils/tap/Makefile
 336         extras/Makefile
 337         extras/valgrind/Makefile
 338         babeltrace.pc
 339         babeltrace-ctf.pc
 340 ])
 341
 342 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 343 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 344 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 345 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 346 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 347
 348 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 349 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 350 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 351 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 352
 353 AC_OUTPUT
 354
 355 #
 356 # Mini-report on what will be built.
 357 #
 358
 359 PPRINT_INIT
 360 PPRINT_SET_INDENT(1)
 361 PPRINT_SET_TS(38)
 362
 363 AS_ECHO
 364 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 365 AS_ECHO
 366
 367 PPRINT_SUBTITLE([Features])
 368
 369 # Target architecture we're building for.
 370 target_arch=$host_cpu
 371 [
 372 for f in $CFLAGS; do
 373         if test $f = "-m32"; then
 374                 target_arch="32-bit"
 375         elif test $f = "-m64"; then
 376                 target_arch="64-bit"
 377         fi
 378 done
 379 ]
 380 PPRINT_PROP_STRING([Target architecture], $target_arch)
 381
 382 # python bindings enabled/disabled
 383 test "x$enable_python" = "xyes" && value=1 || value=0
 384 PPRINT_PROP_BOOL([Python bindings], $value)
 385
 386 # python bindings doc enabled/disabled
 387 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 388 PPRINT_PROP_BOOL([Python bindings doc], $value)
 389
 390 # debug info enabled/disabled
 391 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 392 PPRINT_PROP_BOOL([Debug information output], $value)
 393
 394
 395 report_bindir="`eval eval echo $bindir`"
 396 report_libdir="`eval eval echo $libdir`"
 397
 398 # Print the bindir and libdir this `make install' will install into.
 399 AS_ECHO
 400 PPRINT_SUBTITLE([Install directories])
 401 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 402 PPRINT_PROP_STRING([Libraries], [$report_libdir])