configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [1])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_dev_stage], [-rc1])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  34 m4_define([bt_version_name], [])
  35
  36 AC_INIT([babeltrace2], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  37 AC_PROG_SED
  38
  39 # Following the numbering scheme proposed by libtool for the library version
  40 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  41 m4_define([bt_lib_version_current], [0])
  42 m4_define([bt_lib_version_revision], [0])
  43 m4_define([bt_lib_version_age], [0])
  44 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  45
  46 bt_version_description=""
  47 bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
  48
  49 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  50
  51 AC_CONFIG_HEADERS([src/common/config.h])
  52 AC_CONFIG_AUX_DIR([config])
  53 AC_CONFIG_MACRO_DIR([m4])
  54
  55 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  56 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  57 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  58 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  59 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  60 AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
  61
  62 AC_CANONICAL_TARGET
  63 AC_CANONICAL_HOST
  64
  65
  66 ##                     ##
  67 ## Automake base setup ##
  68 ##                     ##
  69
  70 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  71 AM_MAINTAINER_MODE([enable])
  72
  73 # Enable silent rules if available (Introduced in AM 1.11)
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76
  77 ##                      ##
  78 ## OS specific defaults ##
  79 ##                      ##
  80
  81 MINGW32=no
  82 DEFAULT_ENABLE_DEBUG_INFO=yes
  83 LT_NO_UNDEFINED=""
  84 AS_CASE([$host_os],
  85   [solaris*|darwin*],
  86     [
  87         DEFAULT_ENABLE_DEBUG_INFO=no
  88     ],
  89   [cygwin*],
  90     [
  91         DEFAULT_ENABLE_DEBUG_INFO=no
  92         LT_NO_UNDEFINED="-no-undefined"
  93     ],
  94   [mingw*],
  95     [
  96         MINGW32=yes
  97         DEFAULT_ENABLE_DEBUG_INFO=no
  98         LT_NO_UNDEFINED="-no-undefined"
  99     ]
 100 )
 101
 102 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 103 AC_SUBST(LT_NO_UNDEFINED)
 104
 105
 106 ##                   ##
 107 ## C compiler checks ##
 108 ##                   ##
 109
 110 AC_USE_SYSTEM_EXTENSIONS
 111 AC_SYS_LARGEFILE
 112
 113 # Choose the c compiler
 114 AC_PROG_CC
 115
 116 # Make sure the c compiler supports C99
 117 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 118
 119 # Make sure the c compiler supports __attributes__
 120 AX_C___ATTRIBUTE__
 121 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 122   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 123
 124 # Make sur we have pthread support
 125 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 126
 127 # Checks for typedefs, structures, and compiler characteristics.
 128 AC_C_INLINE
 129 AC_C_TYPEOF
 130 AC_TYPE_PID_T
 131 AC_TYPE_SIZE_T
 132 AC_TYPE_INT16_T
 133 AC_TYPE_INT32_T
 134 AC_TYPE_INT64_T
 135 AC_TYPE_INT8_T
 136 AC_TYPE_OFF_T
 137 AC_TYPE_SSIZE_T
 138 AC_TYPE_UINT16_T
 139 AC_TYPE_UINT32_T
 140 AC_TYPE_UINT64_T
 141 AC_TYPE_UINT8_T
 142 AC_CHECK_TYPES([ptrdiff_t])
 143
 144
 145 ##               ##
 146 ## Header checks ##
 147 ##               ##
 148
 149 AC_HEADER_STDBOOL
 150 AC_CHECK_HEADERS([ \
 151         fcntl.h \
 152         float.h \
 153         ftw.h \
 154         libintl.h \
 155         limits.h \
 156         malloc.h \
 157         netdb.h \
 158         netinet/in.h \
 159         stddef.h \
 160         sys/socket.h \
 161         sys/time.h
 162 ])
 163
 164
 165 ##               ##
 166 ## Linker checks ##
 167 ##               ##
 168
 169 # Check if the linker supports no-as-needed
 170 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 171 AC_SUBST([LD_NO_AS_NEEDED])
 172
 173 # Check if the linker supports whole-archive
 174 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 175   [
 176     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 177     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 178   ],[
 179     # Fallback to force_load for the macOS linker
 180     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 181       [
 182         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 183         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 184       ],[
 185         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 186       ]
 187     )
 188   ]
 189 )
 190
 191 # Initialize and configure libtool
 192 LT_INIT([win32-dll])
 193
 194
 195 ##                 ##
 196 ## Programs checks ##
 197 ##                 ##
 198
 199 AC_PROG_MAKE_SET
 200 AC_PROG_MKDIR_P
 201 AC_PROG_LN_S
 202 AC_PATH_PROG([report_fold], [fold])
 203
 204 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 205 # is not distributed in tarballs
 206 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 207 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 208
 209 # check for bison
 210 AC_PROG_YACC
 211 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 212
 213 AS_IF([test "x$have_bison" != "xyes"], [
 214   AS_IF([test "x$in_git_repo" = "xyes"], [
 215     AC_MSG_FAILURE([dnl
 216 Bison >= 2.4 is required when building from the Git repository. You can
 217 set the YACC variable to override automatic detection.
 218     ])
 219   ], [
 220     AC_MSG_WARN([dnl
 221 Missing Bison >= 2.4. Note that the parser files are already built in
 222 this distribution tarball, so Bison is only needed if you intend to
 223 modify their sources. You can set the YACC variable to override automatic
 224 detection.
 225     ])
 226   ])
 227 ])
 228 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 229
 230 # check for flex
 231 AC_PROG_LEX
 232 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 233
 234 AS_IF([test "x$have_flex" != "xyes"], [
 235   AS_IF([test "x$in_git_repo" = "xyes"], [
 236     AC_MSG_FAILURE([dnl
 237 Flex >= 2.5.35 is required when building from the Git repository. You can
 238 set the LEX variable to override automatic detection.
 239     ])
 240   ], [
 241     AC_MSG_WARN([dnl
 242 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 243 this distribution tarball, so Flex is only needed if you intend to
 244 modify their sources. You can set the LEX variable to override automatic
 245 detection.
 246     ])
 247   ])
 248 ])
 249 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 250
 251
 252 ##                ##
 253 ## Library checks ##
 254 ##                ##
 255
 256 # Check what libraries are required on this platform to link sockets programs.
 257 AX_LIB_SOCKET_NSL
 258
 259 # Check for glib >= 2.28 with gmodule support
 260 AM_PATH_GLIB_2_0([2.28.0], [],
 261   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 262   [gmodule-no-export]
 263 )
 264
 265 # Checks for library functions.
 266 AC_FUNC_ALLOCA
 267 AC_FUNC_FORK
 268 AC_FUNC_MKTIME
 269 AC_FUNC_MMAP
 270 AC_FUNC_STRERROR_R
 271 AC_FUNC_STRNLEN
 272 AC_CHECK_FUNCS([ \
 273         atexit \
 274         dup2 \
 275         ftruncate \
 276         gethostbyname \
 277         gettimeofday \
 278         localtime_r \
 279         memchr \
 280         memset \
 281         mkdir \
 282         mkdtemp \
 283         munmap \
 284         rmdir \
 285         setenv \
 286         socket \
 287         strchr \
 288         strdup \
 289         strerror \
 290         strndup \
 291         strnlen \
 292         strrchr \
 293         strstr \
 294         strtoul \
 295         strtoull \
 296         tzset \
 297 ])
 298
 299 # AC_FUNC_MALLOC causes problems when cross-compiling.
 300 #AC_FUNC_MALLOC
 301 #AC_FUNC_REALLOC
 302
 303 # Check for fmemopen
 304 AC_CHECK_LIB([c], [fmemopen],
 305   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 306 )
 307
 308 # Check for open_memstream
 309 AC_CHECK_LIB([c], [open_memstream],
 310   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 311 )
 312
 313 # Check for posix_fallocate
 314 AC_CHECK_LIB([c], [posix_fallocate],
 315   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 316 )
 317
 318 ##                 ##
 319 ## User variables  ##
 320 ##                 ##
 321
 322 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 323 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 324 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 325
 326 # BABELTRACE_PLUGINS_DIR: Plugins directory
 327 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 328 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 329
 330 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 331 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 332 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 333
 334 # BABELTRACE_MINIMAL_LOG_LEVEL:
 335 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 336 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 337 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 338        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 339        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 340   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 341 )
 342 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 343
 344 # BABELTRACE_DEV_MODE:
 345 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 346 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 347         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 348 ], [BABELTRACE_DEV_MODE=0])
 349
 350 # BABELTRACE_DEBUG_MODE:
 351 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 352 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 353         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 354 ], [BABELTRACE_DEBUG_MODE=0])
 355
 356
 357 ##                              ##
 358 ## Optionnal features selection ##
 359 ##                              ##
 360
 361 # Python bindings
 362 # Disabled by default
 363 AC_ARG_ENABLE([python-bindings],
 364   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 365   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 366   [enable_python_bindings=no]
 367 )
 368
 369 # Python plugins
 370 # Disabled by default
 371 AC_ARG_ENABLE([python-plugins],
 372   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])],
 373   [], dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 374   [enable_python_plugins=no]
 375 )
 376
 377 # Debug info
 378 # Enabled by default, except on some platforms
 379 AC_ARG_ENABLE([debug-info],
 380   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 381   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 382   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 383 )
 384
 385 # API documentation
 386 # Disabled by default
 387 AC_ARG_ENABLE([api-doc],
 388   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 389   [enable_api_doc=$enableval],
 390   [enable_api_doc=no]
 391 )
 392
 393 # Built-in plugins
 394 # Disabled by default
 395 AC_ARG_ENABLE([built-in-plugins],
 396   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])],
 397   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 398   [enable_built_in_plugins=no]
 399 )
 400
 401 # Built-in python plugin support
 402 # Disabled by default
 403 AC_ARG_ENABLE([built-in-python-plugin-support],
 404   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])],
 405   [], dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 406   [enable_built_in_python_plugin_support=no]
 407 )
 408
 409 # Man pages
 410 # Enabled by default
 411 AC_ARG_ENABLE([man-pages],
 412   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 413   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 414   [enable_man_pages=yes]
 415 )
 416
 417
 418 # Set automake variables for optionnal feature conditionnals in Makefile.am
 419 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 420 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 421 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 422 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 423 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 424 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 425 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 426 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 427
 428 # Set defines for optionnal features conditionnals in the source code
 429
 430 ## jgalar: still used?
 431 AS_IF([test "x$enable_python_plugins" = xyes],
 432   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 433 )
 434
 435 AS_IF([test "x$enable_debug_info" = xyes],
 436   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 437 )
 438
 439 AS_IF([test "x$enable_built_in_plugins" = xyes],
 440   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 441 )
 442
 443 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 444   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 445 )
 446
 447 AS_IF([test "x$enable_debug_info" = xyes],
 448   [ENABLE_DEBUG_INFO_VAL=1],
 449   [ENABLE_DEBUG_INFO_VAL=0]
 450 )
 451
 452 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 453
 454
 455 # Check for conflicting optional features user choices
 456
 457 AS_IF([test "x$enable_built_in_plugins" = xyes],
 458   [
 459     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 460     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 461     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 462   ]
 463 )
 464
 465 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 466   [
 467     AS_IF([test "x$enable_python_plugins" = xno], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 468     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 469     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 470     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 471   ]
 472 )
 473
 474
 475 # Check for optionnal features dependencies
 476
 477 AS_IF([test "x$enable_python_bindings" = xyes],
 478   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 479 )
 480
 481 AM_PATH_PYTHON([3.0], [
 482   AM_PATH_PYTHON_MODULES([PYTHON])
 483
 484   # pythondir is the path where extra modules are to be installed
 485   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 486
 487   # pyexecdir is the path that contains shared objects used by the extra modules
 488   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 489
 490   AS_IF([test -z "$PYTHON_CONFIG"], [
 491     AC_PATH_PROGS([PYTHON_CONFIG],
 492                   [python$PYTHON_VERSION-config python-config],
 493                   [],
 494                   [`dirname $PYTHON`])
 495   ])
 496
 497   AS_IF([test -n "$PYTHON_CONFIG"], [
 498     AS_IF([test -z "$PYTHON_INCLUDE"], [
 499       AC_MSG_CHECKING([Python include flags])
 500       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 501       AC_MSG_RESULT([$PYTHON_INCLUDE])
 502     ])
 503
 504     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 505       AC_MSG_CHECKING([Python library flags])
 506       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 507       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 508         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 509       ])
 510       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 511     ])
 512   ])
 513 ], [:])
 514
 515 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 516 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 517
 518 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 519 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 520
 521 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 522   AS_IF([test "x$have_python_dev" = xno], [
 523     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 524   ])
 525 ])
 526
 527 AS_IF([test "x$enable_debug_info" = xyes],
 528   [
 529     # Check if libelf and libdw are present
 530     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 531     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 532     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 533     ELFUTILS_LIBS="-lelf -ldw"
 534   ]
 535 )
 536 AC_SUBST([ELFUTILS_LIBS])
 537
 538 AS_IF([test "x$enable_api_doc" = "xyes"],
 539   [
 540     DX_DOXYGEN_FEATURE(ON)
 541     DX_DOT_FEATURE(OFF)
 542     DX_HTML_FEATURE(ON)
 543     DX_CHM_FEATURE(OFF)
 544     DX_CHI_FEATURE(OFF)
 545     DX_MAN_FEATURE(OFF)
 546     DX_RTF_FEATURE(OFF)
 547     DX_XML_FEATURE(OFF)
 548     DX_PDF_FEATURE(OFF)
 549     DX_PS_FEATURE(OFF)
 550     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 551     AS_IF([test -z "$DX_DOXYGEN"],
 552           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 553     )
 554   ]
 555 )
 556
 557 have_asciidoc_xmlto=no
 558 warn_prebuilt_man_pages=no
 559
 560 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 561 AC_PATH_PROG([XMLTO], [xmlto], [no])
 562
 563 AS_IF([test "x$enable_man_pages" = "xyes"], [
 564   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 565     AS_IF([test "x$in_git_repo" = "xyes"], [
 566       # this is an error because we're in the Git repo, which
 567       # means the man pages are not already generated for us,
 568       # thus asciixmlto are required because we were asked
 569       # to build the man pages
 570       AC_MSG_ERROR([
 571 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 572 --disable-man-pages to disable building the man pages, in which case
 573 they will not be installed.
 574       ])
 575     ], [
 576       # only warn here: since we're in the tarball, the man
 577       # pages should already be generated at this point, thus
 578       # asciidoc/xmlto are not strictly required
 579       warn_prebuilt_man_pages=yes
 580     ])
 581   ], [
 582     have_asciidoc_xmlto=yes
 583   ])
 584 ])
 585
 586 # export AsciiDoc and xmlto existence
 587 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 588
 589 # a wonderful hack that seems necessary because $libdir is
 590 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 591 # by autoconf when it's not specified by the user
 592 AS_IF([test "x$exec_prefix" = xNONE], [
 593   AS_IF([test "x$prefix" = xNONE], [
 594     PREFIX="$ac_default_prefix"
 595   ], [
 596     PREFIX="$prefix"
 597   ])
 598
 599   LIBDIR="$PREFIX/lib"
 600 ], [
 601   LIBDIR="$libdir"
 602 ])
 603
 604 AC_SUBST(LIBDIR)
 605
 606 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 607 # test).
 608 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 609
 610 # Check that the current size_t matches the size that glib thinks it should
 611 # be. This catches problems on multi-arch where people try to do a 32-bit
 612 # build while pointing at 64-bit glib headers. This is a common error because
 613 # glib.h is not platform specific but it includes glibconfig.h which is and
 614 # is usually installed in a non-standard path.
 615
 616 # Do this before enabling all the warning flags, as the
 617 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 618 # test fail unnecessarily.
 619
 620 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 621 # output. Specifically allow pkg_config_libdir to be able to print the
 622 # error message.
 623 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 624
 625 save_CFLAGS=${CFLAGS}
 626 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 627 AC_COMPILE_IFELSE([
 628   AC_LANG_PROGRAM([dnl
 629 #include <glib.h>
 630 #include <unistd.h>
 631   ], [dnl
 632 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 633   ])
 634 ],[:],[
 635   AC_MSG_ERROR([dnl
 636 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 637 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 638 target.
 639   ])
 640 ])
 641 CFLAGS=${save_CFLAGS}
 642
 643 # Detect C and LD warning flags supported by the compiler.
 644 AX_COMPILER_FLAGS(
 645         [WARN_CFLAGS], dnl CFLAGS variable name
 646         [WARN_LDFLAGS], dnl LDFLAGS variable name (unused for now)
 647         [], dnl is-release
 648         [], dnl Extra base CFLAGS
 649         [ dnl Extra "yes" CFLAGS
 650                 dnl Disable these flags, either because we don't want them
 651                 dnl or because we want them but are not ready to enable them
 652                 dnl yet.
 653                 -Wno-sign-compare dnl
 654                 -Wno-inline dnl
 655                 -Wno-declaration-after-statement dnl
 656                 -Wno-switch-enum dnl
 657                 -Wno-switch-default dnl
 658                 -Wno-packed dnl
 659                 -Wno-pointer-arith dnl
 660                 -Wno-format-nonliteral dnl
 661                 -Wno-double-promotion dnl
 662                 -Wno-cast-align dnl
 663                 dnl
 664                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 665                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 666                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 667                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 668                 dnl It's simpler to just disable the warning globally.
 669                 dnl
 670                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 671                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 672                 dnl reproduce the warning using that package.
 673                 dnl
 674                 dnl Ref: https://github.com/swig/swig/issues/1259
 675                 -Wno-cast-function-type dnl
 676         ])
 677
 678 # CFLAGS from AX_COMPILER_FLAGS.
 679 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 680
 681 # The test used in AX_COMPILER_FLAGS, generated using AC_LANG_PROGRAM, is
 682 # written in such a way that it triggers a -Wold-style-definition warning.  So
 683 # if the user has -Werror in their CFLAGS, that warning flag will end up
 684 # disabled, because the test program will not build.
 685 #
 686 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 687 # (it is accepted for compatibility although it has no effect), and there is
 688 # not reason to not want it.
 689
 690 AM_CFLAGS="${AM_CFLAGS} -Wold-style-definition"
 691
 692 # We want this one to always be an error.
 693 AM_CFLAGS="${AM_CFLAGS} -Werror=implicit-function-declaration"
 694
 695 # Done for AM_CFLAGS.
 696 AC_SUBST(AM_CFLAGS)
 697
 698 # Set global CPPFLAGS in AM_CPPFLAGS
 699 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 700 AC_SUBST(AM_CPPFLAGS)
 701
 702 # Add glib to global link libs
 703 LIBS="$LIBS $GLIB_LIBS"
 704
 705 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 706 # to rename babeltrace2.bin to babeltrace2 at install time.
 707 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 708 AC_SUBST(program_transform_name)
 709
 710 AC_CONFIG_FILES([
 711         doc/api/Makefile
 712         doc/api/libbabeltrace2/Doxyfile
 713         doc/api/libbabeltrace2/Makefile
 714         doc/contributing-images/Makefile
 715         doc/Makefile
 716         doc/man/asciidoc-attrs.conf
 717         doc/man/Makefile
 718         include/Makefile
 719         Makefile
 720         src/argpar/Makefile
 721         src/autodisc/Makefile
 722         src/babeltrace2-ctf-writer.pc
 723         src/babeltrace2.pc
 724         src/bindings/Makefile
 725         src/bindings/python/bt2/bt2/version.py
 726         src/bindings/python/bt2/Makefile
 727         src/bindings/python/bt2/setup.py
 728         src/bindings/python/Makefile
 729         src/cli/Makefile
 730         src/common/Makefile
 731         src/compat/Makefile
 732         src/ctfser/Makefile
 733         src/ctf-writer/Makefile
 734         src/fd-cache/Makefile
 735         src/lib/graph/Makefile
 736         src/lib/graph/message/Makefile
 737         src/lib/Makefile
 738         src/lib/plugin/Makefile
 739         src/lib/prio-heap/Makefile
 740         src/lib/trace-ir/Makefile
 741         src/logging/Makefile
 742         src/Makefile
 743         src/plugins/common/Makefile
 744         src/plugins/common/muxing/Makefile
 745         src/plugins/common/param-validation/Makefile
 746         src/plugins/ctf/common/bfcr/Makefile
 747         src/plugins/ctf/common/Makefile
 748         src/plugins/ctf/common/metadata/Makefile
 749         src/plugins/ctf/common/msg-iter/Makefile
 750         src/plugins/ctf/fs-sink/Makefile
 751         src/plugins/ctf/fs-src/Makefile
 752         src/plugins/ctf/lttng-live/Makefile
 753         src/plugins/ctf/Makefile
 754         src/plugins/lttng-utils/debug-info/Makefile
 755         src/plugins/lttng-utils/Makefile
 756         src/plugins/Makefile
 757         src/plugins/text/dmesg/Makefile
 758         src/plugins/text/Makefile
 759         src/plugins/text/pretty/Makefile
 760         src/plugins/text/details/Makefile
 761         src/plugins/utils/counter/Makefile
 762         src/plugins/utils/dummy/Makefile
 763         src/plugins/utils/Makefile
 764         src/plugins/utils/muxer/Makefile
 765         src/plugins/utils/trimmer/Makefile
 766         src/py-common/Makefile
 767         src/python-plugin-provider/Makefile
 768         src/param-parse/Makefile
 769         src/string-format/Makefile
 770         tests/bitfield/Makefile
 771         tests/ctf-writer/Makefile
 772         tests/lib/Makefile
 773         tests/lib/test-plugin-plugins/Makefile
 774         tests/Makefile
 775         tests/param-validation/Makefile
 776         tests/plugins/Makefile
 777         tests/plugins/src.ctf.fs/Makefile
 778         tests/plugins/src.ctf.fs/succeed/Makefile
 779         tests/plugins/sink.ctf.fs/Makefile
 780         tests/plugins/sink.ctf.fs/succeed/Makefile
 781         tests/plugins/flt.lttng-utils.debug-info/Makefile
 782         tests/plugins/flt.utils.muxer/Makefile
 783         tests/plugins/flt.utils.muxer/succeed/Makefile
 784         tests/plugins/flt.utils.trimmer/Makefile
 785         tests/utils/Makefile
 786         tests/utils/tap/Makefile
 787 ])
 788
 789 AC_OUTPUT
 790
 791 #
 792 # Mini-report on what will be built.
 793 #
 794
 795 PPRINT_INIT
 796 PPRINT_SET_INDENT(1)
 797 PPRINT_SET_TS(38)
 798
 799 AS_ECHO
 800
 801 AS_IF([test -n "bt_version_name"], [
 802         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 803 ], [
 804         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 805 ])
 806
 807 AS_ECHO
 808
 809 AS_IF([test -n "$bt_version_description"], [
 810         AS_IF([test -n "$report_fold"], [
 811                 AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
 812         ], [
 813                 AS_ECHO("$bt_version_description")
 814         ])
 815
 816         AS_ECHO
 817 ])
 818
 819 PPRINT_SUBTITLE([System])
 820
 821 # Target architecture we're building for.
 822 target_arch=$host_cpu
 823 [
 824 for f in $CFLAGS; do
 825         if test $f = "-m32"; then
 826                 target_arch="32-bit"
 827         elif test $f = "-m64"; then
 828                 target_arch="64-bit"
 829         fi
 830 done
 831 ]
 832
 833 PPRINT_PROP_STRING([Target architecture], $target_arch)
 834
 835 AS_ECHO
 836 PPRINT_SUBTITLE([Python 3 language support])
 837 test "x$have_python" = "xyes" && value=1 || value=0
 838 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 839 test "x$have_python_dev" = "xyes" && value=1 || value=0
 840 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 841 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 842 PPRINT_PROP_BOOL([Python bindings], $value)
 843 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 844 PPRINT_PROP_BOOL([Python plugin support], $value)
 845 AS_IF([test "x$have_python" = "xyes"], [
 846   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 847 ])
 848 AS_IF([test "x$have_python_dev" = "xyes"], [
 849   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 850   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 851   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 852 ])
 853 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 854   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 855   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 856 ])
 857
 858 AS_ECHO
 859 PPRINT_SUBTITLE([Plugins])
 860 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 861 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 862 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 863 PPRINT_PROP_BOOL(['text' plugin], 1)
 864 PPRINT_PROP_BOOL(['utils' plugin], 1)
 865
 866 AS_ECHO
 867 PPRINT_SUBTITLE([Built-in features])
 868 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 869 PPRINT_PROP_BOOL([Built-in plugins], $value)
 870 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 871 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 872
 873 AS_ECHO
 874 PPRINT_SUBTITLE([Documentation])
 875
 876 # man pages build enabled/disabled
 877 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 878
 879 AS_IF([test "x$enable_man_pages" != "xno"], [
 880   AS_IF([test "x$in_git_repo" = "xyes"], [
 881     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 882   ], [
 883     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 884       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 885     ], [
 886       PPRINT_PROP_STRING([build_man_pages_msg],
 887         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 888         $PPRINT_COLOR_SUBTITLE)
 889     ])
 890   ])
 891 ], [
 892   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 893 ])
 894
 895 m4_popdef([build_man_pages_msg])
 896
 897 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 898 PPRINT_PROP_BOOL([HTML API documentation], $value)
 899
 900 AS_ECHO
 901 PPRINT_SUBTITLE([Logging])
 902 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 903
 904 AS_ECHO
 905 PPRINT_SUBTITLE([Special build modes])
 906 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 907 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 908
 909 report_bindir="`eval eval echo $bindir`"
 910 report_libdir="`eval eval echo $libdir`"
 911 report_sysconfdif="`eval eval echo $sysconfdir`"
 912 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 913 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 914
 915 # Print the bindir and libdir this `make install' will install into.
 916 AS_ECHO
 917 PPRINT_SUBTITLE([Install directories])
 918 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 919 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 920 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 921 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 922 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])