configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  41 LIBS="$PTHREAD_LIBS $LIBS"
  42 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  43 CC="$PTHREAD_CC"
  44
  45 # Check linker option
  46 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  47 AC_SUBST([LD_NO_AS_NEEDED])
  48
  49 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  50
  51 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  52         if test x"$YACC" != "xbison -y"; then
  53                 AC_MSG_ERROR([[bison not found and is required when building from git.
  54                 Please install bison]])
  55         fi
  56         AC_PATH_PROG([BISON],[bison])
  57         AX_PROG_BISON_VERSION([2.4], [],[
  58                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  59         ])
  60 fi
  61
  62 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  63         if test x"$LEX" != "xflex"; then
  64                 AC_MSG_ERROR([[flex not found and is required when building from git.
  65                 Please install flex]])
  66         fi
  67         AC_PATH_PROG([FLEX],[flex])
  68         AX_PROG_FLEX_VERSION([2.5.35], [],[
  69                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  70         ])
  71 fi
  72
  73
  74 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  75
  76 # Checks for typedefs, structures, and compiler characteristics.
  77 AC_C_INLINE
  78 AC_TYPE_PID_T
  79 AC_TYPE_SIZE_T
  80 AC_TYPE_INT16_T
  81 AC_TYPE_INT32_T
  82 AC_TYPE_INT64_T
  83 AC_TYPE_INT8_T
  84 AC_TYPE_OFF_T
  85 AC_TYPE_SSIZE_T
  86 AC_TYPE_UINT16_T
  87 AC_TYPE_UINT32_T
  88 AC_TYPE_UINT64_T
  89 AC_TYPE_UINT8_T
  90
  91 # Checks for library functions.
  92 AC_FUNC_MALLOC
  93 AC_FUNC_MMAP
  94 AC_CHECK_FUNCS([ \
  95         gettimeofday munmap strtoul ftruncate gethostbyname \
  96         localtime_r memset mkdir rmdir setenv socket \
  97         strchr strdup strerror strndup strrchr strtoull tzset \
  98 ])
  99
 100 # Check for MinGW32.
 101 MINGW32=no
 102 case $host in
 103   *-*-mingw*)
 104         MINGW32=yes;;
 105 esac
 106
 107 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 108
 109 # Check what libraries are required on this platform to link sockets programs.
 110 AX_LIB_SOCKET_NSL
 111
 112 # Check for libuuid
 113 AC_CHECK_LIB([uuid], [uuid_generate],
 114 [
 115         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 116         have_libuuid=yes
 117 ],
 118 [
 119         # libuuid not found, check for uuid_create in libc.
 120         AC_CHECK_LIB([c], [uuid_create],
 121         [
 122                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 123                 have_libc_uuid=yes
 124         ],
 125         [
 126                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 127                 if test "x$MINGW32" = xno; then
 128                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 129                 fi
 130         ])
 131 ]
 132 )
 133 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 134 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 135
 136 # Check for fmemopen
 137 AC_CHECK_LIB([c], [fmemopen],
 138 [
 139         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 140 ]
 141 )
 142
 143 # Check for open_memstream
 144 AC_CHECK_LIB([c], [open_memstream],
 145 [
 146         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 147 ]
 148 )
 149
 150 # Check for posix_fallocate
 151 AC_CHECK_LIB([c], [posix_fallocate],
 152 [
 153         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 154 ]
 155 )
 156
 157 AC_CHECK_LIB([popt], [poptGetContext], [],
 158         [AC_MSG_ERROR([Cannot find popt.])]
 159 )
 160
 161
 162 # For Python
 163 # SWIG version needed or newer:
 164 swig_version=2.0.0
 165
 166 AC_ARG_ENABLE([python-bindings],
 167               [AC_HELP_STRING([--enable-python-bindings],
 168                               [generate Python bindings])],
 169               [enable_python=yes], [enable_python=no])
 170
 171 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 172
 173 AC_ARG_ENABLE([python-bindings-doc],
 174               [AC_HELP_STRING([--enable-python-bindings-doc],
 175                               [generate Python bindings documentation])],
 176               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 177
 178 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 179   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 180 fi
 181
 182 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 183
 184 if test "x${enable_python:-yes}" = xyes; then
 185   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 186   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 187
 188   AM_PATH_PYTHON_MODULES([PYTHON])
 189   # pythondir is the path where extra modules are to be installed
 190   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 191   # pyexecdir is the path that contains shared objects used by the extra modules
 192   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 193   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 194   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 195   AS_IF([test -z "$PYTHON_INCLUDE"], [
 196     AS_IF([test -z "$PYTHON_CONFIG"], [
 197       AC_PATH_PROGS([PYTHON_CONFIG],
 198                     [python$PYTHON_VERSION-config python-config],
 199                     [no],
 200                     [`dirname $PYTHON`])
 201       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 202     ])
 203     AC_MSG_CHECKING([python include flags])
 204     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 205     AC_MSG_RESULT([$PYTHON_INCLUDE])
 206   ])
 207 else
 208     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 209 [if you want Python bindings.])
 210
 211 fi
 212
 213 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 214     AM_CHECK_PYTHON_SPHINX([PYTHON])
 215     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 216       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 217     )
 218 fi
 219
 220 pkg_modules="gmodule-2.0 >= 2.0.0"
 221 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 222 AC_SUBST(PACKAGE_LIBS)
 223
 224 LIBS="$LIBS $GMODULE_LIBS"
 225 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 226 AC_SUBST(PACKAGE_CFLAGS)
 227
 228 babeltraceincludedir="${includedir}/babeltrace"
 229 AC_SUBST(babeltraceincludedir)
 230
 231 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 232 AC_SUBST(babeltracectfincludedir)
 233
 234 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 235 AC_SUBST(babeltracectfwriterincludedir)
 236
 237 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 238 AC_SUBST(babeltracectfirincludedir)
 239
 240 AC_CONFIG_FILES([
 241         Makefile
 242         types/Makefile
 243         compat/Makefile
 244         formats/Makefile
 245         formats/ctf/Makefile
 246         formats/ctf/types/Makefile
 247         formats/ctf-text/Makefile
 248         formats/ctf-text/types/Makefile
 249         formats/ctf-metadata/Makefile
 250         formats/bt-dummy/Makefile
 251         formats/lttng-live/Makefile
 252         formats/ctf/metadata/Makefile
 253         formats/ctf/writer/Makefile
 254         formats/ctf/ir/Makefile
 255         converter/Makefile
 256         doc/Makefile
 257         doc/bindings/Makefile
 258         doc/bindings/python/Makefile
 259         lib/Makefile
 260         lib/prio_heap/Makefile
 261         include/Makefile
 262         bindings/Makefile
 263         bindings/python/Makefile
 264         tests/Makefile
 265         tests/bin/Makefile
 266         tests/lib/Makefile
 267         tests/utils/Makefile
 268         tests/utils/tap/Makefile
 269         extras/Makefile
 270         extras/valgrind/Makefile
 271         babeltrace.pc
 272         babeltrace-ctf.pc
 273 ])
 274 AC_OUTPUT