configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.50])
   5 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 AM_MAINTAINER_MODE([enable])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 AC_PROG_MKDIR_P
  21 AC_PROG_LN_S
  22
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AC_SYS_LARGEFILE
  26
  27 # Checks for programs.
  28 AC_PROG_CC_STDC
  29 AC_PROG_MAKE_SET
  30 LT_INIT
  31 AC_PROG_YACC
  32 AC_PROG_LEX
  33
  34 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  35         if test x"$YACC" != "xbison -y"; then
  36                 AC_MSG_ERROR([[bison not found and is required when building from git.
  37                 Please install bison]])
  38         fi
  39         AC_PATH_PROG([BISON],[bison])
  40         AX_PROG_BISON_VERSION([2.4], [],[
  41                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  42         ])
  43 fi
  44
  45 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  46         if test x"$LEX" != "xflex"; then
  47                 AC_MSG_ERROR([[flex not found and is required when building from git.
  48                 Please install flex]])
  49         fi
  50         AC_PATH_PROG([FLEX],[flex])
  51         AX_PROG_FLEX_VERSION([2.5.35], [],[
  52                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  53         ])
  54 fi
  55
  56
  57 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  58
  59 # Checks for typedefs, structures, and compiler characteristics.
  60 AC_C_INLINE
  61 AC_TYPE_PID_T
  62 AC_TYPE_SIZE_T
  63
  64 # Checks for library functions.
  65 AC_FUNC_MALLOC
  66 AC_FUNC_MMAP
  67 AC_CHECK_FUNCS([ \
  68         bzero gettimeofday munmap strtoul ftruncate gethostbyname \
  69         localtime_r memset mkdir rmdir setenv socket \
  70         strchr strdup strerror strndup strrchr strtoull tzset \
  71 ])
  72
  73 # Check for MinGW32.
  74 MINGW32=no
  75 case $host in
  76   *-*-mingw*)
  77         MINGW32=yes;;
  78 esac
  79
  80 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  81
  82 # Check for libuuid
  83 AC_CHECK_LIB([uuid], [uuid_generate],
  84 [
  85         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  86         have_libuuid=yes
  87 ],
  88 [
  89         # libuuid not found, check for uuid_create in libc.
  90         AC_CHECK_LIB([c], [uuid_create],
  91         [
  92                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  93                 have_libc_uuid=yes
  94         ],
  95         [
  96                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  97                 if test "x$MINGW32" = xno; then
  98                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  99                 fi
 100         ])
 101 ]
 102 )
 103 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 104 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 105
 106 # Check for fmemopen
 107 AC_CHECK_LIB([c], [fmemopen],
 108 [
 109         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 110 ]
 111 )
 112
 113 # Check for open_memstream
 114 AC_CHECK_LIB([c], [open_memstream],
 115 [
 116         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 117 ]
 118 )
 119
 120 AC_CHECK_LIB([popt], [poptGetContext], [],
 121         [AC_MSG_ERROR([Cannot find popt.])]
 122 )
 123
 124
 125 # For Python
 126 # SWIG version needed or newer:
 127 swig_version=2.0.0
 128
 129 AC_ARG_ENABLE([python-bindings],
 130               [AC_HELP_STRING([--enable-python-bindings],
 131                               [generate Python bindings])],
 132               [enable_python=yes], [enable_python=no])
 133
 134 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 135
 136 AC_ARG_ENABLE([python-bindings-doc],
 137               [AC_HELP_STRING([--enable-python-bindings-doc],
 138                               [generate Python bindings documentation])],
 139               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 140
 141 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 142   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 143 fi
 144
 145 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 146
 147 if test "x${enable_python:-yes}" = xyes; then
 148   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 149   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 150
 151   AM_PATH_PYTHON_MODULES([PYTHON])
 152   # pythondir is the path where extra modules are to be installed
 153   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 154   # pyexecdir is the path that contains shared objects used by the extra modules
 155   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 156   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 157   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 158   AS_IF([test -z "$PYTHON_INCLUDE"], [
 159     AS_IF([test -z "$PYTHON_CONFIG"], [
 160       AC_PATH_PROGS([PYTHON_CONFIG],
 161                     [python$PYTHON_VERSION-config python-config],
 162                     [no],
 163                     [`dirname $PYTHON`])
 164       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 165     ])
 166     AC_MSG_CHECKING([python include flags])
 167     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 168     AC_MSG_RESULT([$PYTHON_INCLUDE])
 169   ])
 170 else
 171     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 172 [if you want Python bindings.])
 173
 174 fi
 175
 176 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 177     AM_CHECK_PYTHON_SPHINX([PYTHON])
 178     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 179       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 180     )
 181 fi
 182
 183 pkg_modules="gmodule-2.0 >= 2.0.0"
 184 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 185 AC_SUBST(PACKAGE_LIBS)
 186
 187 LIBS="$LIBS $GMODULE_LIBS"
 188 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 189 AC_SUBST(PACKAGE_CFLAGS)
 190
 191 babeltraceincludedir="${includedir}/babeltrace"
 192 AC_SUBST(babeltraceincludedir)
 193
 194 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 195 AC_SUBST(babeltracectfincludedir)
 196
 197 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 198 AC_SUBST(babeltracectfwriterincludedir)
 199
 200 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 201 AC_SUBST(babeltracectfirincludedir)
 202
 203 AC_CONFIG_FILES([
 204         Makefile
 205         types/Makefile
 206         compat/Makefile
 207         formats/Makefile
 208         formats/ctf/Makefile
 209         formats/ctf/types/Makefile
 210         formats/ctf-text/Makefile
 211         formats/ctf-text/types/Makefile
 212         formats/ctf-metadata/Makefile
 213         formats/bt-dummy/Makefile
 214         formats/lttng-live/Makefile
 215         formats/ctf/metadata/Makefile
 216         formats/ctf/writer/Makefile
 217         formats/ctf/ir/Makefile
 218         converter/Makefile
 219         doc/Makefile
 220         doc/bindings/Makefile
 221         doc/bindings/python/Makefile
 222         lib/Makefile
 223         lib/prio_heap/Makefile
 224         include/Makefile
 225         bindings/Makefile
 226         bindings/python/Makefile
 227         tests/Makefile
 228         tests/bin/Makefile
 229         tests/lib/Makefile
 230         tests/utils/Makefile
 231         tests/utils/tap/Makefile
 232         extras/Makefile
 233         extras/valgrind/Makefile
 234         babeltrace.pc
 235         babeltrace-ctf.pc
 236 ])
 237 AC_OUTPUT