configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre1])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT(win32-dll)
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53 LIBS="$PTHREAD_LIBS $LIBS"
  54 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  55 CC="$PTHREAD_CC"
  56
  57 # Check linker option
  58 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  59 AC_SUBST([LD_NO_AS_NEEDED])
  60
  61 AC_HEADER_STDBOOL
  62 AC_CHECK_HEADERS([ \
  63         fcntl.h \
  64         float.h \
  65         libintl.h \
  66         limits.h \
  67         malloc.h \
  68         netdb.h \
  69         netinet/in.h \
  70         stddef.h \
  71         sys/socket.h \
  72 ])
  73
  74 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  75         if test x"$(basename "$YACC")" != "xbison -y"; then
  76                 AC_MSG_ERROR([[bison not found and is required when building from git.
  77                 Please install bison]])
  78         fi
  79         AC_PATH_PROG([BISON],[bison])
  80         AX_PROG_BISON_VERSION([2.4], [],[
  81                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  82         ])
  83 fi
  84
  85 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  86         if test x"$LEX" != "xflex"; then
  87                 AC_MSG_ERROR([[flex not found and is required when building from git.
  88                 Please install flex]])
  89         fi
  90         AC_PATH_PROG([FLEX],[flex])
  91         AX_PROG_FLEX_VERSION([2.5.35], [],[
  92                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  93         ])
  94 fi
  95
  96
  97 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  98
  99 # Check what libraries are required on this platform to link sockets programs.
 100 AX_LIB_SOCKET_NSL
 101
 102 # Checks for typedefs, structures, and compiler characteristics.
 103 AC_C_INLINE
 104 AC_TYPE_PID_T
 105 AC_TYPE_SIZE_T
 106 AC_TYPE_INT16_T
 107 AC_TYPE_INT32_T
 108 AC_TYPE_INT64_T
 109 AC_TYPE_INT8_T
 110 AC_TYPE_OFF_T
 111 AC_TYPE_SSIZE_T
 112 AC_TYPE_UINT16_T
 113 AC_TYPE_UINT32_T
 114 AC_TYPE_UINT64_T
 115 AC_TYPE_UINT8_T
 116
 117 # Checks for library functions.
 118 AC_FUNC_ALLOCA
 119 AC_FUNC_FORK
 120 AC_FUNC_MALLOC
 121 AC_FUNC_MKTIME
 122 AC_FUNC_MMAP
 123 AC_FUNC_REALLOC
 124 AC_FUNC_STRERROR_R
 125 AC_CHECK_FUNCS([ \
 126         atexit \
 127         dirfd \
 128         dup2 \
 129         ftruncate \
 130         gethostbyname \
 131         gethostname \
 132         gettimeofday \
 133         localtime_r \
 134         memchr \
 135         memset \
 136         mkdir \
 137         mkdtemp \
 138         munmap \
 139         rmdir \
 140         setenv \
 141         socket \
 142         strchr \
 143         strdup \
 144         strerror \
 145         strndup \
 146         strnlen \
 147         strrchr \
 148         strtoul \
 149         strtoull \
 150         tzset \
 151         uname \
 152 ])
 153
 154 MINGW32=no
 155 DEFAULT_ENABLE_DEBUG_INFO=yes
 156 LT_NO_UNDEFINED=""
 157 AS_CASE([$host_os],
 158   [solaris*|darwin*],
 159     [
 160         DEFAULT_ENABLE_DEBUG_INFO=no
 161     ],
 162   [mingw*],
 163     [
 164         MINGW32=yes
 165         DEFAULT_ENABLE_DEBUG_INFO=no
 166         LT_NO_UNDEFINED="-no-undefined"
 167     ]
 168 )
 169
 170 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 171 AC_SUBST(LT_NO_UNDEFINED)
 172
 173 # Check for uuid in system libs
 174 AC_CHECK_FUNCS([uuid_generate],
 175 [
 176   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 177   link_with_libuuid=no
 178 ],
 179 [
 180   # First, check the pkg-config module is available, otherwise explicitly check
 181   # for libuuid, or uuid support in the C-library.
 182   PKG_CHECK_MODULES([UUID], [uuid],
 183   [
 184     LIBS="${UUID_LIBS} ${LIBS}"
 185     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 186     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 187     link_with_libuuid=yes
 188   ],
 189   [
 190     # Check for libuuid
 191     AC_CHECK_LIB([uuid], [uuid_generate],
 192     [
 193       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 194       link_with_libuuid=yes
 195     ],
 196     [
 197       # libuuid not found, check for uuid_create in libc.
 198       AC_CHECK_LIB([c], [uuid_create],
 199       [
 200         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 201         link_with_libc_uuid=yes
 202       ],
 203       [
 204         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 205         if test "x$MINGW32" = xno; then
 206           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 207         fi
 208       ])
 209     ])
 210   ])
 211 ])
 212
 213 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 214 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 215
 216 # Check for fmemopen
 217 AC_CHECK_LIB([c], [fmemopen],
 218 [
 219         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 220 ]
 221 )
 222
 223 # Check for open_memstream
 224 AC_CHECK_LIB([c], [open_memstream],
 225 [
 226         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 227 ]
 228 )
 229
 230 # Check for posix_fallocate
 231 AC_CHECK_LIB([c], [posix_fallocate],
 232 [
 233         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 234 ]
 235 )
 236
 237 # Check for faccessat
 238 AC_CHECK_LIB([c], [faccessat],
 239 [
 240         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 241 ]
 242 )
 243
 244 AC_CHECK_LIB([popt], [poptGetContext], [],
 245         [AC_MSG_ERROR([Cannot find popt.])]
 246 )
 247
 248 # Plugins
 249 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 250 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 251
 252 # For Python
 253 # SWIG version needed or newer:
 254 swig_version=2.0.0
 255
 256 AC_ARG_ENABLE([python-bindings],
 257               [AC_HELP_STRING([--enable-python-bindings],
 258                               [generate Python bindings])],
 259               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 260
 261 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 262
 263 AC_ARG_ENABLE(
 264         [python-plugins],
 265         [AC_HELP_STRING(
 266                 [--enable-python-plugins],
 267                 [add support for the Babeltrace library and converter to load Python plugins])
 268         ],
 269         [enable_python_plugins=$enableval],
 270         [enable_python_plugins=no]
 271 )
 272
 273 if test "x${enable_python_bindings:-yes}" = xyes; then
 274   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 275 else
 276     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 277 [if you want Python bindings.])
 278 fi
 279
 280 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 281   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 282
 283   AM_PATH_PYTHON_MODULES([PYTHON])
 284   # pythondir is the path where extra modules are to be installed
 285   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 286   # pyexecdir is the path that contains shared objects used by the extra modules
 287   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 288   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 289   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 290   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 291   AS_IF([test -z "$PYTHON_INCLUDE"], [
 292     AS_IF([test -z "$PYTHON_CONFIG"], [
 293       AC_PATH_PROGS([PYTHON_CONFIG],
 294                     [python$PYTHON_VERSION-config python-config],
 295                     [no],
 296                     [`dirname $PYTHON`])
 297       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 298     ])
 299     AC_MSG_CHECKING([Python include flags])
 300     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 301     AC_MSG_RESULT([$PYTHON_INCLUDE])
 302   ])
 303   AS_IF([test -z "$PYTHON_LIBS"], [
 304     AS_IF([test -z "$PYTHON_CONFIG"], [
 305       AC_PATH_PROGS([PYTHON_CONFIG],
 306                     [python$PYTHON_VERSION-config python-config],
 307                     [no],
 308                     [`dirname $PYTHON`])
 309       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 310     ])
 311     AC_MSG_CHECKING([Python library flags])
 312     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 313     AC_MSG_RESULT([$PYTHON_LIBS])
 314   ])
 315 fi
 316
 317 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 318
 319 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 320 AS_IF(
 321   [test "x$enable_python_plugins" != xno],
 322   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 323 )
 324
 325 AC_ARG_ENABLE([python-bindings-doc],
 326               [AC_HELP_STRING([--enable-python-bindings-doc],
 327                               [generate Python bindings documentation])],
 328               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 329
 330 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 331
 332 AC_ARG_ENABLE([python-bindings-tests],
 333               [AC_HELP_STRING([--enable-python-bindings-tests],
 334                               [test Python bindings])],
 335               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 336
 337 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 338
 339 if test "x${enable_python_bindings:-no}" = xno; then
 340   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 341     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 342   fi
 343
 344   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 345     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 346   fi
 347 fi
 348
 349 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 350     AM_CHECK_PYTHON_SPHINX([PYTHON])
 351     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 352       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 353     )
 354 fi
 355
 356 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 357     AM_CHECK_PYTHON_TAPPY([PYTHON])
 358     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 359         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 360     )
 361 fi
 362
 363 # Set default enable state for debug info.
 364 # The _enable_debug_info variable is prepended with an underscore to
 365 # avoid clashing with the one generated by AC_ARG_ENABLE.
 366 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 367
 368 # Optional debug info feature
 369 # Do _not_ indent the help string below (appears in the configure --help
 370 # output).
 371 AC_ARG_ENABLE([debug-info],
 372 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 373 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 374         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 375
 376 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 377
 378 AS_IF([test "x$_enable_debug_info" = xyes], [
 379         # Check if libelf and libdw are present
 380         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 381         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 382         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 383         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 384 ], [])
 385
 386 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 387 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 388 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 389         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 390         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 391         built_in_plugins=yes
 392         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 393 ])
 394 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 395
 396 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 397 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 398 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 399   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 400   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 401   AS_IF([test "x$enable_python_plugins" = "xno"], [
 402     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 403   ])
 404   built_in_python_plugin_support=yes
 405   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 406 ])
 407 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 408
 409 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 410
 411 # Logging
 412 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 413 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=VERBOSE])
 414 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 415         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 416 ])
 417 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 418
 419 LIBS="$LIBS $GMODULE_LIBS"
 420 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 421 AC_SUBST(PACKAGE_CFLAGS)
 422
 423 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 424 AC_SUBST(DEFAULT_INCLUDES)
 425
 426 babeltraceincludedir="${includedir}/babeltrace"
 427 AC_SUBST(babeltraceincludedir)
 428
 429 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 430 AC_SUBST(babeltracectfwriterincludedir)
 431
 432 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 433 AC_SUBST(babeltracectfincludedir)
 434
 435 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 436 AC_SUBST(babeltracectfirincludedir)
 437
 438 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 439 AC_SUBST(babeltracepluginincludedir)
 440
 441 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 442 AC_SUBST(babeltracegraphincludedir)
 443
 444 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 445 AC_SUBST(program_transform_name)
 446
 447 # check for Doxygen
 448 AC_ARG_ENABLE(
 449   [api-doc],
 450   [AC_HELP_STRING(
 451     [--enable-api-doc],
 452     [generate and install HTML API documentation]
 453   )],
 454   [enable_api_doc=$enableval],
 455   [enable_api_doc=no]
 456 )
 457 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 458
 459 AS_IF([test "x$enable_api_doc" = "xyes"], [
 460   DX_DOXYGEN_FEATURE(ON)
 461   DX_DOT_FEATURE(OFF)
 462   DX_HTML_FEATURE(ON)
 463   DX_CHM_FEATURE(OFF)
 464   DX_CHI_FEATURE(OFF)
 465   DX_MAN_FEATURE(OFF)
 466   DX_RTF_FEATURE(OFF)
 467   DX_XML_FEATURE(OFF)
 468   DX_PDF_FEATURE(OFF)
 469   DX_PS_FEATURE(OFF)
 470   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 471 ])
 472
 473         #TODO: removed, work in progress
 474         #bindings/python/Makefile
 475         #bindings/python/babeltrace/Makefile
 476         #bindings/python/bt2/Makefile
 477         #bindings/python/bt2/__init__.py
 478 AC_CONFIG_FILES([
 479         Makefile
 480         common/Makefile
 481         compat/Makefile
 482         cli/Makefile
 483         doc/Makefile
 484         doc/api/Makefile
 485         doc/api/Doxyfile
 486         doc/bindings/Makefile
 487         doc/bindings/python/Makefile
 488         doc/images/Makefile
 489         lib/Makefile
 490         lib/prio_heap/Makefile
 491         lib/plugin/Makefile
 492         lib/graph/Makefile
 493         lib/graph/notification/Makefile
 494         lib/ctf-ir/Makefile
 495         lib/ctf-writer/Makefile
 496         include/Makefile
 497         logging/Makefile
 498         bindings/Makefile
 499         tests/Makefile
 500         tests/cli/Makefile
 501         tests/cli/intersection/Makefile
 502         tests/lib/Makefile
 503         tests/lib/writer/Makefile
 504         tests/lib/test-plugin-plugins/Makefile
 505         tests/utils/Makefile
 506         tests/utils/tap/Makefile
 507         tests/bindings/Makefile
 508         tests/bindings/python/Makefile
 509         tests/bindings/python/bt2/Makefile
 510         tests/plugins/Makefile
 511         extras/Makefile
 512         extras/valgrind/Makefile
 513         plugins/Makefile
 514         plugins/ctf/Makefile
 515         plugins/ctf/common/Makefile
 516         plugins/ctf/common/btr/Makefile
 517         plugins/ctf/common/metadata/Makefile
 518         plugins/ctf/common/notif-iter/Makefile
 519         plugins/ctf/fs-src/Makefile
 520         plugins/ctf/fs-sink/Makefile
 521         plugins/ctf/lttng-live/Makefile
 522         plugins/text/Makefile
 523         plugins/text/pretty/Makefile
 524         plugins/utils/Makefile
 525         plugins/utils/dummy/Makefile
 526         plugins/utils/trimmer/Makefile
 527         plugins/utils/muxer/Makefile
 528         python-plugin-provider/Makefile
 529         plugins/libctfcopytrace/Makefile
 530         plugins/lttng-utils/Makefile
 531         babeltrace.pc
 532         babeltrace-ctf.pc
 533 ])
 534
 535 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 536 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 537 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 538 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 539 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 540
 541 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 542
 543 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 544 AC_CONFIG_FILES([tests/cli/test_trace_copy], [chmod +x tests/cli/test_trace_copy])
 545 AC_CONFIG_FILES([tests/cli/test_debug_info], [chmod +x tests/cli/test_debug_info])
 546 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 547 AC_CONFIG_FILES([tests/cli/test_convert_args], [chmod +x tests/cli/test_convert_args])
 548 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 549 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 550 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 551 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 552 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 553
 554 AS_IF([test "x$enable_python" = "xyes"], [
 555         AC_CONFIG_FILES(
 556                 [tests/bindings/python/bt2/testall.sh],
 557                 [chmod +x tests/bindings/python/bt2/testall.sh]
 558         )
 559 ])
 560
 561 AC_OUTPUT
 562
 563 #
 564 # Mini-report on what will be built.
 565 #
 566
 567 PPRINT_INIT
 568 PPRINT_SET_INDENT(1)
 569 PPRINT_SET_TS(38)
 570
 571 AS_ECHO
 572 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 573 AS_ECHO
 574
 575 PPRINT_SUBTITLE([System])
 576
 577 # Target architecture we're building for.
 578 target_arch=$host_cpu
 579 [
 580 for f in $CFLAGS; do
 581         if test $f = "-m32"; then
 582                 target_arch="32-bit"
 583         elif test $f = "-m64"; then
 584                 target_arch="64-bit"
 585         fi
 586 done
 587 ]
 588
 589 PPRINT_PROP_STRING([Target architecture], $target_arch)
 590
 591 AS_ECHO
 592 PPRINT_SUBTITLE([Python 3 language support])
 593 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 594 PPRINT_PROP_BOOL([Python bindings], $value)
 595 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 596 PPRINT_PROP_BOOL([Python plugin support], $value)
 597 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 598   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 599   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 600 ])
 601
 602 AS_ECHO
 603 PPRINT_SUBTITLE([Plugins])
 604 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 605 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 606 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 607 PPRINT_PROP_BOOL(['text' plugin], 1)
 608 PPRINT_PROP_BOOL(['utils' plugin], 1)
 609
 610 AS_ECHO
 611 PPRINT_SUBTITLE([Built-in features])
 612 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 613 PPRINT_PROP_BOOL([Built-in plugins], $value)
 614 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 615 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 616
 617 AS_ECHO
 618 PPRINT_SUBTITLE([Documentation])
 619 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 620 PPRINT_PROP_BOOL([HTML API documentation], $value)
 621 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 622 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 623
 624 AS_ECHO
 625 PPRINT_SUBTITLE([Logging])
 626 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 627
 628 AS_ECHO
 629 PPRINT_SUBTITLE([Testing])
 630 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 631 PPRINT_PROP_BOOL([Python bindings tests], $value)
 632
 633 report_bindir="`eval eval echo $bindir`"
 634 report_libdir="`eval eval echo $libdir`"
 635 report_sysconfdif="`eval eval echo $sysconfdir`"
 636
 637 # Print the bindir and libdir this `make install' will install into.
 638 AS_ECHO
 639 PPRINT_SUBTITLE([Install directories])
 640 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 641 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 642 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 643 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])