configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [2:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 # Checks for C compiler
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26 AC_PROG_CC
  27 AC_PROG_CC_STDC
  28
  29 # Checks for programs.
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32 AC_PROG_YACC
  33 AC_PROG_LEX
  34 AC_PROG_MKDIR_P
  35 AC_PROG_LN_S
  36
  37 AX_C___ATTRIBUTE__
  38 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  39         [:],
  40         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  41
  42 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  43 LIBS="$PTHREAD_LIBS $LIBS"
  44 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  45 CC="$PTHREAD_CC"
  46
  47 # Check linker option
  48 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  49 AC_SUBST([LD_NO_AS_NEEDED])
  50
  51 AC_HEADER_STDBOOL
  52 AC_CHECK_HEADERS([ \
  53         fcntl.h \
  54         float.h \
  55         libintl.h \
  56         limits.h \
  57         malloc.h \
  58         netdb.h \
  59         netinet/in.h \
  60         stddef.h \
  61         sys/socket.h \
  62 ])
  63
  64 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  65         if test x"$(basename "$YACC")" != "xbison -y"; then
  66                 AC_MSG_ERROR([[bison not found and is required when building from git.
  67                 Please install bison]])
  68         fi
  69         AC_PATH_PROG([BISON],[bison])
  70         AX_PROG_BISON_VERSION([2.4], [],[
  71                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  72         ])
  73 fi
  74
  75 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  76         if test x"$LEX" != "xflex"; then
  77                 AC_MSG_ERROR([[flex not found and is required when building from git.
  78                 Please install flex]])
  79         fi
  80         AC_PATH_PROG([FLEX],[flex])
  81         AX_PROG_FLEX_VERSION([2.5.35], [],[
  82                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  83         ])
  84 fi
  85
  86
  87 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  88
  89 # Check what libraries are required on this platform to link sockets programs.
  90 AX_LIB_SOCKET_NSL
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_INT16_T
  97 AC_TYPE_INT32_T
  98 AC_TYPE_INT64_T
  99 AC_TYPE_INT8_T
 100 AC_TYPE_OFF_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UINT16_T
 103 AC_TYPE_UINT32_T
 104 AC_TYPE_UINT64_T
 105 AC_TYPE_UINT8_T
 106
 107 # Checks for library functions.
 108 AC_FUNC_ALLOCA
 109 AC_FUNC_FORK
 110 AC_FUNC_MALLOC
 111 AC_FUNC_MKTIME
 112 AC_FUNC_MMAP
 113 AC_FUNC_REALLOC
 114 AC_FUNC_STRERROR_R
 115 AC_CHECK_FUNCS([ \
 116         atexit \
 117         dirfd \
 118         dup2 \
 119         ftruncate \
 120         gethostbyname \
 121         gethostname \
 122         gettimeofday \
 123         localtime_r \
 124         memchr \
 125         memset \
 126         mkdir \
 127         mkdtemp \
 128         munmap \
 129         rmdir \
 130         setenv \
 131         socket \
 132         strchr \
 133         strdup \
 134         strerror \
 135         strndup \
 136         strnlen \
 137         strrchr \
 138         strtoul \
 139         strtoull \
 140         tzset \
 141         uname \
 142 ])
 143
 144 MINGW32=no
 145 DEFAULT_ENABLE_DEBUG_INFO=yes
 146 AS_CASE([$host_os],
 147   [solaris*|darwin*],
 148     [
 149         DEFAULT_ENABLE_DEBUG_INFO=no
 150     ],
 151   [mingw*],
 152     [
 153         MINGW32=yes
 154     ]
 155 )
 156
 157 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 158
 159 # Check for uuid in system libs
 160 AC_CHECK_FUNCS([uuid_generate],
 161 [
 162   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 163   link_with_libuuid=no
 164 ],
 165 [
 166   # First, check the pkg-config module is available, otherwise explicitly check
 167   # for libuuid, or uuid support in the C-library.
 168   PKG_CHECK_MODULES([UUID], [uuid],
 169   [
 170     LIBS="${UUID_LIBS} ${LIBS}"
 171     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 172     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 173     link_with_libuuid=yes
 174   ],
 175   [
 176     # Check for libuuid
 177     AC_CHECK_LIB([uuid], [uuid_generate],
 178     [
 179       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 180       link_with_libuuid=yes
 181     ],
 182     [
 183       # libuuid not found, check for uuid_create in libc.
 184       AC_CHECK_LIB([c], [uuid_create],
 185       [
 186         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 187         link_with_libc_uuid=yes
 188       ],
 189       [
 190         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 191         if test "x$MINGW32" = xno; then
 192           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 193         fi
 194       ])
 195     ])
 196   ])
 197 ])
 198
 199 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 200 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 201
 202 # Check for fmemopen
 203 AC_CHECK_LIB([c], [fmemopen],
 204 [
 205         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 206 ]
 207 )
 208
 209 # Check for open_memstream
 210 AC_CHECK_LIB([c], [open_memstream],
 211 [
 212         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 213 ]
 214 )
 215
 216 # Check for posix_fallocate
 217 AC_CHECK_LIB([c], [posix_fallocate],
 218 [
 219         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 220 ]
 221 )
 222
 223 # Check for faccessat
 224 AC_CHECK_LIB([c], [faccessat],
 225 [
 226         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 227 ]
 228 )
 229
 230 AC_CHECK_LIB([popt], [poptGetContext], [],
 231         [AC_MSG_ERROR([Cannot find popt.])]
 232 )
 233
 234 # Plugins
 235 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 236 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 237
 238 # For Python
 239 # SWIG version needed or newer:
 240 swig_version=2.0.0
 241
 242 AC_ARG_ENABLE([python-bindings],
 243               [AC_HELP_STRING([--enable-python-bindings],
 244                               [generate Python bindings])],
 245               [enable_python_bindings=yes], [enable_python_bindings=no])
 246
 247 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 248
 249 AC_ARG_ENABLE(
 250         [python-plugins],
 251         [AC_HELP_STRING(
 252                 [--enable-python-plugins],
 253                 [add support for the Babeltrace library and converter to load Python plugins])
 254         ],
 255         [enable_python_plugins=yes],
 256         [enable_python_plugins=no]
 257 )
 258
 259 if test "x${enable_python_bindings:-yes}" = xyes; then
 260   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 261 else
 262     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 263 [if you want Python bindings.])
 264 fi
 265
 266 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 267   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 268
 269   AM_PATH_PYTHON_MODULES([PYTHON])
 270   # pythondir is the path where extra modules are to be installed
 271   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 272   # pyexecdir is the path that contains shared objects used by the extra modules
 273   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 274   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 275   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 276   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 277   AS_IF([test -z "$PYTHON_INCLUDE"], [
 278     AS_IF([test -z "$PYTHON_CONFIG"], [
 279       AC_PATH_PROGS([PYTHON_CONFIG],
 280                     [python$PYTHON_VERSION-config python-config],
 281                     [no],
 282                     [`dirname $PYTHON`])
 283       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 284     ])
 285     AC_MSG_CHECKING([Python include flags])
 286     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 287     AC_MSG_RESULT([$PYTHON_INCLUDE])
 288   ])
 289   AS_IF([test -z "$PYTHON_LIBS"], [
 290     AS_IF([test -z "$PYTHON_CONFIG"], [
 291       AC_PATH_PROGS([PYTHON_CONFIG],
 292                     [python$PYTHON_VERSION-config python-config],
 293                     [no],
 294                     [`dirname $PYTHON`])
 295       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 296     ])
 297     AC_MSG_CHECKING([Python library flags])
 298     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 299     AC_MSG_RESULT([$PYTHON_LIBS])
 300   ])
 301 fi
 302
 303 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 304 AS_IF(
 305   [test "x$enable_python_plugins" != xno],
 306   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 307 )
 308
 309 AC_ARG_ENABLE([python-bindings-doc],
 310               [AC_HELP_STRING([--enable-python-bindings-doc],
 311                               [generate Python bindings documentation])],
 312               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 313
 314 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 315
 316 AC_ARG_ENABLE([python-bindings-tests],
 317               [AC_HELP_STRING([--enable-python-bindings-tests],
 318                               [test Python bindings])],
 319               [enable_python_bindings_tests=yes], [enable_python_bindings_tests=no])
 320
 321 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 322
 323 if test "x${enable_python_bindings:-no}" = xno; then
 324   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 325     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 326   fi
 327
 328   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 329     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 330   fi
 331 fi
 332
 333 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 334     AM_CHECK_PYTHON_SPHINX([PYTHON])
 335     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 336       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 337     )
 338 fi
 339
 340 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 341     AM_CHECK_PYTHON_TAPPY([PYTHON])
 342     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 343         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 344     )
 345 fi
 346
 347 # Set default enable state for debug info.
 348 # The _enable_debug_info variable is prepended with an underscore to
 349 # avoid clashing with the one generated by AC_ARG_ENABLE.
 350 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 351
 352 # Optional debug info feature
 353 # Do _not_ indent the help string below (appears in the configure --help
 354 # output).
 355 AC_ARG_ENABLE([debug-info],
 356 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 357 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 358         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 359
 360 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 361 AS_IF([test "x$_enable_debug_info" = xyes], [
 362             # Check if libelf and libdw are present
 363             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 364             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 365             BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 366             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 367 ], [])
 368
 369 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 370 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 371 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 372         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 373         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 374         built_in_plugins=yes
 375         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 376 ])
 377 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 378
 379 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace binary])
 380 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 381 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 382   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 383   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 384   built_in_python_plugin_support=yes
 385   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 386 ])
 387 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 388
 389 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 390
 391 LIBS="$LIBS $GMODULE_LIBS"
 392 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 393 AC_SUBST(PACKAGE_CFLAGS)
 394
 395 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 396 AC_SUBST(DEFAULT_INCLUDES)
 397
 398 babeltraceincludedir="${includedir}/babeltrace"
 399 AC_SUBST(babeltraceincludedir)
 400
 401 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 402 AC_SUBST(babeltracectfwriterincludedir)
 403
 404 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 405 AC_SUBST(babeltracectfincludedir)
 406
 407 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 408 AC_SUBST(babeltracectfirincludedir)
 409
 410 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 411 AC_SUBST(babeltracepluginincludedir)
 412
 413 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 414 AC_SUBST(babeltracegraphincludedir)
 415
 416 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 417 AC_SUBST(program_transform_name)
 418
 419 # check for Doxygen
 420 AC_ARG_ENABLE(
 421   [api-doc],
 422   [AC_HELP_STRING(
 423     [--enable-api-doc],
 424     [generate and install HTML API documentation]
 425   )],
 426   [enable_api_doc=$enableval],
 427   [enable_api_doc=no]
 428 )
 429 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 430
 431 AS_IF([test "x$enable_api_doc" = "xyes"], [
 432   DX_DOXYGEN_FEATURE(ON)
 433   DX_DOT_FEATURE(OFF)
 434   DX_HTML_FEATURE(ON)
 435   DX_CHM_FEATURE(OFF)
 436   DX_CHI_FEATURE(OFF)
 437   DX_MAN_FEATURE(OFF)
 438   DX_RTF_FEATURE(OFF)
 439   DX_XML_FEATURE(OFF)
 440   DX_PDF_FEATURE(OFF)
 441   DX_PS_FEATURE(OFF)
 442   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 443 ])
 444
 445 AC_CONFIG_FILES([
 446         Makefile
 447         common/Makefile
 448         compat/Makefile
 449         cli/Makefile
 450         doc/Makefile
 451         doc/api/Makefile
 452         doc/api/Doxyfile
 453         doc/bindings/Makefile
 454         doc/bindings/python/Makefile
 455         doc/images/Makefile
 456         lib/Makefile
 457         lib/prio_heap/Makefile
 458         lib/plugin/Makefile
 459         lib/component/Makefile
 460         lib/component/notification/Makefile
 461         lib/ctf-ir/Makefile
 462         lib/ctf-writer/Makefile
 463         include/Makefile
 464         bindings/Makefile
 465         bindings/python/Makefile
 466         bindings/python/babeltrace/Makefile
 467         bindings/python/bt2/Makefile
 468         bindings/python/bt2/__init__.py
 469         tests/Makefile
 470         tests/bin/Makefile
 471         tests/bin/intersection/Makefile
 472         tests/lib/Makefile
 473         tests/lib/writer/Makefile
 474         tests/lib/test-plugin-plugins/Makefile
 475         tests/utils/Makefile
 476         tests/utils/tap/Makefile
 477         tests/bindings/Makefile
 478         tests/bindings/python/Makefile
 479         tests/bindings/python/bt2/Makefile
 480         extras/Makefile
 481         extras/valgrind/Makefile
 482         plugins/Makefile
 483         plugins/ctf/Makefile
 484         plugins/ctf/common/Makefile
 485         plugins/ctf/common/btr/Makefile
 486         plugins/ctf/common/metadata/Makefile
 487         plugins/ctf/common/notif-iter/Makefile
 488         plugins/ctf/fs/Makefile
 489         plugins/ctf/lttng-live/Makefile
 490         plugins/muxer/Makefile
 491         plugins/text/Makefile
 492         plugins/writer/Makefile
 493         plugins/utils/Makefile
 494         plugins/utils/dummy/Makefile
 495         plugins/utils/trimmer/Makefile
 496         python-plugin-provider/Makefile
 497         plugins/libctfcopytrace/Makefile
 498         babeltrace.pc
 499         babeltrace-ctf.pc
 500 ])
 501
 502 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 503 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 504 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 505 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 506 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 507 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 508 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 509
 510 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 511 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 512 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 513 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 514 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 515
 516 AS_IF([test "x$enable_python" = "xyes"], [
 517         AC_CONFIG_FILES(
 518                 [tests/bindings/python/bt2/testall.sh],
 519                 [chmod +x tests/bindings/python/bt2/testall.sh]
 520         )
 521 ])
 522
 523 AC_OUTPUT
 524
 525 #
 526 # Mini-report on what will be built.
 527 #
 528
 529 PPRINT_INIT
 530 PPRINT_SET_INDENT(1)
 531 PPRINT_SET_TS(38)
 532
 533 AS_ECHO
 534 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 535 AS_ECHO
 536
 537 PPRINT_SUBTITLE([Features])
 538
 539 # Target architecture we're building for.
 540 target_arch=$host_cpu
 541 [
 542 for f in $CFLAGS; do
 543         if test $f = "-m32"; then
 544                 target_arch="32-bit"
 545         elif test $f = "-m64"; then
 546                 target_arch="64-bit"
 547         fi
 548 done
 549 ]
 550 PPRINT_PROP_STRING([Target architecture], $target_arch)
 551
 552 # API doc
 553 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 554 PPRINT_PROP_BOOL([HTML API documentation], $value)
 555
 556 # python bindings enabled/disabled
 557 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 558 PPRINT_PROP_BOOL([Python bindings], $value)
 559
 560 # python bindings doc enabled/disabled
 561 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 562 PPRINT_PROP_BOOL([Python bindings doc], $value)
 563
 564 # python bindings tests enabled/disabled
 565 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 566 PPRINT_PROP_BOOL([Python bindings tests], $value)
 567
 568 # python plugins enabled/disabled
 569 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 570 PPRINT_PROP_BOOL([Python plugin support], $value)
 571
 572 # built-in Python plugin support enabled/disabled
 573 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 574 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 575
 576 # debug info enabled/disabled
 577 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 578 PPRINT_PROP_BOOL([Debug information output], $value)
 579
 580 # built-in plug-ins enabled/disabled
 581 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 582 PPRINT_PROP_BOOL([Built-in plug-ins], $value)
 583
 584 report_bindir="`eval eval echo $bindir`"
 585 report_libdir="`eval eval echo $libdir`"
 586
 587 # Print the bindir and libdir this `make install' will install into.
 588 AS_ECHO
 589 PPRINT_SUBTITLE([Install directories])
 590 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 591 PPRINT_PROP_STRING([Libraries], [$report_libdir])