configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.2.0],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   9
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CANONICAL_TARGET
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  14 AM_MAINTAINER_MODE([enable])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 AC_PROG_MKDIR_P
  20
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 AC_SYS_LARGEFILE
  24
  25 # Checks for programs.
  26 AC_PROG_CC_STDC
  27 AC_PROG_MAKE_SET
  28 LT_INIT
  29 AC_PROG_YACC
  30 AC_PROG_LEX
  31
  32 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  33         if test x"$YACC" != "xbison -y"; then
  34                 AC_MSG_ERROR([[bison not found and is required when building from git.
  35                 Please install bison]])
  36         fi
  37 fi
  38
  39 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  40         if test x"$LEX" != "xflex"; then
  41                 AC_MSG_ERROR([[flex not found and is required when building from git.
  42                 Please install flex]])
  43         fi
  44 fi
  45
  46
  47 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  48
  49 # Checks for typedefs, structures, and compiler characteristics.
  50 AC_C_INLINE
  51 AC_TYPE_PID_T
  52 AC_TYPE_SIZE_T
  53
  54 # Checks for library functions.
  55 AC_FUNC_MALLOC
  56 AC_FUNC_MMAP
  57 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  58
  59 # Check for MinGW32.
  60 MINGW32=no
  61 case $host in
  62   *-*-mingw*)
  63         MINGW32=yes;;
  64 esac
  65
  66 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  67
  68 # Check for libuuid
  69 AC_CHECK_LIB([uuid], [uuid_generate],
  70 [
  71         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  72         have_libuuid=yes
  73 ],
  74 [
  75         # libuuid not found, check for uuid_create in libc.
  76         AC_CHECK_LIB([c], [uuid_create],
  77         [
  78                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  79                 have_libc_uuid=yes
  80         ],
  81         [
  82                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  83                 if test "x$MINGW32" = xno; then
  84                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  85                 fi
  86         ])
  87 ]
  88 )
  89 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  90 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  91
  92 # Check for fmemopen
  93 AC_CHECK_LIB([c], [fmemopen],
  94 [
  95         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
  96 ]
  97 )
  98
  99 # Check for open_memstream
 100 AC_CHECK_LIB([c], [open_memstream],
 101 [
 102         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 103 ]
 104 )
 105
 106 AC_CHECK_LIB([popt], [poptGetContext], [],
 107         [AC_MSG_ERROR([Cannot find popt.])]
 108 )
 109
 110
 111 # For Python
 112 # SWIG version needed or newer:
 113 swig_version=2.0.0
 114
 115 AC_ARG_ENABLE([python-bindings],
 116               [AC_HELP_STRING([--enable-python-bindings],
 117                               [generate Python bindings])],
 118               [enable_python=yes], [enable_python=no])
 119
 120 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 121
 122 if test "x${enable_python:-yes}" = xyes; then
 123   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 124   AM_PATH_PYTHON
 125
 126   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 127   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 128   AS_IF([test -z "$PYTHON_INCLUDE"], [
 129     AS_IF([test -z "$PYTHON_CONFIG"], [
 130       AC_PATH_PROGS([PYTHON_CONFIG],
 131                     [python$PYTHON_VERSION-config python-config],
 132                     [no],
 133                     [`dirname $PYTHON`])
 134       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 135     ])
 136     AC_MSG_CHECKING([python include flags])
 137     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 138     AC_MSG_RESULT([$PYTHON_INCLUDE])
 139   ])
 140
 141 else
 142     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 143 [if you want Python bindings.])
 144
 145 fi
 146
 147 pkg_modules="gmodule-2.0 >= 2.0.0"
 148 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 149 AC_SUBST(PACKAGE_LIBS)
 150
 151 LIBS="$LIBS $GMODULE_LIBS"
 152 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 153 AC_SUBST(PACKAGE_CFLAGS)
 154
 155 babeltraceincludedir="${includedir}/babeltrace"
 156 AC_SUBST(babeltraceincludedir)
 157
 158 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 159 AC_SUBST(babeltracectfincludedir)
 160
 161 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 162 AC_SUBST(babeltracectfwriterincludedir)
 163
 164 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 165 AC_SUBST(babeltracectfirincludedir)
 166
 167 AC_CONFIG_FILES([
 168         Makefile
 169         types/Makefile
 170         compat/Makefile
 171         formats/Makefile
 172         formats/ctf/Makefile
 173         formats/ctf/types/Makefile
 174         formats/ctf-text/Makefile
 175         formats/ctf-text/types/Makefile
 176         formats/ctf-metadata/Makefile
 177         formats/bt-dummy/Makefile
 178         formats/lttng-live/Makefile
 179         formats/ctf/metadata/Makefile
 180         formats/ctf/writer/Makefile
 181         formats/ctf/ir/Makefile
 182         converter/Makefile
 183         doc/Makefile
 184         lib/Makefile
 185         lib/prio_heap/Makefile
 186         include/Makefile
 187         bindings/Makefile
 188         bindings/python/Makefile
 189         tests/Makefile
 190         tests/bin/Makefile
 191         tests/lib/Makefile
 192         tests/utils/Makefile
 193         tests/utils/tap/Makefile
 194         extras/Makefile
 195         extras/valgrind/Makefile
 196         babeltrace.pc
 197         babeltrace-ctf.pc
 198 ])
 199 AC_OUTPUT