configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.50])
   5 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 AM_MAINTAINER_MODE([enable])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 AC_PROG_MKDIR_P
  21 AC_PROG_LN_S
  22
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AC_SYS_LARGEFILE
  26
  27 # Checks for programs.
  28 AC_PROG_CC_STDC
  29 AC_PROG_MAKE_SET
  30 LT_INIT
  31 AC_PROG_YACC
  32 AC_PROG_LEX
  33
  34 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  35         if test x"$YACC" != "xbison -y"; then
  36                 AC_MSG_ERROR([[bison not found and is required when building from git.
  37                 Please install bison]])
  38         fi
  39         AC_PATH_PROG([BISON],[bison])
  40         AX_PROG_BISON_VERSION([2.4], [],[
  41                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  42         ])
  43 fi
  44
  45 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  46         if test x"$LEX" != "xflex"; then
  47                 AC_MSG_ERROR([[flex not found and is required when building from git.
  48                 Please install flex]])
  49         fi
  50         AC_PATH_PROG([FLEX],[flex])
  51         AX_PROG_FLEX_VERSION([2.5.35], [],[
  52                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  53         ])
  54 fi
  55
  56
  57 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  58
  59 # Checks for typedefs, structures, and compiler characteristics.
  60 AC_C_INLINE
  61 AC_TYPE_PID_T
  62 AC_TYPE_SIZE_T
  63
  64 # Checks for library functions.
  65 AC_FUNC_MALLOC
  66 AC_FUNC_MMAP
  67 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  68
  69 # Check for MinGW32.
  70 MINGW32=no
  71 case $host in
  72   *-*-mingw*)
  73         MINGW32=yes;;
  74 esac
  75
  76 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  77
  78 # Check for libuuid
  79 AC_CHECK_LIB([uuid], [uuid_generate],
  80 [
  81         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  82         have_libuuid=yes
  83 ],
  84 [
  85         # libuuid not found, check for uuid_create in libc.
  86         AC_CHECK_LIB([c], [uuid_create],
  87         [
  88                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  89                 have_libc_uuid=yes
  90         ],
  91         [
  92                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  93                 if test "x$MINGW32" = xno; then
  94                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  95                 fi
  96         ])
  97 ]
  98 )
  99 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 100 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 101
 102 # Check for fmemopen
 103 AC_CHECK_LIB([c], [fmemopen],
 104 [
 105         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 106 ]
 107 )
 108
 109 # Check for open_memstream
 110 AC_CHECK_LIB([c], [open_memstream],
 111 [
 112         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 113 ]
 114 )
 115
 116 AC_CHECK_LIB([popt], [poptGetContext], [],
 117         [AC_MSG_ERROR([Cannot find popt.])]
 118 )
 119
 120
 121 # For Python
 122 # SWIG version needed or newer:
 123 swig_version=2.0.0
 124
 125 AC_ARG_ENABLE([python-bindings],
 126               [AC_HELP_STRING([--enable-python-bindings],
 127                               [generate Python bindings])],
 128               [enable_python=yes], [enable_python=no])
 129
 130 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 131
 132 AC_ARG_ENABLE([python-bindings-doc],
 133               [AC_HELP_STRING([--enable-python-bindings-doc],
 134                               [generate Python bindings documentation])],
 135               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 136
 137 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 138   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 139 fi
 140
 141 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 142
 143 if test "x${enable_python:-yes}" = xyes; then
 144   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 145   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 146
 147   AM_PATH_PYTHON_MODULES([PYTHON])
 148   # pythondir is the path where extra modules are to be installed
 149   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 150   # pyexecdir is the path that contains shared objects used by the extra modules
 151   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 152   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 153   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 154   AS_IF([test -z "$PYTHON_INCLUDE"], [
 155     AS_IF([test -z "$PYTHON_CONFIG"], [
 156       AC_PATH_PROGS([PYTHON_CONFIG],
 157                     [python$PYTHON_VERSION-config python-config],
 158                     [no],
 159                     [`dirname $PYTHON`])
 160       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 161     ])
 162     AC_MSG_CHECKING([python include flags])
 163     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 164     AC_MSG_RESULT([$PYTHON_INCLUDE])
 165   ])
 166 else
 167     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 168 [if you want Python bindings.])
 169
 170 fi
 171
 172 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 173     AM_CHECK_PYTHON_SPHINX([PYTHON])
 174     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 175       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 176     )
 177 fi
 178
 179 pkg_modules="gmodule-2.0 >= 2.0.0"
 180 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 181 AC_SUBST(PACKAGE_LIBS)
 182
 183 LIBS="$LIBS $GMODULE_LIBS"
 184 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 185 AC_SUBST(PACKAGE_CFLAGS)
 186
 187 babeltraceincludedir="${includedir}/babeltrace"
 188 AC_SUBST(babeltraceincludedir)
 189
 190 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 191 AC_SUBST(babeltracectfincludedir)
 192
 193 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 194 AC_SUBST(babeltracectfwriterincludedir)
 195
 196 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 197 AC_SUBST(babeltracectfirincludedir)
 198
 199 AC_CONFIG_FILES([
 200         Makefile
 201         types/Makefile
 202         compat/Makefile
 203         formats/Makefile
 204         formats/ctf/Makefile
 205         formats/ctf/types/Makefile
 206         formats/ctf-text/Makefile
 207         formats/ctf-text/types/Makefile
 208         formats/ctf-metadata/Makefile
 209         formats/bt-dummy/Makefile
 210         formats/lttng-live/Makefile
 211         formats/ctf/metadata/Makefile
 212         formats/ctf/writer/Makefile
 213         formats/ctf/ir/Makefile
 214         converter/Makefile
 215         doc/Makefile
 216         doc/bindings/Makefile
 217         doc/bindings/python/Makefile
 218         lib/Makefile
 219         lib/prio_heap/Makefile
 220         include/Makefile
 221         bindings/Makefile
 222         bindings/python/Makefile
 223         tests/Makefile
 224         tests/bin/Makefile
 225         tests/lib/Makefile
 226         tests/utils/Makefile
 227         tests/utils/tap/Makefile
 228         extras/Makefile
 229         extras/valgrind/Makefile
 230         babeltrace.pc
 231         babeltrace-ctf.pc
 232 ])
 233 AC_OUTPUT