configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 # Checks for C compiler
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26 AC_PROG_CC
  27 AC_PROG_CC_STDC
  28
  29 # Checks for programs.
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32 AC_PROG_YACC
  33 AC_PROG_LEX
  34 AC_PROG_MKDIR_P
  35 AC_PROG_LN_S
  36
  37 AX_C___ATTRIBUTE__
  38 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  39         [:],
  40         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  41
  42 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  43 LIBS="$PTHREAD_LIBS $LIBS"
  44 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  45 CC="$PTHREAD_CC"
  46
  47 # Check linker option
  48 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  49 AC_SUBST([LD_NO_AS_NEEDED])
  50
  51 AC_HEADER_STDBOOL
  52 AC_CHECK_HEADERS([ \
  53         fcntl.h \
  54         float.h \
  55         libintl.h \
  56         limits.h \
  57         malloc.h \
  58         netdb.h \
  59         netinet/in.h \
  60         stddef.h \
  61         sys/socket.h \
  62 ])
  63
  64 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  65         if test x"$(basename "$YACC")" != "xbison -y"; then
  66                 AC_MSG_ERROR([[bison not found and is required when building from git.
  67                 Please install bison]])
  68         fi
  69         AC_PATH_PROG([BISON],[bison])
  70         AX_PROG_BISON_VERSION([2.4], [],[
  71                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  72         ])
  73 fi
  74
  75 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  76         if test x"$LEX" != "xflex"; then
  77                 AC_MSG_ERROR([[flex not found and is required when building from git.
  78                 Please install flex]])
  79         fi
  80         AC_PATH_PROG([FLEX],[flex])
  81         AX_PROG_FLEX_VERSION([2.5.35], [],[
  82                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  83         ])
  84 fi
  85
  86
  87 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  88
  89 # Check what libraries are required on this platform to link sockets programs.
  90 AX_LIB_SOCKET_NSL
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_INT16_T
  97 AC_TYPE_INT32_T
  98 AC_TYPE_INT64_T
  99 AC_TYPE_INT8_T
 100 AC_TYPE_OFF_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UINT16_T
 103 AC_TYPE_UINT32_T
 104 AC_TYPE_UINT64_T
 105 AC_TYPE_UINT8_T
 106
 107 # Checks for library functions.
 108 AC_FUNC_ALLOCA
 109 AC_FUNC_FORK
 110 AC_FUNC_MALLOC
 111 AC_FUNC_MKTIME
 112 AC_FUNC_MMAP
 113 AC_FUNC_REALLOC
 114 AC_FUNC_STRERROR_R
 115 AC_CHECK_FUNCS([ \
 116         atexit \
 117         dirfd \
 118         dup2 \
 119         ftruncate \
 120         gethostbyname \
 121         gethostname \
 122         gettimeofday \
 123         localtime_r \
 124         memchr \
 125         memset \
 126         mkdir \
 127         mkdtemp \
 128         munmap \
 129         rmdir \
 130         setenv \
 131         socket \
 132         strchr \
 133         strdup \
 134         strerror \
 135         strndup \
 136         strnlen \
 137         strrchr \
 138         strtoul \
 139         strtoull \
 140         tzset \
 141         uname \
 142 ])
 143
 144 MINGW32=no
 145 DEFAULT_ENABLE_DEBUGINFO=yes
 146 AS_CASE([$host_os],
 147   [solaris*|darwin*],
 148     [
 149         DEFAULT_ENABLE_DEBUGINFO=no
 150     ],
 151   [mingw*],
 152     [
 153         MINGW32=yes
 154     ]
 155 )
 156
 157 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 158
 159 # Check for uuid in system libs
 160 AC_CHECK_FUNCS([uuid_generate],
 161 [
 162   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 163   link_with_libuuid=no
 164 ],
 165 [
 166   # Check for libuuid
 167   AC_CHECK_LIB([uuid], [uuid_generate],
 168   [
 169     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 170     link_with_libuuid=yes
 171   ],
 172   [
 173     # libuuid not found, check for uuid_create in libc.
 174     AC_CHECK_LIB([c], [uuid_create],
 175     [
 176       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 177       link_with_libc_uuid=yes
 178     ],
 179     [
 180       # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 181       if test "x$MINGW32" = xno; then
 182         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 183       fi
 184     ])
 185   ])
 186 ])
 187
 188 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 189 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 190
 191 # Check for fmemopen
 192 AC_CHECK_LIB([c], [fmemopen],
 193 [
 194         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 195 ]
 196 )
 197
 198 # Check for open_memstream
 199 AC_CHECK_LIB([c], [open_memstream],
 200 [
 201         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 202 ]
 203 )
 204
 205 # Check for posix_fallocate
 206 AC_CHECK_LIB([c], [posix_fallocate],
 207 [
 208         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 209 ]
 210 )
 211
 212 # Check for faccessat
 213 AC_CHECK_LIB([c], [faccessat],
 214 [
 215         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 216 ]
 217 )
 218
 219 AC_CHECK_LIB([popt], [poptGetContext], [],
 220         [AC_MSG_ERROR([Cannot find popt.])]
 221 )
 222
 223 # For Python
 224 # SWIG version needed or newer:
 225 swig_version=2.0.0
 226
 227 AC_ARG_ENABLE([python-bindings],
 228               [AC_HELP_STRING([--enable-python-bindings],
 229                               [generate Python bindings])],
 230               [enable_python=yes], [enable_python=no])
 231
 232 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 233
 234 AC_ARG_ENABLE([python-bindings-doc],
 235               [AC_HELP_STRING([--enable-python-bindings-doc],
 236                               [generate Python bindings documentation])],
 237               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 238
 239 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 240   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 241 fi
 242
 243 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 244
 245 if test "x${enable_python:-yes}" = xyes; then
 246   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 247   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 248
 249   AM_PATH_PYTHON_MODULES([PYTHON])
 250   # pythondir is the path where extra modules are to be installed
 251   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 252   # pyexecdir is the path that contains shared objects used by the extra modules
 253   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 254   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 255   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 256   AS_IF([test -z "$PYTHON_INCLUDE"], [
 257     AS_IF([test -z "$PYTHON_CONFIG"], [
 258       AC_PATH_PROGS([PYTHON_CONFIG],
 259                     [python$PYTHON_VERSION-config python-config],
 260                     [no],
 261                     [`dirname $PYTHON`])
 262       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 263     ])
 264     AC_MSG_CHECKING([python include flags])
 265     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 266     AC_MSG_RESULT([$PYTHON_INCLUDE])
 267   ])
 268 else
 269     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 270 [if you want Python bindings.])
 271
 272 fi
 273
 274 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 275     AM_CHECK_PYTHON_SPHINX([PYTHON])
 276     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 277       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 278     )
 279 fi
 280
 281 # Optional debuginfo feature (enabled by default)
 282 AS_IF([test "x$DEFAULT_ENABLE_DEBUGINFO" = xyes],
 283     [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--disable-debug-info], [disable the debug-info feature (default on OS X and Solaris)])], [], [enable_debuginfo=yes])],
 284     [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--enable-debug-info], [enable the debug-info feature (default on Linux)])], [], [enable_debuginfo=no])]
 285 )
 286
 287 AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
 288 AS_IF([test "x$enable_debuginfo" = xyes], [
 289             # Check if libelf and libdw are present
 290             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
 291             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
 292             AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug-info feature. You can disable this feature using --disable-debuginfo.)])
 293             AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debug-info' feature])
 294 ], [])
 295
 296 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 297 AC_SUBST(PACKAGE_LIBS)
 298
 299 LIBS="$LIBS $GMODULE_LIBS"
 300 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 301 AC_SUBST(PACKAGE_CFLAGS)
 302
 303 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 304 AC_SUBST(DEFAULT_INCLUDES)
 305
 306 babeltraceincludedir="${includedir}/babeltrace"
 307 AC_SUBST(babeltraceincludedir)
 308
 309 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 310 AC_SUBST(babeltracectfincludedir)
 311
 312 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 313 AC_SUBST(babeltracectfwriterincludedir)
 314
 315 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 316 AC_SUBST(babeltracectfirincludedir)
 317
 318 AC_CONFIG_FILES([
 319         Makefile
 320         types/Makefile
 321         compat/Makefile
 322         formats/Makefile
 323         formats/ctf/Makefile
 324         formats/ctf/types/Makefile
 325         formats/ctf-text/Makefile
 326         formats/ctf-text/types/Makefile
 327         formats/ctf-metadata/Makefile
 328         formats/bt-dummy/Makefile
 329         formats/lttng-live/Makefile
 330         formats/ctf/metadata/Makefile
 331         formats/ctf/writer/Makefile
 332         formats/ctf/ir/Makefile
 333         converter/Makefile
 334         doc/Makefile
 335         doc/bindings/Makefile
 336         doc/bindings/python/Makefile
 337         doc/images/Makefile
 338         lib/Makefile
 339         lib/prio_heap/Makefile
 340         include/Makefile
 341         bindings/Makefile
 342         bindings/python/Makefile
 343         tests/Makefile
 344         tests/bin/Makefile
 345         tests/lib/Makefile
 346         tests/utils/Makefile
 347         tests/utils/tap/Makefile
 348         extras/Makefile
 349         extras/valgrind/Makefile
 350         babeltrace.pc
 351         babeltrace-ctf.pc
 352 ])
 353
 354 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 355 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 356 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 357 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 358 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 359
 360 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 361 AC_CONFIG_FILES([tests/bin/test_intersection], [chmod +x tests/bin/test_intersection])
 362 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 363
 364 AC_OUTPUT
 365
 366 #
 367 # Mini-report on what will be built.
 368 #
 369
 370 PPRINT_INIT
 371 PPRINT_SET_INDENT(1)
 372 PPRINT_SET_TS(38)
 373
 374 AS_ECHO
 375 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 376 AS_ECHO
 377
 378 PPRINT_SUBTITLE([Features])
 379
 380 # Target architecture we're building for.
 381 target_arch=$host_cpu
 382 [
 383 for f in $CFLAGS; do
 384         if test $f = "-m32"; then
 385                 target_arch="32-bit"
 386         elif test $f = "-m64"; then
 387                 target_arch="64-bit"
 388         fi
 389 done
 390 ]
 391 PPRINT_PROP_STRING([Target architecture], $target_arch)
 392
 393 # python bindings enabled/disabled
 394 test "x$enable_python" = "xyes" && value=1 || value=0
 395 PPRINT_PROP_BOOL([Python bindings], $value)
 396
 397 # python bindings doc enabled/disabled
 398 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 399 PPRINT_PROP_BOOL([Python bindings doc], $value)
 400
 401 # debug-info enabled/disabled
 402 test "x$enable_debuginfo" = "xyes" && value=1 || value=0
 403 PPRINT_PROP_BOOL([Debug information output], $value)
 404
 405
 406 report_bindir="`eval eval echo $bindir`"
 407 report_libdir="`eval eval echo $libdir`"
 408
 409 # Print the bindir and libdir this `make install' will install into.
 410 AS_ECHO
 411 PPRINT_SUBTITLE([Install directories])
 412 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 413 PPRINT_PROP_STRING([Libraries], [$report_libdir])