configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [0])
  31 m4_define([bt_version_patch], [4])
  32 m4_define([bt_version_dev_stage], [])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  34 m4_define([bt_version_name], [Amqui])
  35
  36 AC_INIT([babeltrace2], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  37 AC_PROG_SED
  38
  39 # Following the numbering scheme proposed by libtool for the library version
  40 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  41 m4_define([bt_lib_version_current], [0])
  42 m4_define([bt_lib_version_revision], [0])
  43 m4_define([bt_lib_version_age], [0])
  44 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  45
  46 bt_version_description="Amqui (/ɒmkwiː/) is a town in eastern Québec, Canada, at the base of the Gaspé peninsula in Bas-Saint-Laurent. Located at the confluence of the Humqui and Matapédia Rivers, its proximity to woodlands makes it a great destination for outdoor activities such as camping, hiking, and mountain biking."
  47 bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
  48
  49 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  50
  51 AC_CONFIG_HEADERS([src/common/config.h])
  52 AC_CONFIG_AUX_DIR([config])
  53 AC_CONFIG_MACRO_DIR([m4])
  54
  55 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  56 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  57 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  58 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  59 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  60 AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
  61
  62 AC_CANONICAL_TARGET
  63 AC_CANONICAL_HOST
  64
  65
  66 ##                     ##
  67 ## Automake base setup ##
  68 ##                     ##
  69
  70 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  71 AM_MAINTAINER_MODE([enable])
  72
  73 # Enable silent rules if available (Introduced in AM 1.11)
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76
  77 ##                      ##
  78 ## OS specific defaults ##
  79 ##                      ##
  80
  81 MINGW32=no
  82 DEFAULT_ENABLE_DEBUG_INFO=yes
  83 LT_NO_UNDEFINED=""
  84 AS_CASE([$host_os],
  85   [solaris*|darwin*],
  86     [
  87         DEFAULT_ENABLE_DEBUG_INFO=no
  88     ],
  89   [freebsd*],
  90     [
  91         DEFAULT_ENABLE_DEBUG_INFO=no
  92     ],
  93   [cygwin*],
  94     [
  95         DEFAULT_ENABLE_DEBUG_INFO=no
  96         LT_NO_UNDEFINED="-no-undefined"
  97     ],
  98   [mingw*],
  99     [
 100         MINGW32=yes
 101         DEFAULT_ENABLE_DEBUG_INFO=no
 102         LT_NO_UNDEFINED="-no-undefined"
 103     ]
 104 )
 105
 106 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 107 AC_SUBST(LT_NO_UNDEFINED)
 108
 109
 110 ##                   ##
 111 ## C compiler checks ##
 112 ##                   ##
 113
 114 AC_USE_SYSTEM_EXTENSIONS
 115 AC_SYS_LARGEFILE
 116
 117 # Choose the c compiler
 118 AC_PROG_CC
 119
 120 # Make sure the c compiler supports C99
 121 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 122
 123 # Make sure the c compiler supports __attributes__
 124 AX_C___ATTRIBUTE__
 125 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 126   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 127
 128 # Make sur we have pthread support
 129 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 130
 131 # Checks for typedefs, structures, and compiler characteristics.
 132 AC_C_INLINE
 133 AC_C_TYPEOF
 134 AC_TYPE_PID_T
 135 AC_TYPE_SIZE_T
 136 AC_TYPE_INT16_T
 137 AC_TYPE_INT32_T
 138 AC_TYPE_INT64_T
 139 AC_TYPE_INT8_T
 140 AC_TYPE_OFF_T
 141 AC_TYPE_SSIZE_T
 142 AC_TYPE_UINT16_T
 143 AC_TYPE_UINT32_T
 144 AC_TYPE_UINT64_T
 145 AC_TYPE_UINT8_T
 146 AC_CHECK_TYPES([ptrdiff_t])
 147
 148
 149 ##               ##
 150 ## Header checks ##
 151 ##               ##
 152
 153 AC_HEADER_STDBOOL
 154 AC_CHECK_HEADERS([ \
 155         fcntl.h \
 156         float.h \
 157         ftw.h \
 158         libintl.h \
 159         limits.h \
 160         malloc.h \
 161         netdb.h \
 162         netinet/in.h \
 163         stddef.h \
 164         sys/socket.h \
 165         sys/time.h
 166 ])
 167
 168
 169 ##               ##
 170 ## Linker checks ##
 171 ##               ##
 172
 173 # Check if the linker supports no-as-needed
 174 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 175 AC_SUBST([LD_NO_AS_NEEDED])
 176
 177 # Check if the linker supports whole-archive
 178 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 179   [
 180     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 181     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 182   ],[
 183     # Fallback to force_load for the macOS linker
 184     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 185       [
 186         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 187         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 188       ],[
 189         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 190       ]
 191     )
 192   ]
 193 )
 194
 195 # Initialize and configure libtool
 196 LT_INIT([win32-dll])
 197
 198
 199 ##                 ##
 200 ## Programs checks ##
 201 ##                 ##
 202
 203 AC_PROG_MAKE_SET
 204 AC_PROG_MKDIR_P
 205 AC_PROG_LN_S
 206 AC_PATH_PROG([report_fold], [fold])
 207
 208 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 209 # is not distributed in tarballs
 210 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 211 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 212
 213 # check for bison
 214 AC_PROG_YACC
 215 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 216
 217 AS_IF([test "x$have_bison" != "xyes"], [
 218   AS_IF([test "x$in_git_repo" = "xyes"], [
 219     AC_MSG_FAILURE([dnl
 220 Bison >= 2.4 is required when building from the Git repository. You can
 221 set the YACC variable to override automatic detection.
 222     ])
 223   ], [
 224     AC_MSG_WARN([dnl
 225 Missing Bison >= 2.4. Note that the parser files are already built in
 226 this distribution tarball, so Bison is only needed if you intend to
 227 modify their sources. You can set the YACC variable to override automatic
 228 detection.
 229     ])
 230   ])
 231 ])
 232 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 233
 234 # check for flex
 235 AC_PROG_LEX
 236 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 237
 238 AS_IF([test "x$have_flex" != "xyes"], [
 239   AS_IF([test "x$in_git_repo" = "xyes"], [
 240     AC_MSG_FAILURE([dnl
 241 Flex >= 2.5.35 is required when building from the Git repository. You can
 242 set the LEX variable to override automatic detection.
 243     ])
 244   ], [
 245     AC_MSG_WARN([dnl
 246 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 247 this distribution tarball, so Flex is only needed if you intend to
 248 modify their sources. You can set the LEX variable to override automatic
 249 detection.
 250     ])
 251   ])
 252 ])
 253 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 254
 255
 256 ##                ##
 257 ## Library checks ##
 258 ##                ##
 259
 260 # Check what libraries are required on this platform to link sockets programs.
 261 AX_LIB_SOCKET_NSL
 262
 263 # Check for glib >= 2.28 with gmodule support
 264 AM_PATH_GLIB_2_0([2.28.0], [],
 265   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 266   [gmodule-no-export]
 267 )
 268
 269 # Checks for library functions.
 270 AC_FUNC_ALLOCA
 271 AC_FUNC_FORK
 272 AC_FUNC_MKTIME
 273 AC_FUNC_MMAP
 274 AC_FUNC_STRERROR_R
 275 AC_FUNC_STRNLEN
 276 AC_CHECK_FUNCS([ \
 277         atexit \
 278         dup2 \
 279         ftruncate \
 280         gethostbyname \
 281         gettimeofday \
 282         localtime_r \
 283         memchr \
 284         memset \
 285         mkdir \
 286         mkdtemp \
 287         munmap \
 288         rmdir \
 289         setenv \
 290         socket \
 291         strchr \
 292         strdup \
 293         strerror \
 294         strndup \
 295         strnlen \
 296         strrchr \
 297         strstr \
 298         strtoul \
 299         strtoull \
 300         tzset \
 301 ])
 302
 303 # AC_FUNC_MALLOC causes problems when cross-compiling.
 304 #AC_FUNC_MALLOC
 305 #AC_FUNC_REALLOC
 306
 307 # Check for fmemopen
 308 AC_CHECK_LIB([c], [fmemopen],
 309   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 310 )
 311
 312 # Check for open_memstream
 313 AC_CHECK_LIB([c], [open_memstream],
 314   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 315 )
 316
 317 # Check for posix_fallocate
 318 AC_CHECK_LIB([c], [posix_fallocate],
 319   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 320 )
 321
 322 ##                 ##
 323 ## User variables  ##
 324 ##                 ##
 325
 326 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 327 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 328 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 329
 330 # BABELTRACE_PLUGINS_DIR: Plugins directory
 331 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 332 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 333
 334 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 335 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 336 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 337
 338 # BABELTRACE_MINIMAL_LOG_LEVEL:
 339 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 340 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 341 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 342        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 343        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 344   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 345 )
 346 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 347
 348 # BABELTRACE_DEV_MODE:
 349 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 350 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 351         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 352 ], [BABELTRACE_DEV_MODE=0])
 353
 354 # BABELTRACE_DEBUG_MODE:
 355 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 356 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 357         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 358 ], [BABELTRACE_DEBUG_MODE=0])
 359
 360
 361 ##                              ##
 362 ## Optionnal features selection ##
 363 ##                              ##
 364
 365 # Python bindings
 366 # Disabled by default
 367 AC_ARG_ENABLE([python-bindings],
 368   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 369   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 370   [enable_python_bindings=unspecified]
 371 )
 372
 373 # Python bindings documentation
 374 # Disabled by default
 375 AC_ARG_ENABLE([python-bindings-doc],
 376   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 377   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 378   [enable_python_bindings_doc=no]
 379 )
 380
 381 # Python plugins
 382 # Disabled by default
 383 AC_ARG_ENABLE([python-plugins],
 384   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])]
 385   dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 386 )
 387
 388 # Debug info
 389 # Enabled by default, except on some platforms
 390 AC_ARG_ENABLE([debug-info],
 391   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 392   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 393   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 394 )
 395
 396 # API documentation
 397 # Disabled by default
 398 AC_ARG_ENABLE([api-doc],
 399   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 400   [enable_api_doc=$enableval]
 401 )
 402
 403 # Built-in plugins
 404 # Disabled by default
 405 AC_ARG_ENABLE([built-in-plugins],
 406   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])]
 407   dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 408 )
 409
 410 # Built-in python plugin support
 411 # Disabled by default
 412 AC_ARG_ENABLE([built-in-python-plugin-support],
 413   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])]
 414   dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 415 )
 416
 417 # Man pages
 418 # Enabled by default
 419 AC_ARG_ENABLE([man-pages],
 420   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 421   [], dnl AC_ARG_ENABLE will fill enable_man_pages with the user choice
 422   [enable_man_pages=yes]
 423 )
 424
 425
 426 # Set automake variables for optionnal feature conditionnals in Makefile.am
 427 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 428 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 429 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 430 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 431 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 432 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 433 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 434 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 435 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 436
 437 # Set defines for optionnal features conditionnals in the source code
 438
 439 ## jgalar: still used?
 440 AS_IF([test "x$enable_python_plugins" = xyes],
 441   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 442 )
 443
 444 AS_IF([test "x$enable_debug_info" = xyes],
 445   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 446 )
 447
 448 AS_IF([test "x$enable_built_in_plugins" = xyes],
 449   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 450 )
 451
 452 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 453   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 454 )
 455
 456 AS_IF([test "x$enable_debug_info" = xyes],
 457   [ENABLE_DEBUG_INFO_VAL=1],
 458   [ENABLE_DEBUG_INFO_VAL=0]
 459 )
 460
 461 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 462
 463 # Check for conflicting Python related features user choices.
 464 AS_IF([test "x$enable_python_plugins" = xyes],
 465   [
 466     AS_IF([test "x$enable_python_bindings" = xunspecified],
 467       [
 468         # --enable-python-plugins was provided but --enable-python-bindings was
 469         # omitted. Turn the Python bindings ON anyway because it's needed to
 470         # use the Python plugins.
 471         enable_python_bindings=yes
 472       ],
 473       [
 474         AS_IF([test "x$enable_python_bindings" = xno],
 475           [
 476             # --enable-python-plugins _and_ --disable-python-bindings were
 477             # used. This is invalid because Python plugins need the Python
 478             # bindings to be useful.
 479             AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
 480           ]
 481         )
 482       ]
 483     )
 484   ]
 485 )
 486
 487 # Check for conflicting optional features user choices
 488
 489 AS_IF([test "x$enable_built_in_plugins" = xyes],
 490   [
 491     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 492     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 493     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 494   ]
 495 )
 496
 497 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 498   [
 499     AS_IF([test "x$enable_python_plugins" != xyes], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 500     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 501     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 502     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 503   ]
 504 )
 505
 506
 507 # Check for optionnal features dependencies
 508
 509 AS_IF([test "x$enable_python_bindings" = xyes],
 510   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 511 )
 512
 513 AM_PATH_PYTHON([3.0], [
 514   AM_PATH_PYTHON_MODULES([PYTHON])
 515
 516   # pythondir is the path where extra modules are to be installed
 517   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 518
 519   # pyexecdir is the path that contains shared objects used by the extra modules
 520   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 521
 522   AS_IF([test -z "$PYTHON_CONFIG"], [
 523     AC_PATH_PROGS([PYTHON_CONFIG],
 524                   [python$PYTHON_VERSION-config python-config],
 525                   [],
 526                   [`dirname $PYTHON`])
 527   ])
 528
 529   AS_IF([test -n "$PYTHON_CONFIG"], [
 530     AS_IF([test -z "$PYTHON_INCLUDE"], [
 531       AC_MSG_CHECKING([Python include flags])
 532       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 533       AC_MSG_RESULT([$PYTHON_INCLUDE])
 534     ])
 535
 536     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 537       AC_MSG_CHECKING([Python library flags])
 538       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 539       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 540         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 541       ])
 542       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 543     ])
 544   ])
 545 ], [:])
 546
 547 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 548 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 549
 550 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 551 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 552
 553 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 554   AS_IF([test "x$have_python_dev" = xno], [
 555     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 556   ])
 557 ])
 558
 559 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 560   [
 561     AM_CHECK_PYTHON_SPHINX([PYTHON])
 562     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno], [
 563       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])
 564     ])
 565
 566     AS_IF([test "x$enable_python_bindings" != xyes], [
 567       AC_MSG_ERROR([The Python bindings are required to build their documentation])
 568     ])
 569   ]
 570 )
 571
 572 AS_IF([test "x$enable_debug_info" = xyes],
 573   [
 574     # Check if libelf and libdw are present
 575     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 576     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 577     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 578     ELFUTILS_LIBS="-lelf -ldw"
 579   ]
 580 )
 581 AC_SUBST([ELFUTILS_LIBS])
 582
 583 AS_IF([test "x$enable_api_doc" = "xyes"],
 584   [
 585     DX_DOXYGEN_FEATURE(ON)
 586     DX_DOT_FEATURE(OFF)
 587     DX_HTML_FEATURE(ON)
 588     DX_CHM_FEATURE(OFF)
 589     DX_CHI_FEATURE(OFF)
 590     DX_MAN_FEATURE(OFF)
 591     DX_RTF_FEATURE(OFF)
 592     DX_XML_FEATURE(OFF)
 593     DX_PDF_FEATURE(OFF)
 594     DX_PS_FEATURE(OFF)
 595     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 596     AS_IF([test -z "$DX_DOXYGEN"],
 597           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 598     )
 599   ]
 600 )
 601
 602 have_asciidoc_xmlto=no
 603 warn_prebuilt_man_pages=no
 604
 605 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 606 AC_PATH_PROG([XMLTO], [xmlto], [no])
 607
 608 AS_IF([test "x$enable_man_pages" = "xyes"], [
 609   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 610     AS_IF([test "x$in_git_repo" = "xyes"], [
 611       # this is an error because we're in the Git repo, which
 612       # means the man pages are not already generated for us,
 613       # thus asciixmlto are required because we were asked
 614       # to build the man pages
 615       AC_MSG_ERROR([
 616 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 617 --disable-man-pages to disable building the man pages, in which case
 618 they will not be installed.
 619       ])
 620     ], [
 621       # only warn here: since we're in the tarball, the man
 622       # pages should already be generated at this point, thus
 623       # asciidoc/xmlto are not strictly required
 624       warn_prebuilt_man_pages=yes
 625     ])
 626   ], [
 627     have_asciidoc_xmlto=yes
 628   ])
 629 ])
 630
 631 # export AsciiDoc and xmlto existence
 632 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 633
 634 # a wonderful hack that seems necessary because $libdir is
 635 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 636 # by autoconf when it's not specified by the user
 637 AS_IF([test "x$exec_prefix" = xNONE], [
 638   AS_IF([test "x$prefix" = xNONE], [
 639     PREFIX="$ac_default_prefix"
 640   ], [
 641     PREFIX="$prefix"
 642   ])
 643
 644   LIBDIR="$PREFIX/lib"
 645 ], [
 646   LIBDIR="$libdir"
 647 ])
 648
 649 AC_SUBST(LIBDIR)
 650
 651 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 652 # test).
 653 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 654
 655 # Check that the current size_t matches the size that glib thinks it should
 656 # be. This catches problems on multi-arch where people try to do a 32-bit
 657 # build while pointing at 64-bit glib headers. This is a common error because
 658 # glib.h is not platform specific but it includes glibconfig.h which is and
 659 # is usually installed in a non-standard path.
 660
 661 # Do this before enabling all the warning flags, as the
 662 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 663 # test fail unnecessarily.
 664
 665 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 666 # output. Specifically allow pkg_config_libdir to be able to print the
 667 # error message.
 668 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 669
 670 save_CFLAGS=${CFLAGS}
 671 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 672 AC_COMPILE_IFELSE([
 673   AC_LANG_PROGRAM([dnl
 674 #include <glib.h>
 675 #include <unistd.h>
 676   ], [dnl
 677 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 678   ])
 679 ],[:],[
 680   AC_MSG_ERROR([dnl
 681 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 682 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 683 target.
 684   ])
 685 ])
 686 CFLAGS=${save_CFLAGS}
 687
 688 # Detect C and LD warning flags supported by the compiler.
 689 AX_COMPILER_FLAGS(
 690         [WARN_CFLAGS], dnl CFLAGS variable name
 691         [WARN_LDFLAGS], dnl LDFLAGS variable name (unused for now)
 692         [], dnl is-release
 693         [], dnl Extra base CFLAGS
 694         [ dnl Extra "yes" CFLAGS
 695                 dnl Disable these flags, either because we don't want them
 696                 dnl or because we want them but are not ready to enable them
 697                 dnl yet.
 698                 -Wno-sign-compare dnl
 699                 -Wno-inline dnl
 700                 -Wno-declaration-after-statement dnl
 701                 -Wno-switch-enum dnl
 702                 -Wno-switch-default dnl
 703                 -Wno-packed dnl
 704                 -Wno-pointer-arith dnl
 705                 -Wno-format-nonliteral dnl
 706                 -Wno-double-promotion dnl
 707                 -Wno-cast-align dnl
 708                 dnl
 709                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 710                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 711                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 712                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 713                 dnl It's simpler to just disable the warning globally.
 714                 dnl
 715                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 716                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 717                 dnl reproduce the warning using that package.
 718                 dnl
 719                 dnl Ref: https://github.com/swig/swig/issues/1259
 720                 -Wno-cast-function-type dnl
 721         ])
 722
 723 # CFLAGS from AX_COMPILER_FLAGS.
 724 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 725
 726 # The test used in AX_COMPILER_FLAGS, generated using AC_LANG_PROGRAM, is
 727 # written in such a way that it triggers a -Wold-style-definition warning.  So
 728 # if the user has -Werror in their CFLAGS, that warning flag will end up
 729 # disabled, because the test program will not build.
 730 #
 731 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 732 # (it is accepted for compatibility although it has no effect), and there is
 733 # not reason to not want it.
 734
 735 AM_CFLAGS="${AM_CFLAGS} -Wold-style-definition"
 736
 737 # We want this one to always be an error.
 738 AM_CFLAGS="${AM_CFLAGS} -Werror=implicit-function-declaration"
 739
 740 # Done for AM_CFLAGS.
 741 AC_SUBST(AM_CFLAGS)
 742
 743 # Set global CPPFLAGS in AM_CPPFLAGS
 744 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 745 AC_SUBST(AM_CPPFLAGS)
 746
 747 # Add glib to global link libs
 748 LIBS="$LIBS $GLIB_LIBS"
 749
 750 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 751 # to rename babeltrace2.bin to babeltrace2 at install time.
 752 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 753 AC_SUBST(program_transform_name)
 754
 755 AC_CONFIG_FILES([
 756         doc/api/Makefile
 757         doc/api/libbabeltrace2/Doxyfile
 758         doc/api/libbabeltrace2/Makefile
 759         doc/bindings/Makefile
 760         doc/bindings/python/Makefile
 761         doc/contributing-images/Makefile
 762         doc/Makefile
 763         doc/man/asciidoc-attrs.conf
 764         doc/man/Makefile
 765         include/Makefile
 766         Makefile
 767         src/argpar/Makefile
 768         src/autodisc/Makefile
 769         src/babeltrace2-ctf-writer.pc
 770         src/babeltrace2.pc
 771         src/bindings/Makefile
 772         src/bindings/python/bt2/bt2/version.py
 773         src/bindings/python/bt2/Makefile
 774         src/bindings/python/bt2/setup.py
 775         src/bindings/python/Makefile
 776         src/cli/Makefile
 777         src/common/Makefile
 778         src/compat/Makefile
 779         src/ctfser/Makefile
 780         src/ctf-writer/Makefile
 781         src/fd-cache/Makefile
 782         src/lib/graph/Makefile
 783         src/lib/graph/message/Makefile
 784         src/lib/Makefile
 785         src/lib/plugin/Makefile
 786         src/lib/prio-heap/Makefile
 787         src/lib/trace-ir/Makefile
 788         src/logging/Makefile
 789         src/Makefile
 790         src/plugins/common/Makefile
 791         src/plugins/common/muxing/Makefile
 792         src/plugins/common/param-validation/Makefile
 793         src/plugins/ctf/common/bfcr/Makefile
 794         src/plugins/ctf/common/Makefile
 795         src/plugins/ctf/common/metadata/Makefile
 796         src/plugins/ctf/common/msg-iter/Makefile
 797         src/plugins/ctf/fs-sink/Makefile
 798         src/plugins/ctf/fs-src/Makefile
 799         src/plugins/ctf/lttng-live/Makefile
 800         src/plugins/ctf/Makefile
 801         src/plugins/lttng-utils/debug-info/Makefile
 802         src/plugins/lttng-utils/Makefile
 803         src/plugins/Makefile
 804         src/plugins/text/dmesg/Makefile
 805         src/plugins/text/Makefile
 806         src/plugins/text/pretty/Makefile
 807         src/plugins/text/details/Makefile
 808         src/plugins/utils/counter/Makefile
 809         src/plugins/utils/dummy/Makefile
 810         src/plugins/utils/Makefile
 811         src/plugins/utils/muxer/Makefile
 812         src/plugins/utils/trimmer/Makefile
 813         src/py-common/Makefile
 814         src/python-plugin-provider/Makefile
 815         src/param-parse/Makefile
 816         src/string-format/Makefile
 817         tests/bitfield/Makefile
 818         tests/ctf-writer/Makefile
 819         tests/lib/Makefile
 820         tests/lib/test-plugin-plugins/Makefile
 821         tests/Makefile
 822         tests/param-validation/Makefile
 823         tests/plugins/Makefile
 824         tests/plugins/src.ctf.fs/Makefile
 825         tests/plugins/src.ctf.fs/succeed/Makefile
 826         tests/plugins/sink.ctf.fs/Makefile
 827         tests/plugins/sink.ctf.fs/succeed/Makefile
 828         tests/plugins/flt.lttng-utils.debug-info/Makefile
 829         tests/plugins/flt.utils.muxer/Makefile
 830         tests/plugins/flt.utils.muxer/succeed/Makefile
 831         tests/plugins/flt.utils.trimmer/Makefile
 832         tests/utils/Makefile
 833         tests/utils/tap/Makefile
 834 ])
 835
 836 AC_OUTPUT
 837
 838 #
 839 # Mini-report on what will be built.
 840 #
 841
 842 PPRINT_INIT
 843 PPRINT_SET_INDENT(1)
 844 PPRINT_SET_TS(38)
 845
 846 AS_ECHO
 847
 848 AS_IF([test -n "bt_version_name"], [
 849         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 850 ], [
 851         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 852 ])
 853
 854 AS_ECHO
 855
 856 AS_IF([test -n "$bt_version_description"], [
 857         AS_IF([test -n "$report_fold"], [
 858                 AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
 859         ], [
 860                 AS_ECHO("$bt_version_description")
 861         ])
 862
 863         AS_ECHO
 864 ])
 865
 866 PPRINT_SUBTITLE([System])
 867
 868 # Target architecture we're building for.
 869 target_arch=$host_cpu
 870 [
 871 for f in $CFLAGS; do
 872         if test $f = "-m32"; then
 873                 target_arch="32-bit"
 874         elif test $f = "-m64"; then
 875                 target_arch="64-bit"
 876         fi
 877 done
 878 ]
 879
 880 PPRINT_PROP_STRING([Target architecture], $target_arch)
 881
 882 AS_ECHO
 883 PPRINT_SUBTITLE([Python 3 language support])
 884 test "x$have_python" = "xyes" && value=1 || value=0
 885 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 886 test "x$have_python_dev" = "xyes" && value=1 || value=0
 887 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 888 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 889 PPRINT_PROP_BOOL([Python bindings], $value)
 890 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 891 PPRINT_PROP_BOOL([Python plugin support], $value)
 892 AS_IF([test "x$have_python" = "xyes"], [
 893   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 894 ])
 895 AS_IF([test "x$have_python_dev" = "xyes"], [
 896   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 897   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 898   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 899 ])
 900 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 901   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 902   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 903 ])
 904
 905 AS_ECHO
 906 PPRINT_SUBTITLE([Plugins])
 907 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 908 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 909 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 910 PPRINT_PROP_BOOL(['text' plugin], 1)
 911 PPRINT_PROP_BOOL(['utils' plugin], 1)
 912
 913 AS_ECHO
 914 PPRINT_SUBTITLE([Built-in features])
 915 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 916 PPRINT_PROP_BOOL([Built-in plugins], $value)
 917 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 918 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 919
 920 AS_ECHO
 921 PPRINT_SUBTITLE([Documentation])
 922
 923 # man pages build enabled/disabled
 924 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 925
 926 AS_IF([test "x$enable_man_pages" != "xno"], [
 927   AS_IF([test "x$in_git_repo" = "xyes"], [
 928     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 929   ], [
 930     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 931       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 932     ], [
 933       PPRINT_PROP_STRING([build_man_pages_msg],
 934         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 935         $PPRINT_COLOR_SUBTITLE)
 936     ])
 937   ])
 938 ], [
 939   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 940 ])
 941
 942 m4_popdef([build_man_pages_msg])
 943
 944 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 945 PPRINT_PROP_BOOL([HTML API documentation], $value)
 946 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 947 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 948
 949 AS_ECHO
 950 PPRINT_SUBTITLE([Logging])
 951 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 952
 953 AS_ECHO
 954 PPRINT_SUBTITLE([Special build modes])
 955 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 956 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 957
 958 report_bindir="`eval eval echo $bindir`"
 959 report_libdir="`eval eval echo $libdir`"
 960 report_sysconfdif="`eval eval echo $sysconfdir`"
 961 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 962 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 963
 964 # Print the bindir and libdir this `make install' will install into.
 965 AS_ECHO
 966 PPRINT_SUBTITLE([Install directories])
 967 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 968 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 969 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 970 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 971 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])