configure.ac

   1 dnl SPDX-License-Identifier: MIT
   2 dnl
   3 dnl Copyright (C) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 ##                     ##
   8 ## Autoconf base setup ##
   9 ##                     ##
  10
  11 AC_PREREQ([2.69])
  12
  13 m4_define([bt_version_major], [2])
  14 m4_define([bt_version_minor], [1])
  15 m4_define([bt_version_patch], [0])
  16 m4_define([bt_version_dev_stage], [-rc1])
  17 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  18 m4_define([bt_version_name], [])
  19
  20 AC_INIT([babeltrace2],[bt_version],[jeremie dot galarneau at efficios dot com],[],[https://efficios.com/babeltrace/])
  21
  22 # Following the numbering scheme proposed by libtool for the library version
  23 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  24 m4_define([bt_lib_version_current], [0])
  25 m4_define([bt_lib_version_revision], [0])
  26 m4_define([bt_lib_version_age], [0])
  27 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  28 m4_define([bt_version_description], [])
  29 m4_define([bt_version_description_c_safe], AS_ESCAPE(bt_version_description))
  30
  31 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  32
  33 AC_CONFIG_HEADERS([src/common/config.h])
  34 AC_CONFIG_AUX_DIR([config])
  35 AC_CONFIG_MACRO_DIR([m4])
  36
  37 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  38 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  39 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  40 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  41 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  42 AC_DEFINE([BT_VERSION_DESCRIPTION], ["]bt_version_description_c_safe["], [Babeltrace version description])
  43
  44 AC_CANONICAL_TARGET
  45 AC_CANONICAL_HOST
  46
  47
  48 ##                     ##
  49 ## Automake base setup ##
  50 ##                     ##
  51
  52 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  53 AM_MAINTAINER_MODE([enable])
  54
  55 # Enable silent rules by default
  56 AM_SILENT_RULES([yes])
  57
  58
  59 ##                      ##
  60 ## OS specific defaults ##
  61 ##                      ##
  62
  63 MINGW32=no
  64 LT_NO_UNDEFINED=""
  65 AS_CASE([$host_os],
  66   [solaris*|darwin*],
  67     [
  68         AE_FEATURE_DISABLE([debug-info])
  69     ],
  70   [freebsd*],
  71     [
  72         DEFAULT_ENABLE_DEBUG_INFO=no
  73     ],
  74   [cygwin*],
  75     [
  76         AE_FEATURE_DISABLE([debug-info])
  77         LT_NO_UNDEFINED="-no-undefined"
  78     ],
  79   [mingw*],
  80     [
  81         MINGW32=yes
  82         AE_FEATURE_DISABLE([debug-info])
  83         LT_NO_UNDEFINED="-no-undefined"
  84     ]
  85 )
  86
  87 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  88 AC_SUBST(LT_NO_UNDEFINED)
  89
  90
  91 ##                   ##
  92 ## C compiler checks ##
  93 ##                   ##
  94
  95 # Choose the c compiler
  96 AC_PROG_CC_STDC
  97
  98 # Make sure the c compiler supports C99
  99 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 100
 101 # Enable available system extensions and LFS support
 102 AC_USE_SYSTEM_EXTENSIONS
 103 AC_SYS_LARGEFILE
 104
 105 # Make sure the c compiler supports __attributes__
 106 AX_C___ATTRIBUTE__
 107 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 108   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 109
 110 # Make sur we have pthread support
 111 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 112
 113 # Checks for typedefs, structures, and compiler characteristics.
 114 AC_C_INLINE
 115 AC_C_TYPEOF
 116 AC_TYPE_PID_T
 117 AC_TYPE_SIZE_T
 118 AC_TYPE_INT16_T
 119 AC_TYPE_INT32_T
 120 AC_TYPE_INT64_T
 121 AC_TYPE_INT8_T
 122 AC_TYPE_OFF_T
 123 AC_TYPE_SSIZE_T
 124 AC_TYPE_UINT16_T
 125 AC_TYPE_UINT32_T
 126 AC_TYPE_UINT64_T
 127 AC_TYPE_UINT8_T
 128 AC_CHECK_TYPES([ptrdiff_t])
 129
 130
 131 ##               ##
 132 ## Header checks ##
 133 ##               ##
 134
 135 AC_HEADER_STDBOOL
 136 AC_CHECK_HEADERS([ \
 137         fcntl.h \
 138         float.h \
 139         ftw.h \
 140         libintl.h \
 141         limits.h \
 142         malloc.h \
 143         netdb.h \
 144         netinet/in.h \
 145         stddef.h \
 146         sys/socket.h \
 147         sys/time.h
 148 ])
 149
 150
 151 ##               ##
 152 ## Linker checks ##
 153 ##               ##
 154
 155 # Check if the linker supports no-as-needed
 156 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 157 AC_SUBST([LD_NO_AS_NEEDED])
 158
 159 # Check if the linker supports whole-archive
 160 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 161   [
 162     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 163     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 164   ],[
 165     # Fallback to force_load for the macOS linker
 166     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 167       [
 168         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 169         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 170       ],[
 171         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 172       ]
 173     )
 174   ]
 175 )
 176
 177 # Check if the linker supports the "notext" keyword
 178 AX_CHECK_LINK_FLAG([-Wl,-z,notext],[
 179         AC_SUBST([LD_NOTEXT], [-Wl,-z,notext])
 180 ])
 181
 182
 183 ##                 ##
 184 ## Programs checks ##
 185 ##                 ##
 186
 187 AM_PROG_AR
 188 AC_PROG_MAKE_SET
 189 AC_PROG_MKDIR_P
 190 AC_PROG_LN_S
 191 AC_PROG_SED
 192 AC_PATH_PROG([report_fold], [fold])
 193
 194 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 195 # is not distributed in tarballs
 196 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 197 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 198
 199 # check for bison
 200 AC_PROG_YACC
 201 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 202
 203 AS_IF([test "x$have_bison" != "xyes"], [
 204   AS_IF([test "x$in_git_repo" = "xyes"], [
 205     AC_MSG_FAILURE([dnl
 206 Bison >= 2.4 is required when building from the Git repository. You can
 207 set the YACC variable to override automatic detection.
 208     ])
 209   ], [
 210     AC_MSG_WARN([dnl
 211 Missing Bison >= 2.4. Note that the parser files are already built in
 212 this distribution tarball, so Bison is only needed if you intend to
 213 modify their sources. You can set the YACC variable to override automatic
 214 detection.
 215     ])
 216   ])
 217 ])
 218 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 219
 220 # check for flex
 221 AC_PROG_LEX
 222 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 223
 224 AS_IF([test "x$have_flex" != "xyes"], [
 225   AS_IF([test "x$in_git_repo" = "xyes"], [
 226     AC_MSG_FAILURE([dnl
 227 Flex >= 2.5.35 is required when building from the Git repository. You can
 228 set the LEX variable to override automatic detection.
 229     ])
 230   ], [
 231     AC_MSG_WARN([dnl
 232 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 233 this distribution tarball, so Flex is only needed if you intend to
 234 modify their sources. You can set the LEX variable to override automatic
 235 detection.
 236     ])
 237   ])
 238 ])
 239 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 240
 241 # Initialize and configure libtool
 242 LT_INIT([win32-dll])
 243
 244
 245 ##                ##
 246 ## Library checks ##
 247 ##                ##
 248
 249 # Check what libraries are required on this platform to link sockets programs.
 250 AX_LIB_SOCKET_NSL
 251
 252 # Check for glib >= 2.28 with gmodule support
 253 AM_PATH_GLIB_2_0([2.28.0], [],
 254   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 255   [gmodule-no-export]
 256 )
 257
 258 # Checks for library functions.
 259 AC_FUNC_ALLOCA
 260 AC_FUNC_FORK
 261 AC_FUNC_MKTIME
 262 AC_FUNC_MMAP
 263 AC_FUNC_STRERROR_R
 264 AC_FUNC_STRNLEN
 265 AC_CHECK_FUNCS([ \
 266         atexit \
 267         dup2 \
 268         ftruncate \
 269         gethostbyname \
 270         gettimeofday \
 271         localtime_r \
 272         memchr \
 273         memset \
 274         mkdir \
 275         mkdtemp \
 276         munmap \
 277         rmdir \
 278         setenv \
 279         socket \
 280         strchr \
 281         strdup \
 282         strerror \
 283         strndup \
 284         strnlen \
 285         strrchr \
 286         strstr \
 287         strtoul \
 288         strtoull \
 289         tzset \
 290 ])
 291
 292 # AC_FUNC_MALLOC causes problems when cross-compiling.
 293 #AC_FUNC_MALLOC
 294 #AC_FUNC_REALLOC
 295
 296 # Check for fmemopen
 297 AC_CHECK_LIB([c], [fmemopen],
 298   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 299 )
 300
 301 # Check for open_memstream
 302 AC_CHECK_LIB([c], [open_memstream],
 303   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 304 )
 305
 306 # Check for posix_fallocate
 307 AC_CHECK_LIB([c], [posix_fallocate],
 308   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 309 )
 310
 311
 312 ##                 ##
 313 ## User variables  ##
 314 ##                 ##
 315
 316 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 317 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 318 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 319
 320 # BABELTRACE_PLUGINS_DIR: Plugins directory
 321 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 322 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 323
 324 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 325 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 326 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 327
 328 # BABELTRACE_MINIMAL_LOG_LEVEL:
 329 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 330 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 331 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 332        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 333        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 334   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 335 )
 336 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 337
 338 # BABELTRACE_DEV_MODE:
 339 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 340 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 341         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 342 ], [BABELTRACE_DEV_MODE=0])
 343 AM_CONDITIONAL([DEV_MODE], [test "x$BABELTRACE_DEV_MODE" = x1])
 344
 345 # BABELTRACE_DEBUG_MODE:
 346 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 347 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 348         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 349 ], [BABELTRACE_DEBUG_MODE=0])
 350
 351
 352 ##                              ##
 353 ## Optionnal features selection ##
 354 ##                              ##
 355
 356 # Python bindings
 357 # Disabled by default
 358 AE_FEATURE_DEFAULT_DISABLE
 359 AE_FEATURE([python-bindings],[build the Python bindings])
 360
 361 # Python bindings documentation
 362 # Disabled by default
 363 AE_FEATURE_DEFAULT_DISABLE
 364 AE_FEATURE([python-bindings-doc],[build the Python bindings documentation])
 365
 366 # Python plugins
 367 # Disabled by default
 368 AE_FEATURE_DEFAULT_DISABLE
 369 AE_FEATURE([python-plugins],[enable the Python plugins support for the library and converter])
 370
 371 # Debug info
 372 # Enabled by default, except on some platforms
 373 AE_FEATURE_DEFAULT_ENABLE
 374 AE_FEATURE([debug-info],[disable the debug info support (default on macOS, Solaris and Windows)])
 375
 376 # API documentation
 377 # Disabled by default
 378 AE_FEATURE_DEFAULT_DISABLE
 379 AE_FEATURE([api-doc],[build the HTML API documentation])
 380
 381 # Built-in plugins
 382 # Disabled by default
 383 AE_FEATURE_DEFAULT_DISABLE
 384 AE_FEATURE([built-in-plugins],[Statically-link in-tree plug-ins into the babeltrace2 executable])
 385
 386 # Built-in python plugin support
 387 # Disabled by default
 388 AE_FEATURE_DEFAULT_DISABLE
 389 AE_FEATURE([built-in-python-plugin-support],[Statically-link Python plugin support into the babeltrace library])
 390
 391 # Man pages
 392 # Enabled by default
 393 AE_FEATURE_DEFAULT_ENABLE
 394 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball])
 395
 396 # When given, add -Werror to WARN_CFLAGS.
 397 # Disabled by default
 398 AE_FEATURE_DEFAULT_DISABLE
 399 AE_FEATURE([Werror],[Treat compiler warnings as errors.])
 400
 401
 402 ##                                          ##
 403 ## Check for conflicting features selection ##
 404 ##                                          ##
 405
 406 # Check for conflicting Python related features user choices.
 407 AE_IF_FEATURE_ENABLED([python-plugins], [
 408   AE_IF_FEATURE_UNDEF([python-bindings], [
 409     # --enable-python-plugins was provided but --enable-python-bindings was
 410     # omitted. Turn the Python bindings ON anyway because it's needed to
 411     # use the Python plugins.
 412     AE_FEATURE_ENABLE([python-bindings])
 413   ], [
 414     AE_IF_FEATURE_DISABLED([python-bindings], [
 415       # --enable-python-plugins _and_ --disable-python-bindings were
 416       # used. This is invalid because Python plugins need the Python
 417       # bindings to be useful.
 418       AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
 419     ])
 420   ])
 421 ])
 422
 423 # Check for conflicting optional features user choices
 424 AE_IF_FEATURE_ENABLED([built-in-plugins], [
 425     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 426     AE_IF_FEATURE_NOT_ENABLED([static], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 427     AE_IF_FEATURE_ENABLED([shared], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 428 ])
 429
 430 AE_IF_FEATURE_ENABLED([built-in-python-plugin-support], [
 431     AE_IF_FEATURE_NOT_ENABLED([python-plugins], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 432     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 433     AE_IF_FEATURE_NOT_ENABLED([static], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 434     AE_IF_FEATURE_ENABLED([shared], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 435 ])
 436
 437
 438 ##                                                                           ##
 439 ## Set automake variables for optionnal feature conditionnals in Makefile.am ##
 440 ##                                                                           ##
 441
 442 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], AE_IS_FEATURE_ENABLED([python-bindings]))
 443 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], AE_IS_FEATURE_ENABLED([python-bindings-doc]))
 444 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], AE_IS_FEATURE_ENABLED([python-plugins]))
 445 AM_CONDITIONAL([ENABLE_DEBUG_INFO], AE_IS_FEATURE_ENABLED([debug-info]))
 446 AM_CONDITIONAL([ENABLE_API_DOC], AE_IS_FEATURE_ENABLED([api-doc]))
 447 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], AE_IS_FEATURE_ENABLED([built-in-plugins]))
 448 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], AE_IS_FEATURE_ENABLED([built-in-python-plugin-support]))
 449 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 450 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], AE_IS_FEATURE_ENABLED([python-bindings]) || AE_IS_FEATURE_ENABLED([python-plugins]))
 451
 452
 453 ##                                                                     ##
 454 ## Set defines for optionnal features conditionnals in the source code ##
 455 ##                                                                     ##
 456
 457 AE_IF_FEATURE_ENABLED([built-in-plugins],
 458   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 459 )
 460
 461 AE_IF_FEATURE_ENABLED([built-in-python-plugin-support],
 462   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 463 )
 464
 465 AE_IF_FEATURE_ENABLED([debug-info], [ENABLE_DEBUG_INFO_VAL=1], [ENABLE_DEBUG_INFO_VAL=0])
 466 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 467
 468
 469 ##                                           ##
 470 ## Check for optionnal features dependencies ##
 471 ##                                           ##
 472
 473 # The Python bindings require SWIG
 474 AE_IF_FEATURE_ENABLED([python-plugins],
 475   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 476 )
 477
 478 # Always check for python, we will fail later if some features require it and
 479 # it's unavailable.
 480 AM_PATH_PYTHON([3.0], [
 481   AE_PATH_PYTHON_MODULES([PYTHON])
 482
 483   # pythondir is the path where extra modules are to be installed
 484   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 485
 486   # pyexecdir is the path that contains shared objects used by the extra modules
 487   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 488
 489   AS_IF([test -z "$PYTHON_CONFIG"], [
 490     AC_PATH_PROGS([PYTHON_CONFIG],
 491                   [python$PYTHON_VERSION-config python-config],
 492                   [],
 493                   [`dirname $PYTHON`])
 494   ])
 495
 496   AS_IF([test -n "$PYTHON_CONFIG"], [
 497     AS_IF([test -z "$PYTHON_INCLUDE"], [
 498       AC_MSG_CHECKING([Python include flags])
 499       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 500       AC_MSG_RESULT([$PYTHON_INCLUDE])
 501     ])
 502
 503     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 504       AC_MSG_CHECKING([Python library flags])
 505       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 506       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 507         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 508       ])
 509       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 510     ])
 511   ])
 512 ], [:])
 513
 514 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 515 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 516
 517 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 518 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 519
 520 AS_IF([AE_IS_FEATURE_ENABLED([python-bindings]) || AE_IS_FEATURE_ENABLED([python-plugins])], [
 521   AS_IF([test "x$have_python_dev" = xno], [
 522     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 523   ])
 524 ])
 525
 526 AE_IF_FEATURE_ENABLED([python-bindings-doc],
 527   [
 528     AE_CHECK_PYTHON_SPHINX([PYTHON])
 529     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno], [
 530       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])
 531     ])
 532
 533     AE_IF_FEATURE_NOT_ENABLED([python-bindings], [
 534       AC_MSG_ERROR([The Python bindings are required to build their documentation])
 535     ])
 536   ]
 537 )
 538
 539 AE_IF_FEATURE_ENABLED([debug-info], [
 540   # Check if libelf and libdw are present
 541   PKG_CHECK_MODULES([ELFUTILS], [libelf >= 0.154 libdw >= 0.154],
 542     [
 543       dnl PKG_CHECK_MODULES defines ELFUTILS_LIBS
 544     ],
 545     [
 546       AC_MSG_ERROR([elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.])
 547     ])
 548 ])
 549 AC_SUBST([ELFUTILS_LIBS])
 550
 551 AE_IF_FEATURE_ENABLED([api-doc],
 552   [
 553     DX_DOXYGEN_FEATURE(ON)
 554     DX_DOT_FEATURE(OFF)
 555     DX_HTML_FEATURE(ON)
 556     DX_CHM_FEATURE(OFF)
 557     DX_CHI_FEATURE(OFF)
 558     DX_MAN_FEATURE(OFF)
 559     DX_RTF_FEATURE(OFF)
 560     DX_XML_FEATURE(OFF)
 561     DX_PDF_FEATURE(OFF)
 562     DX_PS_FEATURE(OFF)
 563     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 564     AS_IF([test -z "$DX_DOXYGEN"],
 565           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 566     )
 567   ]
 568 )
 569
 570 have_asciidoc_xmlto=no
 571 warn_prebuilt_man_pages=no
 572
 573 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 574 AC_PATH_PROG([XMLTO], [xmlto], [no])
 575
 576 AE_IF_FEATURE_ENABLED([man-pages], [
 577   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 578     AS_IF([test "x$in_git_repo" = "xyes"], [
 579       # this is an error because we're in the Git repo, which
 580       # means the man pages are not already generated for us,
 581       # thus asciixmlto are required because we were asked
 582       # to build the man pages
 583       AC_MSG_ERROR([
 584 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 585 --disable-man-pages to disable building the man pages, in which case
 586 they will not be installed.
 587       ])
 588     ], [
 589       # only warn here: since we're in the tarball, the man
 590       # pages should already be generated at this point, thus
 591       # asciidoc/xmlto are not strictly required
 592       warn_prebuilt_man_pages=yes
 593     ])
 594   ], [
 595     have_asciidoc_xmlto=yes
 596   ])
 597 ])
 598
 599 # export AsciiDoc and xmlto existence
 600 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 601
 602 # a wonderful hack that seems necessary because $libdir is
 603 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 604 # by autoconf when it's not specified by the user
 605 AS_IF([test "x$exec_prefix" = xNONE], [
 606   AS_IF([test "x$prefix" = xNONE], [
 607     PREFIX="$ac_default_prefix"
 608   ], [
 609     PREFIX="$prefix"
 610   ])
 611
 612   LIBDIR="$PREFIX/lib"
 613 ], [
 614   LIBDIR="$libdir"
 615 ])
 616
 617 AC_SUBST(LIBDIR)
 618
 619
 620
 621
 622 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 623 # test).
 624 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 625
 626 # Check that the current size_t matches the size that glib thinks it should
 627 # be. This catches problems on multi-arch where people try to do a 32-bit
 628 # build while pointing at 64-bit glib headers. This is a common error because
 629 # glib.h is not platform specific but it includes glibconfig.h which is and
 630 # is usually installed in a non-standard path.
 631
 632 # Do this before enabling all the warning flags, as the
 633 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 634 # test fail unnecessarily.
 635
 636 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 637 # output. Specifically allow pkg_config_libdir to be able to print the
 638 # error message.
 639 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 640
 641 save_CFLAGS=${CFLAGS}
 642 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 643 AC_COMPILE_IFELSE([
 644   AC_LANG_PROGRAM([dnl
 645 #include <glib.h>
 646 #include <unistd.h>
 647   ], [dnl
 648 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 649   ])
 650 ],[:],[
 651   AC_MSG_ERROR([dnl
 652 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 653 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 654 target.
 655   ])
 656 ])
 657 CFLAGS=${save_CFLAGS}
 658
 659 # Detect C and LD warning flags supported by the compiler.
 660
 661 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
 662 #
 663 # Pass -Werror as an extra flag during the test: this is needed to make the
 664 # -Wunknown-warning-option diagnostic fatal with clang.
 665 AX_APPEND_COMPILE_FLAGS([ dnl
 666                 -Wall dnl
 667                 -Wextra dnl
 668                 -Wmissing-prototypes dnl
 669                 -Wmissing-declarations dnl
 670                 -Wnull-dereference dnl
 671                 -Wundef dnl
 672                 -Wredundant-decls dnl
 673                 -Wshadow dnl
 674                 -Wjump-misses-init dnl
 675                 -Wsuggest-attribute=format dnl
 676                 -Wtautological-constant-out-of-range-compare dnl
 677                 -Wnested-externs dnl
 678                 -Wwrite-strings dnl
 679                 -Wformat=2 dnl
 680                 -Wstrict-aliasing dnl
 681                 -Wmissing-noreturn dnl
 682                 -Winit-self dnl
 683                 -Wduplicated-cond dnl
 684                 -Wduplicated-branches dnl
 685                 -Wlogical-op dnl
 686                 -Wno-unused-parameter dnl
 687                 -Wno-sign-compare dnl
 688                 dnl
 689                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 690                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 691                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 692                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 693                 dnl It's simpler to just disable the warning globally.
 694                 dnl
 695                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 696                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 697                 dnl reproduce the warning using that package.
 698                 dnl
 699                 dnl Ref: https://github.com/swig/swig/issues/1259
 700                 -Wno-cast-function-type dnl
 701                 -Wno-missing-field-initializers dnl
 702         ],
 703         [WARN_CFLAGS],
 704         [-Werror])
 705
 706 AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
 707
 708 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 709 # written in such a way that it triggers warnings with the following warning
 710 # flags.  So they would always end up disabled if we put them there, because
 711 # the test program would not build.
 712 #
 713 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 714 # Clang >= 4.0.
 715 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 716
 717 # CFLAGS from AX_APPEND_COMPILE_FLAGS.
 718 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 719
 720 # Done for AM_CFLAGS.
 721 AC_SUBST(AM_CFLAGS)
 722
 723 # Set global CPPFLAGS in AM_CPPFLAGS
 724 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 725 AC_SUBST(AM_CPPFLAGS)
 726
 727 # Add glib to global link libs
 728 LIBS="$LIBS $GLIB_LIBS"
 729
 730 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 731 # to rename babeltrace2.bin to babeltrace2 at install time.
 732 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 733 AC_SUBST(program_transform_name)
 734
 735 AC_CONFIG_FILES([
 736         doc/api/Makefile
 737         doc/api/libbabeltrace2/Doxyfile
 738         doc/api/libbabeltrace2/Makefile
 739         doc/bindings/Makefile
 740         doc/bindings/python/Makefile
 741         doc/contributing-images/Makefile
 742         doc/Makefile
 743         doc/man/asciidoc-attrs.conf
 744         doc/man/Makefile
 745         include/Makefile
 746         Makefile
 747         src/argpar/Makefile
 748         src/autodisc/Makefile
 749         src/babeltrace2-ctf-writer.pc
 750         src/babeltrace2.pc
 751         src/bindings/Makefile
 752         src/bindings/python/bt2/bt2/version.py
 753         src/bindings/python/bt2/Makefile
 754         src/bindings/python/bt2/setup.py
 755         src/bindings/python/Makefile
 756         src/cli/Makefile
 757         src/common/Makefile
 758         src/compat/Makefile
 759         src/ctfser/Makefile
 760         src/ctf-writer/Makefile
 761         src/fd-cache/Makefile
 762         src/lib/graph/Makefile
 763         src/lib/graph/message/Makefile
 764         src/lib/Makefile
 765         src/lib/plugin/Makefile
 766         src/lib/prio-heap/Makefile
 767         src/lib/trace-ir/Makefile
 768         src/logging/Makefile
 769         src/Makefile
 770         src/plugins/common/Makefile
 771         src/plugins/common/muxing/Makefile
 772         src/plugins/common/param-validation/Makefile
 773         src/plugins/ctf/common/bfcr/Makefile
 774         src/plugins/ctf/common/Makefile
 775         src/plugins/ctf/common/metadata/Makefile
 776         src/plugins/ctf/common/msg-iter/Makefile
 777         src/plugins/ctf/fs-sink/Makefile
 778         src/plugins/ctf/fs-src/Makefile
 779         src/plugins/ctf/lttng-live/Makefile
 780         src/plugins/ctf/Makefile
 781         src/plugins/lttng-utils/debug-info/Makefile
 782         src/plugins/lttng-utils/Makefile
 783         src/plugins/Makefile
 784         src/plugins/text/dmesg/Makefile
 785         src/plugins/text/Makefile
 786         src/plugins/text/pretty/Makefile
 787         src/plugins/text/details/Makefile
 788         src/plugins/utils/counter/Makefile
 789         src/plugins/utils/dummy/Makefile
 790         src/plugins/utils/Makefile
 791         src/plugins/utils/muxer/Makefile
 792         src/plugins/utils/trimmer/Makefile
 793         src/py-common/Makefile
 794         src/python-plugin-provider/Makefile
 795         src/param-parse/Makefile
 796         src/string-format/Makefile
 797         tests/bitfield/Makefile
 798         tests/ctf-writer/Makefile
 799         tests/lib/Makefile
 800         tests/lib/test-plugin-plugins/Makefile
 801         tests/lib/conds/Makefile
 802         tests/Makefile
 803         tests/param-validation/Makefile
 804         tests/plugins/Makefile
 805         tests/plugins/src.ctf.fs/Makefile
 806         tests/plugins/src.ctf.fs/succeed/Makefile
 807         tests/plugins/sink.ctf.fs/Makefile
 808         tests/plugins/sink.ctf.fs/succeed/Makefile
 809         tests/plugins/flt.lttng-utils.debug-info/Makefile
 810         tests/plugins/flt.utils.muxer/Makefile
 811         tests/plugins/flt.utils.muxer/succeed/Makefile
 812         tests/plugins/flt.utils.trimmer/Makefile
 813         tests/plugins/sink.text.pretty/Makefile
 814         tests/utils/Makefile
 815         tests/utils/tap/Makefile
 816 ])
 817
 818 AC_OUTPUT
 819
 820 #
 821 # Mini-report on what will be built.
 822 #
 823
 824 PPRINT_INIT
 825 PPRINT_SET_INDENT(1)
 826 PPRINT_SET_TS(38)
 827
 828 AS_ECHO
 829
 830 AS_IF([test -n "bt_version_name"], [
 831         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 832 ], [
 833         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 834 ])
 835
 836 AS_ECHO
 837
 838 AS_IF([test -n "bt_version_description"], [
 839         AS_IF([test -n "$report_fold"], [
 840                 AS_ECHO("`AS_ECHO("bt_version_description") | $report_fold -s`")
 841         ], [
 842                 AS_ECHO("bt_version_description")
 843         ])
 844
 845         AS_ECHO
 846 ])
 847
 848 PPRINT_SUBTITLE([System])
 849
 850 # Target architecture we're building for.
 851 target_arch=$host_cpu
 852 [
 853 for f in $CFLAGS; do
 854         if test $f = "-m32"; then
 855                 target_arch="32-bit"
 856         elif test $f = "-m64"; then
 857                 target_arch="64-bit"
 858         fi
 859 done
 860 ]
 861
 862 PPRINT_PROP_STRING([Target architecture], $target_arch)
 863
 864 AS_ECHO
 865 PPRINT_SUBTITLE([Python 3 language support])
 866 test "x$have_python" = "xyes" && value=1 || value=0
 867 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 868 test "x$have_python_dev" = "xyes" && value=1 || value=0
 869 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 870 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 871 PPRINT_PROP_BOOL_CUSTOM([Python bindings], $value, [To enable, use --enable-python-bindings])
 872 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 873 PPRINT_PROP_BOOL_CUSTOM([Python plugin support], $value, [To enable, use --enable-python-plugins])
 874 AS_IF([test "x$have_python" = "xyes"], [
 875   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 876 ])
 877 AS_IF([test "x$have_python_dev" = "xyes"], [
 878   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 879   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 880   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 881 ])
 882 AE_IF_FEATURE_ENABLED([python-bindings], [
 883   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 884   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 885 ])
 886
 887 AS_ECHO
 888 PPRINT_SUBTITLE([Plugins])
 889 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 890 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 891 PPRINT_PROP_BOOL_CUSTOM(['lttng-utils' plugin], $value, [To enable, use --enable-debug-info])
 892 PPRINT_PROP_BOOL(['text' plugin], 1)
 893 PPRINT_PROP_BOOL(['utils' plugin], 1)
 894
 895 AS_ECHO
 896 PPRINT_SUBTITLE([Built-in features])
 897 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 898 PPRINT_PROP_BOOL_CUSTOM([Built-in plugins], $value, [To enable, use --enable-built-in-plugins])
 899 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 900 PPRINT_PROP_BOOL_CUSTOM([Built-in Python plugin support], $value, [To enable, use --enable-built-in-python-plugin-support])
 901
 902 AS_ECHO
 903 PPRINT_SUBTITLE([Documentation])
 904
 905 # man pages build enabled/disabled
 906 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 907
 908 AS_IF([test "x$enable_man_pages" != "xno"], [
 909   AS_IF([test "x$in_git_repo" = "xyes"], [
 910     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 911   ], [
 912     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 913       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 914     ], [
 915       PPRINT_PROP_STRING([build_man_pages_msg],
 916         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 917         $PPRINT_COLOR_SUBTITLE)
 918     ])
 919   ])
 920 ], [
 921   PPRINT_PROP_BOOL_CUSTOM([build_man_pages_msg], 0, [To build man pages, use --enable-man-pages])
 922 ])
 923
 924 m4_popdef([build_man_pages_msg])
 925
 926 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 927 PPRINT_PROP_BOOL_CUSTOM([HTML API documentation], $value, [To build documentation, use --enable-api-doc])
 928 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 929 PPRINT_PROP_BOOL_CUSTOM([Python bindings documentation], $value, [To build the Python bindings documentation, use --enable-python-bindings-doc])
 930
 931 AS_ECHO
 932 PPRINT_SUBTITLE([Logging])
 933 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 934
 935 AS_ECHO
 936 PPRINT_SUBTITLE([Special build modes])
 937 PPRINT_PROP_BOOL_CUSTOM([Debug mode], $BABELTRACE_DEBUG_MODE, [To enable, set the BABELTRACE_DEBUG_MODE environment variable to 1])
 938 PPRINT_PROP_BOOL_CUSTOM([Developer mode], $BABELTRACE_DEV_MODE, [To enable, set the BABELTRACE_DEV_MODE environment variable to 1])
 939
 940 report_bindir="`eval eval echo $bindir`"
 941 report_libdir="`eval eval echo $libdir`"
 942 report_sysconfdif="`eval eval echo $sysconfdir`"
 943 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 944 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 945
 946 # Print the bindir and libdir this `make install' will install into.
 947 AS_ECHO
 948 PPRINT_SUBTITLE([Install directories])
 949 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 950 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 951 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 952 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 953 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])