configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   9
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CANONICAL_TARGET
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  14 AM_MAINTAINER_MODE([enable])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 AC_PROG_MKDIR_P
  20 AC_PROG_LN_S
  21
  22 AC_CONFIG_HEADERS([config.h])
  23
  24 AC_SYS_LARGEFILE
  25
  26 # Checks for programs.
  27 AC_PROG_CC_STDC
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32
  33 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  34         if test x"$YACC" != "xbison -y"; then
  35                 AC_MSG_ERROR([[bison not found and is required when building from git.
  36                 Please install bison]])
  37         fi
  38 fi
  39
  40 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  41         if test x"$LEX" != "xflex"; then
  42                 AC_MSG_ERROR([[flex not found and is required when building from git.
  43                 Please install flex]])
  44         fi
  45 fi
  46
  47
  48 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  49
  50 # Checks for typedefs, structures, and compiler characteristics.
  51 AC_C_INLINE
  52 AC_TYPE_PID_T
  53 AC_TYPE_SIZE_T
  54
  55 # Checks for library functions.
  56 AC_FUNC_MALLOC
  57 AC_FUNC_MMAP
  58 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  59
  60 # Check for MinGW32.
  61 MINGW32=no
  62 case $host in
  63   *-*-mingw*)
  64         MINGW32=yes;;
  65 esac
  66
  67 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  68
  69 # Check for libuuid
  70 AC_CHECK_LIB([uuid], [uuid_generate],
  71 [
  72         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  73         have_libuuid=yes
  74 ],
  75 [
  76         # libuuid not found, check for uuid_create in libc.
  77         AC_CHECK_LIB([c], [uuid_create],
  78         [
  79                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  80                 have_libc_uuid=yes
  81         ],
  82         [
  83                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  84                 if test "x$MINGW32" = xno; then
  85                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  86                 fi
  87         ])
  88 ]
  89 )
  90 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  91 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  92
  93 # Check for fmemopen
  94 AC_CHECK_LIB([c], [fmemopen],
  95 [
  96         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
  97 ]
  98 )
  99
 100 # Check for open_memstream
 101 AC_CHECK_LIB([c], [open_memstream],
 102 [
 103         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 104 ]
 105 )
 106
 107 AC_CHECK_LIB([popt], [poptGetContext], [],
 108         [AC_MSG_ERROR([Cannot find popt.])]
 109 )
 110
 111
 112 # For Python
 113 # SWIG version needed or newer:
 114 swig_version=2.0.0
 115
 116 AC_ARG_ENABLE([python-bindings],
 117               [AC_HELP_STRING([--enable-python-bindings],
 118                               [generate Python bindings])],
 119               [enable_python=yes], [enable_python=no])
 120
 121 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 122
 123 AC_ARG_ENABLE([python-bindings-doc],
 124               [AC_HELP_STRING([--enable-python-bindings-doc],
 125                               [generate Python bindings documentation])],
 126               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 127
 128 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 129   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 130 fi
 131
 132 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 133
 134 if test "x${enable_python:-yes}" = xyes; then
 135   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 136   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 137
 138   AM_PATH_PYTHON_MODULES([PYTHON])
 139   # pythondir is the path where extra modules are to be installed
 140   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 141   # pyexecdir is the path that contains shared objects used by the extra modules
 142   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 143   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 144   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 145   AS_IF([test -z "$PYTHON_INCLUDE"], [
 146     AS_IF([test -z "$PYTHON_CONFIG"], [
 147       AC_PATH_PROGS([PYTHON_CONFIG],
 148                     [python$PYTHON_VERSION-config python-config],
 149                     [no],
 150                     [`dirname $PYTHON`])
 151       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 152     ])
 153     AC_MSG_CHECKING([python include flags])
 154     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 155     AC_MSG_RESULT([$PYTHON_INCLUDE])
 156   ])
 157 else
 158     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 159 [if you want Python bindings.])
 160
 161 fi
 162
 163 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 164     AM_CHECK_PYTHON_SPHINX([PYTHON])
 165     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 166       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 167     )
 168 fi
 169
 170 pkg_modules="gmodule-2.0 >= 2.0.0"
 171 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 172 AC_SUBST(PACKAGE_LIBS)
 173
 174 LIBS="$LIBS $GMODULE_LIBS"
 175 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 176 AC_SUBST(PACKAGE_CFLAGS)
 177
 178 babeltraceincludedir="${includedir}/babeltrace"
 179 AC_SUBST(babeltraceincludedir)
 180
 181 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 182 AC_SUBST(babeltracectfincludedir)
 183
 184 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 185 AC_SUBST(babeltracectfwriterincludedir)
 186
 187 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 188 AC_SUBST(babeltracectfirincludedir)
 189
 190 AC_CONFIG_FILES([
 191         Makefile
 192         types/Makefile
 193         compat/Makefile
 194         formats/Makefile
 195         formats/ctf/Makefile
 196         formats/ctf/types/Makefile
 197         formats/ctf-text/Makefile
 198         formats/ctf-text/types/Makefile
 199         formats/ctf-metadata/Makefile
 200         formats/bt-dummy/Makefile
 201         formats/lttng-live/Makefile
 202         formats/ctf/metadata/Makefile
 203         formats/ctf/writer/Makefile
 204         formats/ctf/ir/Makefile
 205         converter/Makefile
 206         doc/Makefile
 207         doc/bindings/Makefile
 208         doc/bindings/python/Makefile
 209         lib/Makefile
 210         lib/prio_heap/Makefile
 211         include/Makefile
 212         bindings/Makefile
 213         bindings/python/Makefile
 214         tests/Makefile
 215         tests/bin/Makefile
 216         tests/lib/Makefile
 217         tests/utils/Makefile
 218         tests/utils/tap/Makefile
 219         extras/Makefile
 220         extras/valgrind/Makefile
 221         babeltrace.pc
 222         babeltrace-ctf.pc
 223 ])
 224 AC_OUTPUT