configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre1])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT(win32-dll)
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53 LIBS="$PTHREAD_LIBS $LIBS"
  54 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  55 CC="$PTHREAD_CC"
  56
  57 # Check linker option
  58 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  59 AC_SUBST([LD_NO_AS_NEEDED])
  60
  61 AC_HEADER_STDBOOL
  62 AC_CHECK_HEADERS([ \
  63         fcntl.h \
  64         float.h \
  65         ftw.h \
  66         libintl.h \
  67         limits.h \
  68         malloc.h \
  69         netdb.h \
  70         netinet/in.h \
  71         stddef.h \
  72         sys/socket.h \
  73 ])
  74
  75 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  76         if test x"$(basename "$YACC")" != "xbison -y"; then
  77                 AC_MSG_ERROR([[bison not found and is required when building from git.
  78                 Please install bison]])
  79         fi
  80         AC_PATH_PROG([BISON],[bison])
  81         AX_PROG_BISON_VERSION([2.4], [],[
  82                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  83         ])
  84 fi
  85
  86 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  87         if test x"$LEX" != "xflex"; then
  88                 AC_MSG_ERROR([[flex not found and is required when building from git.
  89                 Please install flex]])
  90         fi
  91         AC_PATH_PROG([FLEX],[flex])
  92         AX_PROG_FLEX_VERSION([2.5.35], [],[
  93                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  94         ])
  95 fi
  96
  97
  98 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule-no-export)
  99
 100 # Check what libraries are required on this platform to link sockets programs.
 101 AX_LIB_SOCKET_NSL
 102
 103 # Checks for typedefs, structures, and compiler characteristics.
 104 AC_C_INLINE
 105 AC_TYPE_PID_T
 106 AC_TYPE_SIZE_T
 107 AC_TYPE_INT16_T
 108 AC_TYPE_INT32_T
 109 AC_TYPE_INT64_T
 110 AC_TYPE_INT8_T
 111 AC_TYPE_OFF_T
 112 AC_TYPE_SSIZE_T
 113 AC_TYPE_UINT16_T
 114 AC_TYPE_UINT32_T
 115 AC_TYPE_UINT64_T
 116 AC_TYPE_UINT8_T
 117
 118 # Checks for library functions.
 119 AC_FUNC_ALLOCA
 120 AC_FUNC_FORK
 121 AC_FUNC_MALLOC
 122 AC_FUNC_MKTIME
 123 AC_FUNC_MMAP
 124 AC_FUNC_REALLOC
 125 AC_FUNC_STRERROR_R
 126 AC_CHECK_FUNCS([ \
 127         atexit \
 128         dup2 \
 129         ftruncate \
 130         gethostbyname \
 131         gethostname \
 132         gettimeofday \
 133         localtime_r \
 134         memchr \
 135         memset \
 136         mkdir \
 137         mkdtemp \
 138         munmap \
 139         rmdir \
 140         setenv \
 141         socket \
 142         strchr \
 143         strdup \
 144         strerror \
 145         strndup \
 146         strnlen \
 147         strrchr \
 148         strtoul \
 149         strtoull \
 150         tzset \
 151         uname \
 152 ])
 153
 154 MINGW32=no
 155 DEFAULT_ENABLE_DEBUG_INFO=yes
 156 LT_NO_UNDEFINED=""
 157 AS_CASE([$host_os],
 158   [solaris*|darwin*],
 159     [
 160         DEFAULT_ENABLE_DEBUG_INFO=no
 161     ],
 162   [mingw*],
 163     [
 164         MINGW32=yes
 165         DEFAULT_ENABLE_DEBUG_INFO=no
 166         LT_NO_UNDEFINED="-no-undefined"
 167     ]
 168 )
 169
 170 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 171 AC_SUBST(LT_NO_UNDEFINED)
 172
 173 # Check for uuid in system libs
 174 AC_CHECK_FUNCS([uuid_generate],
 175 [
 176   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 177   link_with_libuuid=no
 178 ],
 179 [
 180   # First, check the pkg-config module is available, otherwise explicitly check
 181   # for libuuid, or uuid support in the C-library.
 182   PKG_CHECK_MODULES([UUID], [uuid],
 183   [
 184     LIBS="${UUID_LIBS} ${LIBS}"
 185     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 186     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 187     link_with_libuuid=yes
 188   ],
 189   [
 190     # Check for libuuid
 191     AC_CHECK_LIB([uuid], [uuid_generate],
 192     [
 193       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 194       link_with_libuuid=yes
 195     ],
 196     [
 197       # libuuid not found, check for uuid_create in libc.
 198       AC_CHECK_LIB([c], [uuid_create],
 199       [
 200         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 201         link_with_libc_uuid=yes
 202       ],
 203       [
 204         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 205         if test "x$MINGW32" = xno; then
 206           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 207         fi
 208       ])
 209     ])
 210   ])
 211 ])
 212
 213 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 214 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 215
 216 # Check for fmemopen
 217 AC_CHECK_LIB([c], [fmemopen],
 218 [
 219         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 220 ]
 221 )
 222
 223 # Check for open_memstream
 224 AC_CHECK_LIB([c], [open_memstream],
 225 [
 226         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 227 ]
 228 )
 229
 230 # Check for posix_fallocate
 231 AC_CHECK_LIB([c], [posix_fallocate],
 232 [
 233         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 234 ]
 235 )
 236
 237 AC_CHECK_LIB([popt], [poptGetContext], [],
 238         [AC_MSG_ERROR([Cannot find popt.])]
 239 )
 240
 241 # Plugins
 242 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 243 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 244
 245 # For Python
 246 # SWIG version needed or newer:
 247 swig_version=2.0.0
 248
 249 AC_ARG_ENABLE([python-bindings],
 250               [AC_HELP_STRING([--enable-python-bindings],
 251                               [generate Python bindings])],
 252               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 253
 254 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 255
 256 AC_ARG_ENABLE(
 257         [python-plugins],
 258         [AC_HELP_STRING(
 259                 [--enable-python-plugins],
 260                 [add support for the Babeltrace library and converter to load Python plugins])
 261         ],
 262         [enable_python_plugins=$enableval],
 263         [enable_python_plugins=no]
 264 )
 265
 266 if test "x${enable_python_bindings:-yes}" = xyes; then
 267   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 268 else
 269     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 270 [if you want Python bindings.])
 271 fi
 272
 273 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 274   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 275
 276   AM_PATH_PYTHON_MODULES([PYTHON])
 277   # pythondir is the path where extra modules are to be installed
 278   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 279   # pyexecdir is the path that contains shared objects used by the extra modules
 280   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 281   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 282   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 283   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 284   AS_IF([test -z "$PYTHON_INCLUDE"], [
 285     AS_IF([test -z "$PYTHON_CONFIG"], [
 286       AC_PATH_PROGS([PYTHON_CONFIG],
 287                     [python$PYTHON_VERSION-config python-config],
 288                     [no],
 289                     [`dirname $PYTHON`])
 290       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 291     ])
 292     AC_MSG_CHECKING([Python include flags])
 293     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 294     AC_MSG_RESULT([$PYTHON_INCLUDE])
 295   ])
 296   AS_IF([test -z "$PYTHON_LIBS"], [
 297     AS_IF([test -z "$PYTHON_CONFIG"], [
 298       AC_PATH_PROGS([PYTHON_CONFIG],
 299                     [python$PYTHON_VERSION-config python-config],
 300                     [no],
 301                     [`dirname $PYTHON`])
 302       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 303     ])
 304     AC_MSG_CHECKING([Python library flags])
 305     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 306     AC_MSG_RESULT([$PYTHON_LIBS])
 307   ])
 308 fi
 309
 310 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 311
 312 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 313 AS_IF(
 314   [test "x$enable_python_plugins" != xno],
 315   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 316 )
 317
 318 AC_ARG_ENABLE([python-bindings-doc],
 319               [AC_HELP_STRING([--enable-python-bindings-doc],
 320                               [generate Python bindings documentation])],
 321               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 322
 323 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 324
 325 AC_ARG_ENABLE([python-bindings-tests],
 326               [AC_HELP_STRING([--enable-python-bindings-tests],
 327                               [test Python bindings])],
 328               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 329
 330 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 331
 332 if test "x${enable_python_bindings:-no}" = xno; then
 333   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 334     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 335   fi
 336
 337   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 338     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 339   fi
 340 fi
 341
 342 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 343     AM_CHECK_PYTHON_SPHINX([PYTHON])
 344     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 345       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 346     )
 347 fi
 348
 349 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 350     AM_CHECK_PYTHON_TAPPY([PYTHON])
 351     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 352         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 353     )
 354 fi
 355
 356 # Set default enable state for debug info.
 357 # The _enable_debug_info variable is prepended with an underscore to
 358 # avoid clashing with the one generated by AC_ARG_ENABLE.
 359 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 360
 361 # Optional debug info feature
 362 # Do _not_ indent the help string below (appears in the configure --help
 363 # output).
 364 AC_ARG_ENABLE([debug-info],
 365 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 366 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 367         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 368
 369 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 370
 371 AS_IF([test "x$_enable_debug_info" = xyes], [
 372         # Check if libelf and libdw are present
 373         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 374         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 375         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 376         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 377 ], [])
 378
 379 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 380 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 381 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 382         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 383         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 384         built_in_plugins=yes
 385         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 386 ])
 387 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 388
 389 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 390 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 391 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 392   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 393   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 394   AS_IF([test "x$enable_python_plugins" = "xno"], [
 395     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 396   ])
 397   built_in_python_plugin_support=yes
 398   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 399 ])
 400 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 401
 402 PKG_CHECK_MODULES(GMODULE, [gmodule-no-export-2.0 >= 2.0.0])
 403
 404 # Logging
 405 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 406 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=VERBOSE])
 407 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 408         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 409 ])
 410 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 411
 412 LIBS="$LIBS $GMODULE_LIBS"
 413 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 414 AC_SUBST(PACKAGE_CFLAGS)
 415
 416 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 417 AC_SUBST(DEFAULT_INCLUDES)
 418
 419 babeltraceincludedir="${includedir}/babeltrace"
 420 AC_SUBST(babeltraceincludedir)
 421
 422 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 423 AC_SUBST(babeltracectfwriterincludedir)
 424
 425 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 426 AC_SUBST(babeltracectfincludedir)
 427
 428 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 429 AC_SUBST(babeltracectfirincludedir)
 430
 431 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 432 AC_SUBST(babeltracepluginincludedir)
 433
 434 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 435 AC_SUBST(babeltracegraphincludedir)
 436
 437 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 438 AC_SUBST(program_transform_name)
 439
 440 # check for Doxygen
 441 AC_ARG_ENABLE(
 442   [api-doc],
 443   [AC_HELP_STRING(
 444     [--enable-api-doc],
 445     [generate and install HTML API documentation]
 446   )],
 447   [enable_api_doc=$enableval],
 448   [enable_api_doc=no]
 449 )
 450 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 451
 452 AS_IF([test "x$enable_api_doc" = "xyes"], [
 453   DX_DOXYGEN_FEATURE(ON)
 454   DX_DOT_FEATURE(OFF)
 455   DX_HTML_FEATURE(ON)
 456   DX_CHM_FEATURE(OFF)
 457   DX_CHI_FEATURE(OFF)
 458   DX_MAN_FEATURE(OFF)
 459   DX_RTF_FEATURE(OFF)
 460   DX_XML_FEATURE(OFF)
 461   DX_PDF_FEATURE(OFF)
 462   DX_PS_FEATURE(OFF)
 463   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 464 ])
 465
 466         #TODO: removed, work in progress
 467         #bindings/python/Makefile
 468         #bindings/python/babeltrace/Makefile
 469         #bindings/python/bt2/Makefile
 470         #bindings/python/bt2/__init__.py
 471 AC_CONFIG_FILES([
 472         Makefile
 473         common/Makefile
 474         compat/Makefile
 475         cli/Makefile
 476         doc/Makefile
 477         doc/api/Makefile
 478         doc/api/Doxyfile
 479         doc/bindings/Makefile
 480         doc/bindings/python/Makefile
 481         doc/images/Makefile
 482         lib/Makefile
 483         lib/prio_heap/Makefile
 484         lib/plugin/Makefile
 485         lib/graph/Makefile
 486         lib/graph/notification/Makefile
 487         lib/ctf-ir/Makefile
 488         lib/ctf-writer/Makefile
 489         include/Makefile
 490         logging/Makefile
 491         bindings/Makefile
 492         tests/Makefile
 493         tests/cli/Makefile
 494         tests/cli/intersection/Makefile
 495         tests/lib/Makefile
 496         tests/lib/writer/Makefile
 497         tests/lib/test-plugin-plugins/Makefile
 498         tests/utils/Makefile
 499         tests/utils/tap/Makefile
 500         tests/bindings/Makefile
 501         tests/bindings/python/Makefile
 502         tests/bindings/python/bt2/Makefile
 503         tests/plugins/Makefile
 504         extras/Makefile
 505         extras/valgrind/Makefile
 506         plugins/Makefile
 507         plugins/ctf/Makefile
 508         plugins/ctf/common/Makefile
 509         plugins/ctf/common/btr/Makefile
 510         plugins/ctf/common/metadata/Makefile
 511         plugins/ctf/common/notif-iter/Makefile
 512         plugins/ctf/fs-src/Makefile
 513         plugins/ctf/fs-sink/Makefile
 514         plugins/ctf/lttng-live/Makefile
 515         plugins/text/Makefile
 516         plugins/text/pretty/Makefile
 517         plugins/utils/Makefile
 518         plugins/utils/dummy/Makefile
 519         plugins/utils/trimmer/Makefile
 520         plugins/utils/muxer/Makefile
 521         python-plugin-provider/Makefile
 522         plugins/libctfcopytrace/Makefile
 523         plugins/lttng-utils/Makefile
 524         babeltrace.pc
 525         babeltrace-ctf.pc
 526 ])
 527
 528 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 529 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 530 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 531 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 532 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 533
 534 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 535
 536 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 537 AC_CONFIG_FILES([tests/cli/test_trace_copy], [chmod +x tests/cli/test_trace_copy])
 538 AC_CONFIG_FILES([tests/cli/test_debug_info], [chmod +x tests/cli/test_debug_info])
 539 AC_CONFIG_FILES([tests/cli/test_trimmer], [chmod +x tests/cli/test_trimmer])
 540 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 541 AC_CONFIG_FILES([tests/cli/test_convert_args], [chmod +x tests/cli/test_convert_args])
 542 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 543 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 544 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 545 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 546 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 547
 548 AS_IF([test "x$enable_python" = "xyes"], [
 549         AC_CONFIG_FILES(
 550                 [tests/bindings/python/bt2/testall.sh],
 551                 [chmod +x tests/bindings/python/bt2/testall.sh]
 552         )
 553 ])
 554
 555 AC_OUTPUT
 556
 557 #
 558 # Mini-report on what will be built.
 559 #
 560
 561 PPRINT_INIT
 562 PPRINT_SET_INDENT(1)
 563 PPRINT_SET_TS(38)
 564
 565 AS_ECHO
 566 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 567 AS_ECHO
 568
 569 PPRINT_SUBTITLE([System])
 570
 571 # Target architecture we're building for.
 572 target_arch=$host_cpu
 573 [
 574 for f in $CFLAGS; do
 575         if test $f = "-m32"; then
 576                 target_arch="32-bit"
 577         elif test $f = "-m64"; then
 578                 target_arch="64-bit"
 579         fi
 580 done
 581 ]
 582
 583 PPRINT_PROP_STRING([Target architecture], $target_arch)
 584
 585 AS_ECHO
 586 PPRINT_SUBTITLE([Python 3 language support])
 587 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 588 PPRINT_PROP_BOOL([Python bindings], $value)
 589 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 590 PPRINT_PROP_BOOL([Python plugin support], $value)
 591 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 592   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 593   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 594 ])
 595
 596 AS_ECHO
 597 PPRINT_SUBTITLE([Plugins])
 598 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 599 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 600 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 601 PPRINT_PROP_BOOL(['text' plugin], 1)
 602 PPRINT_PROP_BOOL(['utils' plugin], 1)
 603
 604 AS_ECHO
 605 PPRINT_SUBTITLE([Built-in features])
 606 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 607 PPRINT_PROP_BOOL([Built-in plugins], $value)
 608 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 609 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 610
 611 AS_ECHO
 612 PPRINT_SUBTITLE([Documentation])
 613 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 614 PPRINT_PROP_BOOL([HTML API documentation], $value)
 615 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 616 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 617
 618 AS_ECHO
 619 PPRINT_SUBTITLE([Logging])
 620 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 621
 622 AS_ECHO
 623 PPRINT_SUBTITLE([Testing])
 624 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 625 PPRINT_PROP_BOOL([Python bindings tests], $value)
 626
 627 report_bindir="`eval eval echo $bindir`"
 628 report_libdir="`eval eval echo $libdir`"
 629 report_sysconfdif="`eval eval echo $sysconfdir`"
 630
 631 # Print the bindir and libdir this `make install' will install into.
 632 AS_ECHO
 633 PPRINT_SUBTITLE([Install directories])
 634 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 635 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 636 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 637 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])