configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [1])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_dev_stage], [-rc1])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  34 m4_define([bt_version_name], [])
  35
  36 AC_INIT([babeltrace2], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  37 AC_PROG_SED
  38
  39 # Following the numbering scheme proposed by libtool for the library version
  40 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  41 m4_define([bt_lib_version_current], [0])
  42 m4_define([bt_lib_version_revision], [0])
  43 m4_define([bt_lib_version_age], [0])
  44 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  45
  46 bt_version_description=""
  47 bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
  48
  49 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  50
  51 AC_CONFIG_HEADERS([src/common/config.h])
  52 AC_CONFIG_AUX_DIR([config])
  53 AC_CONFIG_MACRO_DIR([m4])
  54
  55 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  56 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  57 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  58 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  59 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  60 AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
  61
  62 AC_CANONICAL_TARGET
  63 AC_CANONICAL_HOST
  64
  65
  66 ##                     ##
  67 ## Automake base setup ##
  68 ##                     ##
  69
  70 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  71 AM_MAINTAINER_MODE([enable])
  72
  73 # Enable silent rules if available (Introduced in AM 1.11)
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76
  77 ##                      ##
  78 ## OS specific defaults ##
  79 ##                      ##
  80
  81 MINGW32=no
  82 DEFAULT_ENABLE_DEBUG_INFO=yes
  83 LT_NO_UNDEFINED=""
  84 AS_CASE([$host_os],
  85   [solaris*|darwin*],
  86     [
  87         DEFAULT_ENABLE_DEBUG_INFO=no
  88     ],
  89   [cygwin*],
  90     [
  91         DEFAULT_ENABLE_DEBUG_INFO=no
  92         LT_NO_UNDEFINED="-no-undefined"
  93     ],
  94   [mingw*],
  95     [
  96         MINGW32=yes
  97         DEFAULT_ENABLE_DEBUG_INFO=no
  98         LT_NO_UNDEFINED="-no-undefined"
  99     ]
 100 )
 101
 102 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 103 AC_SUBST(LT_NO_UNDEFINED)
 104
 105
 106 ##                   ##
 107 ## C compiler checks ##
 108 ##                   ##
 109
 110 AC_USE_SYSTEM_EXTENSIONS
 111 AC_SYS_LARGEFILE
 112
 113 # Choose the c compiler
 114 AC_PROG_CC
 115
 116 # Make sure the c compiler supports C99
 117 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 118
 119 # Make sure the c compiler supports __attributes__
 120 AX_C___ATTRIBUTE__
 121 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 122   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 123
 124 # Make sur we have pthread support
 125 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 126
 127 # Checks for typedefs, structures, and compiler characteristics.
 128 AC_C_INLINE
 129 AC_C_TYPEOF
 130 AC_TYPE_PID_T
 131 AC_TYPE_SIZE_T
 132 AC_TYPE_INT16_T
 133 AC_TYPE_INT32_T
 134 AC_TYPE_INT64_T
 135 AC_TYPE_INT8_T
 136 AC_TYPE_OFF_T
 137 AC_TYPE_SSIZE_T
 138 AC_TYPE_UINT16_T
 139 AC_TYPE_UINT32_T
 140 AC_TYPE_UINT64_T
 141 AC_TYPE_UINT8_T
 142 AC_CHECK_TYPES([ptrdiff_t])
 143
 144
 145 ##               ##
 146 ## Header checks ##
 147 ##               ##
 148
 149 AC_HEADER_STDBOOL
 150 AC_CHECK_HEADERS([ \
 151         fcntl.h \
 152         float.h \
 153         ftw.h \
 154         libintl.h \
 155         limits.h \
 156         malloc.h \
 157         netdb.h \
 158         netinet/in.h \
 159         stddef.h \
 160         sys/socket.h \
 161         sys/time.h
 162 ])
 163
 164
 165 ##               ##
 166 ## Linker checks ##
 167 ##               ##
 168
 169 # Check if the linker supports no-as-needed
 170 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 171 AC_SUBST([LD_NO_AS_NEEDED])
 172
 173 # Check if the linker supports whole-archive
 174 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 175   [
 176     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 177     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 178   ],[
 179     # Fallback to force_load for the macOS linker
 180     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 181       [
 182         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 183         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 184       ],[
 185         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 186       ]
 187     )
 188   ]
 189 )
 190
 191 # Initialize and configure libtool
 192 LT_INIT([win32-dll])
 193
 194
 195 ##                 ##
 196 ## Programs checks ##
 197 ##                 ##
 198
 199 AC_PROG_MAKE_SET
 200 AC_PROG_MKDIR_P
 201 AC_PROG_LN_S
 202 AC_PATH_PROG([report_fold], [fold])
 203
 204 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 205 # is not distributed in tarballs
 206 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 207 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 208
 209 # check for bison
 210 AC_PROG_YACC
 211 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 212
 213 AS_IF([test "x$have_bison" != "xyes"], [
 214   AS_IF([test "x$in_git_repo" = "xyes"], [
 215     AC_MSG_FAILURE([dnl
 216 Bison >= 2.4 is required when building from the Git repository. You can
 217 set the YACC variable to override automatic detection.
 218     ])
 219   ], [
 220     AC_MSG_WARN([dnl
 221 Missing Bison >= 2.4. Note that the parser files are already built in
 222 this distribution tarball, so Bison is only needed if you intend to
 223 modify their sources. You can set the YACC variable to override automatic
 224 detection.
 225     ])
 226   ])
 227 ])
 228 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 229
 230 # check for flex
 231 AC_PROG_LEX
 232 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 233
 234 AS_IF([test "x$have_flex" != "xyes"], [
 235   AS_IF([test "x$in_git_repo" = "xyes"], [
 236     AC_MSG_FAILURE([dnl
 237 Flex >= 2.5.35 is required when building from the Git repository. You can
 238 set the LEX variable to override automatic detection.
 239     ])
 240   ], [
 241     AC_MSG_WARN([dnl
 242 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 243 this distribution tarball, so Flex is only needed if you intend to
 244 modify their sources. You can set the LEX variable to override automatic
 245 detection.
 246     ])
 247   ])
 248 ])
 249 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 250
 251
 252 ##                ##
 253 ## Library checks ##
 254 ##                ##
 255
 256 # Check what libraries are required on this platform to link sockets programs.
 257 AX_LIB_SOCKET_NSL
 258
 259 # Check for glib >= 2.28 with gmodule support
 260 AM_PATH_GLIB_2_0([2.28.0], [],
 261   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 262   [gmodule-no-export]
 263 )
 264
 265 # Checks for library functions.
 266 AC_FUNC_ALLOCA
 267 AC_FUNC_FORK
 268 AC_FUNC_MKTIME
 269 AC_FUNC_MMAP
 270 AC_FUNC_STRERROR_R
 271 AC_FUNC_STRNLEN
 272 AC_CHECK_FUNCS([ \
 273         atexit \
 274         dup2 \
 275         ftruncate \
 276         gethostbyname \
 277         gettimeofday \
 278         localtime_r \
 279         memchr \
 280         memset \
 281         mkdir \
 282         mkdtemp \
 283         munmap \
 284         rmdir \
 285         setenv \
 286         socket \
 287         strchr \
 288         strdup \
 289         strerror \
 290         strndup \
 291         strnlen \
 292         strrchr \
 293         strstr \
 294         strtoul \
 295         strtoull \
 296         tzset \
 297 ])
 298
 299 # AC_FUNC_MALLOC causes problems when cross-compiling.
 300 #AC_FUNC_MALLOC
 301 #AC_FUNC_REALLOC
 302
 303 # Check for fmemopen
 304 AC_CHECK_LIB([c], [fmemopen],
 305   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 306 )
 307
 308 # Check for open_memstream
 309 AC_CHECK_LIB([c], [open_memstream],
 310   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 311 )
 312
 313 # Check for posix_fallocate
 314 AC_CHECK_LIB([c], [posix_fallocate],
 315   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 316 )
 317
 318 ##                 ##
 319 ## User variables  ##
 320 ##                 ##
 321
 322 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 323 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 324 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 325
 326 # BABELTRACE_PLUGINS_DIR: Plugins directory
 327 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 328 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 329
 330 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 331 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 332 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 333
 334 # BABELTRACE_MINIMAL_LOG_LEVEL:
 335 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 336 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 337 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 338        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 339        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 340   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 341 )
 342 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 343
 344 # BABELTRACE_DEV_MODE:
 345 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 346 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 347         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 348 ], [BABELTRACE_DEV_MODE=0])
 349
 350 # BABELTRACE_DEBUG_MODE:
 351 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 352 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 353         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 354 ], [BABELTRACE_DEBUG_MODE=0])
 355
 356
 357 ##                              ##
 358 ## Optionnal features selection ##
 359 ##                              ##
 360
 361 # Python bindings
 362 # Disabled by default
 363 AC_ARG_ENABLE([python-bindings],
 364   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 365   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 366   [enable_python_bindings=unspecified]
 367 )
 368
 369 # Python plugins
 370 # Disabled by default
 371 AC_ARG_ENABLE([python-plugins],
 372   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])]
 373   dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 374 )
 375
 376 # Debug info
 377 # Enabled by default, except on some platforms
 378 AC_ARG_ENABLE([debug-info],
 379   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 380   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 381   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 382 )
 383
 384 # API documentation
 385 # Disabled by default
 386 AC_ARG_ENABLE([api-doc],
 387   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 388   [enable_api_doc=$enableval]
 389 )
 390
 391 # Built-in plugins
 392 # Disabled by default
 393 AC_ARG_ENABLE([built-in-plugins],
 394   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])]
 395   dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 396 )
 397
 398 # Built-in python plugin support
 399 # Disabled by default
 400 AC_ARG_ENABLE([built-in-python-plugin-support],
 401   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])]
 402   dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 403 )
 404
 405 # Man pages
 406 # Enabled by default
 407 AC_ARG_ENABLE([man-pages],
 408   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 409   [], dnl AC_ARG_ENABLE will fill enable_man_pages with the user choice
 410   [enable_man_pages=yes]
 411 )
 412
 413
 414 # Set automake variables for optionnal feature conditionnals in Makefile.am
 415 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 416 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 417 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 418 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 419 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 420 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 421 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 422 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 423
 424 # Set defines for optionnal features conditionnals in the source code
 425
 426 ## jgalar: still used?
 427 AS_IF([test "x$enable_python_plugins" = xyes],
 428   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 429 )
 430
 431 AS_IF([test "x$enable_debug_info" = xyes],
 432   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 433 )
 434
 435 AS_IF([test "x$enable_built_in_plugins" = xyes],
 436   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 437 )
 438
 439 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 440   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 441 )
 442
 443 AS_IF([test "x$enable_debug_info" = xyes],
 444   [ENABLE_DEBUG_INFO_VAL=1],
 445   [ENABLE_DEBUG_INFO_VAL=0]
 446 )
 447
 448 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 449
 450 # Check for conflicting Python related features user choices.
 451 AS_IF([test "x$enable_python_plugins" = xyes],
 452   [
 453     AS_IF([test "x$enable_python_bindings" = xunspecified],
 454       [
 455         # --enable-python-plugins was provided but --enable-python-bindings was
 456         # omitted. Turn the Python bindings ON anyway because it's needed to
 457         # use the Python plugins.
 458         enable_python_bindings=yes
 459       ],
 460       [
 461         AS_IF([test "x$enable_python_bindings" = xno],
 462           [
 463             # --enable-python-plugins _and_ --disable-python-bindings were
 464             # used. This is invalid because Python plugins need the Python
 465             # bindings to be useful.
 466             AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
 467           ]
 468         )
 469       ]
 470     )
 471   ]
 472 )
 473
 474 # Check for conflicting optional features user choices
 475
 476 AS_IF([test "x$enable_built_in_plugins" = xyes],
 477   [
 478     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 479     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 480     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 481   ]
 482 )
 483
 484 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 485   [
 486     AS_IF([test "x$enable_python_plugins" != xyes], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 487     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 488     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 489     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 490   ]
 491 )
 492
 493
 494 # Check for optionnal features dependencies
 495
 496 AS_IF([test "x$enable_python_bindings" = xyes],
 497   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 498 )
 499
 500 AM_PATH_PYTHON([3.0], [
 501   AM_PATH_PYTHON_MODULES([PYTHON])
 502
 503   # pythondir is the path where extra modules are to be installed
 504   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 505
 506   # pyexecdir is the path that contains shared objects used by the extra modules
 507   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 508
 509   AS_IF([test -z "$PYTHON_CONFIG"], [
 510     AC_PATH_PROGS([PYTHON_CONFIG],
 511                   [python$PYTHON_VERSION-config python-config],
 512                   [],
 513                   [`dirname $PYTHON`])
 514   ])
 515
 516   AS_IF([test -n "$PYTHON_CONFIG"], [
 517     AS_IF([test -z "$PYTHON_INCLUDE"], [
 518       AC_MSG_CHECKING([Python include flags])
 519       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 520       AC_MSG_RESULT([$PYTHON_INCLUDE])
 521     ])
 522
 523     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 524       AC_MSG_CHECKING([Python library flags])
 525       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 526       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 527         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 528       ])
 529       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 530     ])
 531   ])
 532 ], [:])
 533
 534 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 535 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 536
 537 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 538 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 539
 540 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 541   AS_IF([test "x$have_python_dev" = xno], [
 542     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 543   ])
 544 ])
 545
 546 AS_IF([test "x$enable_debug_info" = xyes],
 547   [
 548     # Check if libelf and libdw are present
 549     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 550     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 551     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 552     ELFUTILS_LIBS="-lelf -ldw"
 553   ]
 554 )
 555 AC_SUBST([ELFUTILS_LIBS])
 556
 557 AS_IF([test "x$enable_api_doc" = "xyes"],
 558   [
 559     DX_DOXYGEN_FEATURE(ON)
 560     DX_DOT_FEATURE(OFF)
 561     DX_HTML_FEATURE(ON)
 562     DX_CHM_FEATURE(OFF)
 563     DX_CHI_FEATURE(OFF)
 564     DX_MAN_FEATURE(OFF)
 565     DX_RTF_FEATURE(OFF)
 566     DX_XML_FEATURE(OFF)
 567     DX_PDF_FEATURE(OFF)
 568     DX_PS_FEATURE(OFF)
 569     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 570     AS_IF([test -z "$DX_DOXYGEN"],
 571           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 572     )
 573   ]
 574 )
 575
 576 have_asciidoc_xmlto=no
 577 warn_prebuilt_man_pages=no
 578
 579 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 580 AC_PATH_PROG([XMLTO], [xmlto], [no])
 581
 582 AS_IF([test "x$enable_man_pages" = "xyes"], [
 583   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 584     AS_IF([test "x$in_git_repo" = "xyes"], [
 585       # this is an error because we're in the Git repo, which
 586       # means the man pages are not already generated for us,
 587       # thus asciixmlto are required because we were asked
 588       # to build the man pages
 589       AC_MSG_ERROR([
 590 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 591 --disable-man-pages to disable building the man pages, in which case
 592 they will not be installed.
 593       ])
 594     ], [
 595       # only warn here: since we're in the tarball, the man
 596       # pages should already be generated at this point, thus
 597       # asciidoc/xmlto are not strictly required
 598       warn_prebuilt_man_pages=yes
 599     ])
 600   ], [
 601     have_asciidoc_xmlto=yes
 602   ])
 603 ])
 604
 605 # export AsciiDoc and xmlto existence
 606 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 607
 608 # a wonderful hack that seems necessary because $libdir is
 609 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 610 # by autoconf when it's not specified by the user
 611 AS_IF([test "x$exec_prefix" = xNONE], [
 612   AS_IF([test "x$prefix" = xNONE], [
 613     PREFIX="$ac_default_prefix"
 614   ], [
 615     PREFIX="$prefix"
 616   ])
 617
 618   LIBDIR="$PREFIX/lib"
 619 ], [
 620   LIBDIR="$libdir"
 621 ])
 622
 623 AC_SUBST(LIBDIR)
 624
 625 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 626 # test).
 627 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 628
 629 # Check that the current size_t matches the size that glib thinks it should
 630 # be. This catches problems on multi-arch where people try to do a 32-bit
 631 # build while pointing at 64-bit glib headers. This is a common error because
 632 # glib.h is not platform specific but it includes glibconfig.h which is and
 633 # is usually installed in a non-standard path.
 634
 635 # Do this before enabling all the warning flags, as the
 636 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 637 # test fail unnecessarily.
 638
 639 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 640 # output. Specifically allow pkg_config_libdir to be able to print the
 641 # error message.
 642 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 643
 644 save_CFLAGS=${CFLAGS}
 645 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 646 AC_COMPILE_IFELSE([
 647   AC_LANG_PROGRAM([dnl
 648 #include <glib.h>
 649 #include <unistd.h>
 650   ], [dnl
 651 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 652   ])
 653 ],[:],[
 654   AC_MSG_ERROR([dnl
 655 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 656 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 657 target.
 658   ])
 659 ])
 660 CFLAGS=${save_CFLAGS}
 661
 662 # Detect C and LD warning flags supported by the compiler.
 663
 664 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
 665 #
 666 # Pass -Werror as an extra flag during the test: this is needed to make the
 667 # -Wunknown-warning-option diagnostic fatal with clang.
 668 AX_APPEND_COMPILE_FLAGS([ dnl
 669                 -Wall dnl
 670                 -Wextra dnl
 671                 -Wstrict-prototypes dnl
 672                 -Wmissing-prototypes dnl
 673                 -Wmissing-declarations dnl
 674                 -Wnull-dereference dnl
 675                 -Wundef dnl
 676                 -Wredundant-decls dnl
 677                 -Wshadow dnl
 678                 -Wjump-misses-init dnl
 679                 -Wtautological-constant-out-of-range-compare dnl
 680                 -Wnested-externs dnl
 681                 -Wwrite-strings dnl
 682                 -Wformat=2 dnl
 683                 -Wno-format-nonliteral dnl
 684                 -Wstrict-aliasing dnl
 685                 -Wmissing-noreturn dnl
 686                 -Winit-self dnl
 687                 -Wduplicated-cond dnl
 688                 -Wduplicated-branches dnl
 689                 -Wlogical-op dnl
 690                 -Wno-unused-parameter dnl
 691                 -Wno-sign-compare dnl
 692                 dnl
 693                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 694                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 695                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 696                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 697                 dnl It's simpler to just disable the warning globally.
 698                 dnl
 699                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 700                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 701                 dnl reproduce the warning using that package.
 702                 dnl
 703                 dnl Ref: https://github.com/swig/swig/issues/1259
 704                 -Wno-cast-function-type dnl
 705                 -Wno-missing-field-initializers dnl
 706         ],
 707         [WARN_CFLAGS],
 708         [-Werror])
 709
 710 # When given, add -Werror to WARN_CFLAGS.
 711 AC_ARG_ENABLE([Werror],
 712         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
 713 )
 714 AS_IF([test "x$enable_Werror" = "xyes"],
 715         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
 716 )
 717
 718 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 719 # written in such a way that it triggers a -Wold-style-definition warning.  So
 720 # this warning always ends up disabled if we put it there, because the test
 721 # program does not build.
 722 #
 723 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 724 # (it is accepted for compatibility although it has no effect), and there is
 725 # not reason to not want it.
 726
 727 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition"
 728
 729 # CFLAGS from AX_APPEND_COMPILE_FLAGS.
 730 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 731
 732 # Done for AM_CFLAGS.
 733 AC_SUBST(AM_CFLAGS)
 734
 735 # Set global CPPFLAGS in AM_CPPFLAGS
 736 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 737 AC_SUBST(AM_CPPFLAGS)
 738
 739 # Add glib to global link libs
 740 LIBS="$LIBS $GLIB_LIBS"
 741
 742 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 743 # to rename babeltrace2.bin to babeltrace2 at install time.
 744 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 745 AC_SUBST(program_transform_name)
 746
 747 AC_CONFIG_FILES([
 748         doc/api/Makefile
 749         doc/api/libbabeltrace2/Doxyfile
 750         doc/api/libbabeltrace2/Makefile
 751         doc/contributing-images/Makefile
 752         doc/Makefile
 753         doc/man/asciidoc-attrs.conf
 754         doc/man/Makefile
 755         include/Makefile
 756         Makefile
 757         src/argpar/Makefile
 758         src/autodisc/Makefile
 759         src/babeltrace2-ctf-writer.pc
 760         src/babeltrace2.pc
 761         src/bindings/Makefile
 762         src/bindings/python/bt2/bt2/version.py
 763         src/bindings/python/bt2/Makefile
 764         src/bindings/python/bt2/setup.py
 765         src/bindings/python/Makefile
 766         src/cli/Makefile
 767         src/common/Makefile
 768         src/compat/Makefile
 769         src/ctfser/Makefile
 770         src/ctf-writer/Makefile
 771         src/fd-cache/Makefile
 772         src/lib/graph/Makefile
 773         src/lib/graph/message/Makefile
 774         src/lib/Makefile
 775         src/lib/plugin/Makefile
 776         src/lib/prio-heap/Makefile
 777         src/lib/trace-ir/Makefile
 778         src/logging/Makefile
 779         src/Makefile
 780         src/plugins/common/Makefile
 781         src/plugins/common/muxing/Makefile
 782         src/plugins/common/param-validation/Makefile
 783         src/plugins/ctf/common/bfcr/Makefile
 784         src/plugins/ctf/common/Makefile
 785         src/plugins/ctf/common/metadata/Makefile
 786         src/plugins/ctf/common/msg-iter/Makefile
 787         src/plugins/ctf/fs-sink/Makefile
 788         src/plugins/ctf/fs-src/Makefile
 789         src/plugins/ctf/lttng-live/Makefile
 790         src/plugins/ctf/Makefile
 791         src/plugins/lttng-utils/debug-info/Makefile
 792         src/plugins/lttng-utils/Makefile
 793         src/plugins/Makefile
 794         src/plugins/text/dmesg/Makefile
 795         src/plugins/text/Makefile
 796         src/plugins/text/pretty/Makefile
 797         src/plugins/text/details/Makefile
 798         src/plugins/utils/counter/Makefile
 799         src/plugins/utils/dummy/Makefile
 800         src/plugins/utils/Makefile
 801         src/plugins/utils/muxer/Makefile
 802         src/plugins/utils/trimmer/Makefile
 803         src/py-common/Makefile
 804         src/python-plugin-provider/Makefile
 805         src/param-parse/Makefile
 806         src/string-format/Makefile
 807         tests/bitfield/Makefile
 808         tests/ctf-writer/Makefile
 809         tests/lib/Makefile
 810         tests/lib/test-plugin-plugins/Makefile
 811         tests/Makefile
 812         tests/param-validation/Makefile
 813         tests/plugins/Makefile
 814         tests/plugins/src.ctf.fs/Makefile
 815         tests/plugins/src.ctf.fs/succeed/Makefile
 816         tests/plugins/sink.ctf.fs/Makefile
 817         tests/plugins/sink.ctf.fs/succeed/Makefile
 818         tests/plugins/flt.lttng-utils.debug-info/Makefile
 819         tests/plugins/flt.utils.muxer/Makefile
 820         tests/plugins/flt.utils.muxer/succeed/Makefile
 821         tests/plugins/flt.utils.trimmer/Makefile
 822         tests/utils/Makefile
 823         tests/utils/tap/Makefile
 824 ])
 825
 826 AC_OUTPUT
 827
 828 #
 829 # Mini-report on what will be built.
 830 #
 831
 832 PPRINT_INIT
 833 PPRINT_SET_INDENT(1)
 834 PPRINT_SET_TS(38)
 835
 836 AS_ECHO
 837
 838 AS_IF([test -n "bt_version_name"], [
 839         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 840 ], [
 841         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 842 ])
 843
 844 AS_ECHO
 845
 846 AS_IF([test -n "$bt_version_description"], [
 847         AS_IF([test -n "$report_fold"], [
 848                 AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
 849         ], [
 850                 AS_ECHO("$bt_version_description")
 851         ])
 852
 853         AS_ECHO
 854 ])
 855
 856 PPRINT_SUBTITLE([System])
 857
 858 # Target architecture we're building for.
 859 target_arch=$host_cpu
 860 [
 861 for f in $CFLAGS; do
 862         if test $f = "-m32"; then
 863                 target_arch="32-bit"
 864         elif test $f = "-m64"; then
 865                 target_arch="64-bit"
 866         fi
 867 done
 868 ]
 869
 870 PPRINT_PROP_STRING([Target architecture], $target_arch)
 871
 872 AS_ECHO
 873 PPRINT_SUBTITLE([Python 3 language support])
 874 test "x$have_python" = "xyes" && value=1 || value=0
 875 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 876 test "x$have_python_dev" = "xyes" && value=1 || value=0
 877 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 878 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 879 PPRINT_PROP_BOOL_CUSTOM([Python bindings], $value, [To enable, use --enable-python-bindings])
 880 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 881 PPRINT_PROP_BOOL_CUSTOM([Python plugin support], $value, [To enable, use --enable-python-plugins])
 882 AS_IF([test "x$have_python" = "xyes"], [
 883   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 884 ])
 885 AS_IF([test "x$have_python_dev" = "xyes"], [
 886   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 887   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 888   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 889 ])
 890 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 891   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 892   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 893 ])
 894
 895 AS_ECHO
 896 PPRINT_SUBTITLE([Plugins])
 897 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 898 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 899 PPRINT_PROP_BOOL_CUSTOM(['lttng-utils' plugin], $value, [To enable, use --enable-debug-info])
 900 PPRINT_PROP_BOOL(['text' plugin], 1)
 901 PPRINT_PROP_BOOL(['utils' plugin], 1)
 902
 903 AS_ECHO
 904 PPRINT_SUBTITLE([Built-in features])
 905 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 906 PPRINT_PROP_BOOL_CUSTOM([Built-in plugins], $value, [To enable, use --enable-built-in-plugins])
 907 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 908 PPRINT_PROP_BOOL_CUSTOM([Built-in Python plugin support], $value, [To enable, use --enable-built-in-python-plugin-support])
 909
 910 AS_ECHO
 911 PPRINT_SUBTITLE([Documentation])
 912
 913 # man pages build enabled/disabled
 914 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 915
 916 AS_IF([test "x$enable_man_pages" != "xno"], [
 917   AS_IF([test "x$in_git_repo" = "xyes"], [
 918     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 919   ], [
 920     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 921       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 922     ], [
 923       PPRINT_PROP_STRING([build_man_pages_msg],
 924         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 925         $PPRINT_COLOR_SUBTITLE)
 926     ])
 927   ])
 928 ], [
 929   PPRINT_PROP_BOOL_CUSTOM([build_man_pages_msg], 0, [To build man pages, use --enable-man-pages])
 930 ])
 931
 932 m4_popdef([build_man_pages_msg])
 933
 934 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 935 PPRINT_PROP_BOOL_CUSTOM([HTML API documentation], $value, [To build documentation, use --enable-api-doc])
 936
 937 AS_ECHO
 938 PPRINT_SUBTITLE([Logging])
 939 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 940
 941 AS_ECHO
 942 PPRINT_SUBTITLE([Special build modes])
 943 PPRINT_PROP_BOOL_CUSTOM([Debug mode], $BABELTRACE_DEBUG_MODE, [To enable, set the BABELTRACE_DEBUG_MODE environment variable to 1])
 944 PPRINT_PROP_BOOL_CUSTOM([Developer mode], $BABELTRACE_DEV_MODE, [To enable, set the BABELTRACE_DEV_MODE environment variable to 1])
 945
 946 report_bindir="`eval eval echo $bindir`"
 947 report_libdir="`eval eval echo $libdir`"
 948 report_sysconfdif="`eval eval echo $sysconfdir`"
 949 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 950 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 951
 952 # Print the bindir and libdir this `make install' will install into.
 953 AS_ECHO
 954 PPRINT_SUBTITLE([Install directories])
 955 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 956 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 957 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 958 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 959 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])