configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  41 LIBS="$PTHREAD_LIBS $LIBS"
  42 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  43 CC="$PTHREAD_CC"
  44
  45 # Check linker option
  46 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  47 AC_SUBST([LD_NO_AS_NEEDED])
  48
  49 AC_HEADER_STDBOOL
  50 AC_CHECK_HEADERS([ \
  51         fcntl.h \
  52         float.h \
  53         libintl.h \
  54         limits.h \
  55         malloc.h \
  56         netdb.h \
  57         netinet/in.h \
  58         stddef.h \
  59         sys/socket.h \
  60 ])
  61
  62 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  63         if test x"$(basename "$YACC")" != "xbison -y"; then
  64                 AC_MSG_ERROR([[bison not found and is required when building from git.
  65                 Please install bison]])
  66         fi
  67         AC_PATH_PROG([BISON],[bison])
  68         AX_PROG_BISON_VERSION([2.4], [],[
  69                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  70         ])
  71 fi
  72
  73 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  74         if test x"$LEX" != "xflex"; then
  75                 AC_MSG_ERROR([[flex not found and is required when building from git.
  76                 Please install flex]])
  77         fi
  78         AC_PATH_PROG([FLEX],[flex])
  79         AX_PROG_FLEX_VERSION([2.5.35], [],[
  80                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  81         ])
  82 fi
  83
  84
  85 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  86
  87 # Check what libraries are required on this platform to link sockets programs.
  88 AX_LIB_SOCKET_NSL
  89
  90 # Checks for typedefs, structures, and compiler characteristics.
  91 AC_C_INLINE
  92 AC_TYPE_PID_T
  93 AC_TYPE_SIZE_T
  94 AC_TYPE_INT16_T
  95 AC_TYPE_INT32_T
  96 AC_TYPE_INT64_T
  97 AC_TYPE_INT8_T
  98 AC_TYPE_OFF_T
  99 AC_TYPE_SSIZE_T
 100 AC_TYPE_UINT16_T
 101 AC_TYPE_UINT32_T
 102 AC_TYPE_UINT64_T
 103 AC_TYPE_UINT8_T
 104
 105 # Checks for library functions.
 106 AC_FUNC_ALLOCA
 107 AC_FUNC_FORK
 108 AC_FUNC_MALLOC
 109 AC_FUNC_MKTIME
 110 AC_FUNC_MMAP
 111 AC_FUNC_REALLOC
 112 AC_FUNC_STRERROR_R
 113 AC_CHECK_FUNCS([ \
 114         atexit \
 115         dirfd \
 116         dup2 \
 117         ftruncate \
 118         gethostbyname \
 119         gethostname \
 120         gettimeofday \
 121         localtime_r \
 122         memchr \
 123         memset \
 124         mkdir \
 125         mkdtemp \
 126         munmap \
 127         rmdir \
 128         setenv \
 129         socket \
 130         strchr \
 131         strdup \
 132         strerror \
 133         strndup \
 134         strnlen \
 135         strrchr \
 136         strtoul \
 137         strtoull \
 138         tzset \
 139         uname \
 140 ])
 141
 142 MINGW32=no
 143 DEFAULT_ENABLE_DEBUGINFO=yes
 144 AS_CASE([$host_os],
 145   [solaris*|darwin*],
 146     [
 147         DEFAULT_ENABLE_DEBUGINFO=no
 148     ],
 149   [mingw*],
 150     [
 151         MINGW32=yes
 152     ]
 153 )
 154
 155 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 156
 157 # Check for uuid in system libs
 158 AC_CHECK_FUNCS([uuid_generate],
 159 [
 160   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 161   link_with_libuuid=no
 162 ],
 163 [
 164   # Check for libuuid
 165   AC_CHECK_LIB([uuid], [uuid_generate],
 166   [
 167     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 168     link_with_libuuid=yes
 169   ],
 170   [
 171     # libuuid not found, check for uuid_create in libc.
 172     AC_CHECK_LIB([c], [uuid_create],
 173     [
 174       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 175       link_with_libc_uuid=yes
 176     ],
 177     [
 178       # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 179       if test "x$MINGW32" = xno; then
 180         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 181       fi
 182     ])
 183   ])
 184 ])
 185
 186 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 187 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 188
 189 # Check for fmemopen
 190 AC_CHECK_LIB([c], [fmemopen],
 191 [
 192         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 193 ]
 194 )
 195
 196 # Check for open_memstream
 197 AC_CHECK_LIB([c], [open_memstream],
 198 [
 199         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 200 ]
 201 )
 202
 203 # Check for posix_fallocate
 204 AC_CHECK_LIB([c], [posix_fallocate],
 205 [
 206         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 207 ]
 208 )
 209
 210 # Check for faccessat
 211 AC_CHECK_LIB([c], [faccessat],
 212 [
 213         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 214 ]
 215 )
 216
 217 AC_CHECK_LIB([popt], [poptGetContext], [],
 218         [AC_MSG_ERROR([Cannot find popt.])]
 219 )
 220
 221 # For Python
 222 # SWIG version needed or newer:
 223 swig_version=2.0.0
 224
 225 AC_ARG_ENABLE([python-bindings],
 226               [AC_HELP_STRING([--enable-python-bindings],
 227                               [generate Python bindings])],
 228               [enable_python=yes], [enable_python=no])
 229
 230 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 231
 232 AC_ARG_ENABLE([python-bindings-doc],
 233               [AC_HELP_STRING([--enable-python-bindings-doc],
 234                               [generate Python bindings documentation])],
 235               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 236
 237 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 238   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 239 fi
 240
 241 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 242
 243 if test "x${enable_python:-yes}" = xyes; then
 244   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 245   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 246
 247   AM_PATH_PYTHON_MODULES([PYTHON])
 248   # pythondir is the path where extra modules are to be installed
 249   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 250   # pyexecdir is the path that contains shared objects used by the extra modules
 251   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 252   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 253   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 254   AS_IF([test -z "$PYTHON_INCLUDE"], [
 255     AS_IF([test -z "$PYTHON_CONFIG"], [
 256       AC_PATH_PROGS([PYTHON_CONFIG],
 257                     [python$PYTHON_VERSION-config python-config],
 258                     [no],
 259                     [`dirname $PYTHON`])
 260       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 261     ])
 262     AC_MSG_CHECKING([python include flags])
 263     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 264     AC_MSG_RESULT([$PYTHON_INCLUDE])
 265   ])
 266 else
 267     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 268 [if you want Python bindings.])
 269
 270 fi
 271
 272 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 273     AM_CHECK_PYTHON_SPHINX([PYTHON])
 274     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 275       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 276     )
 277 fi
 278
 279 # Optional debuginfo feature (enabled by default)
 280 AS_IF([test "x$DEFAULT_ENABLE_DEBUGINFO" = xyes],
 281     [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--disable-debug-info], [disable the debug-info feature (default on OS X and Solaris)])], [], [enable_debuginfo=yes])],
 282     [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--enable-debug-info], [enable the debug-info feature (default on Linux)])], [], [enable_debuginfo=no])]
 283 )
 284
 285 AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
 286 AS_IF([test "x$enable_debuginfo" = xyes], [
 287             # Check if libelf and libdw are present
 288             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
 289             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
 290             AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug-info feature. You can disable this feature using --disable-debuginfo.)])
 291             AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debug-info' feature])
 292 ], [])
 293
 294 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 295 AC_SUBST(PACKAGE_LIBS)
 296
 297 LIBS="$LIBS $GMODULE_LIBS"
 298 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 299 AC_SUBST(PACKAGE_CFLAGS)
 300
 301 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 302 AC_SUBST(DEFAULT_INCLUDES)
 303
 304 babeltraceincludedir="${includedir}/babeltrace"
 305 AC_SUBST(babeltraceincludedir)
 306
 307 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 308 AC_SUBST(babeltracectfincludedir)
 309
 310 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 311 AC_SUBST(babeltracectfwriterincludedir)
 312
 313 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 314 AC_SUBST(babeltracectfirincludedir)
 315
 316 AC_CONFIG_FILES([
 317         Makefile
 318         types/Makefile
 319         compat/Makefile
 320         formats/Makefile
 321         formats/ctf/Makefile
 322         formats/ctf/types/Makefile
 323         formats/ctf-text/Makefile
 324         formats/ctf-text/types/Makefile
 325         formats/ctf-metadata/Makefile
 326         formats/bt-dummy/Makefile
 327         formats/lttng-live/Makefile
 328         formats/ctf/metadata/Makefile
 329         formats/ctf/writer/Makefile
 330         formats/ctf/ir/Makefile
 331         converter/Makefile
 332         doc/Makefile
 333         doc/bindings/Makefile
 334         doc/bindings/python/Makefile
 335         doc/images/Makefile
 336         lib/Makefile
 337         lib/prio_heap/Makefile
 338         include/Makefile
 339         bindings/Makefile
 340         bindings/python/Makefile
 341         tests/Makefile
 342         tests/bin/Makefile
 343         tests/lib/Makefile
 344         tests/utils/Makefile
 345         tests/utils/tap/Makefile
 346         extras/Makefile
 347         extras/valgrind/Makefile
 348         babeltrace.pc
 349         babeltrace-ctf.pc
 350 ])
 351
 352 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 353 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 354 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 355 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 356 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 357
 358 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 359 AC_CONFIG_FILES([tests/bin/test_intersection], [chmod +x tests/bin/test_intersection])
 360 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 361
 362 AC_OUTPUT
 363
 364 #
 365 # Mini-report on what will be built.
 366 #
 367
 368 PPRINT_INIT
 369 PPRINT_SET_INDENT(1)
 370 PPRINT_SET_TS(38)
 371
 372 AS_ECHO
 373 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 374 AS_ECHO
 375
 376 PPRINT_SUBTITLE([Features])
 377
 378 # Target architecture we're building for.
 379 target_arch=$host_cpu
 380 [
 381 for f in $CFLAGS; do
 382         if test $f = "-m32"; then
 383                 target_arch="32-bit"
 384         elif test $f = "-m64"; then
 385                 target_arch="64-bit"
 386         fi
 387 done
 388 ]
 389 PPRINT_PROP_STRING([Target architecture], $target_arch)
 390
 391 # python bindings enabled/disabled
 392 test "x$enable_python" = "xyes" && value=1 || value=0
 393 PPRINT_PROP_BOOL([Python bindings], $value)
 394
 395 # python bindings doc enabled/disabled
 396 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 397 PPRINT_PROP_BOOL([Python bindings doc], $value)
 398
 399 # debug-info enabled/disabled
 400 test "x$enable_debuginfo" = "xyes" && value=1 || value=0
 401 PPRINT_PROP_BOOL([Debug information output], $value)
 402
 403
 404 report_bindir="`eval eval echo $bindir`"
 405 report_libdir="`eval eval echo $libdir`"
 406
 407 # Print the bindir and libdir this `make install' will install into.
 408 AS_ECHO
 409 PPRINT_SUBTITLE([Install directories])
 410 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 411 PPRINT_PROP_STRING([Libraries], [$report_libdir])