configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [0])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_extra], [-pre6])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
  34
  35 AC_INIT([babeltrace], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  36
  37 # Following the numbering scheme proposed by libtool for the library version
  38 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  39 m4_define([bt_lib_version_current], [0])
  40 m4_define([bt_lib_version_revision], [0])
  41 m4_define([bt_lib_version_age], [0])
  42 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  43
  44 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  45
  46 AC_CONFIG_HEADERS([src/common/config.h])
  47 AC_CONFIG_AUX_DIR([config])
  48 AC_CONFIG_MACRO_DIR([m4])
  49 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  50
  51 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  52 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  53 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  54 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace extra version])
  55
  56 AC_CANONICAL_TARGET
  57 AC_CANONICAL_HOST
  58
  59
  60 ##                     ##
  61 ## Automake base setup ##
  62 ##                     ##
  63
  64 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 # Enable silent rules if available (Introduced in AM 1.11)
  68 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  69
  70
  71 ##                      ##
  72 ## OS specific defaults ##
  73 ##                      ##
  74
  75 MINGW32=no
  76 DEFAULT_ENABLE_DEBUG_INFO=yes
  77 LT_NO_UNDEFINED=""
  78 AS_CASE([$host_os],
  79   [solaris*|darwin*],
  80     [
  81         DEFAULT_ENABLE_DEBUG_INFO=no
  82     ],
  83   [cygwin*],
  84     [
  85         DEFAULT_ENABLE_DEBUG_INFO=no
  86         LT_NO_UNDEFINED="-no-undefined"
  87     ],
  88   [mingw*],
  89     [
  90         MINGW32=yes
  91         DEFAULT_ENABLE_DEBUG_INFO=no
  92         LT_NO_UNDEFINED="-no-undefined"
  93     ]
  94 )
  95
  96 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  97 AC_SUBST(LT_NO_UNDEFINED)
  98
  99
 100 ##                   ##
 101 ## C compiler checks ##
 102 ##                   ##
 103
 104 AC_USE_SYSTEM_EXTENSIONS
 105 AC_SYS_LARGEFILE
 106
 107 # Choose the c compiler
 108 AC_PROG_CC
 109
 110 # Make sure the c compiler supports C99
 111 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 112
 113 # Make sure the c compiler supports __attributes__
 114 AX_C___ATTRIBUTE__
 115 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 116   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 117
 118 # Make sur we have pthread support
 119 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 120
 121 # Checks for typedefs, structures, and compiler characteristics.
 122 AC_C_INLINE
 123 AC_C_TYPEOF
 124 AC_TYPE_PID_T
 125 AC_TYPE_SIZE_T
 126 AC_TYPE_INT16_T
 127 AC_TYPE_INT32_T
 128 AC_TYPE_INT64_T
 129 AC_TYPE_INT8_T
 130 AC_TYPE_OFF_T
 131 AC_TYPE_SSIZE_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138
 139 ##               ##
 140 ## Header checks ##
 141 ##               ##
 142
 143 AC_HEADER_STDBOOL
 144 AC_CHECK_HEADERS([ \
 145         fcntl.h \
 146         float.h \
 147         ftw.h \
 148         libintl.h \
 149         limits.h \
 150         malloc.h \
 151         netdb.h \
 152         netinet/in.h \
 153         stddef.h \
 154         sys/socket.h \
 155         sys/time.h
 156 ])
 157
 158
 159 ##               ##
 160 ## Linker checks ##
 161 ##               ##
 162
 163 # Check if the linker supports no-as-needed
 164 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 165 AC_SUBST([LD_NO_AS_NEEDED])
 166
 167 # Check if the linker supports whole-archive
 168 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 169   [
 170     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 171     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 172   ],[
 173     # Fallback to force_load for the macOS linker
 174     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 175       [
 176         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 177         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 178       ],[
 179         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 180       ]
 181     )
 182   ]
 183 )
 184
 185 # Initialize and configure libtool
 186 LT_INIT([win32-dll])
 187
 188
 189 ##                 ##
 190 ## Programs checks ##
 191 ##                 ##
 192
 193 AC_PROG_MAKE_SET
 194 AC_PROG_MKDIR_P
 195 AC_PROG_LN_S
 196
 197 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 198 # is not distributed in tarballs
 199 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 200 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 201
 202 # check for bison
 203 AC_PROG_YACC
 204 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 205
 206 AS_IF([test "x$have_bison" != "xyes"], [
 207   AS_IF([test "x$in_git_repo" = "xyes"], [
 208     AC_MSG_FAILURE([dnl
 209 Bison >= 2.4 is required when building from the Git repository. You can
 210 set the YACC variable to override automatic detection.
 211     ])
 212   ], [
 213     AC_MSG_WARN([dnl
 214 Missing Bison >= 2.4. Note that the parser files are already built in
 215 this distribution tarball, so Bison is only needed if you intend to
 216 modify their sources. You can set the YACC variable to override automatic
 217 detection.
 218     ])
 219   ])
 220 ])
 221 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 222
 223 # check for flex
 224 AC_PROG_LEX
 225 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 226
 227 AS_IF([test "x$have_flex" != "xyes"], [
 228   AS_IF([test "x$in_git_repo" = "xyes"], [
 229     AC_MSG_FAILURE([dnl
 230 Flex >= 2.5.35 is required when building from the Git repository. You can
 231 set the LEX variable to override automatic detection.
 232     ])
 233   ], [
 234     AC_MSG_WARN([dnl
 235 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 236 this distribution tarball, so Flex is only needed if you intend to
 237 modify their sources. You can set the LEX variable to override automatic
 238 detection.
 239     ])
 240   ])
 241 ])
 242 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 243
 244
 245 ##                ##
 246 ## Library checks ##
 247 ##                ##
 248
 249 # Check what libraries are required on this platform to link sockets programs.
 250 AX_LIB_SOCKET_NSL
 251
 252 # Check for glib >= 2.22 with gmodule support
 253 AM_PATH_GLIB_2_0([2.22.0], [],
 254   AC_MSG_ERROR([glib >= 2.22 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 255   [gmodule-no-export]
 256 )
 257
 258 # Checks for library functions.
 259 AC_FUNC_ALLOCA
 260 AC_FUNC_FORK
 261 AC_FUNC_MKTIME
 262 AC_FUNC_MMAP
 263 AC_FUNC_STRERROR_R
 264 AC_FUNC_STRNLEN
 265 AC_CHECK_FUNCS([ \
 266         atexit \
 267         dup2 \
 268         ftruncate \
 269         gethostbyname \
 270         gettimeofday \
 271         localtime_r \
 272         memchr \
 273         memset \
 274         mkdir \
 275         mkdtemp \
 276         munmap \
 277         rmdir \
 278         setenv \
 279         socket \
 280         strchr \
 281         strdup \
 282         strerror \
 283         strndup \
 284         strnlen \
 285         strrchr \
 286         strstr \
 287         strtoul \
 288         strtoull \
 289         tzset \
 290 ])
 291
 292 # AC_FUNC_MALLOC causes problems when cross-compiling.
 293 #AC_FUNC_MALLOC
 294 #AC_FUNC_REALLOC
 295
 296 # Check for fmemopen
 297 AC_CHECK_LIB([c], [fmemopen],
 298   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 299 )
 300
 301 # Check for open_memstream
 302 AC_CHECK_LIB([c], [open_memstream],
 303   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 304 )
 305
 306 # Check for posix_fallocate
 307 AC_CHECK_LIB([c], [posix_fallocate],
 308   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 309 )
 310
 311 # Check libpopt
 312 PKG_CHECK_MODULES([POPT], [popt],
 313   [
 314     dnl PKG_CHECK_MODULES defines POPT_LIBS
 315   ],
 316   [
 317     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 318     AC_MSG_WARN([Finding libpopt without pkg-config.])
 319     AC_CHECK_LIB([popt],
 320       [poptGetContext],
 321       [POPT_LIBS="-lpopt"],
 322       [
 323         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 324       ]
 325     )
 326   ]
 327 )
 328 AC_SUBST(POPT_LIBS)
 329
 330
 331 ##                 ##
 332 ## User variables  ##
 333 ##                 ##
 334
 335 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 336 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 337 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 338
 339 # BABELTRACE_PLUGINS_DIR: Plugins directory
 340 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 341 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 342
 343 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 344 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 345 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 346
 347 # BABELTRACE_MINIMAL_LOG_LEVEL:
 348 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 349 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 350 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 351        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 352        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 353   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 354 )
 355 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 356
 357 # BABELTRACE_DEV_MODE:
 358 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 359 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 360         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 361 ], [BABELTRACE_DEV_MODE=0])
 362
 363 # BABELTRACE_DEBUG_MODE:
 364 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 365 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 366         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 367 ], [BABELTRACE_DEBUG_MODE=0])
 368
 369
 370 ##                              ##
 371 ## Optionnal features selection ##
 372 ##                              ##
 373
 374 # Python bindings
 375 # Disabled by default
 376 AC_ARG_ENABLE([python-bindings],
 377   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 378   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 379   [enable_python_bindings=no]
 380 )
 381
 382 # Python bindings documentation
 383 # Disabled by default
 384 AC_ARG_ENABLE([python-bindings-doc],
 385   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 386   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 387   [enable_python_bindings_doc=no]
 388 )
 389
 390 # Python plugins
 391 # Disabled by default
 392 AC_ARG_ENABLE([python-plugins],
 393   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])],
 394   [], dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 395   [enable_python_plugins=no]
 396 )
 397
 398 # Debug info
 399 # Enabled by default, except on some platforms
 400 AC_ARG_ENABLE([debug-info],
 401   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 402   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 403   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 404 )
 405
 406 # API documentation
 407 # Disabled by default
 408 AC_ARG_ENABLE([api-doc],
 409   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 410   [enable_api_doc=$enableval],
 411   [enable_api_doc=no]
 412 )
 413
 414 # Built-in plugins
 415 # Disabled by default
 416 AC_ARG_ENABLE([built-in-plugins],
 417   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])],
 418   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 419   [enable_built_in_plugins=no]
 420 )
 421
 422 # Built-in python plugin support
 423 # Disabled by default
 424 AC_ARG_ENABLE([built-in-python-plugin-support],
 425   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])],
 426   [], dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 427   [enable_built_in_python_plugin_support=no]
 428 )
 429
 430 # Man pages
 431 # Enabled by default
 432 AC_ARG_ENABLE([man-pages],
 433   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 434   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 435   [enable_man_pages=yes]
 436 )
 437
 438
 439 # Set automake variables for optionnal feature conditionnals in Makefile.am
 440 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 441 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 442 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 443 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 444 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 445 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 446 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 447 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 448 AM_CONDITIONAL([HAVE_PYTHON], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 449
 450 # Set defines for optionnal features conditionnals in the source code
 451
 452 ## jgalar: still used?
 453 AS_IF([test "x$enable_python_plugins" = xyes],
 454   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 455 )
 456
 457 AS_IF([test "x$enable_debug_info" = xyes],
 458   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 459 )
 460
 461 AS_IF([test "x$enable_built_in_plugins" = xyes],
 462   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 463 )
 464
 465 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 466   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 467 )
 468
 469 AS_IF([test "x$enable_debug_info" = xyes],
 470   [ENABLE_DEBUG_INFO_VAL=1],
 471   [ENABLE_DEBUG_INFO_VAL=0]
 472 )
 473
 474 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 475
 476
 477 # Check for conflicting optional features user choices
 478
 479 AS_IF([test "x$enable_python_bindings" = xno],
 480   [
 481     AS_IF([test "x$enable_python_bindings_doc" = xyes], [AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])])
 482   ]
 483 )
 484
 485 AS_IF([test "x$enable_built_in_plugins" = xyes],
 486   [
 487     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 488     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 489     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 490   ]
 491 )
 492
 493 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 494   [
 495     AS_IF([test "x$enable_python_plugins" = xno], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 496     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 497     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 498     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 499   ]
 500 )
 501
 502
 503 # Check for optionnal features dependencies
 504
 505 AS_IF([test "x$enable_python_bindings" = xyes],
 506   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 507 )
 508
 509 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes],
 510   [
 511   AM_PATH_PYTHON([3.0], [], [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 512
 513   AM_PATH_PYTHON_MODULES([PYTHON])
 514   # pythondir is the path where extra modules are to be installed
 515   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 516   # pyexecdir is the path that contains shared objects used by the extra modules
 517   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 518   AS_IF([test -z "$PYTHON_INCLUDE"], [
 519     AS_IF([test -z "$PYTHON_CONFIG"], [
 520       AC_PATH_PROGS([PYTHON_CONFIG],
 521                     [python$PYTHON_VERSION-config python-config],
 522                     [no],
 523                     [`dirname $PYTHON`])
 524       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Is python-dev installed?])])
 525     ])
 526     AC_MSG_CHECKING([Python include flags])
 527     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 528     AC_MSG_RESULT([$PYTHON_INCLUDE])
 529   ])
 530   AS_IF([test -z "$PYTHON_LDFLAGS"], [
 531     AS_IF([test -z "$PYTHON_CONFIG"], [
 532       AC_PATH_PROGS([PYTHON_CONFIG],
 533                     [python$PYTHON_VERSION-config python-config],
 534                     [no],
 535                     [`dirname $PYTHON`])
 536       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Is python-dev installed?])])
 537     ])
 538     AC_MSG_CHECKING([Python library flags])
 539     PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 540     AC_MSG_RESULT([$PYTHON_LDFLAGS])
 541   ])
 542   ]
 543 )
 544
 545 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 546   [
 547     AM_CHECK_PYTHON_SPHINX([PYTHON])
 548     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 549       [AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])]
 550     )
 551   ]
 552 )
 553
 554 AS_IF([test "x$enable_debug_info" = xyes],
 555   [
 556     # Check if libelf and libdw are present
 557     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 558     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 559     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 560     ELFUTILS_LIBS="-lelf -ldw"
 561   ]
 562 )
 563 AC_SUBST([ELFUTILS_LIBS])
 564
 565 AS_IF([test "x$enable_api_doc" = "xyes"],
 566   [
 567     DX_DOXYGEN_FEATURE(ON)
 568     DX_DOT_FEATURE(OFF)
 569     DX_HTML_FEATURE(ON)
 570     DX_CHM_FEATURE(OFF)
 571     DX_CHI_FEATURE(OFF)
 572     DX_MAN_FEATURE(OFF)
 573     DX_RTF_FEATURE(OFF)
 574     DX_XML_FEATURE(OFF)
 575     DX_PDF_FEATURE(OFF)
 576     DX_PS_FEATURE(OFF)
 577     DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 578     AS_IF([test -z "$DX_DOXYGEN"],
 579           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 580     )
 581   ]
 582 )
 583
 584 have_asciidoc_xmlto=no
 585 warn_prebuilt_man_pages=no
 586
 587 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 588 AC_PATH_PROG([XMLTO], [xmlto], [no])
 589
 590 AS_IF([test "x$enable_man_pages" = "xyes"], [
 591   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 592     AS_IF([test "x$in_git_repo" = "xyes"], [
 593       # this is an error because we're in the Git repo, which
 594       # means the man pages are not already generated for us,
 595       # thus asciixmlto are required because we were asked
 596       # to build the man pages
 597       AC_MSG_ERROR([
 598 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 599 --disable-man-pages to disable building the man pages, in which case
 600 they will not be installed.
 601       ])
 602     ], [
 603       # only warn here: since we're in the tarball, the man
 604       # pages should already be generated at this point, thus
 605       # asciidoc/xmlto are not strictly required
 606       warn_prebuilt_man_pages=yes
 607     ])
 608   ], [
 609     have_asciidoc_xmlto=yes
 610   ])
 611 ])
 612
 613 # export AsciiDoc and xmlto existence
 614 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 615
 616 # a wonderful hack that seems necessary because $libdir is
 617 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 618 # by autoconf when it's not specified by the user
 619 AS_IF([test "x$exec_prefix" = xNONE], [
 620   AS_IF([test "x$prefix" = xNONE], [
 621     PREFIX="$ac_default_prefix"
 622   ], [
 623     PREFIX="$prefix"
 624   ])
 625
 626   LIBDIR="$PREFIX/lib"
 627 ], [
 628   LIBDIR="$libdir"
 629 ])
 630
 631 AC_SUBST(LIBDIR)
 632
 633
 634 # Set global CFLAGS in AM_CFLAGS
 635 AM_CFLAGS="-Wall -Wformat -Werror=implicit-function-declaration $PTHREAD_CFLAGS $GLIB_CFLAGS"
 636 AC_SUBST(AM_CFLAGS)
 637
 638 # Set global CPPFLAGS in AM_CPPFLAGS
 639 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 640 AC_SUBST(AM_CPPFLAGS)
 641
 642 # Add glib to global link libs
 643 LIBS="$LIBS $GLIB_LIBS"
 644
 645 # Check that the current size_t matches the size that glib thinks it should
 646 # be. This catches problems on multi-arch where people try to do a 32-bit
 647 # build while pointing at 64-bit glib headers. This is a common error because
 648 # glib.h is not platform specific but it includes glibconfig.h which is and
 649 # is usually installed in a non-standard path.
 650
 651 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 652 # output. Specifically allow pkg_config_libdir to be able to print the
 653 # error message.
 654 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 655
 656 save_CFLAGS=${CFLAGS}
 657 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 658 AC_COMPILE_IFELSE([
 659   AC_LANG_PROGRAM([dnl
 660 #include <glib.h>
 661 #include <unistd.h>
 662   ], [dnl
 663 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 664   ])
 665 ],[:],[
 666   AC_MSG_ERROR([dnl
 667 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 668 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 669 target.
 670   ])
 671 ])
 672 CFLAGS=${save_CFLAGS}
 673
 674 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 675 # to rename babeltrace2.bin to babeltrace2 at install time.
 676 program_transform_name="s&babeltrace2\.bin&babeltrace2&;s&babeltrace2-log\.bin&babeltrace2-log&;$program_transform_name"
 677 AC_SUBST(program_transform_name)
 678
 679 AC_CONFIG_FILES([
 680         doc/api/Doxyfile
 681         doc/api/Makefile
 682         doc/bindings/Makefile
 683         doc/bindings/python/Makefile
 684         doc/contributing-images/Makefile
 685         doc/Makefile
 686         doc/man/asciidoc-attrs.conf
 687         doc/man/Makefile
 688         include/Makefile
 689         Makefile
 690         src/babeltrace2-ctf-writer.pc
 691         src/babeltrace2.pc
 692         src/bindings/Makefile
 693         src/bindings/python/bt2/bt2/__init__.py
 694         src/bindings/python/bt2/Makefile
 695         src/bindings/python/bt2/setup.py
 696         src/bindings/python/Makefile
 697         src/cli/Makefile
 698         src/common/Makefile
 699         src/compat/Makefile
 700         src/ctfser/Makefile
 701         src/ctf-writer/Makefile
 702         src/fd-cache/Makefile
 703         src/lib/graph/Makefile
 704         src/lib/graph/message/Makefile
 705         src/lib/Makefile
 706         src/lib/plugin/Makefile
 707         src/lib/prio-heap/Makefile
 708         src/lib/trace-ir/Makefile
 709         src/logging/Makefile
 710         src/Makefile
 711         src/plugins/ctf/common/bfcr/Makefile
 712         src/plugins/ctf/common/Makefile
 713         src/plugins/ctf/common/metadata/Makefile
 714         src/plugins/ctf/common/msg-iter/Makefile
 715         src/plugins/ctf/fs-sink/Makefile
 716         src/plugins/ctf/fs-src/Makefile
 717         src/plugins/ctf/lttng-live/Makefile
 718         src/plugins/ctf/Makefile
 719         src/plugins/lttng-utils/debug-info/Makefile
 720         src/plugins/lttng-utils/Makefile
 721         src/plugins/Makefile
 722         src/plugins/text/dmesg/Makefile
 723         src/plugins/text/Makefile
 724         src/plugins/text/pretty/Makefile
 725         src/plugins/text/details/Makefile
 726         src/plugins/utils/counter/Makefile
 727         src/plugins/utils/dummy/Makefile
 728         src/plugins/utils/Makefile
 729         src/plugins/utils/muxer/Makefile
 730         src/plugins/utils/trimmer/Makefile
 731         src/py-common/Makefile
 732         src/python-plugin-provider/Makefile
 733         tests/bitfield/Makefile
 734         tests/ctf-writer/Makefile
 735         tests/lib/Makefile
 736         tests/lib/test-plugin-plugins/Makefile
 737         tests/Makefile
 738         tests/plugins/Makefile
 739         tests/plugins/src.ctf.fs/Makefile
 740         tests/plugins/src.ctf.fs/succeed/Makefile
 741         tests/plugins/sink.ctf.fs/Makefile
 742         tests/plugins/sink.ctf.fs/succeed/Makefile
 743         tests/plugins/flt.lttng-utils.debug-info/Makefile
 744         tests/plugins/flt.utils.trimmer/Makefile
 745         tests/utils/Makefile
 746         tests/utils/tap/Makefile
 747 ])
 748
 749 AC_OUTPUT
 750
 751 #
 752 # Mini-report on what will be built.
 753 #
 754
 755 PPRINT_INIT
 756 PPRINT_SET_INDENT(1)
 757 PPRINT_SET_TS(38)
 758
 759 AS_ECHO
 760 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 761 AS_ECHO
 762
 763 PPRINT_SUBTITLE([System])
 764
 765 # Target architecture we're building for.
 766 target_arch=$host_cpu
 767 [
 768 for f in $CFLAGS; do
 769         if test $f = "-m32"; then
 770                 target_arch="32-bit"
 771         elif test $f = "-m64"; then
 772                 target_arch="64-bit"
 773         fi
 774 done
 775 ]
 776
 777 PPRINT_PROP_STRING([Target architecture], $target_arch)
 778
 779 AS_ECHO
 780 PPRINT_SUBTITLE([Python 3 language support])
 781 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 782 PPRINT_PROP_BOOL([Python bindings], $value)
 783 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 784 PPRINT_PROP_BOOL([Python plugin support], $value)
 785 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 786   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 787   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 788 ])
 789
 790 AS_ECHO
 791 PPRINT_SUBTITLE([Plugins])
 792 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 793 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 794 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 795 PPRINT_PROP_BOOL(['text' plugin], 1)
 796 PPRINT_PROP_BOOL(['utils' plugin], 1)
 797
 798 AS_ECHO
 799 PPRINT_SUBTITLE([Built-in features])
 800 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 801 PPRINT_PROP_BOOL([Built-in plugins], $value)
 802 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 803 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 804
 805 AS_ECHO
 806 PPRINT_SUBTITLE([Documentation])
 807
 808 # man pages build enabled/disabled
 809 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 810
 811 AS_IF([test "x$enable_man_pages" != "xno"], [
 812   AS_IF([test "x$in_git_repo" = "xyes"], [
 813     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 814   ], [
 815     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 816       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 817     ], [
 818       PPRINT_PROP_STRING([build_man_pages_msg],
 819         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 820         $PPRINT_COLOR_SUBTITLE)
 821     ])
 822   ])
 823 ], [
 824   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 825 ])
 826
 827 m4_popdef([build_man_pages_msg])
 828
 829 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 830 PPRINT_PROP_BOOL([HTML API documentation], $value)
 831 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 832 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 833
 834 AS_ECHO
 835 PPRINT_SUBTITLE([Logging])
 836 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 837
 838 AS_ECHO
 839 PPRINT_SUBTITLE([Special build modes])
 840 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 841 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 842
 843 report_bindir="`eval eval echo $bindir`"
 844 report_libdir="`eval eval echo $libdir`"
 845 report_sysconfdif="`eval eval echo $sysconfdir`"
 846 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 847 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 848
 849 # Print the bindir and libdir this `make install' will install into.
 850 AS_ECHO
 851 PPRINT_SUBTITLE([Install directories])
 852 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 853 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 854 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 855 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 856 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])