configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre3])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([include/config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT(win32-dll)
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53
  54 # Check linker option
  55 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  56 AC_SUBST([LD_NO_AS_NEEDED])
  57
  58 AC_HEADER_STDBOOL
  59 AC_CHECK_HEADERS([ \
  60         fcntl.h \
  61         float.h \
  62         ftw.h \
  63         libintl.h \
  64         limits.h \
  65         malloc.h \
  66         netdb.h \
  67         netinet/in.h \
  68         stddef.h \
  69         sys/socket.h \
  70 ])
  71
  72 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  73         if test x"$(basename "$YACC")" != "xbison -y"; then
  74                 AC_MSG_ERROR([[bison not found and is required when building from git.
  75                 Please install bison]])
  76         fi
  77         AC_PATH_PROG([BISON],[bison])
  78         AX_PROG_BISON_VERSION([2.4], [],[
  79                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  80         ])
  81 fi
  82
  83 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  84         if test x"$LEX" != "xflex"; then
  85                 AC_MSG_ERROR([[flex not found and is required when building from git.
  86                 Please install flex]])
  87         fi
  88         AC_PATH_PROG([FLEX],[flex])
  89         AX_PROG_FLEX_VERSION([2.5.35], [],[
  90                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  91         ])
  92 fi
  93
  94
  95 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule-no-export)
  96
  97 # Check what libraries are required on this platform to link sockets programs.
  98 AX_LIB_SOCKET_NSL
  99
 100 # Checks for typedefs, structures, and compiler characteristics.
 101 AC_C_INLINE
 102 AC_TYPE_PID_T
 103 AC_TYPE_SIZE_T
 104 AC_TYPE_INT16_T
 105 AC_TYPE_INT32_T
 106 AC_TYPE_INT64_T
 107 AC_TYPE_INT8_T
 108 AC_TYPE_OFF_T
 109 AC_TYPE_SSIZE_T
 110 AC_TYPE_UINT16_T
 111 AC_TYPE_UINT32_T
 112 AC_TYPE_UINT64_T
 113 AC_TYPE_UINT8_T
 114
 115 # Checks for library functions.
 116 AC_FUNC_ALLOCA
 117 AC_FUNC_FORK
 118 AC_FUNC_MKTIME
 119 AC_FUNC_MMAP
 120 AC_FUNC_STRERROR_R
 121 AC_CHECK_FUNCS([ \
 122         atexit \
 123         dup2 \
 124         ftruncate \
 125         gethostbyname \
 126         gethostname \
 127         gettimeofday \
 128         localtime_r \
 129         memchr \
 130         memset \
 131         mkdir \
 132         mkdtemp \
 133         munmap \
 134         rmdir \
 135         setenv \
 136         socket \
 137         strchr \
 138         strdup \
 139         strerror \
 140         strndup \
 141         strnlen \
 142         strrchr \
 143         strtoul \
 144         strtoull \
 145         tzset \
 146         uname \
 147 ])
 148
 149 # AC_FUNC_MALLOC causes problems when cross-compiling.
 150 #AC_FUNC_MALLOC
 151 #AC_FUNC_REALLOC
 152
 153 MINGW32=no
 154 DEFAULT_ENABLE_DEBUG_INFO=yes
 155 LT_NO_UNDEFINED=""
 156 AS_CASE([$host_os],
 157   [solaris*|darwin*],
 158     [
 159         DEFAULT_ENABLE_DEBUG_INFO=no
 160     ],
 161   [cygwin*],
 162     [
 163         DEFAULT_ENABLE_DEBUG_INFO=no
 164         LT_NO_UNDEFINED="-no-undefined"
 165     ],
 166   [mingw*],
 167     [
 168         MINGW32=yes
 169         DEFAULT_ENABLE_DEBUG_INFO=no
 170         LT_NO_UNDEFINED="-no-undefined"
 171     ]
 172 )
 173
 174 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 175 AC_SUBST(LT_NO_UNDEFINED)
 176
 177 # First, check for uuid in system libs
 178 AH_TEMPLATE([BABELTRACE_HAVE_LIBUUID], [Define if you have libuuid support])
 179 AC_CHECK_FUNCS([uuid_generate],
 180   [
 181     AC_DEFINE([BABELTRACE_HAVE_LIBUUID], [1])
 182     UUID_LIBS=""
 183   ],
 184   [
 185     # Then, check if the pkg-config module is available, otherwise explicitly check
 186     # for libuuid, or uuid support in the C-library.
 187     PKG_CHECK_MODULES([UUID], [uuid],
 188       [
 189         AC_DEFINE([BABELTRACE_HAVE_LIBUUID], [1])
 190         dnl PKG_CHECK_MODULES defines UUID_LIBS
 191       ],
 192       [
 193         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 194         AC_MSG_WARN([Finding libuuid without pkg-config.])
 195         AC_CHECK_LIB([uuid], [uuid_generate],
 196           [
 197             AC_DEFINE([BABELTRACE_HAVE_LIBUUID], [1])
 198             UUID_LIBS="-luuid"
 199           ],
 200           [
 201             # libuuid not found, check for uuid_create in libc.
 202             AC_CHECK_LIB([c], [uuid_create],
 203               [
 204                 AC_DEFINE([BABELTRACE_HAVE_LIBUUID], [1])
 205                 UUID_LIBS="-lc"
 206               ],
 207               [
 208                 # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 209                 if test "x$MINGW32" = xno; then
 210                   AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 211                 fi
 212               ]
 213             )
 214           ]
 215         )
 216       ]
 217     )
 218   ]
 219 )
 220 AC_SUBST(UUID_LIBS)
 221
 222 # Check for fmemopen
 223 AC_CHECK_LIB([c], [fmemopen],
 224 [
 225         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 226 ]
 227 )
 228
 229 # Check for open_memstream
 230 AC_CHECK_LIB([c], [open_memstream],
 231 [
 232         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 233 ]
 234 )
 235
 236 # Check for posix_fallocate
 237 AC_CHECK_LIB([c], [posix_fallocate],
 238 [
 239         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 240 ]
 241 )
 242
 243 # Check libpopt
 244 PKG_CHECK_MODULES([POPT], [popt],
 245   [
 246     dnl PKG_CHECK_MODULES defines POPT_LIBS
 247   ],
 248   [
 249     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 250     AC_MSG_WARN([Finding libpopt without pkg-config.])
 251     AC_CHECK_LIB([popt],
 252       [poptGetContext],
 253       [POPT_LIBS="-lpopt"],
 254       [
 255         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 256       ]
 257     )
 258   ]
 259 )
 260 AC_SUBST(POPT_LIBS)
 261
 262 # Plugins
 263 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 264 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 265
 266 # For Python
 267 # SWIG version needed or newer:
 268 swig_version=2.0.0
 269
 270 AC_ARG_ENABLE([python-bindings],
 271               [AC_HELP_STRING([--enable-python-bindings],
 272                               [generate Python bindings])],
 273               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 274
 275 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 276
 277 AC_ARG_ENABLE(
 278         [python-plugins],
 279         [AC_HELP_STRING(
 280                 [--enable-python-plugins],
 281                 [add support for the Babeltrace library and converter to load Python plugins])
 282         ],
 283         [enable_python_plugins=$enableval],
 284         [enable_python_plugins=no]
 285 )
 286
 287 if test "x${enable_python_bindings:-yes}" = xyes; then
 288   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 289 else
 290     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 291 [if you want Python bindings.])
 292 fi
 293
 294 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 295   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 296
 297   AM_PATH_PYTHON_MODULES([PYTHON])
 298   # pythondir is the path where extra modules are to be installed
 299   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 300   # pyexecdir is the path that contains shared objects used by the extra modules
 301   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 302   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 303   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 304   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 305   AS_IF([test -z "$PYTHON_INCLUDE"], [
 306     AS_IF([test -z "$PYTHON_CONFIG"], [
 307       AC_PATH_PROGS([PYTHON_CONFIG],
 308                     [python$PYTHON_VERSION-config python-config],
 309                     [no],
 310                     [`dirname $PYTHON`])
 311       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 312     ])
 313     AC_MSG_CHECKING([Python include flags])
 314     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 315     AC_MSG_RESULT([$PYTHON_INCLUDE])
 316   ])
 317   AS_IF([test -z "$PYTHON_LIBS"], [
 318     AS_IF([test -z "$PYTHON_CONFIG"], [
 319       AC_PATH_PROGS([PYTHON_CONFIG],
 320                     [python$PYTHON_VERSION-config python-config],
 321                     [no],
 322                     [`dirname $PYTHON`])
 323       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 324     ])
 325     AC_MSG_CHECKING([Python library flags])
 326     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 327     AC_MSG_RESULT([$PYTHON_LIBS])
 328   ])
 329 fi
 330
 331 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 332
 333 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 334 AS_IF(
 335   [test "x$enable_python_plugins" != xno],
 336   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 337 )
 338
 339 AC_ARG_ENABLE([python-bindings-doc],
 340               [AC_HELP_STRING([--enable-python-bindings-doc],
 341                               [generate Python bindings documentation])],
 342               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 343
 344 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 345
 346 AC_ARG_ENABLE([python-bindings-tests],
 347               [AC_HELP_STRING([--enable-python-bindings-tests],
 348                               [test Python bindings])],
 349               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 350
 351 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 352
 353 if test "x${enable_python_bindings:-no}" = xno; then
 354   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 355     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 356   fi
 357
 358   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 359     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 360   fi
 361 fi
 362
 363 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 364     AM_CHECK_PYTHON_SPHINX([PYTHON])
 365     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 366       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 367     )
 368 fi
 369
 370 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 371     AM_CHECK_PYTHON_TAPPY([PYTHON])
 372     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 373         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 374     )
 375 fi
 376
 377 # Set default enable state for debug info.
 378 # The _enable_debug_info variable is prepended with an underscore to
 379 # avoid clashing with the one generated by AC_ARG_ENABLE.
 380 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 381
 382 # Optional debug info feature
 383 # Do _not_ indent the help string below (appears in the configure --help
 384 # output).
 385 AC_ARG_ENABLE([debug-info],
 386 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 387 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 388         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 389
 390 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 391
 392 AS_IF([test "x$_enable_debug_info" = xyes], [
 393         # Check if libelf and libdw are present
 394         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 395         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 396         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 397         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 398 ], [])
 399
 400 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 401 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 402 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 403         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 404         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 405         built_in_plugins=yes
 406         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 407 ])
 408 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 409
 410 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 411 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 412 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 413   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 414   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 415   AS_IF([test "x$enable_python_plugins" = "xno"], [
 416     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 417   ])
 418   built_in_python_plugin_support=yes
 419   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 420 ])
 421 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 422
 423 PKG_CHECK_MODULES(GMODULE, [gmodule-no-export-2.0 >= 2.0.0])
 424
 425 # Logging
 426 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 427 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=VERBOSE])
 428 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 429         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 430 ])
 431 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 432
 433 AM_CFLAGS="-Wall -Wformat $PTHREAD_CFLAGS $GLIB_CFLAGS"
 434 AC_SUBST(AM_CFLAGS)
 435
 436 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 437 AC_SUBST(AM_CPPFLAGS)
 438
 439 LIBS="$GLIB_LIBS"
 440
 441 babeltraceincludedir="${includedir}/babeltrace"
 442 AC_SUBST(babeltraceincludedir)
 443
 444 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 445 AC_SUBST(babeltracectfwriterincludedir)
 446
 447 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 448 AC_SUBST(babeltracectfincludedir)
 449
 450 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 451 AC_SUBST(babeltracectfirincludedir)
 452
 453 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 454 AC_SUBST(babeltracepluginincludedir)
 455
 456 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 457 AC_SUBST(babeltracegraphincludedir)
 458
 459 program_transform_name="s&babeltrace\.bin&babeltrace&;s&babeltrace-log\.bin&babeltrace-log&;$program_transform_name"
 460 AC_SUBST(program_transform_name)
 461
 462 # check for Doxygen
 463 AC_ARG_ENABLE(
 464   [api-doc],
 465   [AC_HELP_STRING(
 466     [--enable-api-doc],
 467     [generate and install HTML API documentation]
 468   )],
 469   [enable_api_doc=$enableval],
 470   [enable_api_doc=no]
 471 )
 472 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 473
 474 AS_IF([test "x$enable_api_doc" = "xyes"], [
 475   DX_DOXYGEN_FEATURE(ON)
 476   DX_DOT_FEATURE(OFF)
 477   DX_HTML_FEATURE(ON)
 478   DX_CHM_FEATURE(OFF)
 479   DX_CHI_FEATURE(OFF)
 480   DX_MAN_FEATURE(OFF)
 481   DX_RTF_FEATURE(OFF)
 482   DX_XML_FEATURE(OFF)
 483   DX_PDF_FEATURE(OFF)
 484   DX_PS_FEATURE(OFF)
 485   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 486 ])
 487
 488         #TODO: removed, work in progress
 489         #bindings/python/Makefile
 490         #bindings/python/babeltrace/Makefile
 491         #bindings/python/bt2/Makefile
 492         #bindings/python/bt2/__init__.py
 493 AC_CONFIG_FILES([
 494         Makefile
 495         common/Makefile
 496         compat/Makefile
 497         cli/Makefile
 498         doc/Makefile
 499         doc/api/Makefile
 500         doc/api/Doxyfile
 501         doc/bindings/Makefile
 502         doc/bindings/python/Makefile
 503         doc/images/Makefile
 504         lib/Makefile
 505         lib/prio_heap/Makefile
 506         lib/plugin/Makefile
 507         lib/graph/Makefile
 508         lib/graph/notification/Makefile
 509         lib/ctf-ir/Makefile
 510         lib/ctf-writer/Makefile
 511         include/Makefile
 512         logging/Makefile
 513         bindings/Makefile
 514         tests/Makefile
 515         tests/cli/Makefile
 516         tests/cli/intersection/Makefile
 517         tests/lib/Makefile
 518         tests/lib/writer/Makefile
 519         tests/lib/test-plugin-plugins/Makefile
 520         tests/utils/Makefile
 521         tests/utils/tap/Makefile
 522         tests/bindings/Makefile
 523         tests/bindings/python/Makefile
 524         tests/bindings/python/bt2/Makefile
 525         tests/plugins/Makefile
 526         extras/Makefile
 527         extras/valgrind/Makefile
 528         plugins/Makefile
 529         plugins/ctf/Makefile
 530         plugins/ctf/common/Makefile
 531         plugins/ctf/common/btr/Makefile
 532         plugins/ctf/common/metadata/Makefile
 533         plugins/ctf/common/notif-iter/Makefile
 534         plugins/ctf/fs-src/Makefile
 535         plugins/ctf/fs-sink/Makefile
 536         plugins/ctf/lttng-live/Makefile
 537         plugins/text/Makefile
 538   plugins/text/dmesg/Makefile
 539         plugins/text/pretty/Makefile
 540         plugins/utils/Makefile
 541         plugins/utils/dummy/Makefile
 542         plugins/utils/counter/Makefile
 543         plugins/utils/trimmer/Makefile
 544         plugins/utils/muxer/Makefile
 545         python-plugin-provider/Makefile
 546         plugins/libctfcopytrace/Makefile
 547         plugins/lttng-utils/Makefile
 548         babeltrace.pc
 549         babeltrace-ctf.pc
 550 ])
 551
 552 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 553 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 554 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 555 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 556 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 557
 558 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 559
 560 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 561 AC_CONFIG_FILES([tests/cli/test_trace_copy], [chmod +x tests/cli/test_trace_copy])
 562 AC_CONFIG_FILES([tests/cli/test_debug_info], [chmod +x tests/cli/test_debug_info])
 563 AC_CONFIG_FILES([tests/cli/test_trimmer], [chmod +x tests/cli/test_trimmer])
 564 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 565 AC_CONFIG_FILES([tests/cli/test_convert_args], [chmod +x tests/cli/test_convert_args])
 566 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 567 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 568 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 569 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 570 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 571
 572 AS_IF([test "x$enable_python" = "xyes"], [
 573         AC_CONFIG_FILES(
 574                 [tests/bindings/python/bt2/testall.sh],
 575                 [chmod +x tests/bindings/python/bt2/testall.sh]
 576         )
 577 ])
 578
 579 AC_OUTPUT
 580
 581 #
 582 # Mini-report on what will be built.
 583 #
 584
 585 PPRINT_INIT
 586 PPRINT_SET_INDENT(1)
 587 PPRINT_SET_TS(38)
 588
 589 AS_ECHO
 590 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 591 AS_ECHO
 592
 593 PPRINT_SUBTITLE([System])
 594
 595 # Target architecture we're building for.
 596 target_arch=$host_cpu
 597 [
 598 for f in $CFLAGS; do
 599         if test $f = "-m32"; then
 600                 target_arch="32-bit"
 601         elif test $f = "-m64"; then
 602                 target_arch="64-bit"
 603         fi
 604 done
 605 ]
 606
 607 PPRINT_PROP_STRING([Target architecture], $target_arch)
 608
 609 AS_ECHO
 610 PPRINT_SUBTITLE([Python 3 language support])
 611 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 612 PPRINT_PROP_BOOL([Python bindings], $value)
 613 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 614 PPRINT_PROP_BOOL([Python plugin support], $value)
 615 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 616   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 617   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 618 ])
 619
 620 AS_ECHO
 621 PPRINT_SUBTITLE([Plugins])
 622 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 623 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 624 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 625 PPRINT_PROP_BOOL(['text' plugin], 1)
 626 PPRINT_PROP_BOOL(['utils' plugin], 1)
 627
 628 AS_ECHO
 629 PPRINT_SUBTITLE([Built-in features])
 630 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 631 PPRINT_PROP_BOOL([Built-in plugins], $value)
 632 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 633 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 634
 635 AS_ECHO
 636 PPRINT_SUBTITLE([Documentation])
 637 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 638 PPRINT_PROP_BOOL([HTML API documentation], $value)
 639 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 640 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 641
 642 AS_ECHO
 643 PPRINT_SUBTITLE([Logging])
 644 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 645
 646 AS_ECHO
 647 PPRINT_SUBTITLE([Testing])
 648 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 649 PPRINT_PROP_BOOL([Python bindings tests], $value)
 650
 651 report_bindir="`eval eval echo $bindir`"
 652 report_libdir="`eval eval echo $libdir`"
 653 report_sysconfdif="`eval eval echo $sysconfdir`"
 654
 655 # Print the bindir and libdir this `make install' will install into.
 656 AS_ECHO
 657 PPRINT_SUBTITLE([Install directories])
 658 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 659 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 660 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 661 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])