configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  41 LIBS="$PTHREAD_LIBS $LIBS"
  42 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  43 CC="$PTHREAD_CC"
  44
  45 # Check linker option
  46 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  47 AC_SUBST([LD_NO_AS_NEEDED])
  48
  49 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  50
  51 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  52         if test x"$YACC" != "xbison -y"; then
  53                 AC_MSG_ERROR([[bison not found and is required when building from git.
  54                 Please install bison]])
  55         fi
  56         AC_PATH_PROG([BISON],[bison])
  57         AX_PROG_BISON_VERSION([2.4], [],[
  58                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  59         ])
  60 fi
  61
  62 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  63         if test x"$LEX" != "xflex"; then
  64                 AC_MSG_ERROR([[flex not found and is required when building from git.
  65                 Please install flex]])
  66         fi
  67         AC_PATH_PROG([FLEX],[flex])
  68         AX_PROG_FLEX_VERSION([2.5.35], [],[
  69                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  70         ])
  71 fi
  72
  73
  74 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  75
  76 # Checks for typedefs, structures, and compiler characteristics.
  77 AC_C_INLINE
  78 AC_TYPE_PID_T
  79 AC_TYPE_SIZE_T
  80 AC_TYPE_INT16_T
  81 AC_TYPE_INT32_T
  82 AC_TYPE_INT64_T
  83 AC_TYPE_INT8_T
  84 AC_TYPE_OFF_T
  85 AC_TYPE_SSIZE_T
  86 AC_TYPE_UINT16_T
  87 AC_TYPE_UINT32_T
  88 AC_TYPE_UINT64_T
  89 AC_TYPE_UINT8_T
  90
  91 # Checks for library functions.
  92 AC_FUNC_MALLOC
  93 AC_FUNC_MMAP
  94 AC_CHECK_FUNCS([ \
  95         gettimeofday munmap strtoul ftruncate gethostbyname \
  96         localtime_r memset mkdir rmdir setenv socket \
  97         strchr strdup strerror strndup strrchr strtoull tzset \
  98         strnlen mkdtemp dirfd \
  99 ])
 100
 101 # Check for MinGW32.
 102 MINGW32=no
 103 case $host in
 104   *-*-mingw*)
 105         MINGW32=yes;;
 106 esac
 107
 108 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 109
 110 # Check what libraries are required on this platform to link sockets programs.
 111 AX_LIB_SOCKET_NSL
 112
 113 # Check for libuuid
 114 AC_CHECK_LIB([uuid], [uuid_generate],
 115 [
 116         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 117         have_libuuid=yes
 118 ],
 119 [
 120         # libuuid not found, check for uuid_create in libc.
 121         AC_CHECK_LIB([c], [uuid_create],
 122         [
 123                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 124                 have_libc_uuid=yes
 125         ],
 126         [
 127                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 128                 if test "x$MINGW32" = xno; then
 129                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 130                 fi
 131         ])
 132 ]
 133 )
 134 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 135 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 136
 137 # Check for fmemopen
 138 AC_CHECK_LIB([c], [fmemopen],
 139 [
 140         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 141 ]
 142 )
 143
 144 # Check for open_memstream
 145 AC_CHECK_LIB([c], [open_memstream],
 146 [
 147         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 148 ]
 149 )
 150
 151 # Check for posix_fallocate
 152 AC_CHECK_LIB([c], [posix_fallocate],
 153 [
 154         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 155 ]
 156 )
 157
 158 # Check for faccessat
 159 AC_CHECK_LIB([c], [faccessat],
 160 [
 161         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 162 ]
 163 )
 164
 165 AC_CHECK_LIB([popt], [poptGetContext], [],
 166         [AC_MSG_ERROR([Cannot find popt.])]
 167 )
 168
 169 # For Python
 170 # SWIG version needed or newer:
 171 swig_version=2.0.0
 172
 173 AC_ARG_ENABLE([python-bindings],
 174               [AC_HELP_STRING([--enable-python-bindings],
 175                               [generate Python bindings])],
 176               [enable_python=yes], [enable_python=no])
 177
 178 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 179
 180 AC_ARG_ENABLE([python-bindings-doc],
 181               [AC_HELP_STRING([--enable-python-bindings-doc],
 182                               [generate Python bindings documentation])],
 183               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 184
 185 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 186   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 187 fi
 188
 189 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 190
 191 if test "x${enable_python:-yes}" = xyes; then
 192   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 193   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 194
 195   AM_PATH_PYTHON_MODULES([PYTHON])
 196   # pythondir is the path where extra modules are to be installed
 197   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 198   # pyexecdir is the path that contains shared objects used by the extra modules
 199   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 200   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 201   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 202   AS_IF([test -z "$PYTHON_INCLUDE"], [
 203     AS_IF([test -z "$PYTHON_CONFIG"], [
 204       AC_PATH_PROGS([PYTHON_CONFIG],
 205                     [python$PYTHON_VERSION-config python-config],
 206                     [no],
 207                     [`dirname $PYTHON`])
 208       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 209     ])
 210     AC_MSG_CHECKING([python include flags])
 211     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 212     AC_MSG_RESULT([$PYTHON_INCLUDE])
 213   ])
 214 else
 215     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 216 [if you want Python bindings.])
 217
 218 fi
 219
 220 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 221     AM_CHECK_PYTHON_SPHINX([PYTHON])
 222     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 223       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 224     )
 225 fi
 226
 227 pkg_modules="gmodule-2.0 >= 2.0.0"
 228 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 229 AC_SUBST(PACKAGE_LIBS)
 230
 231 LIBS="$LIBS $GMODULE_LIBS"
 232 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 233 AC_SUBST(PACKAGE_CFLAGS)
 234
 235 babeltraceincludedir="${includedir}/babeltrace"
 236 AC_SUBST(babeltraceincludedir)
 237
 238 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 239 AC_SUBST(babeltracectfincludedir)
 240
 241 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 242 AC_SUBST(babeltracectfwriterincludedir)
 243
 244 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 245 AC_SUBST(babeltracectfirincludedir)
 246
 247 AC_CONFIG_FILES([
 248         Makefile
 249         types/Makefile
 250         compat/Makefile
 251         formats/Makefile
 252         formats/ctf/Makefile
 253         formats/ctf/types/Makefile
 254         formats/ctf-text/Makefile
 255         formats/ctf-text/types/Makefile
 256         formats/ctf-metadata/Makefile
 257         formats/bt-dummy/Makefile
 258         formats/lttng-live/Makefile
 259         formats/ctf/metadata/Makefile
 260         formats/ctf/writer/Makefile
 261         formats/ctf/ir/Makefile
 262         converter/Makefile
 263         doc/Makefile
 264         doc/bindings/Makefile
 265         doc/bindings/python/Makefile
 266         lib/Makefile
 267         lib/prio_heap/Makefile
 268         include/Makefile
 269         bindings/Makefile
 270         bindings/python/Makefile
 271         tests/Makefile
 272         tests/bin/Makefile
 273         tests/lib/Makefile
 274         tests/utils/Makefile
 275         tests/utils/tap/Makefile
 276         extras/Makefile
 277         extras/valgrind/Makefile
 278         babeltrace.pc
 279         babeltrace-ctf.pc
 280 ])
 281 AC_OUTPUT