configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [2:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 # Checks for C compiler
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26 AC_PROG_CC
  27 AC_PROG_CC_STDC
  28
  29 # Checks for programs.
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32 AC_PROG_YACC
  33 AC_PROG_LEX
  34 AC_PROG_MKDIR_P
  35 AC_PROG_LN_S
  36
  37 AX_C___ATTRIBUTE__
  38 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  39         [:],
  40         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  41
  42 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  43 LIBS="$PTHREAD_LIBS $LIBS"
  44 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  45 CC="$PTHREAD_CC"
  46
  47 # Check linker option
  48 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  49 AC_SUBST([LD_NO_AS_NEEDED])
  50
  51 AC_HEADER_STDBOOL
  52 AC_CHECK_HEADERS([ \
  53         fcntl.h \
  54         float.h \
  55         libintl.h \
  56         limits.h \
  57         malloc.h \
  58         netdb.h \
  59         netinet/in.h \
  60         stddef.h \
  61         sys/socket.h \
  62 ])
  63
  64 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  65         if test x"$(basename "$YACC")" != "xbison -y"; then
  66                 AC_MSG_ERROR([[bison not found and is required when building from git.
  67                 Please install bison]])
  68         fi
  69         AC_PATH_PROG([BISON],[bison])
  70         AX_PROG_BISON_VERSION([2.4], [],[
  71                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  72         ])
  73 fi
  74
  75 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  76         if test x"$LEX" != "xflex"; then
  77                 AC_MSG_ERROR([[flex not found and is required when building from git.
  78                 Please install flex]])
  79         fi
  80         AC_PATH_PROG([FLEX],[flex])
  81         AX_PROG_FLEX_VERSION([2.5.35], [],[
  82                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  83         ])
  84 fi
  85
  86
  87 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  88
  89 # Check what libraries are required on this platform to link sockets programs.
  90 AX_LIB_SOCKET_NSL
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_INT16_T
  97 AC_TYPE_INT32_T
  98 AC_TYPE_INT64_T
  99 AC_TYPE_INT8_T
 100 AC_TYPE_OFF_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UINT16_T
 103 AC_TYPE_UINT32_T
 104 AC_TYPE_UINT64_T
 105 AC_TYPE_UINT8_T
 106
 107 # Checks for library functions.
 108 AC_FUNC_ALLOCA
 109 AC_FUNC_FORK
 110 AC_FUNC_MALLOC
 111 AC_FUNC_MKTIME
 112 AC_FUNC_MMAP
 113 AC_FUNC_REALLOC
 114 AC_FUNC_STRERROR_R
 115 AC_CHECK_FUNCS([ \
 116         atexit \
 117         dirfd \
 118         dup2 \
 119         ftruncate \
 120         gethostbyname \
 121         gethostname \
 122         gettimeofday \
 123         localtime_r \
 124         memchr \
 125         memset \
 126         mkdir \
 127         mkdtemp \
 128         munmap \
 129         rmdir \
 130         setenv \
 131         socket \
 132         strchr \
 133         strdup \
 134         strerror \
 135         strndup \
 136         strnlen \
 137         strrchr \
 138         strtoul \
 139         strtoull \
 140         tzset \
 141         uname \
 142 ])
 143
 144 MINGW32=no
 145 DEFAULT_ENABLE_DEBUG_INFO=yes
 146 AS_CASE([$host_os],
 147   [solaris*|darwin*],
 148     [
 149         DEFAULT_ENABLE_DEBUG_INFO=no
 150     ],
 151   [mingw*],
 152     [
 153         MINGW32=yes
 154     ]
 155 )
 156
 157 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 158
 159 # Check for uuid in system libs
 160 AC_CHECK_FUNCS([uuid_generate],
 161 [
 162   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 163   link_with_libuuid=no
 164 ],
 165 [
 166   # First, check the pkg-config module is available, otherwise explicitly check
 167   # for libuuid, or uuid support in the C-library.
 168   PKG_CHECK_MODULES([UUID], [uuid],
 169   [
 170     LIBS="${UUID_LIBS} ${LIBS}"
 171     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 172     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 173     link_with_libuuid=yes
 174   ],
 175   [
 176     # Check for libuuid
 177     AC_CHECK_LIB([uuid], [uuid_generate],
 178     [
 179       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 180       link_with_libuuid=yes
 181     ],
 182     [
 183       # libuuid not found, check for uuid_create in libc.
 184       AC_CHECK_LIB([c], [uuid_create],
 185       [
 186         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 187         link_with_libc_uuid=yes
 188       ],
 189       [
 190         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 191         if test "x$MINGW32" = xno; then
 192           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 193         fi
 194       ])
 195     ])
 196   ])
 197 ])
 198
 199 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 200 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 201
 202 # Check for fmemopen
 203 AC_CHECK_LIB([c], [fmemopen],
 204 [
 205         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 206 ]
 207 )
 208
 209 # Check for open_memstream
 210 AC_CHECK_LIB([c], [open_memstream],
 211 [
 212         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 213 ]
 214 )
 215
 216 # Check for posix_fallocate
 217 AC_CHECK_LIB([c], [posix_fallocate],
 218 [
 219         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 220 ]
 221 )
 222
 223 # Check for faccessat
 224 AC_CHECK_LIB([c], [faccessat],
 225 [
 226         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 227 ]
 228 )
 229
 230 AC_CHECK_LIB([popt], [poptGetContext], [],
 231         [AC_MSG_ERROR([Cannot find popt.])]
 232 )
 233
 234 # Plugins
 235 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 236 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 237
 238 # For Python
 239 # SWIG version needed or newer:
 240 swig_version=2.0.0
 241
 242 AC_ARG_ENABLE([python-bindings],
 243               [AC_HELP_STRING([--enable-python-bindings],
 244                               [generate Python bindings])],
 245               [enable_python=yes], [enable_python=no])
 246
 247 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 248
 249 AC_ARG_ENABLE([python-bindings-doc],
 250               [AC_HELP_STRING([--enable-python-bindings-doc],
 251                               [generate Python bindings documentation])],
 252               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 253
 254 AC_ARG_ENABLE([python-bindings-tests],
 255               [AC_HELP_STRING([--enable-python-bindings-tests],
 256                               [test Python bindings])],
 257               [enable_python_bindings_tests=yes], [enable_python_bindings_tests=no])
 258
 259 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 260
 261 if test "x${enable_python:-no}" = xno; then
 262   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 263     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 264   fi
 265
 266   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 267     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 268   fi
 269 fi
 270
 271 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 272
 273 if test "x${enable_python:-yes}" = xyes; then
 274   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 275   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 276
 277   AM_PATH_PYTHON_MODULES([PYTHON])
 278   # pythondir is the path where extra modules are to be installed
 279   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 280   # pyexecdir is the path that contains shared objects used by the extra modules
 281   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 282   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 283   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 284   AS_IF([test -z "$PYTHON_INCLUDE"], [
 285     AS_IF([test -z "$PYTHON_CONFIG"], [
 286       AC_PATH_PROGS([PYTHON_CONFIG],
 287                     [python$PYTHON_VERSION-config python-config],
 288                     [no],
 289                     [`dirname $PYTHON`])
 290       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 291     ])
 292     AC_MSG_CHECKING([python include flags])
 293     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 294     AC_MSG_RESULT([$PYTHON_INCLUDE])
 295   ])
 296 else
 297     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 298 [if you want Python bindings.])
 299
 300 fi
 301
 302 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 303     AM_CHECK_PYTHON_SPHINX([PYTHON])
 304     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 305       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 306     )
 307 fi
 308
 309 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 310     AM_CHECK_PYTHON_TAPPY([PYTHON])
 311     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 312         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 313     )
 314 fi
 315
 316 # Set default enable state for debug info.
 317 # The _enable_debug_info variable is prepended with an underscore to
 318 # avoid clashing with the one generated by AC_ARG_ENABLE.
 319 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 320
 321 # Optional debug info feature
 322 # Do _not_ indent the help string below (appears in the configure --help
 323 # output).
 324 AC_ARG_ENABLE([debug-info],
 325 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 326 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 327         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 328
 329 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 330 AS_IF([test "x$_enable_debug_info" = xyes], [
 331             # Check if libelf and libdw are present
 332             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 333             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 334             BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 335             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 336 ], [])
 337
 338 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 339 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 340 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 341         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 342         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 343         built_in_plugins=yes
 344         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 345 ])
 346 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 347
 348 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 349
 350 LIBS="$LIBS $GMODULE_LIBS"
 351 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 352 AC_SUBST(PACKAGE_CFLAGS)
 353
 354 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 355 AC_SUBST(DEFAULT_INCLUDES)
 356
 357 babeltraceincludedir="${includedir}/babeltrace"
 358 AC_SUBST(babeltraceincludedir)
 359
 360 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 361 AC_SUBST(babeltracectfincludedir)
 362
 363 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 364 AC_SUBST(babeltracectfwriterincludedir)
 365
 366 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 367 AC_SUBST(babeltracectfirincludedir)
 368
 369 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 370 AC_SUBST(babeltracepluginincludedir)
 371
 372 babeltracecomponentincludedir="${includedir}/babeltrace/component"
 373 AC_SUBST(babeltracecomponentincludedir)
 374
 375 babeltracecomponentnotifincludedir="${includedir}/babeltrace/component/notification"
 376 AC_SUBST(babeltracecomponentnotifincludedir)
 377
 378 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 379 AC_SUBST(program_transform_name)
 380
 381 # check for Doxygen
 382 AC_ARG_ENABLE(
 383   [api-doc],
 384   [AC_HELP_STRING(
 385     [--enable-api-doc],
 386     [generate and install HTML API documentation]
 387   )],
 388   [enable_api_doc=$enableval],
 389   [enable_api_doc=no]
 390 )
 391 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 392
 393 AS_IF([test "x$enable_api_doc" = "xyes"], [
 394   DX_DOXYGEN_FEATURE(ON)
 395   DX_DOT_FEATURE(OFF)
 396   DX_HTML_FEATURE(ON)
 397   DX_CHM_FEATURE(OFF)
 398   DX_CHI_FEATURE(OFF)
 399   DX_MAN_FEATURE(OFF)
 400   DX_RTF_FEATURE(OFF)
 401   DX_XML_FEATURE(OFF)
 402   DX_PDF_FEATURE(OFF)
 403   DX_PS_FEATURE(OFF)
 404   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 405 ])
 406
 407 AC_CONFIG_FILES([
 408         Makefile
 409         types/Makefile
 410         compat/Makefile
 411         formats/Makefile
 412         formats/ctf/Makefile
 413         formats/ctf/types/Makefile
 414         formats/ctf-text/Makefile
 415         formats/ctf-text/types/Makefile
 416         formats/ctf-metadata/Makefile
 417         formats/bt-dummy/Makefile
 418         formats/lttng-live/Makefile
 419         formats/ctf/metadata/Makefile
 420         formats/ctf/writer/Makefile
 421         formats/ctf/ir/Makefile
 422         converter/Makefile
 423         doc/Makefile
 424         doc/api/Makefile
 425         doc/api/Doxyfile
 426         doc/bindings/Makefile
 427         doc/bindings/python/Makefile
 428         doc/images/Makefile
 429         lib/Makefile
 430         lib/prio_heap/Makefile
 431         lib/plugin/Makefile
 432         lib/component/Makefile
 433         lib/component/notification/Makefile
 434         include/Makefile
 435         bindings/Makefile
 436         bindings/python/Makefile
 437         bindings/python/babeltrace/Makefile
 438         bindings/python/bt2/Makefile
 439         bindings/python/bt2/__init__.py
 440         tests/Makefile
 441         tests/bin/Makefile
 442         tests/bin/intersection/Makefile
 443         tests/lib/Makefile
 444         tests/lib/writer/Makefile
 445         tests/lib/test-plugin-plugins/Makefile
 446         tests/utils/Makefile
 447         tests/utils/tap/Makefile
 448         tests/bindings/Makefile
 449         tests/bindings/python/Makefile
 450         tests/bindings/python/bt2/Makefile
 451         extras/Makefile
 452         extras/valgrind/Makefile
 453         plugins/Makefile
 454         plugins/ctf/Makefile
 455         plugins/ctf/common/Makefile
 456         plugins/ctf/common/btr/Makefile
 457         plugins/ctf/common/metadata/Makefile
 458         plugins/ctf/common/notif-iter/Makefile
 459         plugins/ctf/fs/Makefile
 460         plugins/ctf/lttng-live/Makefile
 461         plugins/muxer/Makefile
 462         plugins/text/Makefile
 463         plugins/trimmer/Makefile
 464         plugins/writer/Makefile
 465         babeltrace.pc
 466         babeltrace-ctf.pc
 467 ])
 468
 469 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 470 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 471 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 472 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 473 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 474 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 475 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 476
 477 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 478 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 479 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 480 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 481 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 482 AC_CONFIG_FILES([tests/bin/test_formats], [chmod +x tests/bin/test_formats])
 483
 484 AS_IF([test "x$enable_python" = "xyes"], [
 485         AC_CONFIG_FILES(
 486                 [tests/bindings/python/bt2/testall.sh],
 487                 [chmod +x tests/bindings/python/bt2/testall.sh]
 488         )
 489 ])
 490
 491 AC_OUTPUT
 492
 493 #
 494 # Mini-report on what will be built.
 495 #
 496
 497 PPRINT_INIT
 498 PPRINT_SET_INDENT(1)
 499 PPRINT_SET_TS(38)
 500
 501 AS_ECHO
 502 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 503 AS_ECHO
 504
 505 PPRINT_SUBTITLE([Features])
 506
 507 # Target architecture we're building for.
 508 target_arch=$host_cpu
 509 [
 510 for f in $CFLAGS; do
 511         if test $f = "-m32"; then
 512                 target_arch="32-bit"
 513         elif test $f = "-m64"; then
 514                 target_arch="64-bit"
 515         fi
 516 done
 517 ]
 518 PPRINT_PROP_STRING([Target architecture], $target_arch)
 519
 520 # API doc
 521 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 522 PPRINT_PROP_BOOL([HTML API documentation], $value)
 523
 524 # python bindings enabled/disabled
 525 test "x$enable_python" = "xyes" && value=1 || value=0
 526 PPRINT_PROP_BOOL([Python bindings], $value)
 527
 528 # python bindings doc enabled/disabled
 529 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 530 PPRINT_PROP_BOOL([Python bindings doc], $value)
 531
 532 # python bindings tests enabled/disabled
 533 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 534 PPRINT_PROP_BOOL([Python bindings tests], $value)
 535
 536 # debug info enabled/disabled
 537 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 538 PPRINT_PROP_BOOL([Debug information output], $value)
 539
 540 # built-in plug-ins enabled/disabled
 541 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 542 PPRINT_PROP_BOOL([Built-in plug-ins], $value)
 543
 544 report_bindir="`eval eval echo $bindir`"
 545 report_libdir="`eval eval echo $libdir`"
 546
 547 # Print the bindir and libdir this `make install' will install into.
 548 AS_ECHO
 549 PPRINT_SUBTITLE([Install directories])
 550 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 551 PPRINT_PROP_STRING([Libraries], [$report_libdir])