configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [0])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_dev_stage], [])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  34 m4_define([bt_version_name], [Amqui])
  35
  36 AC_INIT([babeltrace], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  37 AC_PROG_SED
  38
  39 # Following the numbering scheme proposed by libtool for the library version
  40 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  41 m4_define([bt_lib_version_current], [0])
  42 m4_define([bt_lib_version_revision], [0])
  43 m4_define([bt_lib_version_age], [0])
  44 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  45
  46 bt_version_description="Amqui (/ɒmkwiː/) is a town in eastern Québec, Canada, at the base of the Gaspé peninsula in Bas-Saint-Laurent. Located at the confluence of the Humqui and Matapédia Rivers, its proximity to woodlands makes it a great destination for outdoor activities such as camping, hiking, and mountain biking."
  47 bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
  48
  49 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  50
  51 AC_CONFIG_HEADERS([src/common/config.h])
  52 AC_CONFIG_AUX_DIR([config])
  53 AC_CONFIG_MACRO_DIR([m4])
  54
  55 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  56 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  57 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  58 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  59 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  60 AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
  61
  62 AC_CANONICAL_TARGET
  63 AC_CANONICAL_HOST
  64
  65
  66 ##                     ##
  67 ## Automake base setup ##
  68 ##                     ##
  69
  70 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  71 AM_MAINTAINER_MODE([enable])
  72
  73 # Enable silent rules if available (Introduced in AM 1.11)
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76
  77 ##                      ##
  78 ## OS specific defaults ##
  79 ##                      ##
  80
  81 MINGW32=no
  82 DEFAULT_ENABLE_DEBUG_INFO=yes
  83 LT_NO_UNDEFINED=""
  84 AS_CASE([$host_os],
  85   [solaris*|darwin*],
  86     [
  87         DEFAULT_ENABLE_DEBUG_INFO=no
  88     ],
  89   [cygwin*],
  90     [
  91         DEFAULT_ENABLE_DEBUG_INFO=no
  92         LT_NO_UNDEFINED="-no-undefined"
  93     ],
  94   [mingw*],
  95     [
  96         MINGW32=yes
  97         DEFAULT_ENABLE_DEBUG_INFO=no
  98         LT_NO_UNDEFINED="-no-undefined"
  99     ]
 100 )
 101
 102 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 103 AC_SUBST(LT_NO_UNDEFINED)
 104
 105
 106 ##                   ##
 107 ## C compiler checks ##
 108 ##                   ##
 109
 110 AC_USE_SYSTEM_EXTENSIONS
 111 AC_SYS_LARGEFILE
 112
 113 # Choose the c compiler
 114 AC_PROG_CC
 115
 116 # Make sure the c compiler supports C99
 117 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 118
 119 # Make sure the c compiler supports __attributes__
 120 AX_C___ATTRIBUTE__
 121 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 122   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 123
 124 # Make sur we have pthread support
 125 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 126
 127 # Checks for typedefs, structures, and compiler characteristics.
 128 AC_C_INLINE
 129 AC_C_TYPEOF
 130 AC_TYPE_PID_T
 131 AC_TYPE_SIZE_T
 132 AC_TYPE_INT16_T
 133 AC_TYPE_INT32_T
 134 AC_TYPE_INT64_T
 135 AC_TYPE_INT8_T
 136 AC_TYPE_OFF_T
 137 AC_TYPE_SSIZE_T
 138 AC_TYPE_UINT16_T
 139 AC_TYPE_UINT32_T
 140 AC_TYPE_UINT64_T
 141 AC_TYPE_UINT8_T
 142 AC_CHECK_TYPES([ptrdiff_t])
 143
 144
 145 ##               ##
 146 ## Header checks ##
 147 ##               ##
 148
 149 AC_HEADER_STDBOOL
 150 AC_CHECK_HEADERS([ \
 151         fcntl.h \
 152         float.h \
 153         ftw.h \
 154         libintl.h \
 155         limits.h \
 156         malloc.h \
 157         netdb.h \
 158         netinet/in.h \
 159         stddef.h \
 160         sys/socket.h \
 161         sys/time.h
 162 ])
 163
 164
 165 ##               ##
 166 ## Linker checks ##
 167 ##               ##
 168
 169 # Check if the linker supports no-as-needed
 170 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 171 AC_SUBST([LD_NO_AS_NEEDED])
 172
 173 # Check if the linker supports whole-archive
 174 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 175   [
 176     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 177     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 178   ],[
 179     # Fallback to force_load for the macOS linker
 180     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 181       [
 182         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 183         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 184       ],[
 185         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 186       ]
 187     )
 188   ]
 189 )
 190
 191 # Initialize and configure libtool
 192 LT_INIT([win32-dll])
 193
 194
 195 ##                 ##
 196 ## Programs checks ##
 197 ##                 ##
 198
 199 AC_PROG_MAKE_SET
 200 AC_PROG_MKDIR_P
 201 AC_PROG_LN_S
 202 AC_PATH_PROG([report_fold], [fold])
 203
 204 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 205 # is not distributed in tarballs
 206 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 207 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 208
 209 # check for bison
 210 AC_PROG_YACC
 211 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 212
 213 AS_IF([test "x$have_bison" != "xyes"], [
 214   AS_IF([test "x$in_git_repo" = "xyes"], [
 215     AC_MSG_FAILURE([dnl
 216 Bison >= 2.4 is required when building from the Git repository. You can
 217 set the YACC variable to override automatic detection.
 218     ])
 219   ], [
 220     AC_MSG_WARN([dnl
 221 Missing Bison >= 2.4. Note that the parser files are already built in
 222 this distribution tarball, so Bison is only needed if you intend to
 223 modify their sources. You can set the YACC variable to override automatic
 224 detection.
 225     ])
 226   ])
 227 ])
 228 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 229
 230 # check for flex
 231 AC_PROG_LEX
 232 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 233
 234 AS_IF([test "x$have_flex" != "xyes"], [
 235   AS_IF([test "x$in_git_repo" = "xyes"], [
 236     AC_MSG_FAILURE([dnl
 237 Flex >= 2.5.35 is required when building from the Git repository. You can
 238 set the LEX variable to override automatic detection.
 239     ])
 240   ], [
 241     AC_MSG_WARN([dnl
 242 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 243 this distribution tarball, so Flex is only needed if you intend to
 244 modify their sources. You can set the LEX variable to override automatic
 245 detection.
 246     ])
 247   ])
 248 ])
 249 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 250
 251
 252 ##                ##
 253 ## Library checks ##
 254 ##                ##
 255
 256 # Check what libraries are required on this platform to link sockets programs.
 257 AX_LIB_SOCKET_NSL
 258
 259 # Check for glib >= 2.28 with gmodule support
 260 AM_PATH_GLIB_2_0([2.28.0], [],
 261   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 262   [gmodule-no-export]
 263 )
 264
 265 # Checks for library functions.
 266 AC_FUNC_ALLOCA
 267 AC_FUNC_FORK
 268 AC_FUNC_MKTIME
 269 AC_FUNC_MMAP
 270 AC_FUNC_STRERROR_R
 271 AC_FUNC_STRNLEN
 272 AC_CHECK_FUNCS([ \
 273         atexit \
 274         dup2 \
 275         ftruncate \
 276         gethostbyname \
 277         gettimeofday \
 278         localtime_r \
 279         memchr \
 280         memset \
 281         mkdir \
 282         mkdtemp \
 283         munmap \
 284         rmdir \
 285         setenv \
 286         socket \
 287         strchr \
 288         strdup \
 289         strerror \
 290         strndup \
 291         strnlen \
 292         strrchr \
 293         strstr \
 294         strtoul \
 295         strtoull \
 296         tzset \
 297 ])
 298
 299 # AC_FUNC_MALLOC causes problems when cross-compiling.
 300 #AC_FUNC_MALLOC
 301 #AC_FUNC_REALLOC
 302
 303 # Check for fmemopen
 304 AC_CHECK_LIB([c], [fmemopen],
 305   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 306 )
 307
 308 # Check for open_memstream
 309 AC_CHECK_LIB([c], [open_memstream],
 310   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 311 )
 312
 313 # Check for posix_fallocate
 314 AC_CHECK_LIB([c], [posix_fallocate],
 315   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 316 )
 317
 318 ##                 ##
 319 ## User variables  ##
 320 ##                 ##
 321
 322 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 323 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 324 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 325
 326 # BABELTRACE_PLUGINS_DIR: Plugins directory
 327 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 328 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 329
 330 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 331 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 332 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 333
 334 # BABELTRACE_MINIMAL_LOG_LEVEL:
 335 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 336 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 337 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 338        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 339        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 340   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 341 )
 342 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 343
 344 # BABELTRACE_DEV_MODE:
 345 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 346 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 347         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 348 ], [BABELTRACE_DEV_MODE=0])
 349
 350 # BABELTRACE_DEBUG_MODE:
 351 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 352 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 353         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 354 ], [BABELTRACE_DEBUG_MODE=0])
 355
 356
 357 ##                              ##
 358 ## Optionnal features selection ##
 359 ##                              ##
 360
 361 # Python bindings
 362 # Disabled by default
 363 AC_ARG_ENABLE([python-bindings],
 364   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 365   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 366   [enable_python_bindings=no]
 367 )
 368
 369 # Python bindings documentation
 370 # Disabled by default
 371 AC_ARG_ENABLE([python-bindings-doc],
 372   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 373   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 374   [enable_python_bindings_doc=no]
 375 )
 376
 377 # Python plugins
 378 # Disabled by default
 379 AC_ARG_ENABLE([python-plugins],
 380   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])],
 381   [], dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 382   [enable_python_plugins=no]
 383 )
 384
 385 # Debug info
 386 # Enabled by default, except on some platforms
 387 AC_ARG_ENABLE([debug-info],
 388   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 389   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 390   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 391 )
 392
 393 # API documentation
 394 # Disabled by default
 395 AC_ARG_ENABLE([api-doc],
 396   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 397   [enable_api_doc=$enableval],
 398   [enable_api_doc=no]
 399 )
 400
 401 # Built-in plugins
 402 # Disabled by default
 403 AC_ARG_ENABLE([built-in-plugins],
 404   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])],
 405   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 406   [enable_built_in_plugins=no]
 407 )
 408
 409 # Built-in python plugin support
 410 # Disabled by default
 411 AC_ARG_ENABLE([built-in-python-plugin-support],
 412   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])],
 413   [], dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 414   [enable_built_in_python_plugin_support=no]
 415 )
 416
 417 # Man pages
 418 # Enabled by default
 419 AC_ARG_ENABLE([man-pages],
 420   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 421   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 422   [enable_man_pages=yes]
 423 )
 424
 425
 426 # Set automake variables for optionnal feature conditionnals in Makefile.am
 427 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 428 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 429 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 430 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 431 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 432 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 433 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 434 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 435 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 436
 437 # Set defines for optionnal features conditionnals in the source code
 438
 439 ## jgalar: still used?
 440 AS_IF([test "x$enable_python_plugins" = xyes],
 441   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 442 )
 443
 444 AS_IF([test "x$enable_debug_info" = xyes],
 445   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 446 )
 447
 448 AS_IF([test "x$enable_built_in_plugins" = xyes],
 449   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 450 )
 451
 452 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 453   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 454 )
 455
 456 AS_IF([test "x$enable_debug_info" = xyes],
 457   [ENABLE_DEBUG_INFO_VAL=1],
 458   [ENABLE_DEBUG_INFO_VAL=0]
 459 )
 460
 461 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 462
 463
 464 # Check for conflicting optional features user choices
 465
 466 AS_IF([test "x$enable_python_bindings" = xno],
 467   [
 468     AS_IF([test "x$enable_python_bindings_doc" = xyes], [AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])])
 469   ]
 470 )
 471
 472 AS_IF([test "x$enable_built_in_plugins" = xyes],
 473   [
 474     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 475     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 476     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 477   ]
 478 )
 479
 480 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 481   [
 482     AS_IF([test "x$enable_python_plugins" = xno], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 483     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 484     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 485     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 486   ]
 487 )
 488
 489
 490 # Check for optionnal features dependencies
 491
 492 AS_IF([test "x$enable_python_bindings" = xyes],
 493   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 494 )
 495
 496 AM_PATH_PYTHON([3.0], [
 497   AM_PATH_PYTHON_MODULES([PYTHON])
 498
 499   # pythondir is the path where extra modules are to be installed
 500   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 501
 502   # pyexecdir is the path that contains shared objects used by the extra modules
 503   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 504
 505   AS_IF([test -z "$PYTHON_CONFIG"], [
 506     AC_PATH_PROGS([PYTHON_CONFIG],
 507                   [python$PYTHON_VERSION-config python-config],
 508                   [],
 509                   [`dirname $PYTHON`])
 510   ])
 511
 512   AS_IF([test -n "$PYTHON_CONFIG"], [
 513     AS_IF([test -z "$PYTHON_INCLUDE"], [
 514       AC_MSG_CHECKING([Python include flags])
 515       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 516       AC_MSG_RESULT([$PYTHON_INCLUDE])
 517     ])
 518
 519     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 520       AC_MSG_CHECKING([Python library flags])
 521       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 522       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 523         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 524       ])
 525       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 526     ])
 527   ])
 528 ], [:])
 529
 530 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 531 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 532
 533 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 534 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 535
 536 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 537   AS_IF([test "x$have_python_dev" = xno], [
 538     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 539   ])
 540 ])
 541
 542 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 543   [
 544     AM_CHECK_PYTHON_SPHINX([PYTHON])
 545     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 546       [AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])]
 547     )
 548   ]
 549 )
 550
 551 AS_IF([test "x$enable_debug_info" = xyes],
 552   [
 553     # Check if libelf and libdw are present
 554     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 555     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 556     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 557     ELFUTILS_LIBS="-lelf -ldw"
 558   ]
 559 )
 560 AC_SUBST([ELFUTILS_LIBS])
 561
 562 AS_IF([test "x$enable_api_doc" = "xyes"],
 563   [
 564     DX_DOXYGEN_FEATURE(ON)
 565     DX_DOT_FEATURE(OFF)
 566     DX_HTML_FEATURE(ON)
 567     DX_CHM_FEATURE(OFF)
 568     DX_CHI_FEATURE(OFF)
 569     DX_MAN_FEATURE(OFF)
 570     DX_RTF_FEATURE(OFF)
 571     DX_XML_FEATURE(OFF)
 572     DX_PDF_FEATURE(OFF)
 573     DX_PS_FEATURE(OFF)
 574     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 575     AS_IF([test -z "$DX_DOXYGEN"],
 576           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 577     )
 578   ]
 579 )
 580
 581 have_asciidoc_xmlto=no
 582 warn_prebuilt_man_pages=no
 583
 584 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 585 AC_PATH_PROG([XMLTO], [xmlto], [no])
 586
 587 AS_IF([test "x$enable_man_pages" = "xyes"], [
 588   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 589     AS_IF([test "x$in_git_repo" = "xyes"], [
 590       # this is an error because we're in the Git repo, which
 591       # means the man pages are not already generated for us,
 592       # thus asciixmlto are required because we were asked
 593       # to build the man pages
 594       AC_MSG_ERROR([
 595 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 596 --disable-man-pages to disable building the man pages, in which case
 597 they will not be installed.
 598       ])
 599     ], [
 600       # only warn here: since we're in the tarball, the man
 601       # pages should already be generated at this point, thus
 602       # asciidoc/xmlto are not strictly required
 603       warn_prebuilt_man_pages=yes
 604     ])
 605   ], [
 606     have_asciidoc_xmlto=yes
 607   ])
 608 ])
 609
 610 # export AsciiDoc and xmlto existence
 611 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 612
 613 # a wonderful hack that seems necessary because $libdir is
 614 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 615 # by autoconf when it's not specified by the user
 616 AS_IF([test "x$exec_prefix" = xNONE], [
 617   AS_IF([test "x$prefix" = xNONE], [
 618     PREFIX="$ac_default_prefix"
 619   ], [
 620     PREFIX="$prefix"
 621   ])
 622
 623   LIBDIR="$PREFIX/lib"
 624 ], [
 625   LIBDIR="$libdir"
 626 ])
 627
 628 AC_SUBST(LIBDIR)
 629
 630 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 631 # test).
 632 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 633
 634 # Check that the current size_t matches the size that glib thinks it should
 635 # be. This catches problems on multi-arch where people try to do a 32-bit
 636 # build while pointing at 64-bit glib headers. This is a common error because
 637 # glib.h is not platform specific but it includes glibconfig.h which is and
 638 # is usually installed in a non-standard path.
 639
 640 # Do this before enabling all the warning flags, as the
 641 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 642 # test fail unnecessarily.
 643
 644 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 645 # output. Specifically allow pkg_config_libdir to be able to print the
 646 # error message.
 647 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 648
 649 save_CFLAGS=${CFLAGS}
 650 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 651 AC_COMPILE_IFELSE([
 652   AC_LANG_PROGRAM([dnl
 653 #include <glib.h>
 654 #include <unistd.h>
 655   ], [dnl
 656 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 657   ])
 658 ],[:],[
 659   AC_MSG_ERROR([dnl
 660 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 661 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 662 target.
 663   ])
 664 ])
 665 CFLAGS=${save_CFLAGS}
 666
 667 # Detect C and LD warning flags supported by the compiler.
 668 AX_COMPILER_FLAGS(
 669         [WARN_CFLAGS], dnl CFLAGS variable name
 670         [WARN_LDFLAGS], dnl LDFLAGS variable name (unused for now)
 671         [], dnl is-release
 672         [], dnl Extra base CFLAGS
 673         [ dnl Extra "yes" CFLAGS
 674                 dnl Disable these flags, either because we don't want them
 675                 dnl or because we want them but are not ready to enable them
 676                 dnl yet.
 677                 -Wno-sign-compare dnl
 678                 -Wno-inline dnl
 679                 -Wno-declaration-after-statement dnl
 680                 -Wno-switch-enum dnl
 681                 -Wno-switch-default dnl
 682                 -Wno-packed dnl
 683                 -Wno-pointer-arith dnl
 684                 -Wno-format-nonliteral dnl
 685                 -Wno-double-promotion dnl
 686                 -Wno-cast-align dnl
 687                 dnl
 688                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 689                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 690                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 691                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 692                 dnl It's simpler to just disable the warning globally.
 693                 dnl
 694                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 695                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 696                 dnl reproduce the warning using that package.
 697                 dnl
 698                 dnl Ref: https://github.com/swig/swig/issues/1259
 699                 -Wno-cast-function-type dnl
 700         ])
 701
 702 # CFLAGS from AX_COMPILER_FLAGS.
 703 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 704
 705 # The test used in AX_COMPILER_FLAGS, generated using AC_LANG_PROGRAM, is
 706 # written in such a way that it triggers a -Wold-style-definition warning.  So
 707 # if the user has -Werror in their CFLAGS, that warning flag will end up
 708 # disabled, because the test program will not build.
 709 #
 710 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 711 # (it is accepted for compatibility although it has no effect), and there is
 712 # not reason to not want it.
 713
 714 AM_CFLAGS="${AM_CFLAGS} -Wold-style-definition"
 715
 716 # We want this one to always be an error.
 717 AM_CFLAGS="${AM_CFLAGS} -Werror=implicit-function-declaration"
 718
 719 # Done for AM_CFLAGS.
 720 AC_SUBST(AM_CFLAGS)
 721
 722 # Set global CPPFLAGS in AM_CPPFLAGS
 723 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 724 AC_SUBST(AM_CPPFLAGS)
 725
 726 # Add glib to global link libs
 727 LIBS="$LIBS $GLIB_LIBS"
 728
 729 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 730 # to rename babeltrace2.bin to babeltrace2 at install time.
 731 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 732 AC_SUBST(program_transform_name)
 733
 734 AC_CONFIG_FILES([
 735         doc/api/Makefile
 736         doc/api/libbabeltrace2/Doxyfile
 737         doc/api/libbabeltrace2/Makefile
 738         doc/bindings/Makefile
 739         doc/bindings/python/Makefile
 740         doc/contributing-images/Makefile
 741         doc/Makefile
 742         doc/man/asciidoc-attrs.conf
 743         doc/man/Makefile
 744         include/Makefile
 745         Makefile
 746         src/argpar/Makefile
 747         src/autodisc/Makefile
 748         src/babeltrace2-ctf-writer.pc
 749         src/babeltrace2.pc
 750         src/bindings/Makefile
 751         src/bindings/python/bt2/bt2/version.py
 752         src/bindings/python/bt2/Makefile
 753         src/bindings/python/bt2/setup.py
 754         src/bindings/python/Makefile
 755         src/cli/Makefile
 756         src/common/Makefile
 757         src/compat/Makefile
 758         src/ctfser/Makefile
 759         src/ctf-writer/Makefile
 760         src/fd-cache/Makefile
 761         src/lib/graph/Makefile
 762         src/lib/graph/message/Makefile
 763         src/lib/Makefile
 764         src/lib/plugin/Makefile
 765         src/lib/prio-heap/Makefile
 766         src/lib/trace-ir/Makefile
 767         src/logging/Makefile
 768         src/Makefile
 769         src/plugins/common/Makefile
 770         src/plugins/common/muxing/Makefile
 771         src/plugins/common/param-validation/Makefile
 772         src/plugins/ctf/common/bfcr/Makefile
 773         src/plugins/ctf/common/Makefile
 774         src/plugins/ctf/common/metadata/Makefile
 775         src/plugins/ctf/common/msg-iter/Makefile
 776         src/plugins/ctf/fs-sink/Makefile
 777         src/plugins/ctf/fs-src/Makefile
 778         src/plugins/ctf/lttng-live/Makefile
 779         src/plugins/ctf/Makefile
 780         src/plugins/lttng-utils/debug-info/Makefile
 781         src/plugins/lttng-utils/Makefile
 782         src/plugins/Makefile
 783         src/plugins/text/dmesg/Makefile
 784         src/plugins/text/Makefile
 785         src/plugins/text/pretty/Makefile
 786         src/plugins/text/details/Makefile
 787         src/plugins/utils/counter/Makefile
 788         src/plugins/utils/dummy/Makefile
 789         src/plugins/utils/Makefile
 790         src/plugins/utils/muxer/Makefile
 791         src/plugins/utils/trimmer/Makefile
 792         src/py-common/Makefile
 793         src/python-plugin-provider/Makefile
 794         src/param-parse/Makefile
 795         src/string-format/Makefile
 796         tests/bitfield/Makefile
 797         tests/ctf-writer/Makefile
 798         tests/lib/Makefile
 799         tests/lib/test-plugin-plugins/Makefile
 800         tests/Makefile
 801         tests/param-validation/Makefile
 802         tests/plugins/Makefile
 803         tests/plugins/src.ctf.fs/Makefile
 804         tests/plugins/src.ctf.fs/succeed/Makefile
 805         tests/plugins/sink.ctf.fs/Makefile
 806         tests/plugins/sink.ctf.fs/succeed/Makefile
 807         tests/plugins/flt.lttng-utils.debug-info/Makefile
 808         tests/plugins/flt.utils.muxer/Makefile
 809         tests/plugins/flt.utils.muxer/succeed/Makefile
 810         tests/plugins/flt.utils.trimmer/Makefile
 811         tests/utils/Makefile
 812         tests/utils/tap/Makefile
 813 ])
 814
 815 AC_OUTPUT
 816
 817 #
 818 # Mini-report on what will be built.
 819 #
 820
 821 PPRINT_INIT
 822 PPRINT_SET_INDENT(1)
 823 PPRINT_SET_TS(38)
 824
 825 AS_ECHO
 826
 827 AS_IF([test -n "bt_version_name"], [
 828         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 829 ], [
 830         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 831 ])
 832
 833 AS_ECHO
 834
 835 AS_IF([test -n "$bt_version_description"], [
 836         AS_IF([test -n "$report_fold"], [
 837                 AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
 838         ], [
 839                 AS_ECHO("$bt_version_description")
 840         ])
 841
 842         AS_ECHO
 843 ])
 844
 845 PPRINT_SUBTITLE([System])
 846
 847 # Target architecture we're building for.
 848 target_arch=$host_cpu
 849 [
 850 for f in $CFLAGS; do
 851         if test $f = "-m32"; then
 852                 target_arch="32-bit"
 853         elif test $f = "-m64"; then
 854                 target_arch="64-bit"
 855         fi
 856 done
 857 ]
 858
 859 PPRINT_PROP_STRING([Target architecture], $target_arch)
 860
 861 AS_ECHO
 862 PPRINT_SUBTITLE([Python 3 language support])
 863 test "x$have_python" = "xyes" && value=1 || value=0
 864 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 865 test "x$have_python_dev" = "xyes" && value=1 || value=0
 866 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 867 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 868 PPRINT_PROP_BOOL([Python bindings], $value)
 869 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 870 PPRINT_PROP_BOOL([Python plugin support], $value)
 871 AS_IF([test "x$have_python" = "xyes"], [
 872   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 873 ])
 874 AS_IF([test "x$have_python_dev" = "xyes"], [
 875   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 876   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 877   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 878 ])
 879 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 880   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 881   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 882 ])
 883
 884 AS_ECHO
 885 PPRINT_SUBTITLE([Plugins])
 886 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 887 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 888 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 889 PPRINT_PROP_BOOL(['text' plugin], 1)
 890 PPRINT_PROP_BOOL(['utils' plugin], 1)
 891
 892 AS_ECHO
 893 PPRINT_SUBTITLE([Built-in features])
 894 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 895 PPRINT_PROP_BOOL([Built-in plugins], $value)
 896 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 897 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 898
 899 AS_ECHO
 900 PPRINT_SUBTITLE([Documentation])
 901
 902 # man pages build enabled/disabled
 903 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 904
 905 AS_IF([test "x$enable_man_pages" != "xno"], [
 906   AS_IF([test "x$in_git_repo" = "xyes"], [
 907     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 908   ], [
 909     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 910       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 911     ], [
 912       PPRINT_PROP_STRING([build_man_pages_msg],
 913         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 914         $PPRINT_COLOR_SUBTITLE)
 915     ])
 916   ])
 917 ], [
 918   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 919 ])
 920
 921 m4_popdef([build_man_pages_msg])
 922
 923 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 924 PPRINT_PROP_BOOL([HTML API documentation], $value)
 925 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 926 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 927
 928 AS_ECHO
 929 PPRINT_SUBTITLE([Logging])
 930 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 931
 932 AS_ECHO
 933 PPRINT_SUBTITLE([Special build modes])
 934 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 935 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 936
 937 report_bindir="`eval eval echo $bindir`"
 938 report_libdir="`eval eval echo $libdir`"
 939 report_sysconfdif="`eval eval echo $sysconfdir`"
 940 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 941 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 942
 943 # Print the bindir and libdir this `make install' will install into.
 944 AS_ECHO
 945 PPRINT_SUBTITLE([Install directories])
 946 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 947 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 948 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 949 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 950 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])