configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [0])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_extra], [-pre6])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
  34
  35 AC_INIT([babeltrace], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  36
  37 # Following the numbering scheme proposed by libtool for the library version
  38 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  39 m4_define([bt_lib_version_current], [0])
  40 m4_define([bt_lib_version_revision], [0])
  41 m4_define([bt_lib_version_age], [0])
  42 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  43
  44 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  45
  46 AC_CONFIG_HEADERS([src/common/config.h])
  47 AC_CONFIG_AUX_DIR([config])
  48 AC_CONFIG_MACRO_DIR([m4])
  49
  50 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  51 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  52 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  53 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace extra version])
  54
  55 AC_CANONICAL_TARGET
  56 AC_CANONICAL_HOST
  57
  58
  59 ##                     ##
  60 ## Automake base setup ##
  61 ##                     ##
  62
  63 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  64 AM_MAINTAINER_MODE([enable])
  65
  66 # Enable silent rules if available (Introduced in AM 1.11)
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69
  70 ##                      ##
  71 ## OS specific defaults ##
  72 ##                      ##
  73
  74 MINGW32=no
  75 DEFAULT_ENABLE_DEBUG_INFO=yes
  76 LT_NO_UNDEFINED=""
  77 AS_CASE([$host_os],
  78   [solaris*|darwin*],
  79     [
  80         DEFAULT_ENABLE_DEBUG_INFO=no
  81     ],
  82   [cygwin*],
  83     [
  84         DEFAULT_ENABLE_DEBUG_INFO=no
  85         LT_NO_UNDEFINED="-no-undefined"
  86     ],
  87   [mingw*],
  88     [
  89         MINGW32=yes
  90         DEFAULT_ENABLE_DEBUG_INFO=no
  91         LT_NO_UNDEFINED="-no-undefined"
  92     ]
  93 )
  94
  95 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  96 AC_SUBST(LT_NO_UNDEFINED)
  97
  98
  99 ##                   ##
 100 ## C compiler checks ##
 101 ##                   ##
 102
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Choose the c compiler
 107 AC_PROG_CC
 108
 109 # Make sure the c compiler supports C99
 110 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 111
 112 # Make sure the c compiler supports __attributes__
 113 AX_C___ATTRIBUTE__
 114 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 115   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 116
 117 # Make sur we have pthread support
 118 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 119
 120 # Checks for typedefs, structures, and compiler characteristics.
 121 AC_C_INLINE
 122 AC_C_TYPEOF
 123 AC_TYPE_PID_T
 124 AC_TYPE_SIZE_T
 125 AC_TYPE_INT16_T
 126 AC_TYPE_INT32_T
 127 AC_TYPE_INT64_T
 128 AC_TYPE_INT8_T
 129 AC_TYPE_OFF_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UINT16_T
 132 AC_TYPE_UINT32_T
 133 AC_TYPE_UINT64_T
 134 AC_TYPE_UINT8_T
 135 AC_CHECK_TYPES([ptrdiff_t])
 136
 137
 138 ##               ##
 139 ## Header checks ##
 140 ##               ##
 141
 142 AC_HEADER_STDBOOL
 143 AC_CHECK_HEADERS([ \
 144         fcntl.h \
 145         float.h \
 146         ftw.h \
 147         libintl.h \
 148         limits.h \
 149         malloc.h \
 150         netdb.h \
 151         netinet/in.h \
 152         stddef.h \
 153         sys/socket.h \
 154         sys/time.h
 155 ])
 156
 157
 158 ##               ##
 159 ## Linker checks ##
 160 ##               ##
 161
 162 # Check if the linker supports no-as-needed
 163 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 164 AC_SUBST([LD_NO_AS_NEEDED])
 165
 166 # Check if the linker supports whole-archive
 167 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 168   [
 169     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 170     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 171   ],[
 172     # Fallback to force_load for the macOS linker
 173     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 174       [
 175         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 176         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 177       ],[
 178         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 179       ]
 180     )
 181   ]
 182 )
 183
 184 # Initialize and configure libtool
 185 LT_INIT([win32-dll])
 186
 187
 188 ##                 ##
 189 ## Programs checks ##
 190 ##                 ##
 191
 192 AC_PROG_MAKE_SET
 193 AC_PROG_MKDIR_P
 194 AC_PROG_LN_S
 195
 196 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 197 # is not distributed in tarballs
 198 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 199 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 200
 201 # check for bison
 202 AC_PROG_YACC
 203 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 204
 205 AS_IF([test "x$have_bison" != "xyes"], [
 206   AS_IF([test "x$in_git_repo" = "xyes"], [
 207     AC_MSG_FAILURE([dnl
 208 Bison >= 2.4 is required when building from the Git repository. You can
 209 set the YACC variable to override automatic detection.
 210     ])
 211   ], [
 212     AC_MSG_WARN([dnl
 213 Missing Bison >= 2.4. Note that the parser files are already built in
 214 this distribution tarball, so Bison is only needed if you intend to
 215 modify their sources. You can set the YACC variable to override automatic
 216 detection.
 217     ])
 218   ])
 219 ])
 220 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 221
 222 # check for flex
 223 AC_PROG_LEX
 224 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 225
 226 AS_IF([test "x$have_flex" != "xyes"], [
 227   AS_IF([test "x$in_git_repo" = "xyes"], [
 228     AC_MSG_FAILURE([dnl
 229 Flex >= 2.5.35 is required when building from the Git repository. You can
 230 set the LEX variable to override automatic detection.
 231     ])
 232   ], [
 233     AC_MSG_WARN([dnl
 234 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 235 this distribution tarball, so Flex is only needed if you intend to
 236 modify their sources. You can set the LEX variable to override automatic
 237 detection.
 238     ])
 239   ])
 240 ])
 241 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 242
 243
 244 ##                ##
 245 ## Library checks ##
 246 ##                ##
 247
 248 # Check what libraries are required on this platform to link sockets programs.
 249 AX_LIB_SOCKET_NSL
 250
 251 # Check for glib >= 2.22 with gmodule support
 252 AM_PATH_GLIB_2_0([2.22.0], [],
 253   AC_MSG_ERROR([glib >= 2.22 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 254   [gmodule-no-export]
 255 )
 256
 257 # Checks for library functions.
 258 AC_FUNC_ALLOCA
 259 AC_FUNC_FORK
 260 AC_FUNC_MKTIME
 261 AC_FUNC_MMAP
 262 AC_FUNC_STRERROR_R
 263 AC_FUNC_STRNLEN
 264 AC_CHECK_FUNCS([ \
 265         atexit \
 266         dup2 \
 267         ftruncate \
 268         gethostbyname \
 269         gettimeofday \
 270         localtime_r \
 271         memchr \
 272         memset \
 273         mkdir \
 274         mkdtemp \
 275         munmap \
 276         rmdir \
 277         setenv \
 278         socket \
 279         strchr \
 280         strdup \
 281         strerror \
 282         strndup \
 283         strnlen \
 284         strrchr \
 285         strstr \
 286         strtoul \
 287         strtoull \
 288         tzset \
 289 ])
 290
 291 # AC_FUNC_MALLOC causes problems when cross-compiling.
 292 #AC_FUNC_MALLOC
 293 #AC_FUNC_REALLOC
 294
 295 # Check for fmemopen
 296 AC_CHECK_LIB([c], [fmemopen],
 297   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 298 )
 299
 300 # Check for open_memstream
 301 AC_CHECK_LIB([c], [open_memstream],
 302   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 303 )
 304
 305 # Check for posix_fallocate
 306 AC_CHECK_LIB([c], [posix_fallocate],
 307   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 308 )
 309
 310 # Check libpopt
 311 PKG_CHECK_MODULES([POPT], [popt],
 312   [
 313     dnl PKG_CHECK_MODULES defines POPT_LIBS
 314   ],
 315   [
 316     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 317     AC_MSG_WARN([Finding libpopt without pkg-config.])
 318     AC_CHECK_LIB([popt],
 319       [poptGetContext],
 320       [POPT_LIBS="-lpopt"],
 321       [
 322         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 323       ]
 324     )
 325   ]
 326 )
 327 AC_SUBST(POPT_LIBS)
 328
 329
 330 ##                 ##
 331 ## User variables  ##
 332 ##                 ##
 333
 334 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 335 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 336 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 337
 338 # BABELTRACE_PLUGINS_DIR: Plugins directory
 339 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 340 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 341
 342 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 343 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 344 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 345
 346 # BABELTRACE_MINIMAL_LOG_LEVEL:
 347 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 348 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 349 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 350        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 351        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 352   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 353 )
 354 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 355
 356 # BABELTRACE_DEV_MODE:
 357 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 358 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 359         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 360 ], [BABELTRACE_DEV_MODE=0])
 361
 362 # BABELTRACE_DEBUG_MODE:
 363 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 364 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 365         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 366 ], [BABELTRACE_DEBUG_MODE=0])
 367
 368
 369 ##                              ##
 370 ## Optionnal features selection ##
 371 ##                              ##
 372
 373 # Python bindings
 374 # Disabled by default
 375 AC_ARG_ENABLE([python-bindings],
 376   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 377   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 378   [enable_python_bindings=no]
 379 )
 380
 381 # Python bindings documentation
 382 # Disabled by default
 383 AC_ARG_ENABLE([python-bindings-doc],
 384   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 385   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 386   [enable_python_bindings_doc=no]
 387 )
 388
 389 # Python plugins
 390 # Disabled by default
 391 AC_ARG_ENABLE([python-plugins],
 392   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])],
 393   [], dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 394   [enable_python_plugins=no]
 395 )
 396
 397 # Debug info
 398 # Enabled by default, except on some platforms
 399 AC_ARG_ENABLE([debug-info],
 400   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 401   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 402   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 403 )
 404
 405 # API documentation
 406 # Disabled by default
 407 AC_ARG_ENABLE([api-doc],
 408   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 409   [enable_api_doc=$enableval],
 410   [enable_api_doc=no]
 411 )
 412
 413 # Built-in plugins
 414 # Disabled by default
 415 AC_ARG_ENABLE([built-in-plugins],
 416   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])],
 417   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 418   [enable_built_in_plugins=no]
 419 )
 420
 421 # Built-in python plugin support
 422 # Disabled by default
 423 AC_ARG_ENABLE([built-in-python-plugin-support],
 424   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])],
 425   [], dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 426   [enable_built_in_python_plugin_support=no]
 427 )
 428
 429 # Man pages
 430 # Enabled by default
 431 AC_ARG_ENABLE([man-pages],
 432   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 433   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 434   [enable_man_pages=yes]
 435 )
 436
 437
 438 # Set automake variables for optionnal feature conditionnals in Makefile.am
 439 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 440 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 441 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 442 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 443 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 444 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 445 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 446 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 447 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 448
 449 # Set defines for optionnal features conditionnals in the source code
 450
 451 ## jgalar: still used?
 452 AS_IF([test "x$enable_python_plugins" = xyes],
 453   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 454 )
 455
 456 AS_IF([test "x$enable_debug_info" = xyes],
 457   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 458 )
 459
 460 AS_IF([test "x$enable_built_in_plugins" = xyes],
 461   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 462 )
 463
 464 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 465   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 466 )
 467
 468 AS_IF([test "x$enable_debug_info" = xyes],
 469   [ENABLE_DEBUG_INFO_VAL=1],
 470   [ENABLE_DEBUG_INFO_VAL=0]
 471 )
 472
 473 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 474
 475
 476 # Check for conflicting optional features user choices
 477
 478 AS_IF([test "x$enable_python_bindings" = xno],
 479   [
 480     AS_IF([test "x$enable_python_bindings_doc" = xyes], [AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])])
 481   ]
 482 )
 483
 484 AS_IF([test "x$enable_built_in_plugins" = xyes],
 485   [
 486     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 487     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 488     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 489   ]
 490 )
 491
 492 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 493   [
 494     AS_IF([test "x$enable_python_plugins" = xno], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 495     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 496     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 497     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 498   ]
 499 )
 500
 501
 502 # Check for optionnal features dependencies
 503
 504 AS_IF([test "x$enable_python_bindings" = xyes],
 505   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 506 )
 507
 508 AM_PATH_PYTHON([3.0], [
 509   AM_PATH_PYTHON_MODULES([PYTHON])
 510
 511   # pythondir is the path where extra modules are to be installed
 512   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 513
 514   # pyexecdir is the path that contains shared objects used by the extra modules
 515   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 516
 517   AS_IF([test -z "$PYTHON_CONFIG"], [
 518     AC_PATH_PROGS([PYTHON_CONFIG],
 519                   [python$PYTHON_VERSION-config python-config],
 520                   [],
 521                   [`dirname $PYTHON`])
 522   ])
 523
 524   AS_IF([test -n "$PYTHON_CONFIG"], [
 525     AS_IF([test -z "$PYTHON_INCLUDE"], [
 526       AC_MSG_CHECKING([Python include flags])
 527       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 528       AC_MSG_RESULT([$PYTHON_INCLUDE])
 529     ])
 530
 531     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 532       AC_MSG_CHECKING([Python library flags])
 533       PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 534       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 535     ])
 536   ])
 537 ], [:])
 538
 539 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 540 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 541
 542 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 543 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 544
 545 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 546   AS_IF([test "x$have_python_dev" = xno], [
 547     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 548   ])
 549 ])
 550
 551 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 552   [
 553     AM_CHECK_PYTHON_SPHINX([PYTHON])
 554     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 555       [AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])]
 556     )
 557   ]
 558 )
 559
 560 AS_IF([test "x$enable_debug_info" = xyes],
 561   [
 562     # Check if libelf and libdw are present
 563     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 564     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 565     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 566     ELFUTILS_LIBS="-lelf -ldw"
 567   ]
 568 )
 569 AC_SUBST([ELFUTILS_LIBS])
 570
 571 AS_IF([test "x$enable_api_doc" = "xyes"],
 572   [
 573     DX_DOXYGEN_FEATURE(ON)
 574     DX_DOT_FEATURE(OFF)
 575     DX_HTML_FEATURE(ON)
 576     DX_CHM_FEATURE(OFF)
 577     DX_CHI_FEATURE(OFF)
 578     DX_MAN_FEATURE(OFF)
 579     DX_RTF_FEATURE(OFF)
 580     DX_XML_FEATURE(OFF)
 581     DX_PDF_FEATURE(OFF)
 582     DX_PS_FEATURE(OFF)
 583     DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 584     AS_IF([test -z "$DX_DOXYGEN"],
 585           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 586     )
 587   ]
 588 )
 589
 590 have_asciidoc_xmlto=no
 591 warn_prebuilt_man_pages=no
 592
 593 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 594 AC_PATH_PROG([XMLTO], [xmlto], [no])
 595
 596 AS_IF([test "x$enable_man_pages" = "xyes"], [
 597   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 598     AS_IF([test "x$in_git_repo" = "xyes"], [
 599       # this is an error because we're in the Git repo, which
 600       # means the man pages are not already generated for us,
 601       # thus asciixmlto are required because we were asked
 602       # to build the man pages
 603       AC_MSG_ERROR([
 604 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 605 --disable-man-pages to disable building the man pages, in which case
 606 they will not be installed.
 607       ])
 608     ], [
 609       # only warn here: since we're in the tarball, the man
 610       # pages should already be generated at this point, thus
 611       # asciidoc/xmlto are not strictly required
 612       warn_prebuilt_man_pages=yes
 613     ])
 614   ], [
 615     have_asciidoc_xmlto=yes
 616   ])
 617 ])
 618
 619 # export AsciiDoc and xmlto existence
 620 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 621
 622 # a wonderful hack that seems necessary because $libdir is
 623 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 624 # by autoconf when it's not specified by the user
 625 AS_IF([test "x$exec_prefix" = xNONE], [
 626   AS_IF([test "x$prefix" = xNONE], [
 627     PREFIX="$ac_default_prefix"
 628   ], [
 629     PREFIX="$prefix"
 630   ])
 631
 632   LIBDIR="$PREFIX/lib"
 633 ], [
 634   LIBDIR="$libdir"
 635 ])
 636
 637 AC_SUBST(LIBDIR)
 638
 639
 640 # Set global CFLAGS in AM_CFLAGS
 641 AM_CFLAGS="-Wall -Wformat -Werror=implicit-function-declaration $PTHREAD_CFLAGS $GLIB_CFLAGS"
 642 AC_SUBST(AM_CFLAGS)
 643
 644 # Set global CPPFLAGS in AM_CPPFLAGS
 645 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 646 AC_SUBST(AM_CPPFLAGS)
 647
 648 # Add glib to global link libs
 649 LIBS="$LIBS $GLIB_LIBS"
 650
 651 # Check that the current size_t matches the size that glib thinks it should
 652 # be. This catches problems on multi-arch where people try to do a 32-bit
 653 # build while pointing at 64-bit glib headers. This is a common error because
 654 # glib.h is not platform specific but it includes glibconfig.h which is and
 655 # is usually installed in a non-standard path.
 656
 657 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 658 # output. Specifically allow pkg_config_libdir to be able to print the
 659 # error message.
 660 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 661
 662 save_CFLAGS=${CFLAGS}
 663 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 664 AC_COMPILE_IFELSE([
 665   AC_LANG_PROGRAM([dnl
 666 #include <glib.h>
 667 #include <unistd.h>
 668   ], [dnl
 669 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 670   ])
 671 ],[:],[
 672   AC_MSG_ERROR([dnl
 673 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 674 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 675 target.
 676   ])
 677 ])
 678 CFLAGS=${save_CFLAGS}
 679
 680 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 681 # to rename babeltrace2.bin to babeltrace2 at install time.
 682 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 683 AC_SUBST(program_transform_name)
 684
 685 AC_CONFIG_FILES([
 686         doc/api/Doxyfile
 687         doc/api/Makefile
 688         doc/bindings/Makefile
 689         doc/bindings/python/Makefile
 690         doc/contributing-images/Makefile
 691         doc/Makefile
 692         doc/man/asciidoc-attrs.conf
 693         doc/man/Makefile
 694         include/Makefile
 695         Makefile
 696         src/argpar/Makefile
 697         src/babeltrace2-ctf-writer.pc
 698         src/babeltrace2.pc
 699         src/bindings/Makefile
 700         src/bindings/python/bt2/bt2/version.py
 701         src/bindings/python/bt2/Makefile
 702         src/bindings/python/bt2/setup.py
 703         src/bindings/python/Makefile
 704         src/cli/Makefile
 705         src/common/Makefile
 706         src/compat/Makefile
 707         src/ctfser/Makefile
 708         src/ctf-writer/Makefile
 709         src/fd-cache/Makefile
 710         src/lib/graph/Makefile
 711         src/lib/graph/message/Makefile
 712         src/lib/Makefile
 713         src/lib/plugin/Makefile
 714         src/lib/prio-heap/Makefile
 715         src/lib/trace-ir/Makefile
 716         src/logging/Makefile
 717         src/Makefile
 718         src/plugins/ctf/common/bfcr/Makefile
 719         src/plugins/ctf/common/Makefile
 720         src/plugins/ctf/common/metadata/Makefile
 721         src/plugins/ctf/common/msg-iter/Makefile
 722         src/plugins/ctf/fs-sink/Makefile
 723         src/plugins/ctf/fs-src/Makefile
 724         src/plugins/ctf/lttng-live/Makefile
 725         src/plugins/ctf/Makefile
 726         src/plugins/lttng-utils/debug-info/Makefile
 727         src/plugins/lttng-utils/Makefile
 728         src/plugins/Makefile
 729         src/plugins/text/dmesg/Makefile
 730         src/plugins/text/Makefile
 731         src/plugins/text/pretty/Makefile
 732         src/plugins/text/details/Makefile
 733         src/plugins/utils/counter/Makefile
 734         src/plugins/utils/dummy/Makefile
 735         src/plugins/utils/Makefile
 736         src/plugins/utils/muxer/Makefile
 737         src/plugins/utils/trimmer/Makefile
 738         src/py-common/Makefile
 739         src/python-plugin-provider/Makefile
 740         tests/bitfield/Makefile
 741         tests/ctf-writer/Makefile
 742         tests/argpar/Makefile
 743         tests/lib/Makefile
 744         tests/lib/test-plugin-plugins/Makefile
 745         tests/Makefile
 746         tests/plugins/Makefile
 747         tests/plugins/src.ctf.fs/Makefile
 748         tests/plugins/src.ctf.fs/succeed/Makefile
 749         tests/plugins/sink.ctf.fs/Makefile
 750         tests/plugins/sink.ctf.fs/succeed/Makefile
 751         tests/plugins/flt.lttng-utils.debug-info/Makefile
 752         tests/plugins/flt.utils.trimmer/Makefile
 753         tests/utils/Makefile
 754         tests/utils/tap/Makefile
 755 ])
 756
 757 AC_OUTPUT
 758
 759 #
 760 # Mini-report on what will be built.
 761 #
 762
 763 PPRINT_INIT
 764 PPRINT_SET_INDENT(1)
 765 PPRINT_SET_TS(38)
 766
 767 AS_ECHO
 768 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 769 AS_ECHO
 770
 771 PPRINT_SUBTITLE([System])
 772
 773 # Target architecture we're building for.
 774 target_arch=$host_cpu
 775 [
 776 for f in $CFLAGS; do
 777         if test $f = "-m32"; then
 778                 target_arch="32-bit"
 779         elif test $f = "-m64"; then
 780                 target_arch="64-bit"
 781         fi
 782 done
 783 ]
 784
 785 PPRINT_PROP_STRING([Target architecture], $target_arch)
 786
 787 AS_ECHO
 788 PPRINT_SUBTITLE([Python 3 language support])
 789 test "x$have_python" = "xyes" && value=1 || value=0
 790 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 791 test "x$have_python_dev" = "xyes" && value=1 || value=0
 792 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 793 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 794 PPRINT_PROP_BOOL([Python bindings], $value)
 795 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 796 PPRINT_PROP_BOOL([Python plugin support], $value)
 797 AS_IF([test "x$have_python" = "xyes"], [
 798   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 799 ])
 800 AS_IF([test "x$have_python_dev" = "xyes"], [
 801   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 802   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 803   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 804 ])
 805 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 806   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 807   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 808 ])
 809
 810 AS_ECHO
 811 PPRINT_SUBTITLE([Plugins])
 812 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 813 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 814 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 815 PPRINT_PROP_BOOL(['text' plugin], 1)
 816 PPRINT_PROP_BOOL(['utils' plugin], 1)
 817
 818 AS_ECHO
 819 PPRINT_SUBTITLE([Built-in features])
 820 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 821 PPRINT_PROP_BOOL([Built-in plugins], $value)
 822 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 823 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 824
 825 AS_ECHO
 826 PPRINT_SUBTITLE([Documentation])
 827
 828 # man pages build enabled/disabled
 829 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 830
 831 AS_IF([test "x$enable_man_pages" != "xno"], [
 832   AS_IF([test "x$in_git_repo" = "xyes"], [
 833     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 834   ], [
 835     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 836       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 837     ], [
 838       PPRINT_PROP_STRING([build_man_pages_msg],
 839         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 840         $PPRINT_COLOR_SUBTITLE)
 841     ])
 842   ])
 843 ], [
 844   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 845 ])
 846
 847 m4_popdef([build_man_pages_msg])
 848
 849 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 850 PPRINT_PROP_BOOL([HTML API documentation], $value)
 851 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 852 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 853
 854 AS_ECHO
 855 PPRINT_SUBTITLE([Logging])
 856 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 857
 858 AS_ECHO
 859 PPRINT_SUBTITLE([Special build modes])
 860 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 861 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 862
 863 report_bindir="`eval eval echo $bindir`"
 864 report_libdir="`eval eval echo $libdir`"
 865 report_sysconfdif="`eval eval echo $sysconfdir`"
 866 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 867 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 868
 869 # Print the bindir and libdir this `make install' will install into.
 870 AS_ECHO
 871 PPRINT_SUBTITLE([Install directories])
 872 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 873 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 874 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 875 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 876 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])