configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre1])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT(win32-dll)
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53 LIBS="$PTHREAD_LIBS $LIBS"
  54 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  55 CC="$PTHREAD_CC"
  56
  57 # Check linker option
  58 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  59 AC_SUBST([LD_NO_AS_NEEDED])
  60
  61 AC_HEADER_STDBOOL
  62 AC_CHECK_HEADERS([ \
  63         fcntl.h \
  64         float.h \
  65         libintl.h \
  66         limits.h \
  67         malloc.h \
  68         netdb.h \
  69         netinet/in.h \
  70         stddef.h \
  71         sys/socket.h \
  72 ])
  73
  74 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  75         if test x"$(basename "$YACC")" != "xbison -y"; then
  76                 AC_MSG_ERROR([[bison not found and is required when building from git.
  77                 Please install bison]])
  78         fi
  79         AC_PATH_PROG([BISON],[bison])
  80         AX_PROG_BISON_VERSION([2.4], [],[
  81                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  82         ])
  83 fi
  84
  85 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  86         if test x"$LEX" != "xflex"; then
  87                 AC_MSG_ERROR([[flex not found and is required when building from git.
  88                 Please install flex]])
  89         fi
  90         AC_PATH_PROG([FLEX],[flex])
  91         AX_PROG_FLEX_VERSION([2.5.35], [],[
  92                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  93         ])
  94 fi
  95
  96
  97 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule-no-export)
  98
  99 # Check what libraries are required on this platform to link sockets programs.
 100 AX_LIB_SOCKET_NSL
 101
 102 # Checks for typedefs, structures, and compiler characteristics.
 103 AC_C_INLINE
 104 AC_TYPE_PID_T
 105 AC_TYPE_SIZE_T
 106 AC_TYPE_INT16_T
 107 AC_TYPE_INT32_T
 108 AC_TYPE_INT64_T
 109 AC_TYPE_INT8_T
 110 AC_TYPE_OFF_T
 111 AC_TYPE_SSIZE_T
 112 AC_TYPE_UINT16_T
 113 AC_TYPE_UINT32_T
 114 AC_TYPE_UINT64_T
 115 AC_TYPE_UINT8_T
 116
 117 # Checks for library functions.
 118 AC_FUNC_ALLOCA
 119 AC_FUNC_FORK
 120 AC_FUNC_MALLOC
 121 AC_FUNC_MKTIME
 122 AC_FUNC_MMAP
 123 AC_FUNC_REALLOC
 124 AC_FUNC_STRERROR_R
 125 AC_CHECK_FUNCS([ \
 126         atexit \
 127         dup2 \
 128         ftruncate \
 129         gethostbyname \
 130         gethostname \
 131         gettimeofday \
 132         localtime_r \
 133         memchr \
 134         memset \
 135         mkdir \
 136         mkdtemp \
 137         munmap \
 138         rmdir \
 139         setenv \
 140         socket \
 141         strchr \
 142         strdup \
 143         strerror \
 144         strndup \
 145         strnlen \
 146         strrchr \
 147         strtoul \
 148         strtoull \
 149         tzset \
 150         uname \
 151 ])
 152
 153 MINGW32=no
 154 DEFAULT_ENABLE_DEBUG_INFO=yes
 155 LT_NO_UNDEFINED=""
 156 AS_CASE([$host_os],
 157   [solaris*|darwin*],
 158     [
 159         DEFAULT_ENABLE_DEBUG_INFO=no
 160     ],
 161   [mingw*],
 162     [
 163         MINGW32=yes
 164         DEFAULT_ENABLE_DEBUG_INFO=no
 165         LT_NO_UNDEFINED="-no-undefined"
 166     ]
 167 )
 168
 169 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 170 AC_SUBST(LT_NO_UNDEFINED)
 171
 172 # Check for uuid in system libs
 173 AC_CHECK_FUNCS([uuid_generate],
 174 [
 175   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 176   link_with_libuuid=no
 177 ],
 178 [
 179   # First, check the pkg-config module is available, otherwise explicitly check
 180   # for libuuid, or uuid support in the C-library.
 181   PKG_CHECK_MODULES([UUID], [uuid],
 182   [
 183     LIBS="${UUID_LIBS} ${LIBS}"
 184     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 185     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 186     link_with_libuuid=yes
 187   ],
 188   [
 189     # Check for libuuid
 190     AC_CHECK_LIB([uuid], [uuid_generate],
 191     [
 192       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 193       link_with_libuuid=yes
 194     ],
 195     [
 196       # libuuid not found, check for uuid_create in libc.
 197       AC_CHECK_LIB([c], [uuid_create],
 198       [
 199         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 200         link_with_libc_uuid=yes
 201       ],
 202       [
 203         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 204         if test "x$MINGW32" = xno; then
 205           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 206         fi
 207       ])
 208     ])
 209   ])
 210 ])
 211
 212 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 213 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 214
 215 # Check for fmemopen
 216 AC_CHECK_LIB([c], [fmemopen],
 217 [
 218         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 219 ]
 220 )
 221
 222 # Check for open_memstream
 223 AC_CHECK_LIB([c], [open_memstream],
 224 [
 225         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 226 ]
 227 )
 228
 229 # Check for posix_fallocate
 230 AC_CHECK_LIB([c], [posix_fallocate],
 231 [
 232         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 233 ]
 234 )
 235
 236 AC_CHECK_LIB([popt], [poptGetContext], [],
 237         [AC_MSG_ERROR([Cannot find popt.])]
 238 )
 239
 240 # Plugins
 241 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 242 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 243
 244 # For Python
 245 # SWIG version needed or newer:
 246 swig_version=2.0.0
 247
 248 AC_ARG_ENABLE([python-bindings],
 249               [AC_HELP_STRING([--enable-python-bindings],
 250                               [generate Python bindings])],
 251               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 252
 253 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 254
 255 AC_ARG_ENABLE(
 256         [python-plugins],
 257         [AC_HELP_STRING(
 258                 [--enable-python-plugins],
 259                 [add support for the Babeltrace library and converter to load Python plugins])
 260         ],
 261         [enable_python_plugins=$enableval],
 262         [enable_python_plugins=no]
 263 )
 264
 265 if test "x${enable_python_bindings:-yes}" = xyes; then
 266   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 267 else
 268     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 269 [if you want Python bindings.])
 270 fi
 271
 272 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 273   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 274
 275   AM_PATH_PYTHON_MODULES([PYTHON])
 276   # pythondir is the path where extra modules are to be installed
 277   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 278   # pyexecdir is the path that contains shared objects used by the extra modules
 279   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 280   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 281   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 282   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 283   AS_IF([test -z "$PYTHON_INCLUDE"], [
 284     AS_IF([test -z "$PYTHON_CONFIG"], [
 285       AC_PATH_PROGS([PYTHON_CONFIG],
 286                     [python$PYTHON_VERSION-config python-config],
 287                     [no],
 288                     [`dirname $PYTHON`])
 289       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 290     ])
 291     AC_MSG_CHECKING([Python include flags])
 292     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 293     AC_MSG_RESULT([$PYTHON_INCLUDE])
 294   ])
 295   AS_IF([test -z "$PYTHON_LIBS"], [
 296     AS_IF([test -z "$PYTHON_CONFIG"], [
 297       AC_PATH_PROGS([PYTHON_CONFIG],
 298                     [python$PYTHON_VERSION-config python-config],
 299                     [no],
 300                     [`dirname $PYTHON`])
 301       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 302     ])
 303     AC_MSG_CHECKING([Python library flags])
 304     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 305     AC_MSG_RESULT([$PYTHON_LIBS])
 306   ])
 307 fi
 308
 309 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 310
 311 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 312 AS_IF(
 313   [test "x$enable_python_plugins" != xno],
 314   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 315 )
 316
 317 AC_ARG_ENABLE([python-bindings-doc],
 318               [AC_HELP_STRING([--enable-python-bindings-doc],
 319                               [generate Python bindings documentation])],
 320               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 321
 322 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 323
 324 AC_ARG_ENABLE([python-bindings-tests],
 325               [AC_HELP_STRING([--enable-python-bindings-tests],
 326                               [test Python bindings])],
 327               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 328
 329 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 330
 331 if test "x${enable_python_bindings:-no}" = xno; then
 332   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 333     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 334   fi
 335
 336   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 337     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 338   fi
 339 fi
 340
 341 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 342     AM_CHECK_PYTHON_SPHINX([PYTHON])
 343     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 344       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 345     )
 346 fi
 347
 348 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 349     AM_CHECK_PYTHON_TAPPY([PYTHON])
 350     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 351         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 352     )
 353 fi
 354
 355 # Set default enable state for debug info.
 356 # The _enable_debug_info variable is prepended with an underscore to
 357 # avoid clashing with the one generated by AC_ARG_ENABLE.
 358 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 359
 360 # Optional debug info feature
 361 # Do _not_ indent the help string below (appears in the configure --help
 362 # output).
 363 AC_ARG_ENABLE([debug-info],
 364 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 365 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 366         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 367
 368 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 369
 370 AS_IF([test "x$_enable_debug_info" = xyes], [
 371         # Check if libelf and libdw are present
 372         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 373         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 374         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 375         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 376 ], [])
 377
 378 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 379 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 380 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 381         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 382         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 383         built_in_plugins=yes
 384         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 385 ])
 386 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 387
 388 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 389 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 390 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 391   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 392   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 393   AS_IF([test "x$enable_python_plugins" = "xno"], [
 394     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 395   ])
 396   built_in_python_plugin_support=yes
 397   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 398 ])
 399 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 400
 401 PKG_CHECK_MODULES(GMODULE, [gmodule-no-export-2.0 >= 2.0.0])
 402
 403 # Logging
 404 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 405 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=VERBOSE])
 406 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 407         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 408 ])
 409 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 410
 411 LIBS="$LIBS $GMODULE_LIBS"
 412 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 413 AC_SUBST(PACKAGE_CFLAGS)
 414
 415 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 416 AC_SUBST(DEFAULT_INCLUDES)
 417
 418 babeltraceincludedir="${includedir}/babeltrace"
 419 AC_SUBST(babeltraceincludedir)
 420
 421 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 422 AC_SUBST(babeltracectfwriterincludedir)
 423
 424 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 425 AC_SUBST(babeltracectfincludedir)
 426
 427 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 428 AC_SUBST(babeltracectfirincludedir)
 429
 430 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 431 AC_SUBST(babeltracepluginincludedir)
 432
 433 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 434 AC_SUBST(babeltracegraphincludedir)
 435
 436 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 437 AC_SUBST(program_transform_name)
 438
 439 # check for Doxygen
 440 AC_ARG_ENABLE(
 441   [api-doc],
 442   [AC_HELP_STRING(
 443     [--enable-api-doc],
 444     [generate and install HTML API documentation]
 445   )],
 446   [enable_api_doc=$enableval],
 447   [enable_api_doc=no]
 448 )
 449 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 450
 451 AS_IF([test "x$enable_api_doc" = "xyes"], [
 452   DX_DOXYGEN_FEATURE(ON)
 453   DX_DOT_FEATURE(OFF)
 454   DX_HTML_FEATURE(ON)
 455   DX_CHM_FEATURE(OFF)
 456   DX_CHI_FEATURE(OFF)
 457   DX_MAN_FEATURE(OFF)
 458   DX_RTF_FEATURE(OFF)
 459   DX_XML_FEATURE(OFF)
 460   DX_PDF_FEATURE(OFF)
 461   DX_PS_FEATURE(OFF)
 462   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 463 ])
 464
 465         #TODO: removed, work in progress
 466         #bindings/python/Makefile
 467         #bindings/python/babeltrace/Makefile
 468         #bindings/python/bt2/Makefile
 469         #bindings/python/bt2/__init__.py
 470 AC_CONFIG_FILES([
 471         Makefile
 472         common/Makefile
 473         compat/Makefile
 474         cli/Makefile
 475         doc/Makefile
 476         doc/api/Makefile
 477         doc/api/Doxyfile
 478         doc/bindings/Makefile
 479         doc/bindings/python/Makefile
 480         doc/images/Makefile
 481         lib/Makefile
 482         lib/prio_heap/Makefile
 483         lib/plugin/Makefile
 484         lib/graph/Makefile
 485         lib/graph/notification/Makefile
 486         lib/ctf-ir/Makefile
 487         lib/ctf-writer/Makefile
 488         include/Makefile
 489         logging/Makefile
 490         bindings/Makefile
 491         tests/Makefile
 492         tests/cli/Makefile
 493         tests/cli/intersection/Makefile
 494         tests/lib/Makefile
 495         tests/lib/writer/Makefile
 496         tests/lib/test-plugin-plugins/Makefile
 497         tests/utils/Makefile
 498         tests/utils/tap/Makefile
 499         tests/bindings/Makefile
 500         tests/bindings/python/Makefile
 501         tests/bindings/python/bt2/Makefile
 502         tests/plugins/Makefile
 503         extras/Makefile
 504         extras/valgrind/Makefile
 505         plugins/Makefile
 506         plugins/ctf/Makefile
 507         plugins/ctf/common/Makefile
 508         plugins/ctf/common/btr/Makefile
 509         plugins/ctf/common/metadata/Makefile
 510         plugins/ctf/common/notif-iter/Makefile
 511         plugins/ctf/fs-src/Makefile
 512         plugins/ctf/fs-sink/Makefile
 513         plugins/ctf/lttng-live/Makefile
 514         plugins/text/Makefile
 515         plugins/text/pretty/Makefile
 516         plugins/utils/Makefile
 517         plugins/utils/dummy/Makefile
 518         plugins/utils/trimmer/Makefile
 519         plugins/utils/muxer/Makefile
 520         python-plugin-provider/Makefile
 521         plugins/libctfcopytrace/Makefile
 522         plugins/lttng-utils/Makefile
 523         babeltrace.pc
 524         babeltrace-ctf.pc
 525 ])
 526
 527 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 528 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 529 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 530 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 531 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 532
 533 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 534
 535 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 536 AC_CONFIG_FILES([tests/cli/test_trace_copy], [chmod +x tests/cli/test_trace_copy])
 537 AC_CONFIG_FILES([tests/cli/test_debug_info], [chmod +x tests/cli/test_debug_info])
 538 AC_CONFIG_FILES([tests/cli/test_trimmer], [chmod +x tests/cli/test_trimmer])
 539 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 540 AC_CONFIG_FILES([tests/cli/test_convert_args], [chmod +x tests/cli/test_convert_args])
 541 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 542 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 543 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 544 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 545 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 546
 547 AS_IF([test "x$enable_python" = "xyes"], [
 548         AC_CONFIG_FILES(
 549                 [tests/bindings/python/bt2/testall.sh],
 550                 [chmod +x tests/bindings/python/bt2/testall.sh]
 551         )
 552 ])
 553
 554 AC_OUTPUT
 555
 556 #
 557 # Mini-report on what will be built.
 558 #
 559
 560 PPRINT_INIT
 561 PPRINT_SET_INDENT(1)
 562 PPRINT_SET_TS(38)
 563
 564 AS_ECHO
 565 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 566 AS_ECHO
 567
 568 PPRINT_SUBTITLE([System])
 569
 570 # Target architecture we're building for.
 571 target_arch=$host_cpu
 572 [
 573 for f in $CFLAGS; do
 574         if test $f = "-m32"; then
 575                 target_arch="32-bit"
 576         elif test $f = "-m64"; then
 577                 target_arch="64-bit"
 578         fi
 579 done
 580 ]
 581
 582 PPRINT_PROP_STRING([Target architecture], $target_arch)
 583
 584 AS_ECHO
 585 PPRINT_SUBTITLE([Python 3 language support])
 586 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 587 PPRINT_PROP_BOOL([Python bindings], $value)
 588 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 589 PPRINT_PROP_BOOL([Python plugin support], $value)
 590 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 591   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 592   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 593 ])
 594
 595 AS_ECHO
 596 PPRINT_SUBTITLE([Plugins])
 597 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 598 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 599 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 600 PPRINT_PROP_BOOL(['text' plugin], 1)
 601 PPRINT_PROP_BOOL(['utils' plugin], 1)
 602
 603 AS_ECHO
 604 PPRINT_SUBTITLE([Built-in features])
 605 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 606 PPRINT_PROP_BOOL([Built-in plugins], $value)
 607 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 608 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 609
 610 AS_ECHO
 611 PPRINT_SUBTITLE([Documentation])
 612 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 613 PPRINT_PROP_BOOL([HTML API documentation], $value)
 614 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 615 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 616
 617 AS_ECHO
 618 PPRINT_SUBTITLE([Logging])
 619 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 620
 621 AS_ECHO
 622 PPRINT_SUBTITLE([Testing])
 623 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 624 PPRINT_PROP_BOOL([Python bindings tests], $value)
 625
 626 report_bindir="`eval eval echo $bindir`"
 627 report_libdir="`eval eval echo $libdir`"
 628 report_sysconfdif="`eval eval echo $sysconfdir`"
 629
 630 # Print the bindir and libdir this `make install' will install into.
 631 AS_ECHO
 632 PPRINT_SUBTITLE([Install directories])
 633 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 634 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 635 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 636 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])