configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53 LIBS="$PTHREAD_LIBS $LIBS"
  54 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  55 CC="$PTHREAD_CC"
  56
  57 # Check linker option
  58 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  59 AC_SUBST([LD_NO_AS_NEEDED])
  60
  61 AC_HEADER_STDBOOL
  62 AC_CHECK_HEADERS([ \
  63         fcntl.h \
  64         float.h \
  65         libintl.h \
  66         limits.h \
  67         malloc.h \
  68         netdb.h \
  69         netinet/in.h \
  70         stddef.h \
  71         sys/socket.h \
  72 ])
  73
  74 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  75         if test x"$(basename "$YACC")" != "xbison -y"; then
  76                 AC_MSG_ERROR([[bison not found and is required when building from git.
  77                 Please install bison]])
  78         fi
  79         AC_PATH_PROG([BISON],[bison])
  80         AX_PROG_BISON_VERSION([2.4], [],[
  81                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  82         ])
  83 fi
  84
  85 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  86         if test x"$LEX" != "xflex"; then
  87                 AC_MSG_ERROR([[flex not found and is required when building from git.
  88                 Please install flex]])
  89         fi
  90         AC_PATH_PROG([FLEX],[flex])
  91         AX_PROG_FLEX_VERSION([2.5.35], [],[
  92                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  93         ])
  94 fi
  95
  96
  97 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  98
  99 # Check what libraries are required on this platform to link sockets programs.
 100 AX_LIB_SOCKET_NSL
 101
 102 # Checks for typedefs, structures, and compiler characteristics.
 103 AC_C_INLINE
 104 AC_TYPE_PID_T
 105 AC_TYPE_SIZE_T
 106 AC_TYPE_INT16_T
 107 AC_TYPE_INT32_T
 108 AC_TYPE_INT64_T
 109 AC_TYPE_INT8_T
 110 AC_TYPE_OFF_T
 111 AC_TYPE_SSIZE_T
 112 AC_TYPE_UINT16_T
 113 AC_TYPE_UINT32_T
 114 AC_TYPE_UINT64_T
 115 AC_TYPE_UINT8_T
 116
 117 # Checks for library functions.
 118 AC_FUNC_ALLOCA
 119 AC_FUNC_FORK
 120 AC_FUNC_MALLOC
 121 AC_FUNC_MKTIME
 122 AC_FUNC_MMAP
 123 AC_FUNC_REALLOC
 124 AC_FUNC_STRERROR_R
 125 AC_CHECK_FUNCS([ \
 126         atexit \
 127         dirfd \
 128         dup2 \
 129         ftruncate \
 130         gethostbyname \
 131         gethostname \
 132         gettimeofday \
 133         localtime_r \
 134         memchr \
 135         memset \
 136         mkdir \
 137         mkdtemp \
 138         munmap \
 139         rmdir \
 140         setenv \
 141         socket \
 142         strchr \
 143         strdup \
 144         strerror \
 145         strndup \
 146         strnlen \
 147         strrchr \
 148         strtoul \
 149         strtoull \
 150         tzset \
 151         uname \
 152 ])
 153
 154 MINGW32=no
 155 DEFAULT_ENABLE_DEBUG_INFO=yes
 156 AS_CASE([$host_os],
 157   [solaris*|darwin*],
 158     [
 159         DEFAULT_ENABLE_DEBUG_INFO=no
 160     ],
 161   [mingw*],
 162     [
 163         MINGW32=yes
 164         DEFAULT_ENABLE_DEBUG_INFO=no
 165     ]
 166 )
 167
 168 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 169
 170 # Check for uuid in system libs
 171 AC_CHECK_FUNCS([uuid_generate],
 172 [
 173   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 174   link_with_libuuid=no
 175 ],
 176 [
 177   # First, check the pkg-config module is available, otherwise explicitly check
 178   # for libuuid, or uuid support in the C-library.
 179   PKG_CHECK_MODULES([UUID], [uuid],
 180   [
 181     LIBS="${UUID_LIBS} ${LIBS}"
 182     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 183     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 184     link_with_libuuid=yes
 185   ],
 186   [
 187     # Check for libuuid
 188     AC_CHECK_LIB([uuid], [uuid_generate],
 189     [
 190       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 191       link_with_libuuid=yes
 192     ],
 193     [
 194       # libuuid not found, check for uuid_create in libc.
 195       AC_CHECK_LIB([c], [uuid_create],
 196       [
 197         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 198         link_with_libc_uuid=yes
 199       ],
 200       [
 201         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 202         if test "x$MINGW32" = xno; then
 203           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 204         fi
 205       ])
 206     ])
 207   ])
 208 ])
 209
 210 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 211 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 212
 213 # Check for fmemopen
 214 AC_CHECK_LIB([c], [fmemopen],
 215 [
 216         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 217 ]
 218 )
 219
 220 # Check for open_memstream
 221 AC_CHECK_LIB([c], [open_memstream],
 222 [
 223         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 224 ]
 225 )
 226
 227 # Check for posix_fallocate
 228 AC_CHECK_LIB([c], [posix_fallocate],
 229 [
 230         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 231 ]
 232 )
 233
 234 # Check for faccessat
 235 AC_CHECK_LIB([c], [faccessat],
 236 [
 237         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 238 ]
 239 )
 240
 241 AC_CHECK_LIB([popt], [poptGetContext], [],
 242         [AC_MSG_ERROR([Cannot find popt.])]
 243 )
 244
 245 # Plugins
 246 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 247 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 248
 249 # For Python
 250 # SWIG version needed or newer:
 251 swig_version=2.0.0
 252
 253 AC_ARG_ENABLE([python-bindings],
 254               [AC_HELP_STRING([--enable-python-bindings],
 255                               [generate Python bindings])],
 256               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 257
 258 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 259
 260 AC_ARG_ENABLE(
 261         [python-plugins],
 262         [AC_HELP_STRING(
 263                 [--enable-python-plugins],
 264                 [add support for the Babeltrace library and converter to load Python plugins])
 265         ],
 266         [enable_python_plugins=$enableval],
 267         [enable_python_plugins=no]
 268 )
 269
 270 if test "x${enable_python_bindings:-yes}" = xyes; then
 271   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 272 else
 273     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 274 [if you want Python bindings.])
 275 fi
 276
 277 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 278   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 279
 280   AM_PATH_PYTHON_MODULES([PYTHON])
 281   # pythondir is the path where extra modules are to be installed
 282   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 283   # pyexecdir is the path that contains shared objects used by the extra modules
 284   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 285   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 286   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 287   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 288   AS_IF([test -z "$PYTHON_INCLUDE"], [
 289     AS_IF([test -z "$PYTHON_CONFIG"], [
 290       AC_PATH_PROGS([PYTHON_CONFIG],
 291                     [python$PYTHON_VERSION-config python-config],
 292                     [no],
 293                     [`dirname $PYTHON`])
 294       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 295     ])
 296     AC_MSG_CHECKING([Python include flags])
 297     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 298     AC_MSG_RESULT([$PYTHON_INCLUDE])
 299   ])
 300   AS_IF([test -z "$PYTHON_LIBS"], [
 301     AS_IF([test -z "$PYTHON_CONFIG"], [
 302       AC_PATH_PROGS([PYTHON_CONFIG],
 303                     [python$PYTHON_VERSION-config python-config],
 304                     [no],
 305                     [`dirname $PYTHON`])
 306       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 307     ])
 308     AC_MSG_CHECKING([Python library flags])
 309     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 310     AC_MSG_RESULT([$PYTHON_LIBS])
 311   ])
 312 fi
 313
 314 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 315
 316 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 317 AS_IF(
 318   [test "x$enable_python_plugins" != xno],
 319   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 320 )
 321
 322 AC_ARG_ENABLE([python-bindings-doc],
 323               [AC_HELP_STRING([--enable-python-bindings-doc],
 324                               [generate Python bindings documentation])],
 325               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 326
 327 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 328
 329 AC_ARG_ENABLE([python-bindings-tests],
 330               [AC_HELP_STRING([--enable-python-bindings-tests],
 331                               [test Python bindings])],
 332               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 333
 334 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 335
 336 if test "x${enable_python_bindings:-no}" = xno; then
 337   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 338     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 339   fi
 340
 341   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 342     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 343   fi
 344 fi
 345
 346 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 347     AM_CHECK_PYTHON_SPHINX([PYTHON])
 348     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 349       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 350     )
 351 fi
 352
 353 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 354     AM_CHECK_PYTHON_TAPPY([PYTHON])
 355     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 356         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 357     )
 358 fi
 359
 360 # Set default enable state for debug info.
 361 # The _enable_debug_info variable is prepended with an underscore to
 362 # avoid clashing with the one generated by AC_ARG_ENABLE.
 363 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 364
 365 # Optional debug info feature
 366 # Do _not_ indent the help string below (appears in the configure --help
 367 # output).
 368 AC_ARG_ENABLE([debug-info],
 369 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 370 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 371         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 372
 373 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 374
 375 AS_IF([test "x$_enable_debug_info" = xyes], [
 376         # Check if libelf and libdw are present
 377         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 378         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 379         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 380         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 381 ], [])
 382
 383 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 384 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 385 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 386         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 387         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 388         built_in_plugins=yes
 389         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 390 ])
 391 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 392
 393 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 394 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 395 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 396   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 397   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 398   AS_IF([test "x$enable_python_plugins" = "xno"], [
 399     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 400   ])
 401   built_in_python_plugin_support=yes
 402   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 403 ])
 404 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 405
 406 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 407
 408 # Logging
 409 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 410 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=DEBUG])
 411 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 412         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 413 ])
 414 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 415
 416 LIBS="$LIBS $GMODULE_LIBS"
 417 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 418 AC_SUBST(PACKAGE_CFLAGS)
 419
 420 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 421 AC_SUBST(DEFAULT_INCLUDES)
 422
 423 babeltraceincludedir="${includedir}/babeltrace"
 424 AC_SUBST(babeltraceincludedir)
 425
 426 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 427 AC_SUBST(babeltracectfwriterincludedir)
 428
 429 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 430 AC_SUBST(babeltracectfincludedir)
 431
 432 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 433 AC_SUBST(babeltracectfirincludedir)
 434
 435 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 436 AC_SUBST(babeltracepluginincludedir)
 437
 438 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 439 AC_SUBST(babeltracegraphincludedir)
 440
 441 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 442 AC_SUBST(program_transform_name)
 443
 444 # check for Doxygen
 445 AC_ARG_ENABLE(
 446   [api-doc],
 447   [AC_HELP_STRING(
 448     [--enable-api-doc],
 449     [generate and install HTML API documentation]
 450   )],
 451   [enable_api_doc=$enableval],
 452   [enable_api_doc=no]
 453 )
 454 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 455
 456 AS_IF([test "x$enable_api_doc" = "xyes"], [
 457   DX_DOXYGEN_FEATURE(ON)
 458   DX_DOT_FEATURE(OFF)
 459   DX_HTML_FEATURE(ON)
 460   DX_CHM_FEATURE(OFF)
 461   DX_CHI_FEATURE(OFF)
 462   DX_MAN_FEATURE(OFF)
 463   DX_RTF_FEATURE(OFF)
 464   DX_XML_FEATURE(OFF)
 465   DX_PDF_FEATURE(OFF)
 466   DX_PS_FEATURE(OFF)
 467   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 468 ])
 469
 470         #TODO: removed, work in progress
 471         #bindings/python/Makefile
 472         #bindings/python/babeltrace/Makefile
 473         #bindings/python/bt2/Makefile
 474         #bindings/python/bt2/__init__.py
 475 AC_CONFIG_FILES([
 476         Makefile
 477         common/Makefile
 478         compat/Makefile
 479         cli/Makefile
 480         doc/Makefile
 481         doc/api/Makefile
 482         doc/api/Doxyfile
 483         doc/bindings/Makefile
 484         doc/bindings/python/Makefile
 485         doc/images/Makefile
 486         lib/Makefile
 487         lib/prio_heap/Makefile
 488         lib/plugin/Makefile
 489         lib/graph/Makefile
 490         lib/graph/notification/Makefile
 491         lib/ctf-ir/Makefile
 492         lib/ctf-writer/Makefile
 493         include/Makefile
 494         logging/Makefile
 495         bindings/Makefile
 496         tests/Makefile
 497         tests/cli/Makefile
 498         tests/cli/intersection/Makefile
 499         tests/lib/Makefile
 500         tests/lib/writer/Makefile
 501         tests/lib/test-plugin-plugins/Makefile
 502         tests/utils/Makefile
 503         tests/utils/tap/Makefile
 504         tests/bindings/Makefile
 505         tests/bindings/python/Makefile
 506         tests/bindings/python/bt2/Makefile
 507         tests/plugins/Makefile
 508         extras/Makefile
 509         extras/valgrind/Makefile
 510         plugins/Makefile
 511         plugins/ctf/Makefile
 512         plugins/ctf/common/Makefile
 513         plugins/ctf/common/btr/Makefile
 514         plugins/ctf/common/metadata/Makefile
 515         plugins/ctf/common/notif-iter/Makefile
 516         plugins/ctf/fs-src/Makefile
 517         plugins/ctf/fs-sink/Makefile
 518         plugins/ctf/lttng-live/Makefile
 519         plugins/text/Makefile
 520         plugins/text/pretty/Makefile
 521         plugins/utils/Makefile
 522         plugins/utils/dummy/Makefile
 523         plugins/utils/trimmer/Makefile
 524         plugins/utils/muxer/Makefile
 525         python-plugin-provider/Makefile
 526         plugins/libctfcopytrace/Makefile
 527         plugins/lttng-utils/Makefile
 528         babeltrace.pc
 529         babeltrace-ctf.pc
 530 ])
 531
 532 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 533 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 534 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 535 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 536 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 537
 538 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 539
 540 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 541 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 542 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 543 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 544 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 545 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 546 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 547
 548 AS_IF([test "x$enable_python" = "xyes"], [
 549         AC_CONFIG_FILES(
 550                 [tests/bindings/python/bt2/testall.sh],
 551                 [chmod +x tests/bindings/python/bt2/testall.sh]
 552         )
 553 ])
 554
 555 AC_OUTPUT
 556
 557 #
 558 # Mini-report on what will be built.
 559 #
 560
 561 PPRINT_INIT
 562 PPRINT_SET_INDENT(1)
 563 PPRINT_SET_TS(38)
 564
 565 AS_ECHO
 566 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 567 AS_ECHO
 568
 569 PPRINT_SUBTITLE([System])
 570
 571 # Target architecture we're building for.
 572 target_arch=$host_cpu
 573 [
 574 for f in $CFLAGS; do
 575         if test $f = "-m32"; then
 576                 target_arch="32-bit"
 577         elif test $f = "-m64"; then
 578                 target_arch="64-bit"
 579         fi
 580 done
 581 ]
 582
 583 PPRINT_PROP_STRING([Target architecture], $target_arch)
 584
 585 AS_ECHO
 586 PPRINT_SUBTITLE([Python 3 language support])
 587 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 588 PPRINT_PROP_BOOL([Python bindings], $value)
 589 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 590 PPRINT_PROP_BOOL([Python plugin support], $value)
 591 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 592   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 593   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 594 ])
 595
 596 AS_ECHO
 597 PPRINT_SUBTITLE([Plugins])
 598 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 599 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 600 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 601 PPRINT_PROP_BOOL(['text' plugin], 1)
 602 PPRINT_PROP_BOOL(['utils' plugin], 1)
 603
 604 AS_ECHO
 605 PPRINT_SUBTITLE([Built-in features])
 606 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 607 PPRINT_PROP_BOOL([Built-in plugins], $value)
 608 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 609 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 610
 611 AS_ECHO
 612 PPRINT_SUBTITLE([Documentation])
 613 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 614 PPRINT_PROP_BOOL([HTML API documentation], $value)
 615 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 616 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 617
 618 AS_ECHO
 619 PPRINT_SUBTITLE([Logging])
 620 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 621
 622 AS_ECHO
 623 PPRINT_SUBTITLE([Testing])
 624 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 625 PPRINT_PROP_BOOL([Python bindings tests], $value)
 626
 627 report_bindir="`eval eval echo $bindir`"
 628 report_libdir="`eval eval echo $libdir`"
 629 report_sysconfdif="`eval eval echo $sysconfdir`"
 630
 631 # Print the bindir and libdir this `make install' will install into.
 632 AS_ECHO
 633 PPRINT_SUBTITLE([Install directories])
 634 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 635 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 636 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 637 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])