configure.ac

   1 dnl SPDX-License-Identifier: MIT
   2 dnl
   3 dnl Copyright (C) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 ##                     ##
   8 ## Autoconf base setup ##
   9 ##                     ##
  10
  11 AC_PREREQ([2.50])
  12
  13 m4_define([bt_version_major], [2])
  14 m4_define([bt_version_minor], [1])
  15 m4_define([bt_version_patch], [0])
  16 m4_define([bt_version_dev_stage], [-rc1])
  17 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  18 m4_define([bt_version_name], [])
  19
  20 AC_INIT([babeltrace2], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  21 AC_PROG_SED
  22
  23 # Following the numbering scheme proposed by libtool for the library version
  24 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  25 m4_define([bt_lib_version_current], [0])
  26 m4_define([bt_lib_version_revision], [0])
  27 m4_define([bt_lib_version_age], [0])
  28 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  29
  30 bt_version_description=""
  31 bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
  32
  33 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  34
  35 AC_CONFIG_HEADERS([src/common/config.h])
  36 AC_CONFIG_AUX_DIR([config])
  37 AC_CONFIG_MACRO_DIR([m4])
  38
  39 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  40 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  41 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  42 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  43 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  44 AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
  45
  46 AC_CANONICAL_TARGET
  47 AC_CANONICAL_HOST
  48
  49
  50 ##                     ##
  51 ## Automake base setup ##
  52 ##                     ##
  53
  54 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  55 AM_MAINTAINER_MODE([enable])
  56
  57 # Enable silent rules if available (Introduced in AM 1.11)
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  59
  60
  61 ##                      ##
  62 ## OS specific defaults ##
  63 ##                      ##
  64
  65 MINGW32=no
  66 DEFAULT_ENABLE_DEBUG_INFO=yes
  67 LT_NO_UNDEFINED=""
  68 AS_CASE([$host_os],
  69   [solaris*|darwin*],
  70     [
  71         DEFAULT_ENABLE_DEBUG_INFO=no
  72     ],
  73   [cygwin*],
  74     [
  75         DEFAULT_ENABLE_DEBUG_INFO=no
  76         LT_NO_UNDEFINED="-no-undefined"
  77     ],
  78   [mingw*],
  79     [
  80         MINGW32=yes
  81         DEFAULT_ENABLE_DEBUG_INFO=no
  82         LT_NO_UNDEFINED="-no-undefined"
  83     ]
  84 )
  85
  86 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  87 AC_SUBST(LT_NO_UNDEFINED)
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 AC_USE_SYSTEM_EXTENSIONS
  95 AC_SYS_LARGEFILE
  96
  97 # Choose the c compiler
  98 AC_PROG_CC
  99
 100 # Make sure the c compiler supports C99
 101 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 102
 103 # Make sure the c compiler supports __attributes__
 104 AX_C___ATTRIBUTE__
 105 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 106   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 # Make sur we have pthread support
 109 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 110
 111 # Checks for typedefs, structures, and compiler characteristics.
 112 AC_C_INLINE
 113 AC_C_TYPEOF
 114 AC_TYPE_PID_T
 115 AC_TYPE_SIZE_T
 116 AC_TYPE_INT16_T
 117 AC_TYPE_INT32_T
 118 AC_TYPE_INT64_T
 119 AC_TYPE_INT8_T
 120 AC_TYPE_OFF_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UINT16_T
 123 AC_TYPE_UINT32_T
 124 AC_TYPE_UINT64_T
 125 AC_TYPE_UINT8_T
 126 AC_CHECK_TYPES([ptrdiff_t])
 127
 128
 129 ##               ##
 130 ## Header checks ##
 131 ##               ##
 132
 133 AC_HEADER_STDBOOL
 134 AC_CHECK_HEADERS([ \
 135         fcntl.h \
 136         float.h \
 137         ftw.h \
 138         libintl.h \
 139         limits.h \
 140         malloc.h \
 141         netdb.h \
 142         netinet/in.h \
 143         stddef.h \
 144         sys/socket.h \
 145         sys/time.h
 146 ])
 147
 148
 149 ##               ##
 150 ## Linker checks ##
 151 ##               ##
 152
 153 # Check if the linker supports no-as-needed
 154 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 155 AC_SUBST([LD_NO_AS_NEEDED])
 156
 157 # Check if the linker supports whole-archive
 158 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 159   [
 160     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 161     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 162   ],[
 163     # Fallback to force_load for the macOS linker
 164     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 165       [
 166         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 167         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 168       ],[
 169         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 170       ]
 171     )
 172   ]
 173 )
 174
 175 # Initialize and configure libtool
 176 LT_INIT([win32-dll])
 177
 178
 179 ##                 ##
 180 ## Programs checks ##
 181 ##                 ##
 182
 183 AC_PROG_MAKE_SET
 184 AC_PROG_MKDIR_P
 185 AC_PROG_LN_S
 186 AC_PATH_PROG([report_fold], [fold])
 187
 188 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 189 # is not distributed in tarballs
 190 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 191 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 192
 193 # check for bison
 194 AC_PROG_YACC
 195 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 196
 197 AS_IF([test "x$have_bison" != "xyes"], [
 198   AS_IF([test "x$in_git_repo" = "xyes"], [
 199     AC_MSG_FAILURE([dnl
 200 Bison >= 2.4 is required when building from the Git repository. You can
 201 set the YACC variable to override automatic detection.
 202     ])
 203   ], [
 204     AC_MSG_WARN([dnl
 205 Missing Bison >= 2.4. Note that the parser files are already built in
 206 this distribution tarball, so Bison is only needed if you intend to
 207 modify their sources. You can set the YACC variable to override automatic
 208 detection.
 209     ])
 210   ])
 211 ])
 212 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 213
 214 # check for flex
 215 AC_PROG_LEX
 216 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 217
 218 AS_IF([test "x$have_flex" != "xyes"], [
 219   AS_IF([test "x$in_git_repo" = "xyes"], [
 220     AC_MSG_FAILURE([dnl
 221 Flex >= 2.5.35 is required when building from the Git repository. You can
 222 set the LEX variable to override automatic detection.
 223     ])
 224   ], [
 225     AC_MSG_WARN([dnl
 226 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 227 this distribution tarball, so Flex is only needed if you intend to
 228 modify their sources. You can set the LEX variable to override automatic
 229 detection.
 230     ])
 231   ])
 232 ])
 233 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 234
 235
 236 ##                ##
 237 ## Library checks ##
 238 ##                ##
 239
 240 # Check what libraries are required on this platform to link sockets programs.
 241 AX_LIB_SOCKET_NSL
 242
 243 # Check for glib >= 2.28 with gmodule support
 244 AM_PATH_GLIB_2_0([2.28.0], [],
 245   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 246   [gmodule-no-export]
 247 )
 248
 249 # Checks for library functions.
 250 AC_FUNC_ALLOCA
 251 AC_FUNC_FORK
 252 AC_FUNC_MKTIME
 253 AC_FUNC_MMAP
 254 AC_FUNC_STRERROR_R
 255 AC_FUNC_STRNLEN
 256 AC_CHECK_FUNCS([ \
 257         atexit \
 258         dup2 \
 259         ftruncate \
 260         gethostbyname \
 261         gettimeofday \
 262         localtime_r \
 263         memchr \
 264         memset \
 265         mkdir \
 266         mkdtemp \
 267         munmap \
 268         rmdir \
 269         setenv \
 270         socket \
 271         strchr \
 272         strdup \
 273         strerror \
 274         strndup \
 275         strnlen \
 276         strrchr \
 277         strstr \
 278         strtoul \
 279         strtoull \
 280         tzset \
 281 ])
 282
 283 # AC_FUNC_MALLOC causes problems when cross-compiling.
 284 #AC_FUNC_MALLOC
 285 #AC_FUNC_REALLOC
 286
 287 # Check for fmemopen
 288 AC_CHECK_LIB([c], [fmemopen],
 289   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 290 )
 291
 292 # Check for open_memstream
 293 AC_CHECK_LIB([c], [open_memstream],
 294   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 295 )
 296
 297 # Check for posix_fallocate
 298 AC_CHECK_LIB([c], [posix_fallocate],
 299   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 300 )
 301
 302 ##                 ##
 303 ## User variables  ##
 304 ##                 ##
 305
 306 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 307 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 308 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 309
 310 # BABELTRACE_PLUGINS_DIR: Plugins directory
 311 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 312 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 313
 314 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 315 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 316 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 317
 318 # BABELTRACE_MINIMAL_LOG_LEVEL:
 319 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 320 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 321 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 322        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 323        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 324   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 325 )
 326 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 327
 328 # BABELTRACE_DEV_MODE:
 329 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 330 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 331         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 332 ], [BABELTRACE_DEV_MODE=0])
 333 AM_CONDITIONAL([DEV_MODE], [test "x$BABELTRACE_DEV_MODE" = x1])
 334
 335 # BABELTRACE_DEBUG_MODE:
 336 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 337 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 338         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 339 ], [BABELTRACE_DEBUG_MODE=0])
 340
 341
 342 ##                              ##
 343 ## Optionnal features selection ##
 344 ##                              ##
 345
 346 # Python bindings
 347 # Disabled by default
 348 AC_ARG_ENABLE([python-bindings],
 349   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 350   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 351   [enable_python_bindings=unspecified]
 352 )
 353
 354 # Python bindings documentation
 355 # Disabled by default
 356 AC_ARG_ENABLE([python-bindings-doc],
 357   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 358   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 359   [enable_python_bindings_doc=no]
 360 )
 361
 362 # Python plugins
 363 # Disabled by default
 364 AC_ARG_ENABLE([python-plugins],
 365   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])]
 366   dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 367 )
 368
 369 # Debug info
 370 # Enabled by default, except on some platforms
 371 AC_ARG_ENABLE([debug-info],
 372   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 373   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 374   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 375 )
 376
 377 # API documentation
 378 # Disabled by default
 379 AC_ARG_ENABLE([api-doc],
 380   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 381   [enable_api_doc=$enableval]
 382 )
 383
 384 # Built-in plugins
 385 # Disabled by default
 386 AC_ARG_ENABLE([built-in-plugins],
 387   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])]
 388   dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 389 )
 390
 391 # Built-in python plugin support
 392 # Disabled by default
 393 AC_ARG_ENABLE([built-in-python-plugin-support],
 394   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])]
 395   dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 396 )
 397
 398 # Man pages
 399 # Enabled by default
 400 AC_ARG_ENABLE([man-pages],
 401   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 402   [], dnl AC_ARG_ENABLE will fill enable_man_pages with the user choice
 403   [enable_man_pages=yes]
 404 )
 405
 406
 407 # Set automake variables for optionnal feature conditionnals in Makefile.am
 408 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 409 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 410 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 411 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 412 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 413 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 414 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 415 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 416 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 417
 418 # Set defines for optionnal features conditionnals in the source code
 419
 420 AS_IF([test "x$enable_built_in_plugins" = xyes],
 421   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 422 )
 423
 424 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 425   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 426 )
 427
 428 AS_IF([test "x$enable_debug_info" = xyes],
 429   [ENABLE_DEBUG_INFO_VAL=1],
 430   [ENABLE_DEBUG_INFO_VAL=0]
 431 )
 432
 433 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 434
 435 # Check for conflicting Python related features user choices.
 436 AS_IF([test "x$enable_python_plugins" = xyes],
 437   [
 438     AS_IF([test "x$enable_python_bindings" = xunspecified],
 439       [
 440         # --enable-python-plugins was provided but --enable-python-bindings was
 441         # omitted. Turn the Python bindings ON anyway because it's needed to
 442         # use the Python plugins.
 443         enable_python_bindings=yes
 444       ],
 445       [
 446         AS_IF([test "x$enable_python_bindings" = xno],
 447           [
 448             # --enable-python-plugins _and_ --disable-python-bindings were
 449             # used. This is invalid because Python plugins need the Python
 450             # bindings to be useful.
 451             AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
 452           ]
 453         )
 454       ]
 455     )
 456   ]
 457 )
 458
 459 # Check for conflicting optional features user choices
 460
 461 AS_IF([test "x$enable_built_in_plugins" = xyes],
 462   [
 463     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 464     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 465     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 466   ]
 467 )
 468
 469 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 470   [
 471     AS_IF([test "x$enable_python_plugins" != xyes], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 472     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 473     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 474     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 475   ]
 476 )
 477
 478
 479 # Check for optionnal features dependencies
 480
 481 AS_IF([test "x$enable_python_bindings" = xyes],
 482   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 483 )
 484
 485 AM_PATH_PYTHON([3.0], [
 486   AM_PATH_PYTHON_MODULES([PYTHON])
 487
 488   # pythondir is the path where extra modules are to be installed
 489   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 490
 491   # pyexecdir is the path that contains shared objects used by the extra modules
 492   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 493
 494   AS_IF([test -z "$PYTHON_CONFIG"], [
 495     AC_PATH_PROGS([PYTHON_CONFIG],
 496                   [python$PYTHON_VERSION-config python-config],
 497                   [],
 498                   [`dirname $PYTHON`])
 499   ])
 500
 501   AS_IF([test -n "$PYTHON_CONFIG"], [
 502     AS_IF([test -z "$PYTHON_INCLUDE"], [
 503       AC_MSG_CHECKING([Python include flags])
 504       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 505       AC_MSG_RESULT([$PYTHON_INCLUDE])
 506     ])
 507
 508     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 509       AC_MSG_CHECKING([Python library flags])
 510       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 511       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 512         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 513       ])
 514       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 515     ])
 516   ])
 517 ], [:])
 518
 519 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 520 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 521
 522 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 523 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 524
 525 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 526   AS_IF([test "x$have_python_dev" = xno], [
 527     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 528   ])
 529 ])
 530
 531 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 532   [
 533     AM_CHECK_PYTHON_SPHINX([PYTHON])
 534     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno], [
 535       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])
 536     ])
 537
 538     AS_IF([test "x$enable_python_bindings" != xyes], [
 539       AC_MSG_ERROR([The Python bindings are required to build their documentation])
 540     ])
 541   ]
 542 )
 543
 544 AS_IF([test "x$enable_debug_info" = xyes],
 545   [
 546     # Check if libelf and libdw are present
 547     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 548     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 549     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 550     ELFUTILS_LIBS="-lelf -ldw"
 551   ]
 552 )
 553 AC_SUBST([ELFUTILS_LIBS])
 554
 555 AS_IF([test "x$enable_api_doc" = "xyes"],
 556   [
 557     DX_DOXYGEN_FEATURE(ON)
 558     DX_DOT_FEATURE(OFF)
 559     DX_HTML_FEATURE(ON)
 560     DX_CHM_FEATURE(OFF)
 561     DX_CHI_FEATURE(OFF)
 562     DX_MAN_FEATURE(OFF)
 563     DX_RTF_FEATURE(OFF)
 564     DX_XML_FEATURE(OFF)
 565     DX_PDF_FEATURE(OFF)
 566     DX_PS_FEATURE(OFF)
 567     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 568     AS_IF([test -z "$DX_DOXYGEN"],
 569           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 570     )
 571   ]
 572 )
 573
 574 have_asciidoc_xmlto=no
 575 warn_prebuilt_man_pages=no
 576
 577 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 578 AC_PATH_PROG([XMLTO], [xmlto], [no])
 579
 580 AS_IF([test "x$enable_man_pages" = "xyes"], [
 581   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 582     AS_IF([test "x$in_git_repo" = "xyes"], [
 583       # this is an error because we're in the Git repo, which
 584       # means the man pages are not already generated for us,
 585       # thus asciixmlto are required because we were asked
 586       # to build the man pages
 587       AC_MSG_ERROR([
 588 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 589 --disable-man-pages to disable building the man pages, in which case
 590 they will not be installed.
 591       ])
 592     ], [
 593       # only warn here: since we're in the tarball, the man
 594       # pages should already be generated at this point, thus
 595       # asciidoc/xmlto are not strictly required
 596       warn_prebuilt_man_pages=yes
 597     ])
 598   ], [
 599     have_asciidoc_xmlto=yes
 600   ])
 601 ])
 602
 603 # export AsciiDoc and xmlto existence
 604 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 605
 606 # a wonderful hack that seems necessary because $libdir is
 607 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 608 # by autoconf when it's not specified by the user
 609 AS_IF([test "x$exec_prefix" = xNONE], [
 610   AS_IF([test "x$prefix" = xNONE], [
 611     PREFIX="$ac_default_prefix"
 612   ], [
 613     PREFIX="$prefix"
 614   ])
 615
 616   LIBDIR="$PREFIX/lib"
 617 ], [
 618   LIBDIR="$libdir"
 619 ])
 620
 621 AC_SUBST(LIBDIR)
 622
 623 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 624 # test).
 625 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 626
 627 # Check that the current size_t matches the size that glib thinks it should
 628 # be. This catches problems on multi-arch where people try to do a 32-bit
 629 # build while pointing at 64-bit glib headers. This is a common error because
 630 # glib.h is not platform specific but it includes glibconfig.h which is and
 631 # is usually installed in a non-standard path.
 632
 633 # Do this before enabling all the warning flags, as the
 634 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 635 # test fail unnecessarily.
 636
 637 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 638 # output. Specifically allow pkg_config_libdir to be able to print the
 639 # error message.
 640 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 641
 642 save_CFLAGS=${CFLAGS}
 643 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 644 AC_COMPILE_IFELSE([
 645   AC_LANG_PROGRAM([dnl
 646 #include <glib.h>
 647 #include <unistd.h>
 648   ], [dnl
 649 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 650   ])
 651 ],[:],[
 652   AC_MSG_ERROR([dnl
 653 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 654 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 655 target.
 656   ])
 657 ])
 658 CFLAGS=${save_CFLAGS}
 659
 660 # Detect C and LD warning flags supported by the compiler.
 661
 662 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
 663 #
 664 # Pass -Werror as an extra flag during the test: this is needed to make the
 665 # -Wunknown-warning-option diagnostic fatal with clang.
 666 AX_APPEND_COMPILE_FLAGS([ dnl
 667                 -Wall dnl
 668                 -Wextra dnl
 669                 -Wstrict-prototypes dnl
 670                 -Wmissing-prototypes dnl
 671                 -Wmissing-declarations dnl
 672                 -Wnull-dereference dnl
 673                 -Wundef dnl
 674                 -Wredundant-decls dnl
 675                 -Wshadow dnl
 676                 -Wjump-misses-init dnl
 677                 -Wsuggest-attribute=format dnl
 678                 -Wtautological-constant-out-of-range-compare dnl
 679                 -Wnested-externs dnl
 680                 -Wwrite-strings dnl
 681                 -Wformat=2 dnl
 682                 -Wstrict-aliasing dnl
 683                 -Wmissing-noreturn dnl
 684                 -Winit-self dnl
 685                 -Wduplicated-cond dnl
 686                 -Wduplicated-branches dnl
 687                 -Wlogical-op dnl
 688                 -Wno-unused-parameter dnl
 689                 -Wno-sign-compare dnl
 690                 dnl
 691                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 692                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 693                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 694                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 695                 dnl It's simpler to just disable the warning globally.
 696                 dnl
 697                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 698                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 699                 dnl reproduce the warning using that package.
 700                 dnl
 701                 dnl Ref: https://github.com/swig/swig/issues/1259
 702                 -Wno-cast-function-type dnl
 703                 -Wno-missing-field-initializers dnl
 704         ],
 705         [WARN_CFLAGS],
 706         [-Werror])
 707
 708 # When given, add -Werror to WARN_CFLAGS.
 709 AC_ARG_ENABLE([Werror],
 710         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
 711 )
 712 AS_IF([test "x$enable_Werror" = "xyes"],
 713         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
 714 )
 715
 716 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 717 # written in such a way that it triggers a -Wold-style-definition warning.  So
 718 # this warning always ends up disabled if we put it there, because the test
 719 # program does not build.
 720 #
 721 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 722 # (it is accepted for compatibility although it has no effect), and there is
 723 # not reason to not want it.
 724
 725 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition"
 726
 727 # CFLAGS from AX_APPEND_COMPILE_FLAGS.
 728 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 729
 730 # Done for AM_CFLAGS.
 731 AC_SUBST(AM_CFLAGS)
 732
 733 # Set global CPPFLAGS in AM_CPPFLAGS
 734 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 735 AC_SUBST(AM_CPPFLAGS)
 736
 737 # Add glib to global link libs
 738 LIBS="$LIBS $GLIB_LIBS"
 739
 740 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 741 # to rename babeltrace2.bin to babeltrace2 at install time.
 742 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 743 AC_SUBST(program_transform_name)
 744
 745 AC_CONFIG_FILES([
 746         doc/api/Makefile
 747         doc/api/libbabeltrace2/Doxyfile
 748         doc/api/libbabeltrace2/Makefile
 749         doc/bindings/Makefile
 750         doc/bindings/python/Makefile
 751         doc/contributing-images/Makefile
 752         doc/Makefile
 753         doc/man/asciidoc-attrs.conf
 754         doc/man/Makefile
 755         include/Makefile
 756         Makefile
 757         src/argpar/Makefile
 758         src/autodisc/Makefile
 759         src/babeltrace2-ctf-writer.pc
 760         src/babeltrace2.pc
 761         src/bindings/Makefile
 762         src/bindings/python/bt2/bt2/version.py
 763         src/bindings/python/bt2/Makefile
 764         src/bindings/python/bt2/setup.py
 765         src/bindings/python/Makefile
 766         src/cli/Makefile
 767         src/common/Makefile
 768         src/compat/Makefile
 769         src/ctfser/Makefile
 770         src/ctf-writer/Makefile
 771         src/fd-cache/Makefile
 772         src/lib/graph/Makefile
 773         src/lib/graph/message/Makefile
 774         src/lib/Makefile
 775         src/lib/plugin/Makefile
 776         src/lib/prio-heap/Makefile
 777         src/lib/trace-ir/Makefile
 778         src/logging/Makefile
 779         src/Makefile
 780         src/plugins/common/Makefile
 781         src/plugins/common/muxing/Makefile
 782         src/plugins/common/param-validation/Makefile
 783         src/plugins/ctf/common/bfcr/Makefile
 784         src/plugins/ctf/common/Makefile
 785         src/plugins/ctf/common/metadata/Makefile
 786         src/plugins/ctf/common/msg-iter/Makefile
 787         src/plugins/ctf/fs-sink/Makefile
 788         src/plugins/ctf/fs-src/Makefile
 789         src/plugins/ctf/lttng-live/Makefile
 790         src/plugins/ctf/Makefile
 791         src/plugins/lttng-utils/debug-info/Makefile
 792         src/plugins/lttng-utils/Makefile
 793         src/plugins/Makefile
 794         src/plugins/text/dmesg/Makefile
 795         src/plugins/text/Makefile
 796         src/plugins/text/pretty/Makefile
 797         src/plugins/text/details/Makefile
 798         src/plugins/utils/counter/Makefile
 799         src/plugins/utils/dummy/Makefile
 800         src/plugins/utils/Makefile
 801         src/plugins/utils/muxer/Makefile
 802         src/plugins/utils/trimmer/Makefile
 803         src/py-common/Makefile
 804         src/python-plugin-provider/Makefile
 805         src/param-parse/Makefile
 806         src/string-format/Makefile
 807         tests/bitfield/Makefile
 808         tests/ctf-writer/Makefile
 809         tests/lib/Makefile
 810         tests/lib/test-plugin-plugins/Makefile
 811         tests/lib/conds/Makefile
 812         tests/Makefile
 813         tests/param-validation/Makefile
 814         tests/plugins/Makefile
 815         tests/plugins/src.ctf.fs/Makefile
 816         tests/plugins/src.ctf.fs/succeed/Makefile
 817         tests/plugins/sink.ctf.fs/Makefile
 818         tests/plugins/sink.ctf.fs/succeed/Makefile
 819         tests/plugins/flt.lttng-utils.debug-info/Makefile
 820         tests/plugins/flt.utils.muxer/Makefile
 821         tests/plugins/flt.utils.muxer/succeed/Makefile
 822         tests/plugins/flt.utils.trimmer/Makefile
 823         tests/utils/Makefile
 824         tests/utils/tap/Makefile
 825 ])
 826
 827 AC_OUTPUT
 828
 829 #
 830 # Mini-report on what will be built.
 831 #
 832
 833 PPRINT_INIT
 834 PPRINT_SET_INDENT(1)
 835 PPRINT_SET_TS(38)
 836
 837 AS_ECHO
 838
 839 AS_IF([test -n "bt_version_name"], [
 840         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 841 ], [
 842         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 843 ])
 844
 845 AS_ECHO
 846
 847 AS_IF([test -n "$bt_version_description"], [
 848         AS_IF([test -n "$report_fold"], [
 849                 AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
 850         ], [
 851                 AS_ECHO("$bt_version_description")
 852         ])
 853
 854         AS_ECHO
 855 ])
 856
 857 PPRINT_SUBTITLE([System])
 858
 859 # Target architecture we're building for.
 860 target_arch=$host_cpu
 861 [
 862 for f in $CFLAGS; do
 863         if test $f = "-m32"; then
 864                 target_arch="32-bit"
 865         elif test $f = "-m64"; then
 866                 target_arch="64-bit"
 867         fi
 868 done
 869 ]
 870
 871 PPRINT_PROP_STRING([Target architecture], $target_arch)
 872
 873 AS_ECHO
 874 PPRINT_SUBTITLE([Python 3 language support])
 875 test "x$have_python" = "xyes" && value=1 || value=0
 876 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 877 test "x$have_python_dev" = "xyes" && value=1 || value=0
 878 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 879 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 880 PPRINT_PROP_BOOL_CUSTOM([Python bindings], $value, [To enable, use --enable-python-bindings])
 881 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 882 PPRINT_PROP_BOOL_CUSTOM([Python plugin support], $value, [To enable, use --enable-python-plugins])
 883 AS_IF([test "x$have_python" = "xyes"], [
 884   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 885 ])
 886 AS_IF([test "x$have_python_dev" = "xyes"], [
 887   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 888   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 889   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 890 ])
 891 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 892   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 893   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 894 ])
 895
 896 AS_ECHO
 897 PPRINT_SUBTITLE([Plugins])
 898 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 899 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 900 PPRINT_PROP_BOOL_CUSTOM(['lttng-utils' plugin], $value, [To enable, use --enable-debug-info])
 901 PPRINT_PROP_BOOL(['text' plugin], 1)
 902 PPRINT_PROP_BOOL(['utils' plugin], 1)
 903
 904 AS_ECHO
 905 PPRINT_SUBTITLE([Built-in features])
 906 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 907 PPRINT_PROP_BOOL_CUSTOM([Built-in plugins], $value, [To enable, use --enable-built-in-plugins])
 908 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 909 PPRINT_PROP_BOOL_CUSTOM([Built-in Python plugin support], $value, [To enable, use --enable-built-in-python-plugin-support])
 910
 911 AS_ECHO
 912 PPRINT_SUBTITLE([Documentation])
 913
 914 # man pages build enabled/disabled
 915 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 916
 917 AS_IF([test "x$enable_man_pages" != "xno"], [
 918   AS_IF([test "x$in_git_repo" = "xyes"], [
 919     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 920   ], [
 921     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 922       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 923     ], [
 924       PPRINT_PROP_STRING([build_man_pages_msg],
 925         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 926         $PPRINT_COLOR_SUBTITLE)
 927     ])
 928   ])
 929 ], [
 930   PPRINT_PROP_BOOL_CUSTOM([build_man_pages_msg], 0, [To build man pages, use --enable-man-pages])
 931 ])
 932
 933 m4_popdef([build_man_pages_msg])
 934
 935 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 936 PPRINT_PROP_BOOL_CUSTOM([HTML API documentation], $value, [To build documentation, use --enable-api-doc])
 937 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 938 PPRINT_PROP_BOOL_CUSTOM([Python bindings documentation], $value, [To build the Python bindings documentation, use --enable-python-bindings-doc])
 939
 940 AS_ECHO
 941 PPRINT_SUBTITLE([Logging])
 942 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 943
 944 AS_ECHO
 945 PPRINT_SUBTITLE([Special build modes])
 946 PPRINT_PROP_BOOL_CUSTOM([Debug mode], $BABELTRACE_DEBUG_MODE, [To enable, set the BABELTRACE_DEBUG_MODE environment variable to 1])
 947 PPRINT_PROP_BOOL_CUSTOM([Developer mode], $BABELTRACE_DEV_MODE, [To enable, set the BABELTRACE_DEV_MODE environment variable to 1])
 948
 949 report_bindir="`eval eval echo $bindir`"
 950 report_libdir="`eval eval echo $libdir`"
 951 report_sysconfdif="`eval eval echo $sysconfdir`"
 952 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 953 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 954
 955 # Print the bindir and libdir this `make install' will install into.
 956 AS_ECHO
 957 PPRINT_SUBTITLE([Install directories])
 958 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 959 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 960 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 961 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 962 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])